IFS() in Excel: leer meerdere voorwaarden eenvoudig te maken

Als je ooit een complexe logische formule in Excel hebt geprobeerd te bouwen, weet je hoe rommelig het kan worden. Het lastigste aan geneste IF()-verklaringen is uitvinden welke voorwaarde waar hoort.

Daarom introduceerde Excel een nieuwe functie: IFS(). Het is een schonere en eenvoudigere manier om meerdere voorwaarden te controleren zonder jezelf in bochten te wringen. Ik laat je zien hoe IFS() werkt, met voorbeelden en tips zodat je het met vertrouwen kunt gebruiken.

Wat is de IFS()-functie in Excel?

De IFS()-functie helpt ons om meerdere voorwaarden tegelijk te controleren. Hij loopt de voorwaarden na in de volgorde waarin je ze schrijft en geeft het resultaat voor de eerste die TRUE is.

Het is dus een gemakkelijkere manier om te schrijven wat vroeger een rommelige set geneste IF()-formules was. In plaats van meerdere IF()-functies in elkaar te stapelen, zet IFS() al je voorwaarden op één plek. In totaal kun je tot 127 paren van voorwaarde-en-resultaat toevoegen, al betwijfel ik of je er ooit zoveel nodig zult hebben.

Hoe de IFS()-functie werkt

De syntaxis is:

=IFS(logical_test1, value_if_true1, [logical_test2, value_if_true2]…)

Hierbij geldt:

• logical_test1 (vereist) is de eerste voorwaarde.

• value_if_true1 (vereist) retourneert het resultaat als logical_test1 TRUE is.

• De overige 126 argumenten logical_test en value_if_true zijn optioneel.

Hoe gebruik je Excel IFS()

De IFS()-functie geeft verschillende resultaten terug op basis van voorwaarden. Je kunt logische operatoren zoals =, <, >, <= en >= gebruiken om je logica op te bouwen. Zo ga je aan de slag.

Optie 1: Gebruik de formulewizard

Om een Formulewizard te gebruiken: 

1. Klik op de cel waar je je formule wilt hebben.

2. Ga naar het tabblad Formules en kies Functie invoegen.

3. Typ in het zoekvak IFS en klik op Start.

4. Selecteer IFS, klik op OK en voer vervolgens je voorwaarden en resultaten in.

5. Klik nogmaals op OK om de formule toe te passen.

Dit is een snelle manier om een formule op te bouwen zonder alles zelf te typen.

Gebruik de formulewizard om de IFS()-functie toe te passen. Afbeelding door auteur.

Optie 2: Schrijf hem handmatig

Je kunt de formule ook handmatig schrijven. Dit is waarschijnlijk wat de meeste mensen doen. Je hoeft alleen maar =IFS( in de cel te typen en je logica stap voor stap op te bouwen. Stel dat je verzendmethoden toekent op basis van levertijd:

• Als het 2 dagen of minder is, dan is dat Express

• Als het 3 tot 5 dagen is, dan is dat Standaard

Hiervoor is dit de formule:

=IFS(B2<=2, "Express", B2<=5, "Standard")

Pas de IFS()-formule toe in een cel. Afbeelding door auteur.

Je kunt je formule ook kopiëren naar andere cellen. Sleep daarvoor het kleine vierkantje in de hoek van de cel (de vulgreep). Hiermee pas je de formule toe naar beneden in de kolom. Of dubbelklik erop om automatisch te vullen op basis van je gegevens.

Pro tip: Excel werkt de celverwijzingen automatisch bij wanneer je een formule kopieert. Wil je een verwijzing vastzetten, maak er dan een absolute verwijzing van door op F4 te drukken (dit verandert A1 in $A$1).

Kopieer de formule omlaag met een vulgreep. Afbeelding door auteur

Maar in één cel krijg je een #N/A-fout omdat geen van de voorwaarden wordt gehaald. Om dat op te lossen, voeg je aan het eind van de formule een laatste voorwaarde toe met TRUE. Dit werkt als een vangnet; het pakt alles op wat eerder niet matchte en geeft in plaats daarvan een standaardresultaat.

=IFS(B2<=2, "Express", B2<=5, "Standard", TRUE, "Economy")

Dit haalt de #N/A-fout weg en geeft de standaardwaarde terug.

Los de #N/A-fout op met de laatste ELSE-voorwaarde. Afbeelding door auteur.

Voorbeelden van IFS() in de praktijk

Laten we nu enkele praktijkvoorbeelden bekijken, waar de meeste mensen deze functie gebruiken.

Cijfertoekenning

Je kunt IFS() gebruiken om de scores van studenten om te zetten in lettercijfers. Stel dat je een lijst met studenten en hun toetsscores hebt. Met deze formule kun je die cijfers omzetten in letters:

=IFS(C5<60,"F", C5<70,"D", C5<80,"C", C5<90,"B", C5>=90,"A")

Dit is wat er gebeurt:

• Als de score lager is dan 60, geeft hij een F.

• Als hij lager is dan 70, geeft hij een D.

• Als hij lager is dan 80, is dat een C.

• Als hij lager is dan 90, krijg je een B.

• Als hij 90 of hoger is, is dat een A.

Excel controleert elke voorwaarde op volgorde en stopt zodra het er één vindt die TRUE is. Zelfs als meer dan één voorwaarde zou kunnen gelden, telt alleen de eerste match.

Wijs cijfers toe aan studenten met IFS(). Afbeelding door auteur.

Fouten afhandelen met TRUE

Je kunt IFS() ook gebruiken om een aangepaste boodschap te tonen op basis van verschillende statuscodes in plaats van Excel een #N/A-fout te laten weergeven. Als je bijvoorbeeld een lijst met codes hebt en je wilt per code een bericht tonen, kun je deze formule gebruiken:

=IFS(A2=100,"OK", A2=200,"Warning", A2=300,"Error", TRUE,"Invalid")

Zo werkt het:

• Als de code 100 is, toont hij OK.

• Als het 200 is, toont hij Warning.

• Als het 300 is, toont hij Error.

• Als geen van deze klopt, toont hij Invalid.

Dat laatste deel is belangrijk. Het bericht wordt getoond op basis van de code. Als er geen exacte overeenkomst is, fungeert de laatste voorwaarde TRUE als vangnet en retourneert Invalid.

Toon een bericht op basis van de code met de IFS()-functie. Afbeelding door auteur.

Voorwaardelijke tekstlabels

Je kunt IFS() ook gebruiken om items in categorieën als fruit, groenten of dranken in te delen, zodat je het overzicht houdt als er nieuwe worden toegevoegd.

Hier is een eenvoudige formule om dit te doen:

=IFS(A2="Grapes","Fruit", A2="Broccoli","Green Vegetable", A2="Tea","Beverage", TRUE,"Misc")

Dit is wat er gebeurt:

• Als het item Grapes is, toont hij Fruit.

• Als het Broccoli is, toont hij Green Vegetable.

• Als het Tea is, toont hij Beverage.

• Als geen van deze klopt, toont hij Misc.

Die laatste regel (met TRUE) is je back-upoptie. Hij pakt alles op wat niet in de andere categorieën past.

Categoriseer het item met IFS(). Afbeelding door auteur.

Financiële modellering

We kunnen IFS() ook gebruiken voor financiële modellering. Laten we twee veelvoorkomende voorbeelden bekijken:

Kortingstreden toepassen

Je kunt IFS() gebruiken om een korting toe te kennen op basis van het totale aankoopbedrag van een klant.

=IFS(B2>=500,"20% Discount", B2>=300,"10% Discount", B2>=100,"5% Discount", TRUE,"No Discount")

Zo werkt het:

• Als het bedrag gelijk is aan of groter dan 500, retourneert hij 20% Discount

• Als het bedrag gelijk is aan of groter dan 300, retourneert hij 10% Discount.

• Als het bedrag gelijk is aan of groter dan 100, retourneert hij 5% Discount.

• Als het bedrag lager is dan 100, retourneert de laatste voorwaarde TRUE No Discount.

Pas kortingen toe met IFS(). Afbeelding door auteur.

Verlofdagencalculatie

Je kunt ook berekenen op hoeveel verlofdagen een medewerker recht heeft, op basis van hoelang die bij het bedrijf werkt. Gebruik daarvoor de volgende formule:

=IFS(B2>=10,"30 Days", B2>=5,"20 Days", B2>=1,"10 Days", TRUE,"No Leave")

Zo valt het uiteen:

• 10 jaar of meer betekent 30 Days verlof.

• 5 tot 9 jaar betekent 20 Days.

• 1 tot 4 jaar betekent 10 Days.

• Minder dan 1 jaar betekent No Leave.

Wijs verlofdagen toe op basis van dienstjaren met IFS(). Afbeelding door auteur.

Gegevensconversie

Je kunt IFS() ook gebruiken om bestandsgroottes in bytes om te zetten naar beter leesbare eenheden zoals KB, MB of GB:

=IFS(B2<1024, B2 & " Bytes", B2<1048576, ROUND(B2/1024,1) & " KB", B2<1073741824, ROUND(B2/1048576,1) & " MB", TRUE, ROUND(B2/1073741824,1) & " GB")

Deze formule toont:

• Bytes voor waarden onder 1024

• KB voor waarden onder 1 MB

• MB voor waarden onder 1 GB

• GB voor alles daarboven

Zet bestandsgrootte om van bytes naar KB, MB, GB met IFS(). Afbeelding door auteur.

IFS() vs. IF() vs. geneste IF()

Als je met meerdere voorwaarden in Excel werkt, heb je drie opties: IF(), geneste IF() of de IFS()-functie. Ze werken elk anders, dus zo kies je de juiste.

Vergelijking qua leesbaarheid

Als je maar één of twee voorwaarden controleert, is de basisfunctie IF() perfect. Snel, simpel en effectief. Maar het wordt lastig als je meerdere voorwaarden wilt controleren. Dan gaan we IF()-functies in elkaar stapelen, waardoor de formule moeilijker te lezen en nóg lastiger aan te passen is.

Hier is een voorbeeld:

=IF(A1<60,"F",IF(A1<70,"D",IF(A1<80,"C",IF(A1<90,"B","A"))))

Het werkt, maar het is niet makkelijk te volgen. Al die haakjes maken het lastig om te lezen en te updaten.

Geneste IF() is moeilijk te lezen en te begrijpen. Afbeelding door auteur. 

Kijk nu naar dezelfde logica met IFS() in plaats daarvan:

=IFS(A1<60,"F", A1<70,"D", A1<80,"C", A1<90,"B", A1>=90,"A")

Deze ziet er veel eenvoudiger uit. Elke voorwaarde is direct gekoppeld aan een resultaat, zonder nesten en haakjesoverload. Wil je dus een formule die gemakkelijk te lezen, te begrijpen en later te fixen is, dan is IFS() een prima keuze.

IFS() is veel makkelijker te lezen en te begrijpen. Afbeelding door auteur.

Prestatie-overwegingen

De IFS()-functie controleert elke door jou opgegeven voorwaarde, zelfs als er al een match is gevonden. Als je dus vijf voorwaarden opsomt, evalueert Excel ze alsnog alle vijf.

Maar geneste IF()-functies zijn iets slimmer. Ze gebruiken “short-circuiting”, wat betekent dat ze stoppen met controleren zodra ze de eerste TRUE-voorwaarde vinden. Dat bespaart wat tijd in grote spreadsheets met veel formules.

Snelle vergelijking: wanneer gebruik je wat

Hier is een snelle tabelvergelijking om je te helpen begrijpen wanneer je IF(), geneste IF() en IFS() gebruikt:

IFS vs. SWITCH()

IFS() en SWITCH() controleren allebei meerdere voorwaarden in één zelfstandige formule, maar ze werken op verschillende manieren. Hier is een gedetailleerde vergelijking tussen beide:

Dingen om te overwegen

Er zijn een paar dingen om in gedachten te houden wanneer je met de IFS()-functie in Excel werkt.

Veelvoorkomende fouten en hoe je ze oplost

Laten we eerst enkele veelvoorkomende fouten bekijken waar je tegenaan kunt lopen.

Te weinig argumenten

Als we een voorwaarde toevoegen maar vergeten te vermelden wat er moet gebeuren als die waar is (value_if_true), toont Excel een pop-up: "Je hebt te weinig argumenten ingevoerd voor deze functie."

#N/A-fout

De #N/A-fout treedt op wanneer geen van de voorwaarden in de formule TRUE is. Excel heeft er minstens één nodig die matcht, anders loopt het vast. Wil je #N/A niet tonen, voeg dan aan het eind TRUE toe met een vangnetwaarde.

#VALUE!-fout

De #VALUE!-fout verschijnt wanneer een logical_test-argument geen duidelijke TRUE of FALSE retourneert. Misschien is het een typefout, of klopt de voorwaarde net niet. Hoe dan ook, Excel weet er geen raad mee, dus controleer je logica nog eens.

Tips en best practices

Hier zijn nu een paar best practices om je formules beter en eenvoudiger te maken: 

• Houd het zo simpel mogelijk. Tien of minder voorwaarden is meestal genoeg.

• Voeg als laatste voorwaarde een vangnet toe met TRUE. Dat dekt alle gevallen die niet aan je hoofdvoorwaarden voldoen.

• Zorg dat elke voorwaarde een resultaat heeft en dat je tests TRUE of FALSE opleveren.

• Test je formule met randgevallen zoals 0, 100 of zelfs lege cellen om zeker te zijn dat alles gaat zoals je verwacht.

Plus- en minpunten

IFS() heeft duidelijke voordelen, maar er zijn ook een paar dingen om op te letten.

Tot slot

De IFS()-functie is een handige manier om veel voorwaarden te controleren zonder dat je formule een rommeltje wordt. Het is leesbaarder dan meerdere IF()-verklaringen die in elkaar zijn gestapeld en maakt je logica veel duidelijker. Zorg dat je je voorwaarden in de juiste volgorde zet en voeg altijd een laatste vangnet toe met TRUE — zo gaat je formule niet stuk als er niets matcht.

Als je logica voorspelbaar is en duidelijke regels volgt, is IFS() een geweldige manier om je spreadsheet netjes en beheersbaar te houden.