IFS() Excel: Pelajari Cara Menyederhanakan Banyak Kondisi

Jika Anda pernah mencoba membuat rumus logika yang kompleks di Excel, Anda tahu betapa berantakannya hal itu. Hal tersulit dari pernyataan IF() bertingkat adalah menentukan kondisi mana yang ditempatkan di mana.

Itulah sebabnya Excel memperkenalkan fungsi baru bernama IFS(). Ini adalah cara yang lebih rapi dan sederhana untuk memeriksa banyak kondisi tanpa membuat diri Anda kebingungan. Saya akan memandu Anda cara kerja IFS(), dengan contoh dan kiat agar Anda menggunakannya dengan percaya diri.

Apa Itu Fungsi IFS() di Excel?

Fungsi IFS() membantu kita memeriksa banyak kondisi secara bersamaan. Fungsi ini menelusuri setiap kondisi sesuai urutan yang Anda tulis, dan memberikan hasil untuk kondisi pertama yang bernilai TRUE.

Jadi ini adalah cara yang lebih mudah untuk menulis sekumpulan rumus IF() bertingkat yang dulu berantakan. Alih-alih menumpuk banyak fungsi IF() di dalam satu sama lain, IFS() mencantumkan semua kondisi Anda di satu tempat. Secara total, Anda dapat menambahkan hingga 127 pasangan kondisi-hasil, meskipun kecil kemungkinan Anda akan membutuhkan sebanyak itu.

Cara kerja fungsi IFS()

Sintaksnya adalah:

=IFS(logical_test1, value_if_true1, [logical_test2, value_if_true2]…)Didukung oleh

Penjelasannya:

• logical_test1 (wajib) adalah kondisi pertama.

• value_if_true1(wajib) mengembalikan hasil jika logical_test1 bernilai TRUE.

• 126 argumen logical_test dan value_if_true sisanya bersifat opsional.

Cara Menggunakan IFS() di Excel

Fungsi IFS() mengembalikan hasil berbeda berdasarkan kondisi. Anda dapat menggunakan operator logika seperti =, <, >, <=, dan >= untuk membangun logika Anda. Berikut cara memulainya.

Opsi 1: Gunakan Formula Wizard

Untuk menggunakan Formula Wizard: 

1. Klik sel tempat Anda ingin menaruh rumus.

2. Buka tab Formulas dan pilih Insert Function.

3. Di kotak pencarian, ketik IFS dan klik Go.

4. Pilih IFS, klik OK, lalu masukkan kondisi dan hasil Anda.

5. Klik OK lagi untuk menerapkan rumus.

Ini adalah cara cepat untuk membangun rumus tanpa harus mengetiknya sendiri.

Gunakan Formula Wizard untuk menerapkan fungsi IFS(). Gambar oleh Penulis.

Opsi 2: Tulis secara manual

Anda juga bisa menulis rumus secara manual. Ini mungkin yang paling sering dilakukan orang. Yang perlu Anda lakukan hanyalah mengetik =IFS( di sel dan membangun logika selangkah demi selangkah. Misalkan Anda menetapkan metode pengiriman berdasarkan waktu pengantaran:

• Jika 2 hari atau kurang, maka Express

• Jika 3 hingga 5 hari, maka Standard

Untuk ini, berikut rumusnya:

=IFS(B2<=2, "Express", B2<=5, "Standard")Didukung oleh

Terapkan rumus IFS() pada sebuah sel. Gambar oleh Penulis.

Anda juga dapat menyalin rumus ke sel lain. Caranya, seret kotak kecil di sudut bawah sel ( fill handle). Ini akan menerapkan rumus ke bawah kolom. Atau cukup klik ganda untuk mengisi otomatis berdasarkan data Anda.

Kiat Pro: Excel akan otomatis memperbarui referensi sel saat Anda menyalin rumus. Jika Anda ingin mempertahankan referensi agar tetap tetap, ubah menjadi referensi absolut dengan menekan F4 (mengubah A1 menjadi $A$1).

Salin rumus ke bawah menggunakan file handle. Gambar oleh Penulis

Namun muncul galat #N/A di satu sel karena tidak ada kondisi yang terpenuhi. Untuk memperbaikinya, tambahkan kondisi terakhir menggunakan TRUE di akhir rumus. Ini bekerja seperti rencana cadangan; menangkap apa pun yang tidak cocok sebelumnya dan memberikan hasil bawaan sebagai gantinya. 

=IFS(B2<=2, "Express", B2<=5, "Standard", TRUE, "Economy")Didukung oleh

Ini menghilangkan galat #N/A dan mengembalikan nilai default.

Tangani galat #N/A menggunakan kondisi ELSE terakhir. Gambar oleh Penulis.

Contoh Penggunaan IFS() dalam Aksi

Sekarang mari lihat beberapa contoh dunia nyata, tempat sebagian besar orang menggunakan fungsi ini.

Penetapan nilai

Anda dapat menggunakan IFS() untuk mengonversi skor siswa menjadi nilai huruf. Misalkan Anda memiliki daftar siswa dan nilai ujian mereka. Anda dapat menggunakan rumus ini untuk mengubah angka-angka tersebut menjadi nilai:

=IFS(C5<60,"F", C5<70,"D", C5<80,"C", C5<90,"B", C5>=90,"A")Didukung oleh

Berikut yang dilakukan rumus ini:

• Jika skor kurang dari 60, hasilnya F.

• Jika kurang dari 70, hasilnya D.

• Jika kurang dari 80, hasilnya C.

• Jika kurang dari 90, Anda mendapat B.

• Jika 90 atau lebih, hasilnya A.

Excel memeriksa setiap kondisi secara berurutan, dan berhenti segera setelah menemukan yang bernilai TRUE. Meskipun lebih dari satu kondisi bisa berlaku, hanya kecocokan pertama yang dihitung.

Tetapkan nilai untuk siswa menggunakan IFS(). Gambar oleh Penulis.

Penanganan galat dengan TRUE

Anda juga dapat menggunakan IFS() untuk menampilkan pesan khusus berdasarkan berbagai kode status alih-alih membiarkan Excel menampilkan galat #N/A. Misalnya, jika Anda memiliki daftar kode dan ingin menampilkan pesan berdasarkan masing-masing kode, berikut rumus yang bisa digunakan:

=IFS(A2=100,"OK", A2=200,"Warning", A2=300,"Error", TRUE,"Invalid")Didukung oleh

Cara kerjanya:

• Jika kodenya 100, tampil OK.

• Jika 200, tampil Warning.

• Jika 300, tampil Error.

• Jika tidak cocok dengan salah satunya, tampil Invalid.

Bagian terakhir itu penting. Pesan akan ditampilkan berdasarkan kode. Jika tidak ada kecocokan yang tepat, kondisi terakhir TRUE bertindak sebagai cadangan dan mengembalikan Invalid.

Tampilkan pesan berdasarkan kode menggunakan fungsi IFS(). Gambar oleh Penulis.

Label teks bersyarat

Anda juga dapat menggunakan IFS() untuk mengelompokkan item ke dalam kategori seperti buah, sayuran, atau minuman untuk memantau saat item baru ditambahkan.

Berikut rumus sederhana untuk melakukannya:

=IFS(A2="Grapes","Fruit", A2="Broccoli","Green Vegetable", A2="Tea","Beverage", TRUE,"Misc")Didukung oleh

Inilah yang dilakukan:

• Jika itemnya Grapes, tampil Fruit.

• Jika Broccoli, tampil Green Vegetable.

• Jika Tea, tampil Beverage.

• Jika tidak cocok dengan salah satunya, tampil Misc.

Baris terakhir (dengan TRUE) adalah opsi cadangan Anda. Ini menangkap apa pun yang tidak cocok dengan kategori lain.

Kategorikan item menggunakan IFS(). Gambar oleh Penulis.

Pemodelan keuangan

Kita juga dapat menggunakan IFS() untuk keperluan pemodelan keuangan. Mari lihat dua contoh umum:

Menerapkan tingkat diskon

Anda dapat menggunakan IFS() untuk menetapkan diskon berdasarkan total nilai pembelian pelanggan.

=IFS(B2>=500,"20% Discount", B2>=300,"10% Discount", B2>=100,"5% Discount", TRUE,"No Discount")Didukung oleh

Begini cara kerjanya:

• Jika jumlahnya sama dengan atau lebih besar dari 500, mengembalikan 20% Discount

• Jika jumlahnya sama dengan atau lebih besar dari 300, mengembalikan 10% Discount.

• Jika jumlahnya sama dengan atau lebih besar dari 100, mengembalikan 5% Discount.

• Jika jumlahnya kurang dari 100, kondisi akhir TRUE mengembalikan No Discount.

Terapkan diskon menggunakan IFS(). Gambar oleh Penulis.

Menghitung hari cuti

Anda juga dapat menghitung berapa banyak hari cuti yang berhak didapat karyawan, berdasarkan lamanya mereka bekerja di perusahaan. Untuk melakukannya, gunakan rumus berikut:

=IFS(B2>=10,"30 Days", B2>=5,"20 Days", B2>=1,"10 Days", TRUE,"No Leave")Didukung oleh

Berikut rinciannya:

• 10 tahun atau lebih berarti cuti 30 Days.

• 5 hingga 9 tahun berarti 20 Days.

• 1 hingga 4 tahun berarti 10 Days.

• Kurang dari 1 tahun berarti No Leave.

Tetapkan hari cuti berdasarkan masa kerja menggunakan IFS(). Gambar oleh Penulis.

Konversi data

Anda juga dapat menggunakan IFS() untuk mengonversi ukuran file dari byte ke satuan yang lebih mudah dibaca seperti KB, MB, atau GB:

=IFS(B2<1024, B2 & " Bytes", B2<1048576, ROUND(B2/1024,1) & " KB", B2<1073741824, ROUND(B2/1048576,1) & " MB", TRUE, ROUND(B2/1073741824,1) & " GB")Didukung oleh

Rumus ini menampilkan:

• Bytes untuk nilai di bawah 1024

• KB untuk nilai di bawah 1 MB

• MB untuk nilai di bawah 1 GB

• GB untuk apa pun yang lebih besar

Konversi ukuran file dari byte ke KB, MB, GB menggunakan IFS(). Gambar oleh Penulis.

IFS() vs. IF() vs. IF() Bertingkat

Saat bekerja dengan banyak kondisi di Excel, Anda punya tiga opsi: IF(), IF() bertingkat, atau fungsi IFS(). Masing-masing bekerja berbeda, jadi berikut cara memilih yang tepat.

Perbandingan keterbacaan

Jika Anda hanya memeriksa satu atau dua kondisi, fungsi IF() dasar sudah sempurna. Cepat, sederhana, dan menyelesaikan tugas. Namun segalanya menjadi rumit saat Anda mencoba memeriksa banyak kondisi. Saat itulah kita mulai menumpuk fungsi IF() satu di dalam yang lain, yang membuat rumus lebih sulit dibaca dan bahkan lebih sulit diubah nanti.

Berikut contohnya:

=IF(A1<60,"F",IF(A1<70,"D",IF(A1<80,"C",IF(A1<90,"B","A"))))Didukung oleh

Rumus itu bekerja, tetapi tidak mudah diikuti. Semua tanda kurung itu membuatnya menantang untuk dibaca dan diperbarui.

IF() bertingkat sulit dibaca dan dipahami. Gambar oleh Penulis. 

Sekarang lihat logika yang sama menggunakan IFS() sebagai gantinya:

=IFS(A1<60,"F", A1<70,"D", A1<80,"C", A1<90,"B", A1>=90,"A")Didukung oleh

Yang ini terlihat jauh lebih sederhana. Setiap kondisi dipasangkan langsung dengan hasil tanpa ada penumpukan dan kelebihan tanda kurung. Jadi, jika Anda menginginkan rumus yang mudah dibaca, dipahami, dan diperbaiki nanti, IFS() adalah pilihan yang tepat.

IFS() jauh lebih mudah dibaca dan dipahami. Gambar oleh Penulis.

Pertimbangan performa

Fungsi IFS() memeriksa setiap kondisi yang Anda berikan, bahkan jika sudah menemukan kecocokan. Jadi jika Anda mencantumkan lima kondisi, Excel tetap mengevaluasi kelimanya.

Namun fungsi IF() bertingkat sedikit lebih cerdas. Fungsi ini menggunakan “short-circuiting,” yang berarti berhenti memeriksa segera setelah menemukan kondisi TRUE pertama. Itu menghemat sedikit waktu di spreadsheet besar dengan banyak rumus.

Perbandingan cepat: Kapan menggunakan yang mana

Berikut perbandingan tabel singkat untuk membantu Anda memahami kapan menggunakan IF(), IF() bertingkat, dan IFS():

IFS vs. SWITCH()

IFS() dan SWITCH() sama-sama memeriksa banyak kondisi dalam satu rumus mandiri, tetapi keduanya bekerja dengan cara yang berbeda. Berikut perbandingan detail keduanya:

Hal-hal yang Perlu Dipertimbangkan

Ada beberapa hal yang perlu Anda ingat saat bekerja dengan fungsi IFS() di Excel.

Galat umum dan cara memperbaikinya

Pertama, mari lihat beberapa galat umum yang mungkin Anda temui.

Argumen terlalu sedikit

Jika kita menambahkan suatu kondisi tetapi lupa menyertakan apa yang harus terjadi jika bernilai benar (value_if_true). Excel menampilkan pop-up: "You've entered too few arguments for this function."

Galat #N/A

Galat #N/A akan terjadi ketika tidak ada satu pun kondisi dalam rumus yang bernilai TRUE. Excel membutuhkan setidaknya satu yang cocok, jika tidak, akan macet. Jika Anda tidak ingin menampilkan #N/A, tambahkan TRUE di akhir dengan nilai cadangan.

Galat #VALUE!

Galat #VALUE! muncul ketika argumen logical_test tidak mengembalikan TRUE atau FALSE yang jelas. Mungkin ada salah ketik, atau mungkin kondisinya kurang tepat. Apa pun itu, Excel tidak tahu harus berbuat apa, jadi periksa kembali logika Anda.

Tips dan praktik terbaik

Sekarang, berikut beberapa praktik terbaik untuk membuat rumus Anda lebih baik dan lebih sederhana: 

• Usahakan tetap sederhana. Sepuluh kondisi atau kurang biasanya sudah cukup.

• Tambahkan kondisi cadangan menggunakan TRUE sebagai kondisi terakhir Anda. Ini mencakup kasus apa pun yang tidak memenuhi kondisi utama Anda.

• Pastikan setiap kondisi memiliki hasil, dan pengujian Anda mengembalikan TRUE atau FALSE.

• Uji rumus Anda dengan kasus tepi seperti 0, 100, atau bahkan sel kosong untuk memastikan semuanya ditangani sesuai harapan.

Kelebihan dan kekurangan

IFS() memiliki beberapa keunggulan nyata, tetapi ada juga beberapa hal yang perlu diperhatikan.

Pemikiran Akhir 

Fungsi IFS() adalah cara praktis untuk memeriksa banyak kondisi tanpa membuat rumus Anda berantakan. Fungsi ini lebih mudah dibaca daripada banyak pernyataan IF() yang ditumpuk dan membuat logika Anda jauh lebih jelas. Pastikan Anda mencantumkan kondisi dalam urutan yang tepat, dan selalu tambahkan cadangan terakhir menggunakan TRUE — dengan begitu, rumus Anda tidak akan gagal jika tidak ada yang cocok.

Jika logika Anda dapat diprediksi dan mengikuti aturan yang jelas, IFS() adalah cara yang bagus untuk menjaga spreadsheet tetap rapi dan mudah dikelola.