Função SUMIFS() no Excel: Soma de dados com vários critérios

A função SUMIFS() no Excel adiciona números com base em várias condições para nos dar controle preciso sobre os cálculos. Ao contrário do SUMIF(), que verifica uma condição, o SUMIFS() lida com várias condições ao mesmo tempo.

Neste artigo, mostrarei a você como usar o SUMIFS() com exemplos avançados e dicas de solução de problemas. Ao final, você saberá como usar o site SUMIFS() para tornar seus cálculos mais precisos e eficientes.

A resposta rápida

Para usar a função SUMIFS() no Excel, você deve usar a função :

• Digite =SUMIFS( para iniciar a função.

• Selecione o intervalo que contém os valores a serem somados.

• Selecione o intervalo em que a condição será aplicada.

• Digite a condição a ser correspondida.

• Feche os parênteses e pressione Enter.

Aqui, resumi todas as vendas que são maiores que 200.

=SUMIFS(B2:B8, B2:B8, ">200")

Some os valores usando SUMIFS(). Imagem do autor.

Entendendo a função SUMIFS()

A função SUMIFS() do Excel soma valores somente quando todas as condições especificadas são atendidas. Ele oferece suporte a operadores lógicos como maior que >, menor que <, igual a = e diferente de <>, além de caracteres curinga para correspondências parciais. A função funciona com números, texto e datas.

Sintaxe de SUMIFS()

A função SUMIFS() define primeiro o intervalo de valores a serem somados, seguido de pares de intervalos de condições e critérios. Observe que o site SUMIFS() pode lidar com mais de uma condição lógica.

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Aqui:

• sum_range é o intervalo de células que você deseja adicionar.

• criteria_range1 é o primeiro intervalo em que verificamos uma condição.

• criteria1 é a condição aplicada a criteria_range1.

• [criteria_range2, criteria2], … são opcionais. Você pode adicionar mais pares de intervalos e condições. Cada par acrescenta outra condição que deve ser atendida.

Observe que o criteria_range (o intervalo em que as condições são verificadas) deve ter o mesmo número de linhas e colunas que o sum_range (o intervalo que está sendo somado).

Exemplo de SUMIFS()

Vamos tentar um exemplo básico. Tenho um conjunto de dados de frutas com suas quantidades e vendas. E quero encontrar o total de vendas de maçãs em que a quantidade é maior que 5. Portanto, minha fórmula se tornaria:

=SUMIFS(C2:C8, A2:A8, "Apples", B2:B8, ">5")

Aqui, C2:C8 é o intervalo de valores a ser somado (Sales ($)). A2:A8, "Apples" é a condição para incluir somente as linhas em que o produto é Maçãs. E B2:B8, ">5" é a condição para incluir somente as linhas em que a Quantidade for superior a 5.

Fórmula SUMIFS() para somar as vendas em uma condição. Imagem do autor.

SUMIF() vs. SUMIFS()

A principal diferença entre SUMIF() e SUMIFS() é o número de condições que eles usam. O site SUMIF() lida com uma única condição. Mas o site SUMIFS() pode lidar com várias condições. 

Casos de uso de SUMIFS() no Excel

Agora que você sabe como a função SUMIFS() funciona, vamos ver alguns casos avançados em que podemos usá-la no mundo real.

Usando SUMIFS() com diferentes tipos de dados

SUMIFS() pode trabalhar com diferentes tipos de dados, como números, texto e datas. Digamos que eu tenha um relatório de vendas, mas algumas linhas não contêm os nomes dos clientes. E quero resumir apenas aqueles em que temos o nome do cliente. Para isso, uso a seguinte fórmula:

=SUMIFS(C2:C5, A2:A5, "<>")

Essa fórmula examina a coluna Customer, verifica se há células não vazias e, em seguida, soma as vendas correspondentes.

Some todas as células não vazias com a função SUMIFS(). Imagem do autor.

Para resumir as vendas em que os nomes dos clientes estão faltando, uso esta fórmula:  

=SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Some as células em branco com a função SUMIFS(). Imagem do autor.

Em vez de codificar a condição, podemos armazená-la em outra célula. Se eu quiser somar as vendas da Sarah Lee, digito isso na célula E3 e uso esta fórmula:

=SUMIFS(C2:C5, A2:A5, E3)

Sempre que o valor em E3 for alterado, o total será atualizado automaticamente. 

Use SUMIFS() para somar valores usando a referência da célula. Imagem do autor.

Aplicação da lógica OR em SUMIFS()

Sabemos que o site SUMIFS() usa apenas a lógica AND, o que significa que todas as condições que definimos devem ser verdadeiras para que você possa somar os valores. No entanto, se quisermos usar a lógica OR, que soma valores mesmo quando qualquer uma das várias condições é atendida, podemos fazer isso combinando várias SUMIFS().

Por exemplo, se eu quiser somar as vendas de John Doe OU Drake White, combinarei duas fórmulas SUMIFS() como esta:

=SUMIFS(C2:C8, A2:A8, "John Doe") + SUMIFS(C2:C8, A2:A8, "Drake White")

Como Drake White não está na lista, essa parte da fórmula retorna 0. O total inclui apenas as vendas para John Doe, o que mostra como funciona a lógica do OR.

Use a lógica OR na função SUMIFS(). Imagem do autor.

No Excel 365 ou posterior, podemos simplificar isso com uma fórmula de matriz e você obterá o mesmo resultado.

=SUMIFS(C2:C8,A2:A8,{"John Doe","Drake White"})

Use a fórmula de matriz SUMIFS(). Imagem do autor.

SUMIFS() com intervalos nomeados

Também podemos usar os intervalos nomeados em vez de referências de células como A2:A5 ou C2:C5. Neste exemplo, seleciono A2:A5 e o nomeio Customer_list e seleciono C2:C5 e o nomeio Sales_list. Agora para encontrar o total de vendas de John, eu uso esta fórmula:

=SUMIFS(Sales_list, Customer_list, "John")

Some os valores com SUMIFS() usando os intervalos nomeados. Imagem do autor.

Uso de curingas para correspondência parcial

Os curingas são caracteres especiais (* ou ?) que representam caracteres desconhecidos ou variáveis em pesquisas de texto e correspondência de padrões: 

• * corresponde a qualquer número de caracteres (inclusive zero).

• ? corresponde exatamente a um caractere.

Veja como eles funcionam: 

• A* corresponderá a todas as células que começam com A.

• *A corresponderá a todas as células que terminam com A.

• *A* corresponderá a todas as células que contenham A em qualquer lugar.

SUMIFS() oferece recursos de correspondência de texto por meio de caracteres curinga. Ele identifica valores que começam com, terminam com ou contêm padrões de texto específicos. Digamos que eu queira somar as vendas do código do produto que começa com ABC. Nesse caso, minha fórmula é a seguinte:

=SUMIFS(D2:D8, C2:C8, "ABC*")

Para resumir as vendas que terminam em 00, escrevo:

=SUMIFS(B2:B7, A2:A7, "*00")

Use curingas em SUMIFS(). Imagem do autor.

Soma com base em intervalos de datas

SUMIFS() também pode somar valores em um intervalo de datas específico. Se eu quiser saber todas as vendas a partir de janeiro de 2023, usarei a seguinte fórmula: 

=SUMIFS(D2:D8, B2:B8, ">=01-Jan-2023", B2:B8, "<=31-Jan-2023") 

Essa fórmula verificará as datas de 1º de janeiro de 2023 a 31 de janeiro de 2023 e, em seguida, somará todas as vendas. 

Resuma o intervalo de datas usando SUMIFS(). Imagem do autor.

Soma de valores com várias condições numéricas

SUMIFS() pode somar valores que estejam dentro de intervalos numéricos específicos. Aqui, tenho um conjunto de dados aleatório e quero somar os valores em que Sales é maior que 100, mas menor que 300. Para isso, uso a seguinte fórmula:  

=SUMIFS(C2:C5, C2:C5, ">100", C2:C5, "<300")

Essa fórmula especifica primeiro o intervalo de células a ser somado (C2:C5) como o primeiro argumento. Em seguida, ele aplica duas condições descritas acima ao mesmo intervalo. A função SUMIFS() avalia simultaneamente cada célula do intervalo em relação a ambos os critérios. E você pode ver que somente as células com valores entre 100 e 300 (exclusivo) são incluídas na soma. 

Some os valores em um intervalo de números usando SUMIFS(). Imagem do autor.

Solução de problemas se SUMIFS() não funcionar

Se a função SUMIFS() não estiver funcionando como esperado, verifique os seguintes problemas:

Tamanhos de faixa incompatíveis 

Se a fórmula do site SUMIFS() retornar um erro, isso pode ser devido a tamanhos de intervalo incompatíveis. Em SUMIFS(), todos os intervalos que você selecionar, como o sum_range e o criteria_ranges, devem ter o mesmo número de linhas e colunas.

Por exemplo, nessa fórmula, o intervalo de soma é B2:B8, mas o intervalo de critérios é A2:A7, que tem uma linha a menos:

=SUMIFS(B2:B8, A2:A7, "Drake White")

Essa incompatibilidade gerará um erro em #VALUE!. Portanto, verifique se todos os intervalos têm o mesmo tamanho, assim:

=SUMIFS(B2:B8, A2:A8, "John Doe")

Formatação incorreta dos critérios de texto 

Em SUMIFS(), você deve colocar os critérios de texto entre aspas. Se você não fizer isso, poderá obter resultados inadequados. Por exemplo, essa fórmula retornará 0 porque o Excel vê Drake White como um nome ou variável, não como texto :

=SUMIFS(B2:B8, A2:A8, Drake White)

Para corrigi-lo, coloque o Drake White entre aspas desta forma e você obterá o resultado correto:

=SUMIFS(B2:B8, A2:A8, "Drake White")

Valores zero inesperados

Se a fórmula retornar 0 quando você espera um resultado, isso pode ser devido à formatação incorreta de condições numéricas ou baseadas em datas. Em SUMIFS(), condições como >100 ou <01-Jan-2023 devem ser escritas como cadeias de texto entre aspas. Caso contrário, você receberá um erro ou 0 porque a condição não está entre aspas.

Ou podemos armazenar a data em uma célula separada (por exemplo, C1) e usar isso:

=SUMIFS(B2:B8, A2:A8, ">="&C1)

SUMIFS() não está funcionando com transformações de matriz

SUMIFS() não é compatível com determinadas transformações, como a extração de componentes específicos de dados dentro da fórmula. Por exemplo, se eu quiser somar as vendas de janeiro e março, o site SUMIFS() não funcionará diretamente com os critérios de matriz {"January", "March"}. 

Para mostrar isso, suponha que eu tenha meses na coluna A (janeiro, fevereiro, março, abril) e valores de vendas na coluna B (100, 200, 300, 400). A fórmula

=SUMIFS(B2:B5, A2:A5, {"January","March"})

não retornará a soma esperada de 400 (100 + 300). Em vez disso, podemos usar SUMPRODUCT():

=SUMPRODUCT((A2:A5={"January","March"})*B2:B5)

ou envolva o site SUMIFS() com SUM() usando esta fórmula:

=SUM(SUMIFS(B2:B5, A2:A5, {"January","March"}))

Ambas as soluções tratarão corretamente os critérios da matriz e retornarão a soma das vendas de janeiro e março.

Práticas recomendadas para o uso de SUMIFS()

Para aproveitar ao máximo a função SUMIFS(), devemos evitar erros comuns seguindo estas práticas recomendadas: 

• Use curingas para filtragem flexível: É uma boa prática usar curingas ao filtrar os dados porque, às vezes, nossos dados não estão perfeitamente organizados. Talvez os nomes dos produtos nem sempre estejam escritos da mesma forma ou haja espaços extras. Os curingas ajudam você a combinar padrões sem precisar do texto exato.

• Evite critérios de hardcoding: Em vez de digitar as condições diretamente na fórmula, armazene-as em uma célula separada. Se você codificar uma condição como "Drake White" ou ">100", terá que editar a fórmula sempre que quiser alterá-la. No entanto, com as referências de célula, a fórmula será atualizada automaticamente.

• Use referências absolutas ao copiar fórmulas: Quando você copia uma fórmula do SUMIFS() para outras células, o Excel ajusta automaticamente as referências das células. Se você não quiser que isso aconteça, use referências absolutas adicionando $ para bloquear as células no lugar.

Considerações finais

SUMIFS() é uma função do Excel que nos ajuda a analisar dados filtrando e somando números que correspondem a critérios específicos. É ótimo para tarefas como acompanhar as vendas por região, resumir as despesas por categoria ou contar o estoque por tipo de produto. Depois de se familiarizar com o site SUMIFS(), você perceberá que ele economiza tempo e ajuda a identificar tendências importantes nos seus dados sem complicadas soluções alternativas.

Se você quiser desenvolver essas habilidades, confira nosso curso Análise de dados no Excel, Preparação de dados no Excel e Visualização de dados no Excel ou o programa de habilidades Fundamentos do Excel. Eles ajudarão você a aprimorar suas habilidades atuais.