VLOOKUP() di Google Sheets: Cara Menggunakannya + Contoh

VLOOKUP() adalah fungsi Google Sheets yang mencari sebuah nilai dalam kolom dan mengembalikan nilai yang cocok dari kolom lain pada baris yang sama. Anda memberinya sesuatu untuk dicari, memberi tahu di mana mencarinya, dan fungsi ini mengembalikan data yang Anda perlukan.

Fungsi ini paling membantu saat Anda bekerja dengan kumpulan data besar di mana mencari dan mencocokkan data secara manual akan memakan waktu terlalu lama. Namun kapan pun Anda perlu menghubungkan dua tabel data menggunakan nilai bersama, VLOOKUP() adalah fungsi andalan.

Dalam panduan ini, Anda akan mempelajari sintaksnya, cara menggunakannya langkah demi langkah, apa yang menyebabkan hasil yang salah, dan kapan beralih ke alternatifnya seperti INDEX MATCH() atau XLOOKUP().

Apa Sintaks VLOOKUP() di Google Sheets?

Sintaks VLOOKUP() adalah:

=VLOOKUP(search_key, range, index, [is_sorted])

Berikut penjelasannya: 

• search_key adalah nilai yang ingin Anda cari

• range adalah tabel tempat pencarian dilakukan

• index adalah nomor kolom untuk mengembalikan hasil

• [is_sorted] menentukan apakah Anda menginginkan kecocokan persis atau tidak

Bagaimana Cara Melakukan VLOOKUP() di Google Sheets?

Untuk melakukan VLOOKUP() di Google Sheets:

1. Tentukan nilai yang ingin Anda cari: Bisa berupa ID, nama, atau nilai unik lainnya.

2. Identifikasi rentang tabel Anda: Pastikan kolom yang berisi nilai lookup adalah kolom pertama dalam rentang tersebut.

3. Pilih data yang ingin Anda kembalikan: Inilah kolom hasilnya (misalnya, nama, harga, status).

4. Masukkan rumus VLOOKUP() di sel baru: Referensikan nilai lookup, rentang tabel, dan kolom yang ingin dikembalikan.

5. Gunakan kecocokan persis atau perkiraan (FALSE atau TRUE): Dalam kebanyakan kasus, Anda menginginkan kecocokan persis untuk menghindari hasil yang salah (lebih lanjut tentang ini nanti).

Jika Anda memiliki tabel ini:

Dan Anda ingin menemukan nama untuk ID 102, gunakan:

=VLOOKUP(102, A2:B4, 2, FALSE)

Ini memberi tahu Google Sheets untuk:

• Mencari 102 di kolom A
• Mengembalikan nilai dari kolom B
• Memberikan kecocokan persis

Hasilnya, Anda akan mendapatkan Sarah.

Contoh VLOOKUP(). Gambar oleh Penulis.

Cara Kerja VLOOKUP() (Logika Langkah demi Langkah)

VLOOKUP() mengikuti proses pencarian vertikal yang sederhana. Ia selalu mulai dari kolom pertama pada rentang yang Anda pilih, lalu memindai ke bawah, satu baris demi satu, hingga menemukan kecocokan pertama.

Setelah menemukan kecocokan itu, ia tetap pada baris yang sama. Kemudian bergerak ke kolom yang Anda tentukan dan mengembalikan nilai tersebut.

Berikut cara kerjanya langkah demi langkah:

• Mulai di kolom pertama dari rentang
• Mencari ke bawah kolom
• Menemukan nilai yang pertama kali cocok
• Bergerak melintang pada baris yang sama
• Mengembalikan data dari kolom yang ditentukan

Misalkan Anda ingin menemukan jabatan untuk Employee ID E1007. Untuk ini, gunakan rumus berikut:

=VLOOKUP("E1007", A:G, 5, FALSE)

VLOOKUP() di Google Sheets. Gambar oleh Penulis.

Rumus ini:

• Menemukan E1007 di kolom A

• Bergerak melintang pada baris yang sama

• Mengembalikan kolom ke-5 (Jabatan)

• Memberikan hasil Software Engineer.

Catatan: VLOOKUP() hanya dapat mencari dari kiri ke kanan. Jika kolom lookup Anda bukan kolom pertama dalam rentang, fungsi tidak akan berfungsi. Dalam kasus ini, Anda harus menata ulang data atau menggunakan fungsi lain. Kita akan membahasnya nanti.

Kecocokan Persis vs Perkiraan di VLOOKUP()

Kecocokan persis hanya mengembalikan hasil saat nilainya identik. Kecocokan perkiraan mengembalikan nilai terdekat yang tersedia ketika kecocokan persis tidak ditemukan, biasanya berdasarkan data yang sudah diurutkan.

Di VLOOKUP(), ini dikendalikan oleh argumen terakhir. Argumen terakhir, FALSE atau TRUE, adalah bagian yang paling sering salah karena TRUE terlihat tidak berbahaya padahal tidak demikian.

• FALSE berarti hanya kecocokan persis. Jika nilainya tidak ada, Anda akan mendapatkan #N/A, yang sebenarnya membantu.
• TRUE mengembalikan nilai terdekat yang lebih rendah ketika tidak ada kecocokan persis, yang terdengar seperti solusi cadangan namun lebih tepat disebut jawaban salah yang sunyi. Ini juga mengasumsikan data Anda sudah diurutkan. Jika tidak, hasilnya tidak terdefinisi.

Menurut saya, gunakan TRUE hanya untuk lookup bertingkat, seperti tarif pajak atau rentang nilai, di mana perkiraan memang perilaku yang benar menurut desain. Untuk hal lainnya, gunakan FALSE.

Kecocokan persis (FALSE)

Ini memberi tahu VLOOKUP() “Hanya kembalikan hasil jika Anda menemukan nilai yang persis ini.” Misalnya, rumus =VLOOKUP("E1005", A:G, 7, FALSE) mencari E1005, mengembalikan gaji dari kolom ke-7, dan memberikan hasil 90000.

Jika nilainya tidak ada, Anda akan mendapatkan kesalahan #N/A.

Kecocokan persis di VLOOKUP(). Gambar oleh Penulis.

Kecocokan perkiraan (TRUE)

Ini memberi tahu VLOOKUP(), “Jika Anda tidak menemukan kecocokan persis, kembalikan nilai terdekat di bawahnya.” Itu mungkin terdengar membantu — kadang iya, tetapi kadang diam-diam memberi jawaban yang salah.

Misalnya, E1011 tidak ada di dataset kita. ID karyawan terakhir adalah E1010. Jadi jika Anda menggunakan rumus =VLOOKUP("E1011", A:G, 7, TRUE), VLOOKUP() tidak akan mengembalikan error. Sebaliknya, ia akan mengembalikan nilai untuk kecocokan terdekat yang lebih rendah, yaitu E1010. Sel akan menampilkan 88000.

Jadi meskipun E1011 tidak ada, VLOOKUP() tetap memberikan hasil karena TRUE mengizinkan kecocokan perkiraan.

Kecocokan perkiraan di VLOOKUP(). Gambar oleh Penulis.

Sekarang bayangkan data yang sama tidak berurutan, dan saya memasukkan ID karyawan yang tersedia dalam rumus, seperti ini: =VLOOKUP("E1011", A:G, 7, TRUE).

Kali ini, rumus mengembalikan gaji yang salah karena kolom lookup tidak diurutkan, dan kecocokan perkiraan bergantung pada data yang diurutkan.

Kecocokan perkiraan VLOOKUP() memunculkan error karena daftar tidak diurutkan. Gambar oleh Penulis.

Kesalahan Umum di VLOOKUP() dan Cara Memperbaikinya

Mari lihat beberapa masalah paling umum yang mungkin Anda temui dengan VLOOKUP() dan cara mengatasinya: 

Kesalahan #N/A

Kesalahan #N/A berarti VLOOKUP() tidak dapat menemukan nilai yang Anda minta.

Misalkan Anda memiliki rumus ini: =VLOOKUP("E9999", A:G, 7, FALSE)

Jika E9999 tidak berada di kolom pertama rentang, rumus mengembalikan #N/A.

Ini juga dapat terjadi jika nilainya diketik berbeda di sheet, seperti ada spasi ekstra atau masalah pemformatan teks.

Untuk memperbaikinya:

• Pastikan nilainya ada di kolom pertama rentang

• Gunakan referensi sel yang benar alih-alih mengetik nilai secara manual bila memungkinkan

• Tambahkan tanda kutip jika Anda menuliskan nilai teks secara hardcode

• Hapus spasi di awal atau akhir dari data

• Gunakan FALSE hanya saat Anda memerlukan kecocokan persis

Indeks kolom salah

Indeks kolom memberi tahu VLOOKUP() kolom mana yang harus dikembalikan dalam rentang yang dipilih. Jika nomor indeks terlalu besar, rumus mengembalikan #REF!.

Rumus =VLOOKUP("E1005", A:G, 8, FALSE) ini mengembalikan #REF! karena rentang A:G hanya memiliki 7 kolom.

Indeks kolom salah memunculkan error. Gambar oleh Penulis.

Anda juga bisa mendapatkan hasil yang salah jika nomor kolom valid tetapi mengarah ke kolom yang keliru.

Contohnya:

=VLOOKUP("E1005", A:G, 5, FALSE)

Ini mengembalikan jabatan, bukan gaji.

Untuk memperbaikinya:

• Hitung kolom dari kolom pertama rentang yang Anda pilih
• Periksa bahwa nomor kolom sesuai dengan nilai yang ingin Anda kembalikan
• Pastikan kolom tersebut ada di dalam rentang

Masalah kecocokan perkiraan

Jika Anda menggunakan TRUE, VLOOKUP() mencari kecocokan terdekat yang lebih rendah alih-alih mengharuskan kecocokan persis.

Jika Anda mengetik =VLOOKUP("E1011", A:G, 7, TRUE) dan tidak ada E1011 dalam dataset, alih-alih mengembalikan error, rumus mengembalikan 88000, yang milik E1010.

Hasil tersebut mungkin terlihat benar, tetapi itu bukan kecocokan persis.

Untuk memperbaikinya:

• Gunakan FALSE saat Anda membutuhkan hasil yang persis

• Gunakan TRUE hanya ketika data diurutkan dan hasil perkiraan dapat diterima

Masalah rentang

VLOOKUP() juga dapat berhenti berfungsi ketika rentang yang dipilih tidak cocok dengan yang ingin dilakukan rumus.

Misalnya, =VLOOKUP("E1005", A:C, 7, FALSE) mengembalikan #REF! karena rentang A:C hanya memiliki 3 kolom, tetapi rumus meminta kolom ke-7.

Masalah umum lainnya terjadi ketika kolom lookup bukan kolom pertama dalam rentang.

Perhatikan rumus ini:

=VLOOKUP("E1005", B:G, 7, FALSE)

Di sini, kolom pertama dalam rentang adalah kolom B, bukan kolom A. Karena VLOOKUP() hanya mencari kolom pertama dari rentang yang dipilih, fungsi ini tidak dapat menemukan E1005.

Untuk memperbaikinya:

• Pastikan kolom lookup adalah kolom pertama dalam rentang
• Pastikan rentang menyertakan kolom yang ingin Anda kembalikan
• Periksa kembali rentang yang dipilih sebelum menyelesaikan rumus

Rentang salah memunculkan error. Gambar oleh Penulis.

VLOOKUP() Antar Sheet di Google Sheets

Anda dapat menggunakan VLOOKUP() untuk menarik data dari sheet lain dengan menambahkan nama sheet sebelum rentang.

Formatnya seperti ini:

=VLOOKUP(search_key, SheetName!range, index, FALSE)

Bagian SheetName! memberi tahu rumus di sheet mana harus mencari.

Misalkan data Anda disimpan di sheet bernama Employees, dan Anda bekerja di sheet lain. Untuk menemukan departemen untuk employee ID E1005, gunakan:

=VLOOKUP("E1005", Employees!A:G, 4, FALSE)

Berikut penjelasannya:

• Employees!A:G mencari di sheet Employees

• 4 mengembalikan kolom Department

Rumus mengembalikan departemen untuk E1005.

Mereferensikan sheet lain di VLOOKUP(). Gambar oleh Penulis.

Saat nama sheet memiliki spasi

Jika nama sheet berisi spasi, bungkus dengan tanda kutip tunggal seperti ini: 

=VLOOKUP("E1005", 'Employee Data'!A:G, 7, FALSE)

Tanpa tanda kutip, rumus tidak akan berfungsi.

VLOOKUP() vs. INDEX MATCH di Google Sheets

VLOOKUP() mencari dalam kolom tetap dan mengembalikan data berdasarkan posisi, sedangkan INDEX MATCH menemukan nilai menggunakan referensi baris dan kolom secara langsung, sehingga tetap berfungsi meskipun struktur tabel berubah.

VLOOKUP: cepat ditulis, mudah rusak

Anda sudah melihat bahwa =VLOOKUP("E1005", A:G, 7, FALSE) menemukan gaji untuk E1005.

Fungsi ini bekerja baik ketika:

• Kolom lookup berada di sebelah kiri
• Struktur tabel tidak berubah

Masalah muncul saat struktur berubah.

Contohnya:

• Anda menyisipkan kolom baru
• Kolom gaji bergeser dari 7 ke 8
• Rumus masih menggunakan 7

Sekarang rumus mengembalikan nilai yang salah tanpa menampilkan error.

INDEX MATCH: lebih panjang, tetapi stabil

Sekarang lihat lookup yang sama menggunakan INDEX MATCH:

=INDEX(G:G, MATCH("E1005", A:A, 0))

Penjelasannya:

• MATCH() menemukan posisi E1005 di kolom A

• INDEX() mengembalikan nilai dari kolom G pada posisi tersebut

Metode ini tidak bergantung pada nomor kolom, sehingga tetap berfungsi meski tabel berubah.

INDEX MATCH menangani data lebih baik daripada VLOOKUP(). Gambar oleh Penulis.

Kapan benar-benar membantu

Gunakan INDEX MATCH saat data Anda tidak tersusun dari kiri ke kanan. Misalkan Kolom A berisi Employee ID dan Kolom C berisi Last Name. Jika Anda ingin mencari berdasarkan Last Name dan mengembalikan Employee ID, ini adalah lookup dari kanan ke kiri.

VLOOKUP() tidak bisa melakukan ini tanpa mengubah tabel, tetapi INDEX MATCH menanganinya secara langsung:

=INDEX(A:A, MATCH("Wilson", C:C, 0))

Tidak perlu menata ulang data Anda.

VLOOKUP() vs XLOOKUP di Google Sheets

VLOOKUP() mencari dalam struktur tetap dan memiliki keterbatasan, sedangkan XLOOKUP() memungkinkan lookup ke segala arah. Fungsi ini ditambahkan ke Google Sheets pada 2022 dan kini menjadi opsi yang lebih baik dalam banyak kasus.

Katakanlah Anda ingin mencari Employee ID menggunakan Last Name Wilson. Ini adalah lookup dari kanan ke kiri. VLOOKUP() tidak dapat menanganinya tanpa menata ulang tabel, tetapi XLOOKUP() bisa:

=XLOOKUP("Wilson", C:C, A:A)

Rumus ini:

• Mencari Last Name (kolom C)
• Mengembalikan Employee ID (kolom A)

XLOOKUP() di Google Sheets. Gambar oleh Penulis.

XLOOKUP() lebih baik karena: 

• Bekerja ke segala arah (kiri atau kanan)
• Tidak menggunakan nomor kolom
• Mengembalikan kecocokan persis secara default
• Mengizinkan keluaran kustom saat tidak ditemukan kecocokan

Penutup

Jika saya harus memberi satu saran: bangun VLOOKUP() di spreadsheet nyata yang benar-benar Anda pedulikan alih-alih lembar latihan. Kesalahan akan terasa berbeda saat datanya penting. Anda akan ingat mengapa FALSE ada pertama kali TRUE diam-diam memberi gaji yang salah untuk seseorang.

Setelah Anda nyaman, coba berbagai jenis kecocokan, sesuaikan rentang Anda, dan perhatikan kapan hasilnya mulai tidak masuk akal. Biasanya pada titik itulah opsi yang lebih fleksibel seperti INDEX MATCH() atau XLOOKUP() lebih masuk akal.