IFS() Excel: Lerne, mehrere Bedingungen zu vereinfachen

Wenn du schon einmal versucht hast, eine komplexe logische Formel in Excel zu erstellen, weißt du, wie unübersichtlich das werden kann. Das Schwierigste an den verschachtelten IF() Anweisungen ist, herauszufinden, welche Bedingung wohin gehört.

Aus diesem Grund hat Excel eine neue Funktion namens IFS() eingeführt. Das ist ein sauberer und einfacher Weg, um mehrere Bedingungen zu prüfen, ohne sich dabei zu verheddern. Ich zeige dir, wie IFS() funktioniert, mit Beispielen und Tipps, damit du es sicher nutzen kannst.

Was ist die Funktion IFS() in Excel?

Mit der Funktion IFS() können wir mehrere Bedingungen gleichzeitig überprüfen. Sie geht jede Bedingung in der Reihenfolge durch, in der du sie schreibst, und gibt dir das Ergebnis für die erste Bedingung, die TRUE lautet.

So kannst du einfacher schreiben, was früher eine unübersichtliche Reihe von verschachtelten IF() Formeln war. Anstatt mehrere IF() Funktionen ineinander zu stapeln, listet IFS() alle deine Bedingungen an einem Ort auf. Insgesamt kannst du bis zu 127 Bedingungs-Ergebnis-Paare hinzufügen, obwohl ich bezweifle, dass du jemals so viele Bedingungen brauchen wirst.

So funktioniert die Funktion IFS()

Die Syntax lautet:

=IFS(logical_test1, value_if_true1, [logical_test2, value_if_true2]…)

Hier:

• logical_test1 (erforderlich) ist die erste Bedingung.

• value_if_true1(erforderlich) gibt die Ergebnisse zurück, wenn logical_test1 TRUE ist.

• Die restlichen 126 logical_test und value_if_true Argumente sind optional.

Wie man Excel IFS() verwendet

Die Funktion IFS() liefert je nach Bedingungen unterschiedliche Ergebnisse. Du kannst logische Operatoren wie =, <, >, <= und >= verwenden, um deine Logik aufzubauen. Hier erfährst du, wie du anfangen kannst.

Option 1: Verwende den Formel-Assistenten

Um einen Formelassistenten zu verwenden: 

1. Klicke auf die Zelle, in der du deine Formel eingeben willst.

2. Gehe auf die Registerkarte Formeln und wähle Funktion einfügen.

3. Gib in das Suchfeld IFS ein und klicke auf Los.

4. Wähle IFS, klicke auf OK und gib dann deine Bedingungen und Ergebnisse ein.

5. Klicke erneut auf OK , um die Formel anzuwenden.

So kannst du schnell eine Formel erstellen, ohne sie selbst abzutippen.

Verwende den Formelassistenten, um die Funktion IFS() anzuwenden. Bild vom Autor.

Option 2: Schreibe es manuell

Du kannst die Formel auch manuell schreiben. Das ist wahrscheinlich das, was die meisten Menschen tun. Alles, was du tun musst, ist, =IFS( in die Zelle zu schreiben und deine Logik Schritt für Schritt aufzubauen. Angenommen, du ordnest die Versandarten nach der Lieferzeit zu:

• Wenn es 2 Tage oder weniger sind, wäre das Express

• Wenn es 3 bis 5 Tage sind, wäre das Standard

Hier ist die Formel dafür:

=IFS(B2<=2, "Express", B2<=5, "Standard")

Wende die Formel IFS() in einer Zelle an. Bild vom Autor.

Du kannst deine Formel auch in andere Zellen kopieren. Dazu ziehst du das kleine Quadrat in der unteren Ecke der Zelle (den Füllgriff). Dadurch wird die Formel auf die Spalte angewendet. Oder doppelklicke einfach darauf, um es automatisch anhand deiner Daten zu füllen.

Profi-Tipp: Excel aktualisiert automatisch die Zellbezüge, wenn du eine Formel kopierst. Wenn du einen Verweis festhalten willst, wandelst du ihn in einen absoluten Verweis um, indem du F4 drückst (dadurch wird A1 zu $A$1).

Kopiere die Formel mit Hilfe eines Dateihandles herunter. Bild vom Autor

Aber in einer Zelle wird ein #N/A Fehler ausgegeben, weil keine der Bedingungen erfüllt ist. Um das zu beheben, füge eine letzte Bedingung mit TRUE am Ende der Formel hinzu. Dies funktioniert wie ein Backup-Plan; er fängt alles ab, was nicht passt, und gibt dir stattdessen ein Standard-Ergebnis. 

=IFS(B2<=2, "Express", B2<=5, "Standard", TRUE, "Economy")

Dadurch wird der Fehler #N/A entfernt und der Standardwert wiederhergestellt.

Behandle #N/A-Fehler mit der letzten ELSE-Bedingung. Bild vom Autor.

Beispiele für IFS() in Aktion

Sehen wir uns nun einige Beispiele aus der Praxis an, bei denen die meisten Menschen diese Funktion verwenden.

Notenvergabe

Du kannst IFS() verwenden, um die Noten der Schüler/innen in Buchstaben umzuwandeln. Angenommen, du hast eine Liste mit Schülern und ihren Testergebnissen. Mit dieser Formel kannst du diese Zahlen in Noten umwandeln:

=IFS(C5<60,"F", C5<70,"D", C5<80,"C", C5<90,"B", C5>=90,"A")

So funktioniert es:

• Wenn die Punktzahl weniger als 60 beträgt, gibt es eine F.

• Wenn es weniger als 70 ist, gibt es eine D.

• Wenn es weniger als 80 sind, ist das eine C.

• Wenn es weniger als 90 sind, bekommst du eine B.

• Wenn es 90 oder mehr sind, ist das eine A.

Excel prüft jede Bedingung der Reihe nach und hält an, sobald es eine findet, die TRUE lautet. Auch wenn mehr als eine Bedingung zutreffen könnte, zählt nur die erste Übereinstimmung.

Weise den Schülern mit IFS() Noten zu. Bild vom Autor.

Fehlerbehandlung mit TRUE

Du kannst auch IFS() verwenden, um eine benutzerdefinierte Meldung basierend auf verschiedenen Statuscodes anzuzeigen, anstatt Excel einen #N/A Fehler anzeigen zu lassen. Wenn du zum Beispiel eine Liste von Codes hast und für jeden Code eine Nachricht anzeigen möchtest, kannst du folgende Formel verwenden:

=IFS(A2=100,"OK", A2=200,"Warning", A2=300,"Error", TRUE,"Invalid")

So funktioniert es:

• Wenn der Code 100 ist, zeigt er OK an.

• Wenn es 200 sind, zeigt es Warning an.

• Wenn es 300 ist, zeigt es Error an.

• Wenn sie mit keiner dieser Angaben übereinstimmt, wird Invalid angezeigt.

Dieser letzte Teil ist wichtig. Die Nachricht wird anhand des Codes angezeigt. Wenn keine exakten Übereinstimmungen gefunden werden, fungiert die letzte Bedingung TRUE als Fallback und liefert Invalid.

Zeige eine Nachricht auf der Grundlage des Codes mit der Funktion IFS() an. Bild vom Autor.

Bedingte Textbeschriftungen

Du kannst auch IFS() verwenden, um Artikel in Kategorien wie Obst, Gemüse oder Getränke zu sortieren und so den Überblick zu behalten, wenn neue Artikel hinzugefügt werden.

Hier ist eine einfache Formel, um das zu tun:

=IFS(A2="Grapes","Fruit", A2="Broccoli","Green Vegetable", A2="Tea","Beverage", TRUE,"Misc")

Das ist es, was es tut:

• Wenn der Artikel Grapes ist, wird Fruit angezeigt.

• Wenn es Broccoli ist, zeigt es Green Vegetable an.

• Wenn es Tea ist, zeigt es Beverage an.

• Wenn sie mit keiner dieser Angaben übereinstimmt, wird Misc angezeigt.

Die letzte Zeile (mit TRUE) ist deine Backup-Option. Sie fängt alles auf, was nicht in die anderen Kategorien passt.

Kategorisiere den Artikel mit IFS(). Bild vom Autor.

Finanzielle Modellierung

Wir können IFS() auch für die Finanzmodellierung nutzen. Schauen wir uns zwei gängige Beispiele an:

Rabattstaffeln anwenden

Du kannst IFS() verwenden, um einen Rabatt auf der Grundlage des Gesamteinkaufsbetrags eines Kunden zu gewähren.

=IFS(B2>=500,"20% Discount", B2>=300,"10% Discount", B2>=100,"5% Discount", TRUE,"No Discount")

So funktioniert es:

• Wenn der Betrag gleich oder größer als 500 ist, gibt er 20% Discount

• Wenn der Betrag gleich oder größer als 300 ist, wird 10% Discount zurückgegeben.

• Wenn der Betrag gleich oder größer als 100 ist, wird 5% Discount zurückgegeben.

• Wenn der Betrag kleiner als 100 ist, gibt die letzte TRUE Bedingung No Discount zurück.

Wende Rabatte mit IFS() an. Bild vom Autor.

Berechnung der Urlaubstage

Du kannst auch berechnen, wie viele Urlaubstage einem Arbeitnehmer zustehen, je nachdem, wie lange er schon im Unternehmen ist. Verwende dazu die folgende Formel:

=IFS(B2>=10,"30 Days", B2>=5,"20 Days", B2>=1,"10 Days", TRUE,"No Leave")

So sieht es aus:

• 10 oder mehr Jahren bedeutet 30 DaysUrlaub.

• 5 zu 9 Jahren bedeutet 20 Days.

• 1 zu 4 Jahren bedeutet 10 Days.

• Less than 1 Jahr bedeutet No Leave.

Weise mit IFS() Urlaubstage auf der Grundlage von Dienstjahren zu. Bild vom Autor.

Datenkonvertierung

Du kannst IFS() auch verwenden, um Dateigrößen von Bytes in besser lesbare Einheiten wie KB, MB oder GB umzuwandeln:

=IFS(B2<1024, B2 & " Bytes", B2<1048576, ROUND(B2/1024,1) & " KB", B2<1073741824, ROUND(B2/1048576,1) & " MB", TRUE, ROUND(B2/1073741824,1) & " GB")

Diese Formel zeigt:

• Bytes für Werte unter 1024

• KB für Werte unter 1 MB

• MB für Werte unter 1 GB

• GB für alles, was größer ist

Konvertiere die Dateigröße von Bytes in KB, MB, GB mit IFS(). Bild vom Autor.

IFS() vs. IF() vs. Verschachtelte IF()

Wenn du in Excel mit mehreren Bedingungen arbeitest, hast du drei Möglichkeiten: IF(), verschachtelte IF(), oder die Funktion IFS(). Jede funktioniert anders, deshalb erfährst du hier, wie du die richtige Wahl triffst.

Vergleich in der Lesbarkeit

Wenn du nur eine oder zwei Bedingungen überprüfen willst, ist die Basisfunktion IF() perfekt. Es ist schnell, einfach und erledigt den Job. Schwierig wird es aber, wenn du versuchst, mehrere Bedingungen zu prüfen. Dann fangen wir an, IF() Funktionen ineinander zu stapeln, was die Formel schwerer lesbar und später noch schwerer zu ändern macht.

Hier ist ein Beispiel:

=IF(A1<60,"F",IF(A1<70,"D",IF(A1<80,"C",IF(A1<90,"B","A"))))

Es funktioniert, aber es ist nicht einfach zu befolgen. All diese Klammern machen es schwierig, sie zu lesen und zu aktualisieren.

Verschachtelte IF() sind schwer zu lesen und zu verstehen. Bild vom Autor. 

Betrachte nun die gleiche Logik, wenn du stattdessen IFS() verwendest:

=IFS(A1<60,"F", A1<70,"D", A1<80,"C", A1<90,"B", A1>=90,"A")

Das hier sieht viel einfacher aus. Jede Bedingung wird direkt mit einem Ergebnis gepaart, ohne Verschachtelung und Klammerüberladung. Wenn du also eine Formel willst, die einfach zu lesen, zu verstehen und später zu korrigieren ist, ist IFS() eine gute Wahl.

IFS() ist viel einfacher zu lesen und zu verstehen. Bild vom Autor.

Überlegungen zur Leistung

Die Funktion IFS() überprüft jede Bedingung, die du ihr gibst, auch wenn sie bereits eine Übereinstimmung gefunden hat. Wenn du also fünf Bedingungen auflistest, wertet Excel trotzdem alle fünf aus.

Aber verschachtelte IF() Funktionen sind ein bisschen schlauer. Sie verwenden "Kurzschlussverfahren", d.h. sie hören auf zu prüfen, sobald sie die erste TRUE Bedingung finden. Das spart bei großen Tabellenkalkulationen mit vielen Formeln ein wenig Zeit.

Schneller Vergleich: Wann was zu verwenden ist

Hier ist ein kurzer tabellarischer Vergleich, damit du weißt, wann du IF(), nested IF() und IFS() verwenden solltest:

IFS vs. SWITCH()

IFS() und SWITCH() prüfen beide mehrere Bedingungen in einer einzigen, in sich geschlossenen Formel, aber sie funktionieren auf unterschiedliche Weise. Hier ist ein detaillierter Vergleich zwischen beiden:

Zu beachtende Dinge

Du solltest ein paar Dinge beachten, wenn du mit der Funktion IFS() in Excel arbeitest.

Häufige Fehler und wie man sie behebt

Sehen wir uns zunächst einige häufige Fehler an, auf die du stoßen kannst.

Zu wenig Argumente

Wenn wir eine Bedingung hinzufügen, aber vergessen, anzugeben, was passieren soll, wenn sie wahr ist (value_if_true). Excel zeigt ein Pop-up-Fenster an: "Du hast zu wenige Argumente für diese Funktion eingegeben."

#N/A Fehler

#N/A Fehler auftritt, wenn keine der Bedingungen in der Formel TRUE erfüllt ist. Excel braucht mindestens eine Übereinstimmung, sonst bleibt es stecken. Wenn du #N/A nicht anzeigen möchtest, füge TRUE am Ende mit einem Fallback-Wert hinzu.

#WERT! Fehler

#VALUE! Der Fehler tritt auf, wenn ein logical_test Argument kein eindeutiges TRUE oder FALSE zurückgibt. Vielleicht ist es ein Tippfehler oder die Bedingung ist nicht ganz richtig. So oder so wird Excel nicht wissen, was es damit anfangen soll, also überprüfe deine Logik.

Tipps und bewährte Praktiken

Hier sind ein paar Best Practices, um deine Formeln besser und einfacher zu machen: 

• Versuche, die Dinge einfach zu halten. Zehn oder weniger Bedingungen sind in der Regel ausreichend.

• Füge eine Ausweichbedingung mit TRUE als letzte Bedingung hinzu. Sie deckt alle Fälle ab, die nicht deine Hauptbedingungen erfüllen.

• Vergewissere dich, dass jede Bedingung ein Ergebnis hat und dass deine Tests entweder TRUE oder FALSE zurückgeben.

• Teste deine Formel mit Randfällen wie 0, 100 oder sogar leeren Zellen, um sicherzustellen, dass sie alles so behandelt, wie du es erwartest.

Pro und Kontra

IFS() hat einige echte Vorteile, aber es gibt auch ein paar Dinge, auf die du achten solltest.

Schlussgedanken 

Die Funktion IFS() ist eine praktische Methode, um viele Bedingungen zu überprüfen, ohne dass deine Formel unübersichtlich wird. Das ist einfacher zu lesen als mehrere IF() Anweisungen, die ineinander gestapelt sind, und macht deine Logik viel klarer. Achte darauf, dass du deine Bedingungen in der richtigen Reihenfolge auflistest und füge immer einen letzten Fallback hinzu, indem du TRUE verwendest - so wird deine Formel nicht unterbrochen, wenn nichts passt.

Wenn deine Logik vorhersehbar ist und klaren Regeln folgt, ist IFS() eine großartige Möglichkeit, deine Tabellenkalkulation übersichtlich zu halten.