IFS() Excel: Birden Fazla Koşulu Basitleştirmeyi Öğrenin

Excel’de karmaşık bir mantık formülü kurmaya çalıştıysanız, işlerin ne kadar karmaşıklaşabildiğini bilirsiniz. İç içe IF() ifadelerinde en zor olan, hangi koşulun nereye gideceğini çözmektir.

Bu yüzden Excel, IFS() adlı yeni bir işlev tanıttı. Kendinizi düğümlere sokmadan birden fazla koşulu kontrol etmenin daha temiz ve basit bir yoludur. IFS() işlevinin nasıl çalıştığını, onu güvenle kullanmanıza yardımcı olacak örnekler ve ipuçlarıyla anlatacağım.

Excel’de IFS() İşlevi Nedir?

IFS() işlevi, birden fazla koşulu aynı anda kontrol etmemizi sağlar. Yazdığınız sıraya göre her koşula bakar ve TRUE olan ilk koşulun sonucunu verir.

Yani eskiden iç içe geçmiş IF() formülleriyle yazdığımız karışık yapıyı daha kolay bir şekilde oluşturur. Birden fazla IF() işlevini birbirinin içine eklemek yerine, IFS() tüm koşullarınızı tek yerde listeler. Toplamda 127 koşul-sonuç çifti ekleyebilirsiniz; ancak bu kadar çok koşula muhtemelen hiç ihtiyaç duymazsınız.

IFS() işlevi nasıl çalışır

Sözdizimi şöyledir:

=IFS(logical_test1, value_if_true1, [logical_test2, value_if_true2]…)

Burada:

• logical_test1 (zorunlu), ilk koşuldur.

• value_if_true1(zorunlu), logical_test1 TRUE ise döndürülecek sonucu verir.

• Kalan 126 logical_test ve value_if_true bağımsız değişkenleri isteğe bağlıdır.

Excel IFS() Nasıl Kullanılır

IFS() işlevi, koşullara bağlı olarak farklı sonuçlar döndürür. Mantıksal operatörleri (=, <, >, <= ve >=) kullanarak mantığınızı kurabilirsiniz. İşte nasıl başlayacağınız.

Seçenek 1: Formül Sihirbazını kullanın

Formül Sihirbazını kullanmak için: 

1. Formülü yazmak istediğiniz hücreye tıklayın.

2. Formüller sekmesine gidin ve İşlev Ekleyi seçin.

3. Arama kutusuna IFS yazın ve Git’e tıklayın.

4. IFS’i seçin, Tamam deyin, ardından koşullarınızı ve sonuçlarınızı girin.

5. Formülü uygulamak için tekrar Tamam deyin.

Bu, formülü kendiniz yazmadan hızlıca oluşturmanın pratik bir yoludur.

IFS() işlevini uygulamak için Formül Sihirbazını kullanın. Görsel: Yazar.

Seçenek 2: Elle yazın

Formülü elle de yazabilirsiniz. Çoğu kişinin yaptığı da muhtemelen budur. Yapmanız gereken tek şey hücreye =IFS( yazıp mantığınızı adım adım kurmaktır. Diyelim ki teslimat süresine göre gönderim yöntemleri atıyorsunuz:

• 2 gün veya daha az ise Express olur

• 3 ila 5 gün ise Standard olur

Bunun için formül şöyle:

=IFS(B2<=2, "Express", B2<=5, "Standard")

Bir hücrede IFS() formülünü uygulayın. Görsel: Yazar.

Formülünüzü diğer hücrelere de kopyalayabilirsiniz. Bunu yapmak için hücrenin köşesindeki küçük kareyi ( doldurma tutamacı) sürükleyin. Bu, formülü sütun boyunca uygular. Ya da verinize göre otomatik doldurmak için üzerine çift tıklayın.

İpucu: Excel, bir formülü kopyaladığınızda hücre başvurularını otomatik olarak günceller. Bir başvuruyu sabit tutmak istiyorsanız, mutlak başvuruya çevirmek için F4’e basın (A1’i $A$1’e dönüştürür).

Doldurma tutamacını kullanarak formülü aşağı kopyalayın. Görsel: Yazar

Ancak koşulların hiçbirinin sağlanmadığı bir hücrede #N/A hatası verebilir. Bunu düzeltmek için formülün sonuna TRUE kullanarak son bir koşul ekleyin. Bu, bir tür yedek plan gibi çalışır; daha önce eşleşmeyen her şeyi yakalar ve bunun yerine varsayılan bir sonuç verir. 

=IFS(B2<=2, "Express", B2<=5, "Standard", TRUE, "Economy")

Bu, #N/A hatasını kaldırır ve varsayılan değeri döndürür.

Son ELSE koşulunu kullanarak #N/A hatasını yönetin. Görsel: Yazar.

IFS() İşlevinin Kullanımına Örnekler

Şimdi çoğu kişinin bu işlevi kullandığı bazı gerçek senaryolara bakalım.

Not atama

IFS() ile öğrencilerin puanlarını harf notlarına dönüştürebilirsiniz. Diyelim ki öğrencilerin ve sınav puanlarının yer aldığı bir listeniz var. Bu sayıları nota çevirmek için şu formülü kullanabilirsiniz:

=IFS(C5<60,"F", C5<70,"D", C5<80,"C", C5<90,"B", C5>=90,"A")

Formülün yaptığı şudur:

• Puan 60’tan küçükse F verir.

• 70’ten küçükse D verir.

• 80’den küçükse C olur.

• 90’dan küçükse B alırsınız.

• 90 veya üzerindeyse A olur.

Excel, koşulları sırayla kontrol eder ve TRUE olan ilk koşulda durur. Birden fazla koşul geçerli olsa bile yalnızca ilk eşleşme dikkate alınır.

IFS() kullanarak öğrencilere not atayın. Görsel: Yazar.

TRUE ile hata yönetimi

IFS() ile Excel’in #N/A hatası göstermesine izin vermek yerine, farklı durum kodlarına göre özel bir mesaj da gösterebilirsiniz. Örneğin, bir kod listesi varsa ve her birine göre mesaj göstermek istiyorsanız, şu formülü kullanabilirsiniz:

=IFS(A2=100,"OK", A2=200,"Warning", A2=300,"Error", TRUE,"Invalid")

Nasıl çalıştığı şöyle:

• Kod 100 ise OK gösterir.

• 200 ise Warning gösterir.

• 300 ise Error gösterir.

• Hiçbiriyle eşleşmezse Invalid gösterir.

Son kısım önemlidir. Mesajı koda göre gösterecektir. Hiçbir tam eşleşme bulunamazsa, sondaki TRUE koşulu yedek görevi görür ve Invalid döner.

IFS() işlevini kullanarak koda göre mesaj gösterin. Görsel: Yazar.

Koşullu metin etiketleri

IFS() işlevini, yeni öğeler eklendikçe takip edebilmek için öğeleri meyve, sebze veya içecek gibi kategorilere ayırmakta da kullanabilirsiniz.

Bunu yapmak için basit bir formül:

=IFS(A2="Grapes","Fruit", A2="Broccoli","Green Vegetable", A2="Tea","Beverage", TRUE,"Misc")

Yaptığı şey şudur:

• Öğe Grapes ise Fruit gösterir.

• Broccoli ise Green Vegetable gösterir.

• Tea ise Beverage gösterir.

• Hiçbiriyle eşleşmezse Misc gösterir.

Sondaki satır (TRUE ile) yedek seçeneğinizdir. Diğer kategorilere uymayan her şeyi yakalar.

IFS() kullanarak öğeyi kategorize edin. Görsel: Yazar.

Finansal modelleme

IFS() işlevini finansal modelleme amaçları için de kullanabiliriz. İki yaygın örneğe bakalım:

İndirim kademelerini uygulayın

IFS() ile bir müşterinin toplam alışveriş tutarına göre indirim atayabilirsiniz.

=IFS(B2>=500,"20% Discount", B2>=300,"10% Discount", B2>=100,"5% Discount", TRUE,"No Discount")

Nasıl çalıştığı şöyle:

• Tutar 500e eşit veya büyükse 20% Discount döner

• Tutar 300’e eşit veya büyükse 10% Discount döner.

• Tutar 100’e eşit veya büyükse 5% Discount döner.

• Tutar 100’ün altındaysa, son TRUE koşulu No Discount döndürür.

IFS() kullanarak indirimleri uygulayın. Görsel: Yazar.

İzin günlerini hesaplayın

Bir çalışanın şirkette ne kadar süredir bulunduğuna göre ne kadar izin hakkı olduğunu da hesaplayabilirsiniz. Bunun için şu formülü kullanın:

=IFS(B2>=10,"30 Days", B2>=5,"20 Days", B2>=1,"10 Days", TRUE,"No Leave")

Ayrıntısı şöyle:

• 10 yıl veya üzeri 30 Days izin demektir.

• 5 ila 9 yıl arası 20 Days demektir.

• 1 ila 4 yıl arası 10 Days demektir.

• 1 yıldan az ise No Leave demektir.

Kıdeme göre izin günleri atayın. IFS() kullanın. Görsel: Yazar.

Veri dönüştürme

IFS() işlevini bayt cinsinden dosya boyutlarını KB, MB veya GB gibi daha okunabilir birimlere dönüştürmek için de kullanabilirsiniz:

=IFS(B2<1024, B2 & " Bytes", B2<1048576, ROUND(B2/1024,1) & " KB", B2<1073741824, ROUND(B2/1048576,1) & " MB", TRUE, ROUND(B2/1073741824,1) & " GB")

Bu formül şunları gösterir:

• 1024’ün altındaki değerler için Bytes

• 1 MB altındaki değerler için KB

• 1 GB altındaki değerler için MB

• Daha büyük olanlar için GB

IFS() ile dosya boyutunu Bytes, KB, MB, GB olarak dönüştürün. Görsel: Yazar.

IFS() vs. IF() vs. İç İçe IF()

Excel’de birden fazla koşulla çalışırken üç seçeneğiniz vardır: IF(), iç içe IF() veya IFS() işlevi. Her biri farklı çalışır; işte doğru olanı nasıl seçeceğiniz.

Okunabilirlik karşılaştırması

Sadece bir veya iki koşulu kontrol ediyorsanız, temel IF() işlevi idealdir. Hızlı, basit ve işe yarar. Ancak birden çok koşulu kontrol etmeye çalıştığınızda işler zorlaşır. İşte o zaman IF() işlevlerini birbirinin içine yığmaya başlarız; bu da formülü okumayı ve sonradan değiştirmeyi zorlaştırır.

Örneğin:

=IF(A1<60,"F",IF(A1<70,"D",IF(A1<80,"C",IF(A1<90,"B","A"))))

Çalışır, ancak takip etmesi kolay değildir. Tüm bu parantezler okumayı ve güncellemeyi zorlaştırır.

İç içe IF() okumak ve anlamak zordur. Görsel: Yazar. 

Aynı mantığa bir de IFS() ile bakın:

=IFS(A1<60,"F", A1<70,"D", A1<80,"C", A1<90,"B", A1>=90,"A")

Bu çok daha basit görünüyor. Her koşul, herhangi bir iç içe geçirme veya parantez kalabalığı olmadan doğrudan bir sonuçla eşleştirilmiştir. Okuması, anlaması ve sonradan düzeltmesi kolay bir formül istiyorsanız, IFS() harika bir seçimdir.

IFS() okumak ve anlamak çok daha kolaydır. Görsel: Yazar.

Performans değerlendirmeleri

IFS() işlevi, bir eşleşme bulmuş olsa bile verdiğiniz tüm koşulları kontrol eder. Yani beş koşul sıralarsanız, Excel yine de hepsini değerlendirir.

Ancak iç içe IF() işlevleri biraz daha akıllıdır. “Kısa devre” kullanırlar; yani ilk TRUE koşulu bulur bulmaz dururlar. Bu, çok sayıda formül içeren büyük çalışma sayfalarında biraz zaman kazandırır.

Hızlı karşılaştırma: Ne zaman hangisi

IF(), iç içe IF() ve IFS() ne zaman kullanılmalı, anlamak için hızlı bir tablo karşılaştırması:

IFS ve SWITCH()

IFS() ve SWITCH() tek bir formül içinde birden fazla koşulu kontrol eder ancak farklı şekillerde çalışırlar. İşte ikisinin ayrıntılı bir karşılaştırması:

Dikkat Edilecek Noktalar

Excel’de IFS() işleviyle çalışırken aklınızda bulundurmanız gereken birkaç nokta vardır.

Yaygın hatalar ve çözümleri

Önce karşılaşabileceğiniz yaygın hatalara bakalım.

Yetersiz bağımsız değişken

Bir koşul ekler de, doğruysa ne olacağını (value_if_true) eklemeyi unutursak Excel şu açılır uyarıyı gösterir: "Bu işlev için çok az bağımsız değişken girdiniz."

#N/A hatası

#N/A hatası, formüldeki hiçbir koşul TRUE olmadığında oluşur. Excel’in en az bir eşleşmeye ihtiyacı vardır; aksi hâlde takılır. #N/A görüntülemek istemiyorsanız, sona bir geri dönüş değeriyle TRUE ekleyin.

#VALUE! Hatası

#VALUE! hatası, bir logical_test bağımsız değişkeni net bir TRUE veya FALSE döndürmediğinde ortaya çıkar. Belki bir yazım hatası vardır ya da koşul doğru kurulmamiştır. Her iki durumda da Excel ne yapacağını bilemez; bu yüzden mantığınızı tekrar kontrol edin.

İpuçları ve en iyi uygulamalar

Şimdi formüllerinizi daha iyi ve daha basit yapmak için birkaç iyi uygulama: 

• Mümkün olduğunca basit tutmaya çalışın. On veya daha az koşul genellikle yeterlidir.

• Son koşul olarak TRUE kullanarak bir geri dönüş (fallback) ekleyin. Ana koşullarınıza uymayan durumları kapsar.

• Her koşulun bir sonucu olduğundan ve testlerinizin TRUE veya FALSE döndürdüğünden emin olun.

• 0, 100 veya boş hücreler gibi sınır durumlarıyla formülünüzü test edin; beklediğiniz gibi her şeyi ele aldığından emin olun.

Artılar ve eksiler

IFS()ın önemli avantajları vardır; ancak dikkat edilmesi gereken birkaç nokta da bulunur.

Son Düşünceler 

IFS() işlevi, formülünüzün karmaşıklaşmasına izin vermeden çok sayıda koşulu kontrol etmenin kullanışlı bir yoludur. Birbirinin içine yığılmış çok sayıda IF() ifadesine göre daha okunabilir ve mantığınızı daha net kılar. Koşullarınızı doğru sırayla yazdığınızdan ve mutlaka sona bir TRUE geri dönüşü eklediğinizden emin olun — böylece hiçbir şey eşleşmese bile formülünüz bozulmaz.

Mantığınız öngörülebilir ve net kuralları takip ediyorsa, IFS() çalışma sayfanızı düzenli ve yönetimi kolay tutmanın harika bir yoludur.