COUNTIF() Excel: Zellen anhand von Bedingungen zählen

Die verschiedenen Möglichkeiten der Verwendung von Excel COUNTIF() in Excel

Da du nun weißt, wie die Funktion COUNTIF() in Excel funktioniert, schauen wir uns einige weitere Beispiele an, wo wir sie einsetzen können.

Zählen von Zellen, die Text enthalten

COUNTIF() kann zählen, wie oft ein bestimmter Text in den Daten vorkommt. Ich habe zum Beispiel eine Liste von Früchten in A2:A10 und möchte wissen, wie oft Äpfel vorkommen. Hierfür trete ich ein:

=COUNTIF(A2:A10, "Apple")

Diese Formel zählt alle Zellen in diesem Bereich, die genau mit Apple übereinstimmen.

Zähle Zellen mit Text mit COUNTIF(). Bild vom Autor.

Zählen numerischer Werte

Wir können auch Zahlen zählen, die größer als, kleiner als oder gleich einem bestimmten Wert sind. Ich habe zum Beispiel einen Datensatz und kann nun mit der Formel COUNTIF() verschiedene Dinge aus diesem Datensatz herausfinden.  

• Zähle, wie viele Früchte eine größere Menge als 500 haben: =COUNTIF(B2:B10,">500")

• Zählen, wie viele Früchte nicht gleich 500 sind: =COUNTIF(B2:B10, "<>500")

• Um herauszufinden, wie viele Früchte genau 500 in der Menge sind: =COUNTIF(B2:B10, “500”)

• Zählen, wie viele Früchte die Menge unter 500 haben: =COUNTIF(B2:B10,"<500")

Zähle numerische Werte mit der Funktion COUNTIF(). Bild vom Autor.

Wildcards für Teiltreffer verwenden

Manchmal wollen wir Zellen zählen, die einen bestimmten Teil eines Wortes oder Satzes enthalten. In diesem Fall verwenden wir Wildcards. Es gibt zwei Arten von Wildcards:  

• * passt auf eine beliebige Anzahl von Zeichen.

• ? passt nur auf ein einziges Zeichen. 

Ich habe zum Beispiel einen Obst-Datensatz und verwende hier zwei verschiedene Formeln, um dir zu zeigen, wie COUNTIF() mit Platzhaltern umgeht. Um alle Früchte zu zählen, die irgendwo in der Liste n enthalten, gebe ich die folgende Formel ein:

=COUNTIF(A2:A10, "*n*")

Diese Formel verwendet das Sternchen als Platzhalter *, das für eine beliebige Anzahl von Zeichen (einschließlich Null) steht. Wenn du "*n*" eingibst, sucht Excel nach Zellen, in denen "n" irgendwo im Text vorkommt - am Anfang, in der Mitte oder am Ende. Die Formel zählt alle übereinstimmenden Zellen im Bereich A2:A10 und liefert die Gesamtzahl der Früchte, die den Buchstaben "n" enthalten.

Um alle Früchte mit vier Buchstaben zu zählen, die mit K beginnen, tippe ich:

=COUNTIF(A2:A10,"K???")

Diese Formel verwendet das Platzhalterzeichen ?, das für genau ein Zeichen steht. Wenn du "K???" eingibst, zählt Excel alle Zellen im Bereich A2:A10, die mit dem Buchstaben K beginnenund genau vier Buchstaben haben, und zeigt das Endergebnis an .

Verwende Wildcards in der Funktion COUNTIF(). Bild vom Autor.

Anwendung von Kriterien aus einer anderen Zelle

Anstatt die Bedingungen fest zu kodieren, können wir auch den Zellbezug verwenden. Das macht die Formel flexibler, weil sie automatisch aktualisiert wird, wenn sich der Zellwert ändert.

Wenn ich wissen will, wie viele Früchte eine Menge von mehr als 300dann gebe ich die Bedingung in die Zelle D2 ein und verwende dann diesen Zellbezug in der Formel wie folgt:

=COUNTIF(B2:B11, D2)

Wir können den logischen Operator auch in die Anführungszeichen innerhalb der Formel schreiben und & verwenden, um auf die Zelle D3 zu verweisen, wie hier:

=COUNTIF(B2:B11, ">"&D3)

Zähle die Zellen mit dem Zellbezug in der Funktion COUNTIF(). Bild vom Autor.

Zählen von leeren und nicht leeren Zellen

Fehlende Daten können genauso wichtig sein wie die Daten, die du hast. Und COUNTIF() hilft uns, diese Lücken zu erkennen. Nehmen wir an, ich verwalte den Bestand und möchte wissen, wie viele Früchte nicht auf Lager sind (leere Zellen). Dazu erstelle ich die folgende Formel:

=COUNTIF(B2:B11,"")

Und um zu zählen, wie viele Früchte verfügbar sind (nicht leere Zellen), verwende ich diese Formel:

=COUNTIF(B2:B11, "<>")

Wenn deine Zelle jedoch unsichtbaren Text wie Leerzeichen oder andere Sonderzeichen enthält, zählt COUNTIF() sie als nicht leere Zellen.

Zähle leere und nicht leere Zellen mit der Funktion COUNTIF(). Bild vom Autor.

Zählen von Daten auf der Grundlage verschiedener Bedingungen   

Wir können auch Daten zählen, die auf verschiedenen Bedingungen basieren. Nehmen wir an, wir wollen zählen, wie viele Mitarbeiter an dem Datum in Zelle B11 (1. März 2024) eingestellt wurden. Unsere Formel würde also lauten:

=COUNTIF(B2:B9, B11)

Und um zu prüfen, wer an oder vor dem Datum in Zelle B11 eingestellt wurde, verwende ich diese Formel:

=COUNTIF(B2:B9, ">="&B11)

Zähle die Datumsunterschiede mit der Funktion COUNTIF(). Bild vom Autor.

COUNTIF() mit mehreren Kriterien 

Wir können auch COUNTIF() mit mehreren Kriterien verwenden. Wenn ich zählen will, wie viele Daten zwischen dem 1. Januar 2024 und dem 30. Januar 2024 liegen, tippe ich:

=COUNTIF(B2:B9, ">="&B12) - COUNTIF(B2:B9, ">"&B13)

Alternativ kannst du die Funktion COUNTIFS() für mehrere Kriterien wie folgt verwenden:

=COUNTIFS(B2:B9,">="&B12,B2:B9,"<="&B13)

Beide führen zum gleichen Ergebnis. 

Verwende COUNTIF() für zwei Bedingungen. Bild vom Autor.

Excel COUNTIF() vs. COUNTIFS()

Die Funktion COUNTIF() von Excel zählt Zellen anhand eines einzigen Kriteriums, wie wir in den Beispielen oben gesehen haben, und wir können sogar mehrere Bedingungen filtern, indem wir mehr als ein COUNTIF() verwenden, wie wir im letzten Beispiel gesehen haben.

Jetzt ist ein guter Zeitpunkt, um zu sagen, dass Excel eine erweiterte und neuere Funktion namens COUNTIFS() anbietet, wenn deine Daten mehrere Kriterien erfordern. COUNTIFS() verhält sich genau wie COUNTIF(), wenn nur eine Bedingung angegeben wird, aber du kannst auch mehr als eine Bedingung anwenden.

Obwohl COUNTIFS() neuer und leistungsfähiger ist als AND, hat COUNTIF() immer noch seinen Platz in Excel. Sie erstellt oft besser lesbare Formeln für einfache Bedingungen, wodurch deine Tabellenkalkulationen leichter zu verstehen und zu pflegen sind. OR Noch wichtiger ist, dass COUNTIF() im Gegensatz zu COUNTIFS() mit Bedingungen umgehen kann, bei denen du Zellen zählen willst, die eines von mehreren Kriterien erfüllen.

Lass uns das anhand eines einfachen Beispiels verstehen: 

=COUNTIF(B2:B11, "100") + COUNTIF(B2:B11, "900")

Diese Formel zählt die Zellen, in denen der Wert entweder 100 oder 900 ist. Da sich kein 900 in den Zellen befindet und nur ein 100 vorhanden ist, wird als Ergebnis 1 angezeigt.

Anwendung der ODER-Logik mit COUNTIF(). Bild vom Autor. 

Angenommen, ich muss auch wissen, wie oft ein Wert 300 und kiwi in derselben Zeile steht. Hierfür kann ich COUNTIFS() verwenden:

=COUNTIFS(B1:B11, "300", A1:A11, "kiwi")

Die Formel zählt die Zeilen, in denen beide Bedingungen erfüllt sind. Es gibt jedoch 0, weil keine der Bedingungen erfüllt wurde. 

Anwendung der UND-Logik mit COUNTIFS(). Bild vom Autor. 

Diese Unterscheidung ist wichtig zu wissen, deshalb haben wir sie in unseren Excel-Formel-Spickzettel aufgenommen. Und wenn du wirklich auf dem neuesten Stand bleiben willst, empfehle ich dir, unseren Lernpfad Excel Grundlagen zu besuchen.

Häufige Fehler und Fehlersuche

Selbst die besten Excel-Nutzer stoßen manchmal auf COUNTIF() Probleme. Die Funktion ist hilfreich, hat aber ein paar Macken, über die du stolpern kannst. Hier sind die häufigsten Probleme, mit denen Menschen konfrontiert werden, und wie du sie schnell lösen kannst.

Falsche Zählung bei langen Textstrings

COUNTIF() unterstützt keine Textstrings, die länger als 255 Zeichen sind. Wenn du mit längeren Textabschnitten arbeitest und unerwartete Ergebnisse erhältst, versuche es mit CONCATENATE() oder dem & Operator, um deine Kriterien aufzuschlüsseln und in eine handhabbare Form zu bringen: 

=COUNTIF(range, CONCATENATE("First part of text", "Second part of text"))

Oder

=COUNTIF(range, "First part of text" & "Second part of text")

VALUE! Fehler in COUNTIF()

Ein #VALUE! Fehler in COUNTIF() tritt häufig auf, wenn die Formel auf eine geschlossene Arbeitsmappe verweist. Das passiert, weil Excel es nicht zulässt, dass COUNTIF() Daten aus einer externen Datei zählt, wenn die Datei nicht geöffnet ist. Um dieses Problem zu lösen, stelle sicher, dass die referenzierte Arbeitsmappe geöffnet ist, bevor du die Formel ausführst. Die Fehlermeldung sollte verschwinden, sobald die Datei geöffnet ist, und COUNTIF() wird ordnungsgemäß funktionieren.

Falsche Verwendung von Operatoren

Manchmal vergessen wir, logische Operatoren in Anführungszeichen zu setzen. Achte immer darauf, dass Operatoren wie >, < und <> in deinen Kriterien in Anführungszeichen stehen. Sonst bekommst du die Ausgabe nicht.

 oder Beispiel wird die folgende Formel einen Fehler anzeigen:

=COUNTIF(B2:B10,>500)

Um dies zu vermeiden, musst du sicherstellen, dass der logische Operator in Anführungszeichen gesetzt wird. 

=COUNTIF(B2:B10,">500")

Excel COUNTIF() Best Practices

Hier sind einige wichtige Regeln, die du bei der Arbeit mit COUNTIF() in Excel beachten solltest. 

• Verwende benannte Bereiche: Anstatt einen Bereich wie A2:A10 in deiner Formel auszuwählen, gib dem Bereich einen eigenen Namen, damit die Formel leichter zu verstehen ist. Um zum Beispiel zu zählen, wie oft Banana in einer Liste auftaucht, würden wir =COUNTIF(A2:A10, "Banana") verwenden. Wenn ich aber den Bereich in Items benenne und den Zellbezug für die Bedingung verwende, kann ich die Formel wie folgt aktualisieren: =COUNTIF(Items, C2). Auf diese Weise ist die Formel klarer und leichter zu verstehen. 

• Verwende COUNTIFS() für mehrere Bedingungen: Manchmal müssen wir Daten zählen, die auf mehr als einer Bedingung basieren. In einem solchen Fall solltest du statt mehrerer COUNTIF() Formeln COUNTIFS() verwenden, weil es die beste Wahl für die Anwendung mehrerer Filter ist.

COUNTIF() vs. Verwandte Funktionen

Neben COUNTIF() und COUNTIFS() gibt es noch viele andere Excel-Funktionen, um Zellen zu zählen. Jede Funktion hat jedoch einen bestimmten Zweck. Schauen wir uns diese also genauer an:

Wie viele andere Excel-Funktionen ist auch COUNTIF() eine der hilfreichsten Möglichkeiten, um Daten zu zählen und zu filtern. Anstatt deine Liste manuell durchzugehen, kannst du diese Funktion nutzen, um sofort zu finden, was du brauchst. Und das Beste daran ist, dass es mit Text, Zahlen, leeren Zellen und Mustern funktioniert, was die Datenanalyse erleichtert. 

Wenn du mehr lernen möchtest, beginne mit unserem Kurs Einführung in Excel, um die Grundlagen zu lernen. Um eine solide Grundlage zu schaffen, führt dich der Lernpfad Excel-Grundlagen Schritt für Schritt durch alle Kernkonzepte. Wenn du mit Finanzdaten arbeitest, hilft dir unser Kurs Finanzmodellierung in Excel, professionelle Finanzmodelle und Prognosen zu erstellen.