Función SUMIFS() en Excel: Sumar Datos con Múltiples Criterios

La función SUMIFS() de Excel suma números basándose en múltiples condiciones para darnos un control preciso sobre los cálculos. A diferencia de SUMIF(), que comprueba una condición, SUMIFS() trata varias condiciones a la vez.

En este artículo, te mostraré cómo utilizar SUMIFS() con ejemplos avanzados y consejos para solucionar problemas. Al final, sabrás cómo utilizar SUMIFS() para que tus cálculos sean más precisos y eficaces.

La respuesta rápida

Para utilizar la función SUMIFS() en Excel:

• Escribe =SUMIFS( para iniciar la función.

• Selecciona el rango que contiene los valores a sumar.

• Selecciona el rango donde se aplicará la condición.

• Introduce la condición que debe coincidir.

• Cierra los paréntesis y pulsa Intro.

Aquí he sumado todas las ventas superiores a 200.

=SUMIFS(B2:B8, B2:B8, ">200")

Suma los valores utilizando la función SUMIFS(). Imagen del autor.

Comprender la función SUMIFS()

La función SUMIFS() de Excel suma valores sólo cuando se cumplen todas las condiciones especificadas. Admite operadores lógicos como mayor que >, menor que <, igual a =, y no igual a <>, así como caracteres comodín para coincidencias parciales. La función funciona con números, texto y fechas.

Sintaxis de SUMIFS()

La función SUMIFS() define primero el rango de valores a sumar, seguido de pares de rangos de condiciones y criterios. Observa que SUMIFS() puede manejar más de una condición lógica.

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Toma:

• sum_range es el rango de celdas que quieres añadir.

• criteria_range1 es el primer rango en el que comprobamos una condición.

• criteria1 es la condición aplicada a criteria_range1.

• [criteria_range2, criteria2], … son opcionales. Puedes añadir más pares de rangos y condiciones. Cada pareja añade otra condición que debe cumplirse.

Ten en cuenta que criteria_range (el rango donde se comprueban las condiciones) debe tener el mismo número de filas y columnas que sum_range (el rango que se suma).

Ejemplo de SUMIFS()

Probemos con un ejemplo básico. Tengo un conjunto de datos de frutas con sus cantidades y ventas. Y quiero encontrar las ventas totales de Manzanas en las que la Cantidad es mayor que 5. Así que mi fórmula sería

=SUMIFS(C2:C8, A2:A8, "Apples", B2:B8, ">5")

Aquí C2:C8 es el rango de valores a sumar (Sales ($)). A2:A8, "Apples" es la condición para incluir sólo las filas en las que el producto sea Manzanas. Y B2:B8, ">5" es la condición para incluir sólo las filas en las que la Cantidad sea superior a 5.

Fórmula SUMIFS() para sumar las ventas en una condición. Imagen del autor.

SUMIF() vs. SUMIFS()

La principal diferencia entre SUMIF() y SUMIFS() es el número de condiciones que utilizan. El SUMIF() maneja una única condición. Pero SUMIFS() puede manejar múltiples condiciones. 

Casos prácticos de SUMIFS() en Excel

Ahora que ya sabes cómo funciona la función SUMIFS(), veamos algunos casos avanzados en los que podemos utilizarla en el mundo real.

Utilizar SUMIFS() con distintos tipos de datos

SUMIFS() puede trabajar con distintos tipos de datos, como números, texto y fechas. Supongamos que tengo un informe de ventas, pero en algunas filas faltan los nombres de los clientes. Y quiero resumir sólo aquellos en los que tenemos el nombre del cliente. Para ello, utilizo la siguiente fórmula:

=SUMIFS(C2:C5, A2:A5, "<>")

Esta fórmula examina la columna Cliente, comprueba si hay celdas en blanco y suma las ventas correspondientes.

Suma todas las celdas que no estén en blanco con la función SUMIFS(). Imagen del autor.

Para sumar las ventas en las que faltan nombres de clientes, utilizo esta fórmula:  

=SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Suma las celdas en blanco con la función SUMIFS(). Imagen del autor.

En lugar de codificar la condición, podemos almacenarla en otra celda. Si quiero sumar las ventas de Sarah Lee, lo escribo en la celda E3 y utilizo esta fórmula:

=SUMIFS(C2:C5, A2:A5, E3)

Cada vez que cambie el valor en E3, el total se actualizará automáticamente. 

Utiliza SUMIFS() para sumar valores utilizando la referencia de la celda. Imagen del autor.

Aplicar la lógica OR en SUMIFS()

Sabemos que SUMIFS() sólo utiliza la lógica AND, lo que significa que todas las condiciones que establezcamos deben ser verdaderas para sumar los valores. Sin embargo, si queremos utilizar la lógica OR, que suma valores aunque se cumpla alguna de las múltiples condiciones, podemos hacerlo combinando varias SUMIFS().

Por ejemplo, si quiero sumar las ventas de John Doe O Drake White, combino dos fórmulas de SUMIFS() de esta forma:

=SUMIFS(C2:C8, A2:A8, "John Doe") + SUMIFS(C2:C8, A2:A8, "Drake White")

Como Drake White no está en la lista, esa parte de la fórmula devuelve 0. El total sólo incluye las ventas de John Doe, lo que demuestra cómo funciona la lógica de OR.

Utiliza la lógica OR en la función SUMIFS(). Imagen del autor.

En Excel 365 o posterior, podemos simplificarlo con una fórmula de matriz y nos devolverá el mismo resultado.

=SUMIFS(C2:C8,A2:A8,{"John Doe","Drake White"})

Utiliza la fórmula de matriz SUMIFS(). Imagen del autor.

SUMIFS() con rangos con nombre

También podemos utilizar los rangos con nombre en lugar de referencias a celdas como A2:A5 o C2:C5. En este ejemplo, selecciono A2:A5 y le doy el nombre de Customer_list y selecciono C2:C5 y le doy el nombre de Sales_list. Ahora para hallar las ventas totales de Juan, utilizo esta fórmula:

=SUMIFS(Sales_list, Customer_list, "John")

Suma los valores con SUMIFS() utilizando los rangos indicados. Imagen del autor.

Utilizar comodines para coincidencias parciales

Los comodines son caracteres especiales (* o ?) que representan caracteres desconocidos o variables en búsquedas de texto y concordancia de patrones: 

• * coincide con cualquier número de caracteres (incluido el cero).

• ? coincide exactamente con un carácter.

Así es como funcionan: 

• A* coincidirá con todas las celdas que empiecen por A.

• *A coincidirá con todas las celdas que acaben en A.

• *A* coincidirá con todas las celdas que contengan A en cualquier lugar.

SUMIFS() ofrece la posibilidad de hacer coincidir textos mediante caracteres comodín. Identifica los valores que empiezan por, acaban por o contienen patrones de texto específicos. Supongamos que quiero sumar las ventas del Código de Producto que empieza por ABC. En este caso, mi fórmula es la siguiente:

=SUMIFS(D2:D8, C2:C8, "ABC*")

Para resumir las ventas que terminan en 00, escribo:

=SUMIFS(B2:B7, A2:A7, "*00")

Utiliza comodines en SUMIFS(). Imagen del autor.

Suma basada en intervalos de fechas

SUMIFS() también puede sumar valores dentro de un intervalo de fechas concreto. Si quiero conocer todas las ventas a partir de enero de 2023, utilizo la siguiente fórmula: 

=SUMIFS(D2:D8, B2:B8, ">=01-Jan-2023", B2:B8, "<=31-Jan-2023") 

Esta fórmula comprobará las fechas desde el 1 de enero de 2023 hasta el 31 de enero de 2023 y luego sumará todas las ventas. 

Suma el intervalo de fechas utilizando la función SUMIFS(). Imagen del autor.

Sumar valores con múltiples condiciones numéricas

SUMIFS() puede sumar valores que estén dentro de rangos numéricos específicos. Tengo un conjunto de datos aleatorio y quiero sumar los valores en los que Ventas es mayor que 100 pero menor que 300. Para ello, utilizo la siguiente fórmula:  

=SUMIFS(C2:C5, C2:C5, ">100", C2:C5, "<300")

Esta fórmula especifica primero el rango de celdas a sumar (C2:C5) como primer argumento. A continuación, aplica al mismo rango las dos condiciones descritas anteriormente. La función SUMIFS() evalúa simultáneamente cada celda del rango según ambos criterios. Y puedes ver que sólo se incluyen en la suma las celdas con valores entre 100 y 300 (excluyentes). 

Suma los valores de un rango numérico utilizando la función SUMIFS(). Imagen del autor.

Solución de problemas si SUMIFS() no funciona

Si tu función SUMIFS() no funciona como es debido, comprueba los siguientes problemas:

Tamaños de gama no coincidentes 

Si tu fórmula SUMIFS() devuelve un error, puede deberse a que los tamaños de los rangos no coinciden. En SUMIFS(), todos los rangos que selecciones, como el sum_range y el criteria_ranges, deben tener el mismo número de filas y columnas.

Por ejemplo, en esta fórmula el rango de suma es B2:B8, pero el rango de criterios es A2:A7, que tiene una fila menos:

=SUMIFS(B2:B8, A2:A7, "Drake White")

Este desajuste dará un error #VALUE!. Por tanto, asegúrate de que todos los rangos tienen el mismo tamaño, así:

=SUMIFS(B2:B8, A2:A8, "John Doe")

Formato incorrecto de los criterios de texto 

En SUMIFS(), debes entrecomillar los criterios de texto. Si no lo haces, puede dar resultados inadecuados. Por ejemplo, esta fórmula devolverá 0 porque Excel ve a Drake White como un nombre o variable, no como texto :

=SUMIFS(B2:B8, A2:A8, Drake White)

Para solucionarlo, encierra el Drake White entre comillas así y dará el resultado correcto:

=SUMIFS(B2:B8, A2:A8, "Drake White")

Valores cero inesperados

Si la fórmula devuelve 0 cuando esperabas un resultado, puede deberse a un formato incorrecto de las condiciones numéricas o de fecha. En SUMIFS(), las condiciones como >100 o <01-Jan-2023 deben escribirse como cadenas de texto entre comillas. De lo contrario, devolverá un error o 0 porque la condición no está entre comillas.

O podemos almacenar la fecha en una celda aparte (por ejemplo, C1) y utilizar esto:

=SUMIFS(B2:B8, A2:A8, ">="&C1)

SUMIFS() no funciona con transformaciones de matrices

SUMIFS() no admite ciertas transformaciones, como extraer componentes específicos de los datos dentro de la fórmula. Por ejemplo, si quiero sumar las ventas de enero y marzo, SUMIFS() no funcionará directamente con los criterios de matriz {"enero", "marzo"}. 

Para demostrarlo, supón que tengo meses en la columna A (enero, febrero, marzo, abril) y valores de ventas en la columna B (100, 200, 300, 400). La fórmula

=SUMIFS(B2:B5, A2:A5, {"January","March"})

no devolverá la suma esperada de 400 (100 + 300). En su lugar, podemos utilizar SUMPRODUCT():

=SUMPRODUCT((A2:A5={"January","March"})*B2:B5)

o envuelve SUMIFS() con SUM() utilizando esta fórmula:

=SUM(SUMIFS(B2:B5, A2:A5, {"January","March"}))

Ambas soluciones tratarán correctamente los criterios de la matriz y devolverán la suma de las ventas de enero y marzo.

Buenas prácticas para utilizar SUMIFS()

Para sacar el máximo partido de la función SUMIFS(), debemos evitar errores comunes siguiendo estas buenas prácticas: 

• Utiliza comodines para un filtrado flexible: Es una buena práctica utilizar comodines al filtrar los datos, porque a veces nuestros datos no están perfectamente organizados. Puede que los nombres de los productos no se escriban siempre igual, o que haya espacios de más. Los comodines te ayudan a hacer coincidir patrones sin necesidad de texto exacto.

• Evita la codificación rígida de criterios: En lugar de escribir las condiciones directamente en tu fórmula, guárdalas en una celda aparte. Si codificas una condición como "Drake White" o ">100", tendrás que editar la fórmula cada vez que quieras cambiarla. Sin embargo, con las referencias de celda, la fórmula se actualizará automáticamente.

• Utiliza referencias absolutas al copiar fórmulas: Cuando copias una fórmula SUMIFS() en otras celdas, Excel ajusta automáticamente las referencias de las celdas. Si no quieres que esto ocurra, utiliza referencias absolutas añadiendo $ para bloquear las celdas en su sitio.

Reflexiones finales

SUMIFS() es una función de Excel que nos ayuda a analizar datos filtrando y sumando números que coinciden con criterios específicos. Es ideal para tareas como el seguimiento de las ventas por región, el resumen de los gastos por categoría o el recuento del inventario por tipo de producto. Una vez que te sientas cómodo con SUMIFS(), te darás cuenta de que te ahorra tiempo y te ayuda a detectar tendencias importantes en tus datos sin complicadas soluciones.

Si quieres desarrollar estas habilidades, consulta nuestro curso Análisis de datos en Excel, el curso Preparación de datos en Excel y el curso Visualización de datos en Excel o el curso de habilidades Fundamentos de Excel. Te ayudarán a perfeccionar tus habilidades actuales.