Las 20 fórmulas básicas de Excel que todo el mundo debe conocer

Explora las fórmulas esenciales de Excel con ejercicios prácticos en nuestro curso de Introduction to Excel.

¿Por qué son importantes las fórmulas de Excel?

Las fórmulas de Excel son clave por varias razones:

1. Eficiencia: automatizan tareas repetitivas, ahorrando tiempo y reduciendo errores manuales.
2. Análisis de datos: la variedad de fórmulas de Excel permite análisis sofisticados, cruciales para tomar decisiones informadas.
3. Precisión: garantizan resultados consistentes y exactos, esenciales en finanzas y contabilidad.
4. Manipulación de datos: facilitan ordenar, filtrar y transformar grandes volúmenes de datos.
5. Accesibilidad: Excel ofrece una interfaz intuitiva que acerca el análisis complejo a perfiles no técnicos.
6. Versatilidad: se usa en muchos sectores; dominar las fórmulas mejora la empleabilidad y acelera tu carrera profesional.
7. Personalización: Excel permite adaptar fórmulas a necesidades específicas de gestión de datos.

En resumen, las fórmulas de Excel son una base imprescindible para gestionar datos, analizarlos y tomar decisiones con confianza.

Cómo usar fórmulas en Excel

Añadir una fórmula en Excel es bastante sencillo. Si ya manejas algún software de business intelligence, te saldrá de forma natural.  

La forma más rápida y eficaz es escribirlas manualmente. En el siguiente ejemplo, calculamos el IMC (Índice de masa corporal) de los atletas de la tabla.

BMI = weight (KG)/ (Height (m))^2 Con la tecnología de

1. Elige la celda donde quieres el resultado. Puedes seleccionarla con el ratón o moverte con las flechas. 

2. Escribe = en la celda. El signo igual aparecerá en la celda y en la barra de fórmulas. 

3. Escribe la referencia de la celda que vamos a usar en el cálculo. En nuestro caso, es E2 (peso/KG).

4. Añade el signo de división /

5. Para convertir la altura de centímetros a metros, dividimos D2 entre 100.

6. Eleva al cuadrado ^2 la altura y pulsa Enter. 

7. La fórmula final queda así: =E2/(D2/100)^2.

Nota: para obtener la referencia de cualquier celda, mira el nombre de la columna (A, B, C, …) y combínalo con el número de fila (1, 2, 3, …). Por ejemplo, A2, B5 o C12.   

Listo: hemos calculado correctamente el IMC de A Dijiang.

Añadir fórmulas en Excel | Autor

También podemos añadir fórmulas usando la interfaz asistida (GUI). Es muy simple. 

En el siguiente ejemplo, usaremos la GUI para añadir una función IF() que convierta ‘M’ en ‘Male’ y ‘F’ en ‘Female’.

1. Haz clic en el botón fx junto a la barra de fórmulas.

2. Se abrirá una ventana con las funciones más usadas.

3. Puedes buscar una función concreta o seleccionarla desplazándote. En nuestro caso, elegimos IF(). 

4. Añade la lógica B2="M" en el argumento logical_test.

5. Añade “Male” en value_if_true y “Female” en value_if_false. 

Funciona igual que una sentencia if-else: si logical_test es TRUE, la fórmula devuelve “Male”; si no, “Female”.

Fórmula de Excel con la interfaz | Autor

Cómo insertar fórmulas en toda una columna

Ya hemos visto cómo añadir una fórmula a una sola fila. Ahora aplicaremos la misma fórmula a toda una columna. 

Hay varias maneras de hacerlo: 

• Arrastrar el controlador de relleno: al seleccionar la celda, verás un pequeño recuadro verde en la esquina inferior derecha. Es el controlador de relleno. Haz clic, mantén pulsado y arrastra hasta la última fila. Es la forma más común de aplicar fórmulas a varias filas. 
• Doble clic en el controlador de relleno: selecciona la celda con la fórmula y haz doble clic en el controlador. En segundos aplicará la fórmula a toda la columna. 
• Atajo: selecciona la celda con la fórmula y las celdas vacías de debajo. Pulsa CTRL + D para aplicar la fórmula. Asegúrate de no seleccionar nada por encima de la celda con la fórmula. 
• Copiar y pegar: copia la celda con la fórmula (CTRL + C), selecciona las filas vacías de una columna y pégala (CTRL + V). Evita usar el controlador de relleno para seleccionar filas. 

La animación siguiente muestra todas las formas de aplicar una fórmula a varias celdas. 

Fórmula para toda una columna | Autor

Fórmulas básicas en Excel 

Ahora repasemos las fórmulas clave en Excel. Empezaremos por funciones comunes e importantes que, como decíamos, son operaciones integradas que puedes usar dentro de fórmulas para tareas específicas.

Para esta sección, usaremos un subconjunto del dataset de Olympics de DataCamp. Para simplificar, trabajaremos sobre las columnas name, sex, age, height y weight de cuatro atletas. En cada caso, escribirás el nombre de la función y sus argumentos. Nada complicado. 

1. SUM()

La función SUM() suma los números de las celdas que selecciones. Funciona con celdas numéricas y acepta una celda, un rango o varios rangos.

En nuestro caso, aplicaremos SUM() al rango de C2 a C5 y guardaremos el resultado en C6. Suma 24, 23, 21 y 31. También puedes aplicarla a varias columnas.

=SUM(C2:C5)Con la tecnología de

Echa un vistazo a nuestra guía completa para sumar en Excel para saber más.

2. MIN() y MAX()

MIN() requiere un rango de celdas y devuelve el valor mínimo. Por ejemplo, queremos mostrar el peso mínimo de todos los atletas en la celda E6. MIN() buscará el menor valor y mostrará 60.

=MIN(E2:E5)Con la tecnología de

MAX() es lo contrario de MIN(): devuelve el valor máximo del rango seleccionado. En el ejemplo, devuelve 82. 

=MAX(E2:E5)Con la tecnología de

3. AVERAGE()

AVERAGE() calcula la media de las celdas seleccionadas. Puedes pasarle un rango (C2:C5) o celdas sueltas (C2, C3, C5).

Para calcular la media de edad de los atletas, seleccionaremos la columna age, aplicaremos la función y devolveremos el resultado en C7. Suma los valores y los divide entre 4.

=AVERAGE(C2:C5) Con la tecnología de

Tenemos una guía detallada sobre AVERAGE() en Excel si quieres profundizar.

4. COUNT()

COUNT() cuenta cuántas de las celdas seleccionadas contienen números. Omite celdas en blanco y celdas con texto.

Contaremos cuántos pesos de atletas hay, y devolverá 4, ya que no hay valores perdidos ni texto. 

=COUNT(E2:E5)Con la tecnología de

Para contar todo tipo de celdas (fecha y hora, texto, números), usa COUNTA(). 

COUNTA() no cuenta los valores ausentes. Para celdas vacías, usa COUNTBLANK().

Si quieres más ejemplos de cómo usar COUNT() en Excel, consulta nuestra guía.

5. POWER()

Al principio vimos que se puede elevar con ^, alternativa a POWER(). Usa x^y o POWER(x,y); POWER puede ser más claro en fórmulas anidadas para cuadrar, cubicar o elevar a cualquier potencia.

En nuestro caso, dividimos D2 entre 100 para obtener la altura en metros y la elevamos al cuadrado con POWER() usando 2 como segundo argumento.   

=POWER(D2/100,2)Con la tecnología de

6. CEILING() y FLOOR()

Como explicamos en nuestra guía sobre ROUND() en Excel, la función CEILING() redondea un número hacia arriba al múltiplo especificado más cercano. Por ejemplo:

• =CEILING(3.24, 1) redondea 3,24 a 4.

• =CEILING(3.24, 5) redondea 3,24 a 5.

Veamos un ejemplo práctico. Redondeamos F2 al múltiplo de 1 y obtenemos 4. 

=CEILING(F2,1)Con la tecnología de

Opcional: =CEILING.MATH(F2,1)

Por el contrario, FLOOR() redondea un número hacia abajo al múltiplo indicado. Por ejemplo:

• =FLOOR(3.24, 1) redondea 3,24 a 3.

• =FLOOR(3.24, 5) redondea 3,24 a 0.

Como vemos abajo, en lugar de convertir 3,24 en 4, lo redondea a 3. 

=FLOOR(F2,1)Con la tecnología de

Opcional: =FLOOR.MATH(F2,1)

Estas funciones son especialmente útiles cuando trabajas con intervalos estandarizados, como redondear precios, tiempos o cantidades a unidades fijas.

7. CONCAT()

La función CONCAT() une cadenas. Prioriza CONCAT o TEXTJOIN frente a la heredada CONCATENATE; usa TEXTJOIN cuando necesites un delimitador o ignorar vacíos. Por ejemplo, si queremos unir la age y el sex de los atletas, usaremos CONCAT(). La función convierte automáticamente el valor numérico de age a texto y lo combina. 

“24” & “M” = “24M”

=CONCAT(C2,B2)Con la tecnología de

Descubre más sobre esta función en nuestra guía para usar CONCAT() en Excel.

8. TRIM()

Como explicamos en la guía completa de TRIM() en Excel, esta función elimina espacios extra al principio, en medio y al final. Suele usarse para detectar duplicados que parecen distintos por espacios de más.  

Por ejemplo:

1. En A3 hay dos espacios extra: “A   Lamusi”, y TRIM() los elimina correctamente.
2. En A4 “ Christine Jacoba Aaftink” hay un espacio extra al inicio, y TRIM() lo quita sin necesidad de funciones complejas. 

=TRIM(A4)Con la tecnología de

9. REPLACE() y SUBSTITUTE()

REPLACE() sirve para sustituir parte de una cadena por otra nueva.

REPLACE(old_text, start_num, num_chars, new_text)Con la tecnología de

• old_text es el texto original o la celda con el texto.

• start_num es la posición desde la que quieres empezar a sustituir. 

• num_chars es el número de caracteres a reemplazar.

• new_text es el texto nuevo que reemplaza al anterior.

Por ejemplo, cambiaremos A Dijiang por B Dijiang indicando la posición 1, el número de caracteres a sustituir (1) y el nuevo carácter “B”. 

=REPLACE(A2,1,1,"B")Con la tecnología de

SUBSTITUTE() es similar a REPLACE(), pero en vez de indicar posiciones y longitudes, solo pasas el texto antiguo y el nuevo. 

SUBSTITUTE(text, old_text, new_text, [instance_num])Con la tecnología de

Nota: usa instance_num para reemplazar solo una ocurrencia concreta

En nuestro caso, sustituimos "Jacoba" por "Rahim" para mostrar en A4 “Christine Rahim Aaftink”.

SUBSTITUTE() solo cambia las celdas que contienen el texto indicado. La celda A5, “Per Knut Aaland”, no contiene “Jacoba”, así que no cambia. REPLACE() funciona por posición y cambia los caracteres que estén en esa posición, coincidan o no.

=SUBSTITUTE(A4,"Jacoba","Rahim")Con la tecnología de

10. LEFT(), RIGHT() y MID()

LEFT() devuelve el número de caracteres desde el inicio de una cadena. 

Por ejemplo, para mostrar el nombre de pila de “Christine Jacoba Aaftink”, usa LEFT() con 9 caracteres. Mostrará “Christine”.

=LEFT(A2,9)Con la tecnología de

MID() necesita una posición de inicio y una longitud para extraer caracteres del medio. 

Para mostrar el segundo nombre, empieza por “J” (posición 11) y usa 6 como longitud de “Jacoba”.

=MID(A2,11,6)Con la tecnología de

RIGHT() devuelve caracteres desde el final; solo indica cuántos. 

Por ejemplo, para mostrar el apellido “Aaftink”, usamos RIGHT() con siete caracteres. 

=RIGHT(A2,7)Con la tecnología de

11. UPPER(), LOWER() y PROPER()

UPPER(), LOWER() y PROPER() son operaciones básicas de texto. Encontrarás equivalentes en Tableau o Python. Solo necesitan el texto, la celda con la cadena o un rango de celdas. 

UPPER() convierte todo el texto a mayúsculas. 

=UPPER(A1)Con la tecnología de

LOWER() convierte el texto seleccionado a minúsculas.

=LOWER(A1)Con la tecnología de

PROPER() pone en mayúscula la inicial de cada palabra y el resto en minúsculas. 

=PROPER(A1)Con la tecnología de

12. NOW() y TODAY()

NOW() devuelve la fecha y hora actuales y TODAY() solo la fecha actual. Son sencillas y las usaremos para extraer día, mes, año, horas y minutos de una celda de fecha y hora. 

El ejemplo siguiente devuelve la fecha y hora actuales.

=NOW()Con la tecnología de

Para extraer los segundos de la hora, usa SECOND(). 

=SECOND(NOW())Con la tecnología de

De forma similar, TODAY() devuelve solo la fecha actual. 

=TODAY()Con la tecnología de

Para extraer el día, usa DAY().

Además, puedes extraer mes, año, día de la semana, nombre del día, horas y minutos del campo de fecha y hora. 

=DAY(TODAY())Con la tecnología de

13. DATEDIF()

DATEDIF() calcula la diferencia entre dos fechas y la devuelve en días, meses o años, según la unidad elegida.

Precaución: DATEDIF es una función de compatibilidad heredada y puede ser imprecisa con algunas unidades (p. ej., "MD"). Considera usar DAYS(), YEARFRAC() o aritmética con DATE cuando sea posible.

En el ejemplo siguiente, queremos la diferencia en días usando “d” como unidad. Asegúrate de que el primer argumento es la fecha de inicio y el segundo, la fecha de fin. 

start_date < end_date

=DATEDIF(A2,B2,"d")Con la tecnología de

14. VLOOKUP() y HLOOKUP()

La hoja worksheet1 que usaremos aquí contiene todos los datos del dataset de Olympics.

worksheet1

VLOOKUP() busca un valor en la columna más a la izquierda del rango y devuelve el valor de la misma fila en la columna especificada. 

Nota: VLOOKUP() y HLOOKUP() son funciones heredadas/de compatibilidad. Microsoft recomienda usar XLOOKUP() en trabajos nuevos: sustituye a ambas, busca coincidencia exacta por defecto, puede buscar en cualquier dirección y tiene argumento if_not_found. Lee nuestra guía sobre cómo usar XLOOKUP y la comparativa XLOOKUP vs VLOOKUP.

VLOOKUP(lookup_value, table_array, col_index, range_lookup)

• lookup_value: el valor que buscas, presente en la primera columna. 

• table_array: el rango de la tabla, hoja o celdas seleccionadas con varias columnas. 

• col_index: la posición de la columna de la que extraer el valor.

• range_lookup: “TRUE” para coincidencia aproximada (por defecto) y “FALSE” para coincidencia exacta.

En nuestro ejemplo, buscamos A Dijiang (A2) en el rango de worksheet1 (B2:H20). VLOOKUP() comprobará la columna de nombre en worksheet1 y devolverá el valor de la 6.ª columna, el equipo “China”.

=VLOOKUP(A2,worksheet1!B2:H20,6,FALSE)Con la tecnología de

HLOOKUP() busca en la primera fila (en vez de la primera columna) y devuelve el valor de la columna y la fila indicadas. 

HLOOKUP(lookup_value, table_array, row_index, range_lookup)

En nuestro caso, mostraremos el sex de A Dijiang en la celda D8. HLOOKUP() busca el nombre en la primera fila y devuelve “M” de la 2.ª fila de esa misma columna. En ambos casos usamos FALSE para coincidencia exacta. 

=HLOOKUP(B1, B1:E5, 2, FALSE)Con la tecnología de

15. IF()

IF() en Excel es muy directa. Funciona como una estructura if-else en programación: defines la lógica; si se cumple, devuelve un valor, y si no, devuelve otro. 

Por ejemplo, si el IMC de un atleta es menor que 24,9, la función devolverá “Below 24.9”; en caso contrario, “24.9 or above”. Es muy útil para convertir números en categorías.

=IF(G2<24.9,"Below 24.9","24.9 or above")Con la tecnología de

16. SUMIF()

SUMIF() suma solo las celdas que cumplen una condición. Acepta tres argumentos:

SUMIF(range, criteria, [sum_range])Con la tecnología de

• range: celdas que se comprobarán con la condición.

• criteria: la condición, como “M” o “>10”. Pon texto y operadores de comparación entre comillas.

• sum_range: celdas que se sumarán. Si lo omites, Excel suma las celdas de range.

Por ejemplo, para sumar el peso de los atletas masculinos, comprobamos la columna sex (B2:B5) en busca de “M” y sumamos los pesos coincidentes de E2:E5. El resultado es 215.

=SUMIF(B2:B5,"M",E2:E5)Con la tecnología de

Para aplicar más de una condición a la vez, usa SUMIFS().

17. COUNTIF()

COUNTIF() cuenta las celdas que cumplen una condición. A diferencia de COUNT(), también funciona con texto. Acepta dos argumentos:

COUNTIF(range, criteria)Con la tecnología de

• range: celdas que se comprobarán con la condición.

• criteria: la condición, como “M” o “>24”. Pon texto y operadores de comparación entre comillas.

Por ejemplo, para contar los atletas masculinos, comprobamos la columna sex (B2:B5) en busca de “M”. El resultado es 3.

=COUNTIF(B2:B5,"M")Con la tecnología de

Para contar con más de una condición a la vez, usa COUNTIFS().

18. ROUND()

ROUND() redondea un número al número de dígitos que elijas. Acepta dos argumentos:

ROUND(number, num_digits)Con la tecnología de

• number: el valor o celda a redondear.

• num_digits: cuántos dígitos conservar. Un número positivo mantiene ese número de decimales; 0 redondea a entero; un número negativo redondea a la izquierda del decimal (-1 al múltiplo de 10 más cercano).

Por ejemplo, F2 contiene 3,24. Para redondearlo a un decimal, usa 1 como segundo argumento. El resultado es 3,2.

=ROUND(F2,1)Con la tecnología de

ROUND() siempre redondea al valor más cercano. Para forzar hacia arriba o hacia abajo, usa ROUNDUP() o ROUNDDOWN(). Para más ejemplos, consulta nuestra guía de ROUND() en Excel.

19. IFERROR()

IFERROR() comprueba una fórmula y devuelve el valor que elijas si produce un error. Si no hay error, devuelve el resultado normal. Acepta dos argumentos:

IFERROR(value, value_if_error)Con la tecnología de

• value: la fórmula o celda a comprobar.

• value_if_error: qué mostrar si la fórmula devuelve un error: texto, número o cadena vacía (“”).

Por ejemplo, con la fórmula del IMC anterior: si falta la altura de un atleta, la fórmula divide entre cero y muestra #DIV/0!. Al envolverla en IFERROR(), muestra “Missing data”.

=IFERROR(E2/(D2/100)^2,"Missing data")Con la tecnología de

IFERROR() captura todo tipo de errores, incluidos #N/A, #VALUE! y #REF!, así que también puede ocultar fallos reales. Úsalo cuando sepas qué error esperar y revisa los resultados tras aplicarlo.

20. XLOOKUP()

XLOOKUP() busca un valor en un rango y devuelve el valor coincidente de otro. Es el reemplazo moderno de VLOOKUP() y HLOOKUP(). Tiene tres argumentos obligatorios y tres opcionales:

XLOOKUP(lookup_value, lookup_array, return_array, [if_not_found], [match_mode], [search_mode])Con la tecnología de

• lookup_value: el valor a buscar.

• lookup_array: el rango donde buscar.

• return_array: el rango del que devolver el resultado.

• if_not_found: qué mostrar si no hay coincidencia, como “Not found”. Si lo omites, Excel muestra #N/A.

• match_mode: opcional. Por defecto, XLOOKUP() busca coincidencia exacta.

• search_mode: opcional. Por defecto, busca de primero a último.

Por ejemplo, buscamos A Dijiang (A2) en la columna name de worksheet1 (B2:B20) y devolvemos el valor correspondiente de la columna team (G2:G20). Devuelve “China”, igual que el ejemplo con VLOOKUP().

=XLOOKUP(A2,worksheet1!B2:B20,worksheet1!G2:G20)Con la tecnología de

A diferencia de VLOOKUP(), no cuentas posiciones de columna y la columna de búsqueda no tiene que ser la más a la izquierda. Para mostrar un mensaje personalizado si no hay coincidencia, añade el cuarto argumento:

=XLOOKUP(A2,worksheet1!B2:B20,worksheet1!G2:G20,"Not found")Con la tecnología de

XLOOKUP() está disponible en Microsoft 365 y Excel 2021 o posteriores. En versiones anteriores, usa VLOOKUP(). Para saber más, lee nuestra guía de XLOOKUP() y la comparativa XLOOKUP() vs VLOOKUP().

Otros tipos de fórmulas en Excel

Veamos ahora otros tipos de fórmulas: con operadores, fórmulas de matriz y formato condicional basado en fórmulas.

Fórmulas con operadores

Algo tan simple como A1 + A2 es una fórmula porque realiza un cálculo con referencias y un operador, igual que las más complejas. Excel también actualiza el resultado dinámicamente al cambiar A1 o A2. Todo esto cuenta como fórmula:

• Suma: =A1 + B1

• Resta: =A1 - B1

• Multiplicación: =A1 * B1

• División: =A1 / B1

Parece básico, pero es la base de patrones más avanzados como secuencias y cálculos recursivos. Así puedes crear una secuencia de Fibonacci:

• Escribe 0 en A1 y 1 en A2.
• En A3, escribe =A1+A2 y arrastra el controlador de relleno hacia abajo. Cada celda nueva suma las dos superiores.

Fórmulas de matriz

Las fórmulas de matriz realizan varios cálculos a la vez y devuelven un único resultado o varios valores en un rango. Son muy útiles para operaciones con múltiples condiciones o cálculos en datasets grandes.

Aquí tienes un ejemplo que suma valores al cuadrado en un rango: =SUM(A1:A5^2). Puede ser útil si estás pensando en algo como una regresión en Excel. Empieza con el signo igual y realiza un cálculo, pero va más allá del simple ejemplo de SUM() por el uso del acento circunflejo.  

Formato condicional basado en fórmulas

Excel permite aplicar formato condicional usando fórmulas personalizadas en lugar de reglas predefinidas. Por ejemplo, un formato basado en condiciones por fila a través de varias columnas no funcionaría como fórmula de celda normal, pero sí dentro del formato condicional. 

Ejemplo: resaltar una fila completa si una celda cumple una condición. Imagina una tabla donde la columna C contiene estados de pedido ("Pending" o "Shipped") y queremos resaltar las filas con estado "Pending". Pasos:

1. Selecciona todo el rango de tu tabla (p. ej., A2:E100).

2. Ve a Inicio > Formato condicional > Nueva regla.

3. Elige Usar una fórmula para determinar qué celdas se formatean.

4. Introduce esta fórmula: =$C2="Pending"

5. Haz clic en Formato, elige un color de relleno y pulsa OK.

Esta fórmula se parece a algo que pondrías en una celda, pero aquí se aplica de forma relativa por fila y funciona en todo el rango seleccionado. En una celda, =$C2="Pending" devolvería TRUE o FALSE; en formato condicional, Excel resalta dinámicamente filas completas según nuestra lógica.

Combinar funciones en fórmulas

Hasta ahora hemos usado una función cada vez. En la práctica, las fórmulas más útiles combinan varias.

Una función es una operación integrada con nombre y argumentos, como SUM() o IF(). Una fórmula es todo lo que tecleas tras el signo igual. Puede contener una o varias funciones, referencias a celdas, números y operadores como +, / y ^.

Recuperemos la fórmula del IMC, ahora redondeada:

=ROUND(E2/(D2/100)^2,1)Con la tecnología de

• = le dice a Excel que es una fórmula.

• ROUND es la función.

• E2 y D2 son referencias.

• / y ^ son operadores.

• 100, 2 y 1 son números fijos.

Excel evalúa de dentro hacia fuera. Si una función está dentro de otra, primero se ejecuta la interna y su resultado pasa a la externa. Los ejemplos siguientes se construyen unos sobre otros.

Redondear un cálculo

La fórmula del IMC devuelve muchos decimales. Envuélvela en ROUND() para quedarte con uno.

=ROUND(E2/(D2/100)^2,1)Con la tecnología de

Excel divide el peso entre la altura al cuadrado y luego redondea el resultado.

Gestionar datos ausentes

Si la altura de un atleta está en blanco, el ejemplo 1 devuelve #DIV/0!. Envuelve todo con IFERROR().

=IFERROR(ROUND(E2/(D2/100)^2,1),"Missing data")Con la tecnología de

Ahora hay tres capas: el cálculo, ROUND() y IFERROR().

Limpiar texto en un solo paso

TRIM() elimina espacios extra y PROPER() arregla las mayúsculas. Combínalas para limpiar A3, “A Lamusi”, de una vez.

=PROPER(TRIM(A3))Con la tecnología de

Primero se ejecuta TRIM() y luego PROPER() da formato al resultado.

Clasificar valores en categorías

Anida una IF() dentro de otra para clasificar los IMC en tres grupos.

=IF(G2<18.5,"Below 18.5",IF(G2<25,"18.5 to 24.9","25 or above"))Con la tecnología de

Si la primera prueba es verdadera, Excel devuelve “Below 18.5”. Si no, pasa a la segunda IF().

Usar el resultado de una función en un cálculo

Puedes usar el resultado de una función en un cálculo. Para hallar la cuota de peso total que corresponde a los atletas masculinos, divide un SUMIF() entre un SUM().

=SUMIF(B2:B5,"M",E2:E5)/SUM(E2:E5)Con la tecnología de

Da formato de porcentaje a la celda para ver el resultado.

Hacer más segura una búsqueda

Si VLOOKUP() no encuentra coincidencias, devuelve #N/A. Envuélvelo con IFERROR() para mostrar algo más amable.

=IFERROR(VLOOKUP(A2,worksheet1!B2:H20,6,FALSE),"Not found")Con la tecnología de

XLOOKUP() ya incorpora esto con su cuarto argumento, así que ahí no necesitas IFERROR().

Consejos para fórmulas largas

• Construye de dentro hacia fuera. Haz que la función interna funcione en su propia celda y luego ve envolviendo con la siguiente.
• Cuida los paréntesis. Cada paréntesis de apertura necesita su cierre. Excel colorea los pares a medida que escribes.
• Mantén la legibilidad. Si una fórmula necesita más de dos o tres capas, divide el cálculo en columnas auxiliares.

Formación de tu equipo en Excel

Hemos cubierto las fórmulas de Excel que todo el mundo debería conocer, pero formar a varias personas en esto no siempre es sencillo. Tenemos una guía específica sobre formación corporativa en Excel, pero merece la pena mencionarlo aquí.

Excel es mucho más que una hoja de cálculo: a menudo es esencial para gestionar datos, analizar finanzas y tomar decisiones. Invertir en formación de Excel puede impulsar la productividad, la precisión y la eficiencia de tu equipo. Entre los beneficios clave:

• Análisis de datos: competencias avanzadas en Excel permiten interpretar datos con más profundidad y tomar mejores decisiones.

• Eficiencia: la automatización en hojas reduce trabajo manual y errores.

• Precisión financiera: dominar funciones como VLOOKUP() y las tablas dinámicas mejora la gestión financiera.

• Optimización operativa: las herramientas de manipulación de datos de Excel agilizan el manejo de grandes volúmenes, mejorando operaciones.

• Ventaja competitiva: la soltura en Excel te da ventaja para perfeccionar procesos y descubrir insights.

Si quieres formar a tu equipo en habilidades de Excel, desde lo básico hasta fórmulas avanzadas, DataCamp For Business es ideal. Tanto si sois 2 como 10.000 personas, DataCamp For Business ofrece materiales dedicados de Excel y hojas de cálculo, la posibilidad de crear itinerarios de aprendizaje a medida para escalar y personalizar la formación, y informes detallados para medir el impacto de la formación. Solicita una demo hoy para empezar. 

Conclusión

Microsoft Excel es una aplicación potente y fácil de usar para el análisis y la elaboración de informes. En este artículo, has visto la importancia de las fórmulas básicas y cómo te permiten abordar cálculos complejos. Además, has aprendido diferentes formas de añadir fórmulas a las hojas y hemos profundizado en las más esenciales. 

Para seguir aprendiendo Excel y cómo aplicar estas fórmulas al análisis de datos, haz nuestro curso Data Analysis in Excel. Te enseñará los fundamentos de exploración, procesamiento y análisis de datos. Si prefieres el stack de Google y usas Google Sheets, prueba Data Analysis in Spreadsheet.

También puedes dar un paso más con los fundamentos de las hojas de cálculo. Aprenderás análisis de datos, técnicas avanzadas de manipulación, tablas dinámicas y visualización. Por último, consulta nuestra chuleta de fórmulas de Excel como guía rápida y descubre más sobre tipos de datos en Excel.