IFS() Excel: एक से अधिक शर्तों को सरल बनाएँ

यदि आपने कभी Excel में कोई जटिल लॉजिक फ़ॉर्मूला बनाने की कोशिश की है, तो आप जानते हैं कि यह कितना उलझ सकता है। nested IF() स्टेटमेंट्स में सबसे मुश्किल बात होती है यह समझना कि कौन-सी शर्त कहाँ जानी चाहिए।

इसीलिए Excel ने IFS() नाम का नया फ़ंक्शन पेश किया। यह कई शर्तों की जाँच करने का एक साफ़-सुथरा और सरल तरीका है, जिसमें आपको खुद को उलझाने की ज़रूरत नहीं पड़ती। मैं आपको IFS() कैसे काम करता है, इसके उदाहरणों और टिप्स के साथ समझाऊँगा, ताकि आप इसे आत्मविश्वास से इस्तेमाल कर सकें।

Excel में IFS() फ़ंक्शन क्या है?

IFS() फ़ंक्शन हमें एक साथ कई शर्तें जाँचने में मदद करता है। यह आपकी लिखी गई क्रम में हर शर्त को देखता है और पहली TRUE होने वाली शर्त के लिए परिणाम देता है।

यानी जो काम पहले उलझे हुए nested IF() फ़ॉर्मूलों से होता था, उसे लिखना अब आसान हो जाता है। कई IF() फ़ंक्शनों को एक-दूसरे के भीतर रखने के बजाय, IFS() आपकी सभी शर्तों को एक जगह सूचीबद्ध करता है। कुल मिलाकर, आप अधिकतम 127 शर्त-परिणाम जोड़े जोड़ सकते हैं, हालांकि मुझे संदेह है कि आपको इतनी अधिक शर्तों की ज़रूरत पड़ेगी।

IFS() फ़ंक्शन कैसे काम करता है

इसका सिंटैक्स है:

=IFS(logical_test1, value_if_true1, [logical_test2, value_if_true2]…)संचालित द्वारा

यहाँ:

• logical_test1 (आवश्यक) पहली शर्त है।

• value_if_true1 (आवश्यक) वह परिणाम लौटाता है यदि logical_test1 TRUE हो।

• बाकी 126 logical_test और value_if_true आर्ग्युमेंट वैकल्पिक हैं।

Excel IFS() का उपयोग कैसे करें

IFS() फ़ंक्शन शर्तों के आधार पर अलग-अलग परिणाम लौटाता है। आप लॉजिकल ऑपरेटर जैसे =, <, >, <=, और >= का उपयोग करके लॉजिक बना सकते हैं। शुरू करने का तरीका यहाँ है।

विकल्प 1: फ़ॉर्मूला विज़ार्ड का उपयोग करें

एक Formula Wizard का उपयोग करने के लिए: 

1. उस सेल पर क्लिक करें जहाँ आप अपना फ़ॉर्मूला चाहते हैं।

2. Formulas टैब में जाएँ और Insert Function चुनें।

3. सर्च बॉक्स में IFS टाइप करें और Go पर क्लिक करें।

4. IFS चुनें, OK पर क्लिक करें, फिर अपनी शर्तें और परिणाम दर्ज करें।

5. फ़ॉर्मूला लागू करने के लिए फिर से OK पर क्लिक करें।

यह बिना खुद टाइप किए जल्दी फ़ॉर्मूला बनाने का तरीका है।

IFS() फ़ंक्शन लागू करने के लिए फ़ॉर्मूला विज़ार्ड का उपयोग करें। चित्र: लेखक

विकल्प 2: मैन्युअल रूप से लिखें

आप फ़ॉर्मूला मैन्युअल रूप से भी लिख सकते हैं। प्रायः लोग यही करते हैं। आपको बस सेल में =IFS( टाइप करना है और चरण-दर-चरण अपना लॉजिक बनाना है। मान लें कि आप डिलीवरी समय के आधार पर शिपिंग विधियाँ असाइन कर रहे हैं:

• यदि यह 2 दिन या कम है, तो Express होगा

• यदि यह 3 से 5 दिन है, तो Standard होगा

इसके लिए फ़ॉर्मूला यह है:

=IFS(B2<=2, "Express", B2<=5, "Standard")संचालित द्वारा

किसी सेल में IFS() फ़ॉर्मूला लागू करें। चित्र: लेखक

आप अपना फ़ॉर्मूला अन्य सेल में भी कॉपी कर सकते हैं। ऐसा करने के लिए, सेल के कोने में बने छोटे वर्ग (the fill handle) को ड्रैग करें। इससे फ़ॉर्मूला पूरे कॉलम में लागू हो जाएगा। या इसे डबल-क्लिक करें ताकि यह आपके डेटा के आधार पर अपने-आप भर जाए।

प्रो टिप: जब आप किसी फ़ॉर्मूले को कॉपी करते हैं, तो Excel अपने-आप सेल रेफ़रेंस अपडेट कर देता है। यदि आप किसी रेफ़रेंस को स्थिर रखना चाहते हैं, तो absolute reference में बदलने के लिए F4 दबाएँ (यह A1 को $A$1 में बदल देता है)।

फ़िल हैंडल का उपयोग कर फ़ॉर्मूला नीचे कॉपी करें। चित्र: लेखक

लेकिन एक सेल में #N/A त्रुटि आती है क्योंकि कोई भी शर्त पूरी नहीं हुई। इसे ठीक करने के लिए, फ़ॉर्मूला के अंत में TRUE का उपयोग करके अंतिम शर्त जोड़ें। यह एक बैकअप योजना की तरह काम करता है; जो पहले मैच नहीं हुआ उसे पकड़ लेता है और डिफ़ॉल्ट परिणाम देता है। 

=IFS(B2<=2, "Express", B2<=5, "Standard", TRUE, "Economy")संचालित द्वारा

इससे #N/A त्रुटि हट जाती है और डिफ़ॉल्ट मान लौटता है।

अंतिम ELSE शर्त का उपयोग करके #N/A त्रुटि संभालें। चित्र: लेखक

IFS() के व्यावहारिक उदाहरण

अब कुछ वास्तविक उदाहरण देखते हैं, जहाँ अधिकांश लोग इस फ़ंक्शन का उपयोग करते हैं।

ग्रेड असाइनमेंट

आप IFS() का उपयोग छात्रों के स्कोर को लेटर ग्रेड में बदलने के लिए कर सकते हैं। मान लें आपके पास छात्रों और उनके टेस्ट स्कोर की सूची है। आप इन संख्याओं को ग्रेड में बदलने के लिए यह फ़ॉर्मूला लगा सकते हैं:

=IFS(C5<60,"F", C5<70,"D", C5<80,"C", C5<90,"B", C5>=90,"A")संचालित द्वारा

यह क्या करता है:

• यदि स्कोर 60 से कम है, तो F देता है।

• यदि 70 से कम है, तो D देता है।

• यदि 80 से कम है, तो C।

• यदि 90 से कम है, तो B मिलता है।

• यदि 90 या अधिक है, तो A।

Excel क्रम से हर शर्त जाँचता है और जैसे ही कोई TRUE मिलती है, रुक जाता है। भले ही एक से अधिक शर्तें लागू हो सकती हों, केवल पहला मैच मायने रखता है।

IFS() का उपयोग कर छात्रों को ग्रेड असाइन करें। चित्र: लेखक

TRUE के साथ त्रुटि संभालना

आप IFS() की मदद से अलग-अलग स्टेटस कोड के आधार पर कस्टम संदेश भी दिखा सकते हैं, ताकि Excel #N/A त्रुटि न दिखाए। उदाहरण के लिए, यदि आपके पास कोड की सूची है और आप उनके आधार पर संदेश दिखाना चाहते हैं, तो यह फ़ॉर्मूला उपयोग कर सकते हैं:

=IFS(A2=100,"OK", A2=200,"Warning", A2=300,"Error", TRUE,"Invalid")संचालित द्वारा

यह ऐसे काम करता है:

• यदि कोड 100 है, तो OK दिखाता है।

• यदि 200 है, तो Warning।

• यदि 300 है, तो Error।

• यदि इनमें से कोई नहीं, तो Invalid दिखाता है।

आख़िरी हिस्सा महत्वपूर्ण है। यह कोड के आधार पर संदेश दिखाता है। यदि कोई सटीक मैच न मिले, तो आख़िरी TRUE फ़ॉलबैक की तरह काम करता है और Invalid लौटाता है।

IFS() फ़ंक्शन का उपयोग कर कोड के आधार पर संदेश दिखाएँ। चित्र: लेखक

सशर्त टेक्स्ट लेबल

आप IFS() का उपयोग वस्तुओं को फलों, सब्ज़ियों या पेय जैसी श्रेणियों में बाँटने के लिए भी कर सकते हैं, ताकि नए आइटम जुड़ने पर ट्रैक रखना आसान हो।

यह करने के लिए एक सरल फ़ॉर्मूला:

=IFS(A2="Grapes","Fruit", A2="Broccoli","Green Vegetable", A2="Tea","Beverage", TRUE,"Misc")संचालित द्वारा

यह क्या करता है:

• यदि आइटम Grapes है, तो Fruit दिखाता है।

• यदि Broccoli है, तो Green Vegetable दिखाता है।

• यदि Tea है, तो Beverage दिखाता है।

• यदि इनमें से कोई नहीं, तो Misc दिखाता है।

आख़िरी लाइन (TRUE के साथ) आपका बैकअप विकल्प है। यह उन सब चीज़ों को पकड़ लेता है जो बाकी श्रेणियों में फिट नहीं बैठतीं।

IFS() का उपयोग कर आइटम को श्रेणीबद्ध करें। चित्र: लेखक

वित्तीय मॉडलिंग

हम IFS() का उपयोग वित्तीय मॉडलिंग के लिए भी कर सकते हैं। दो सामान्य उदाहरण देखें:

डिस्काउंट टियर लागू करें

आप IFS() का उपयोग ग्राहक की कुल ख़रीद राशि के आधार पर डिस्काउंट असाइन करने के लिए कर सकते हैं।

=IFS(B2>=500,"20% Discount", B2>=300,"10% Discount", B2>=100,"5% Discount", TRUE,"No Discount")संचालित द्वारा

यह ऐसे काम करता है:

• यदि राशि 500 के बराबर या अधिक है, तो 20% Discount लौटाता है

• यदि राशि 300 के बराबर या अधिक है, तो 10% Discount लौटाता है।

• यदि राशि 100 के बराबर या अधिक है, तो 5% Discount लौटाता है।

• यदि राशि 100 से कम है, तो अंतिम TRUE शर्त No Discount लौटाती है।

IFS() का उपयोग कर डिस्काउंट लागू करें। चित्र: लेखक

अवकाश दिनों की गणना

आप यह भी निकाल सकते हैं कि किसी कर्मचारी को कंपनी में उसके कार्यकाल के आधार पर कितने अवकाश दिवस मिलने चाहिए। इसके लिए यह फ़ॉर्मूला उपयोग करें:

=IFS(B2>=10,"30 Days", B2>=5,"20 Days", B2>=1,"10 Days", TRUE,"No Leave")संचालित द्वारा

यह इस तरह विभाजित होता है:

• 10 या अधिक वर्ष का अर्थ 30 Days अवकाश।

• 5 से 9 वर्ष का अर्थ 20 Days।

• 1 से 4 वर्ष का अर्थ 10 Days।

• 1 से कम वर्ष का अर्थ No Leave।

सेवा वर्षों के आधार पर अवकाश दिवस असाइन करें। चित्र: लेखक

डेटा रूपांतरण

आप IFS() का उपयोग बाइट्स में फ़ाइल आकारों को अधिक पढ़ने योग्य इकाइयों जैसे KB, MB, या GB में बदलने के लिए भी कर सकते हैं:

=IFS(B2<1024, B2 & " Bytes", B2<1048576, ROUND(B2/1024,1) & " KB", B2<1073741824, ROUND(B2/1048576,1) & " MB", TRUE, ROUND(B2/1073741824,1) & " GB")संचालित द्वारा

यह फ़ॉर्मूला दिखाता है:

• Bytes उन मानों के लिए जो 1024 से कम हैं

• KB उन मानों के लिए जो 1 MB से कम हैं

• MB उन मानों के लिए जो 1 GB से कम हैं

• GB बाकी सभी के लिए

Bytes से KB, MB, GB में फ़ाइल आकार बदलें। चित्र: लेखक

IFS() बनाम IF() बनाम Nested IF()

जब आप Excel में कई शर्तों के साथ काम करते हैं, तो आपके पास तीन विकल्प होते हैं: IF(), nested IF(), या IFS() फ़ंक्शन। हर एक अलग तरीके से काम करता है, तो सही चुनाव कैसे करें, यह यहाँ है।

पढ़ने-समझने में तुलना

यदि आप केवल एक या दो शर्तें जाँच रहे हैं, तो बेसिक IF() बिल्कुल उपयुक्त है। यह तेज़, सरल है और काम कर देता है। लेकिन कई शर्तें जाँचनी हों तो चीज़ें पेचीदा हो जाती हैं। तब हम IF() फ़ंक्शनों को एक-दूसरे के भीतर स्टैक करना शुरू करते हैं, जिससे फ़ॉर्मूला पढ़ना और बाद में बदलना कठिन हो जाता है।

उदाहरण देखें:

=IF(A1<60,"F",IF(A1<70,"D",IF(A1<80,"C",IF(A1<90,"B","A"))))संचालित द्वारा

यह काम करता है, लेकिन इसे फॉलो करना आसान नहीं है। इतनी सारी ब्रैकेट्स इसे पढ़ना और अपडेट करना मुश्किल बना देती हैं।

Nested IF() पढ़ना और समझना मुश्किल है। चित्र: लेखक 

अब वही लॉजिक IFS() से देखें:

=IFS(A1<60,"F", A1<70,"D", A1<80,"C", A1<90,"B", A1>=90,"A")संचालित द्वारा

यह काफ़ी सरल लगता है। हर शर्त सीधे उसके परिणाम के साथ जोड़ी गई है, बिना nesting और ब्रैकेट्स के बोझ के। इसलिए, यदि आप ऐसा फ़ॉर्मूला चाहते हैं जो पढ़ने, समझने और बाद में सुधारने में आसान हो, तो IFS() एक उत्कृष्ट विकल्प है।

IFS() पढ़ना और समझना कहीं आसान है। चित्र: लेखक

प्रदर्शन से जुड़ी बातें

IFS() फ़ंक्शन आपकी दी गई हर शर्त जाँचता है, भले ही उसे पहले से कोई मैच मिल गया हो। यानी आप पाँच शर्तें लिखते हैं, तो Excel सभी पाँच का मूल्यांकन करेगा।

पर nested IF() कुछ समझदारी से काम करता है। यह “short-circuiting” का उपयोग करता है, यानी पहली TRUE शर्त मिलते ही आगे जाँचना बंद कर देता है। इससे बड़े स्प्रेडशीट्स में, जहाँ बहुत सारे फ़ॉर्मूले हों, थोड़ा समय बच सकता है।

त्वरित तुलना: कब क्या उपयोग करें

यहाँ एक त्वरित सारणीबद्ध तुलना है जो बताएगी कि IF(), nested IF(), और IFS() कब उपयोग करें:

IFS बनाम SWITCH()

IFS() और SWITCH() दोनों ही एक ही फ़ॉर्मूला में कई शर्तें जाँचते हैं, लेकिन वे अलग तरीक़े से काम करते हैं। दोनों के बीच विस्तृत तुलना यहाँ है:

ध्यान देने योग्य बातें

Excel में IFS() फ़ंक्शन के साथ काम करते समय कुछ बातों का ध्यान रखें।

आम त्रुटियाँ और उनके समाधान

पहले, कुछ सामान्य त्रुटियाँ देखें जिनका सामना आपको हो सकता है।

आर्ग्युमेंट बहुत कम

यदि हम कोई शर्त जोड़ते हैं लेकिन यह भूल जाते हैं कि उसके TRUE होने पर क्या होना चाहिए (value_if_true)। Excel एक पॉप-अप दिखाता है: "You've entered too few arguments for this function."

#N/A त्रुटि

#N/A त्रुटि तब होती है जब फ़ॉर्मूला में दी गई किसी भी शर्त का परिणाम TRUE नहीं होता। Excel को कम-से-कम एक मैच चाहिए, वरना वह अटक जाता है। यदि आप #N/A नहीं दिखाना चाहते, तो अंत में TRUE के साथ कोई फ़ॉलबैक मान जोड़ दें।

#VALUE! त्रुटि

#VALUE! त्रुटि तब आती है जब कोई logical_test आर्ग्युमेंट स्पष्ट TRUE या FALSE नहीं लौटाता। हो सकता है टाइपो हो, या शर्त सही न लिखी हो। किसी भी तरह, Excel नहीं समझ पाता, इसलिए अपना लॉजिक ध्यान से जाँचें।

टिप्स और श्रेष्ठ अभ्यास

अब कुछ सर्वोत्तम अभ्यास जो आपके फ़ॉर्मूलों को बेहतर और सरल बनाएँ: 

• चीज़ों को सरल रखने की कोशिश करें। आमतौर पर दस या उससे कम शर्तें पर्याप्त होती हैं।

• अंतिम शर्त के रूप में TRUE के साथ फ़ॉलबैक जोड़ें। यह उन मामलों को कवर करता है जो आपकी मुख्य शर्तों में फिट नहीं बैठते।

• सुनिश्चित करें कि हर शर्त का कोई परिणाम हो, और आपके टेस्ट या तो TRUE या FALSE लौटाएँ।

• अपने फ़ॉर्मूले को 0, 100 या खाली सेल जैसे एज केस के साथ टेस्ट करें, ताकि यह पक्का हो कि सब उम्मीद के मुताबिक़ चल रहा है।

फायदे और सीमाएँ

IFS() के कई फ़ायदे हैं, लेकिन कुछ बातों का ध्यान रखना भी ज़रूरी है।

अंतिम विचार 

IFS() फ़ंक्शन कई शर्तें जाँचने का एक सुविधाजनक तरीका है, बिना आपका फ़ॉर्मूला उलझे। यह एक-दूसरे के भीतर रखे गए कई IF() स्टेटमेंट्स से पढ़ने में आसान है और आपके लॉजिक को कहीं अधिक स्पष्ट बनाता है। अपनी शर्तें सही क्रम में लिखें और अंत में हमेशा TRUE के साथ फ़ॉलबैक जोड़ें — इस तरह, यदि कुछ भी मैच न हो, तो आपका फ़ॉर्मूला नहीं टूटेगा।

यदि आपका लॉजिक अनुमानित है और स्पष्ट नियमों का पालन करता है, तो IFS() आपकी स्प्रेडशीट को सुव्यवस्थित और प्रबंधनीय रखने का बेहतरीन तरीका है।