VLOOKUP() no Google Sheets: como usar + exemplos

VLOOKUP() é uma função do Google Sheets que procura um valor em uma coluna e retorna o valor correspondente de outra coluna na mesma linha. Você diz o que quer encontrar, onde procurar, e ela traz o dado que você precisa.

Ela é especialmente útil quando você trabalha com conjuntos de dados grandes, em que buscar e combinar informações manualmente levaria tempo demais. Mas sempre que você precisar conectar duas tabelas usando um valor em comum, VLOOKUP() é a função certa.

Neste guia, você vai aprender a sintaxe, como usar passo a passo, o que pode levar a resultados incorretos e quando optar por alternativas como INDEX MATCH() ou XLOOKUP().

Qual é a sintaxe de VLOOKUP() no Google Sheets?

A sintaxe de VLOOKUP() é:

=VLOOKUP(search_key, range, index, [is_sorted])

Aqui:

• search_key é o valor que você quer encontrar

• range é a tabela onde a busca acontece

• index é o número da coluna de onde o resultado será retornado

• [is_sorted] define se você quer uma correspondência exata ou não

Como fazer um VLOOKUP() no Google Sheets?

Para fazer um VLOOKUP() no Google Sheets:

1. Defina qual valor você quer buscar: pode ser um ID, nome ou qualquer valor único.

2. Identifique o intervalo da tabela: garanta que a coluna com o valor de busca seja a primeira coluna desse intervalo.

3. Escolha qual dado você quer retornar: é a coluna com o resultado (por exemplo, nome, preço, status).

4. Insira a fórmula VLOOKUP() em uma nova célula: referencie o valor de busca, o intervalo da tabela e a coluna que você quer retornar.

5. Use correspondência exata ou aproximada (FALSE ou TRUE): na maioria dos casos, prefira a correspondência exata para evitar resultados errados (falamos disso já já).

Se você tem esta tabela:

E você quer encontrar o nome do ID 102, use:

=VLOOKUP(102, A2:B4, 2, FALSE)

Isso diz ao Google Sheets para:

• Procurar 102 na coluna A
• Retornar o valor da coluna B
• Exigir correspondência exata

Como resultado, você obterá Sarah.

Exemplo de VLOOKUP(). Imagem do autor.

Como o VLOOKUP() funciona (lógica passo a passo)

VLOOKUP() segue um processo simples de busca vertical. Ele sempre começa na primeira coluna do intervalo selecionado, depois percorre para baixo, linha por linha, até encontrar a primeira correspondência.

Quando encontra essa correspondência, permanece na mesma linha. Em seguida, vai até a coluna que você especificou e retorna aquele valor.

Veja o passo a passo:

• Começa na primeira coluna do intervalo
• Pesquisa para baixo na coluna
• Encontra o primeiro valor correspondente
• Move para a direita na mesma linha
• Retorna o dado da coluna especificada

Digamos que você quer encontrar o cargo (job title) do ID de funcionário E1007. Para isso, use a fórmula a seguir:

=VLOOKUP("E1007", A:G, 5, FALSE)

VLOOKUP() no Google Sheets. Imagem do autor.

Essa fórmula:

• Encontra E1007 na coluna A

• Segue na mesma linha

• Retorna a coluna 5 (Job Title)

• Entrega o resultado Software Engineer.

Importante: VLOOKUP() só busca da esquerda para a direita. Se a sua coluna de busca não for a primeira do intervalo, a função não funciona. Nesse caso, você precisa reorganizar os dados ou usar outra função. Vamos falar disso mais adiante.

Correspondência exata vs. aproximada no VLOOKUP()

A correspondência exata retorna um resultado apenas quando o valor é idêntico. A correspondência aproximada retorna o valor mais próximo disponível quando não encontra uma correspondência exata, geralmente com base em dados ordenados.

No VLOOKUP(), isso é controlado pelo último argumento. Esse último argumento, FALSE ou TRUE, é onde muita gente erra, porque TRUE parece inofensivo — e não é.

• FALSE significa apenas correspondência exata. Se o valor não existir, você recebe #N/A — o que, na prática, é útil.
• TRUE retorna o valor imediatamente menor quando não existe correspondência exata. Parece um “plano B”, mas na verdade é uma resposta silenciosamente errada. Ele também pressupõe que seus dados estejam ordenados. Se não estiverem, o resultado é indefinido.

Eu diria para usar TRUE só em buscas por faixas, como alíquotas de imposto ou faixas de notas, onde o aproximado é o comportamento correto por definição. Para todo o resto, use FALSE.

Correspondência exata (FALSE)

Isso diz ao VLOOKUP(): “Só retorne um resultado se encontrar exatamente este valor.” Por exemplo, esta fórmula =VLOOKUP("E1005", A:G, 7, FALSE) procura E1005, retorna o salário da coluna 7 e dá o resultado 90000.

Se o valor não existir, você recebe o erro #N/A.

Correspondência exata no VLOOKUP(). Imagem do autor.

Correspondência aproximada (TRUE)

Isso diz ao VLOOKUP(): “Se não encontrar uma correspondência exata, retorne o valor mais próximo abaixo dele.” Parece útil — e às vezes é —, mas em outras vezes entrega a resposta errada sem avisar.

Por exemplo, E1011 não existe no nosso conjunto de dados. O último ID de funcionário é E1010. Então, se você usar esta fórmula =VLOOKUP("E1011", A:G, 7, TRUE), VLOOKUP() não vai retornar um erro. Em vez disso, vai retornar o valor da correspondência mais próxima inferior, que é E1010. A célula exibirá 88000.

Então, mesmo que E1011 não exista, VLOOKUP() ainda retorna um resultado porque TRUE permite correspondência aproximada.

Correspondência aproximada no VLOOKUP(). Imagem do autor.

Agora, imagine os mesmos dados fora de ordem e eu digito o ID de funcionário disponível na fórmula, assim: =VLOOKUP("E1011", A:G, 7, TRUE).

Desta vez, a fórmula retorna um salário incorreto porque a coluna de busca não está ordenada, e a correspondência aproximada depende de dados ordenados.

VLOOKUP() com correspondência aproximada gera erro por lista não ordenada. Imagem do autor.

Erros comuns no VLOOKUP() e como corrigi-los

Vamos ver alguns dos problemas mais comuns que você pode encontrar com VLOOKUP() e como resolvê-los:

Erro #N/A

Um erro #N/A significa que VLOOKUP() não encontrou o valor solicitado.

Suponha que você use esta fórmula: =VLOOKUP("E9999", A:G, 7, FALSE)

Se E9999 não estiver na primeira coluna do intervalo, a fórmula retorna #N/A.

Isso também pode acontecer se o valor estiver digitado de forma diferente na planilha, com espaços extras ou problemas de formatação de texto.

Para corrigir:

• Garanta que o valor exista na primeira coluna do intervalo

• Use a referência de célula correta em vez de digitar o valor manualmente sempre que possível

• Adicione aspas se você fixar (hardcode) um valor de texto

• Remova espaços no início ou no fim dos dados

• Use FALSE apenas quando precisar de correspondência exata

Índice de coluna incorreto

O índice de coluna diz ao VLOOKUP() de qual coluna retornar o valor dentro do intervalo selecionado. Se o número do índice for grande demais, a fórmula retorna #REF!.

Esta =VLOOKUP("E1005", A:G, 8, FALSE) retorna #REF! porque o intervalo A:G tem apenas 7 colunas.

Índice de coluna incorreto gera erro. Imagem do autor.

Você também pode obter um resultado errado se o número da coluna for válido, mas apontar para a coluna errada.

Por exemplo:

=VLOOKUP("E1005", A:G, 5, FALSE)

Isso retorna o cargo, não o salário.

Para corrigir:

• Conte as colunas a partir da primeira coluna do intervalo selecionado
• Verifique se o número da coluna corresponde ao valor que você quer retornar
• Garanta que a coluna exista dentro do intervalo

Problemas com correspondência aproximada

Se você usar TRUE, VLOOKUP() procura a correspondência mais próxima inferior em vez de exigir uma exata.

Se você digitar =VLOOKUP("E1011", A:G, 7, TRUE) e não houver E1011 no conjunto de dados, em vez de retornar um erro, a fórmula retorna 88000, que pertence a E1010.

Esse resultado pode parecer correto, mas não é uma correspondência exata.

Para corrigir:

• Use FALSE quando precisar de um resultado exato

• Use TRUE apenas quando os dados estiverem ordenados e um resultado aproximado for aceitável

Problemas de intervalo

VLOOKUP() também pode deixar de funcionar quando o intervalo selecionado não condiz com o que a fórmula tenta fazer.

Por exemplo, =VLOOKUP("E1005", A:C, 7, FALSE) retorna #REF! porque o intervalo A:C tem apenas 3 colunas, mas a fórmula pede a coluna 7.

Outro problema comum acontece quando a coluna de busca não é a primeira coluna do intervalo.

Veja esta fórmula:

=VLOOKUP("E1005", B:G, 7, FALSE)

Aqui, a primeira coluna do intervalo é a coluna B, não a A. Como VLOOKUP() só busca na primeira coluna do intervalo selecionado, ela não consegue encontrar E1005.

Para corrigir:

• Garanta que a coluna de busca seja a primeira coluna do intervalo
• Garanta que o intervalo inclua a coluna que você quer retornar
• Revise o intervalo selecionado antes de finalizar a fórmula

Intervalo errado gera erro. Imagem do autor.

VLOOKUP() entre abas no Google Sheets

Você pode usar VLOOKUP() para puxar dados de outra aba adicionando o nome da aba antes do intervalo.

O formato é assim:

=VLOOKUP(search_key, SheetName!range, index, FALSE)

A parte SheetName! informa em qual aba a fórmula deve buscar.

Suponha que seus dados estejam em uma aba chamada Employees e você esteja trabalhando em outra. Para encontrar o departamento do funcionário E1005, use:

=VLOOKUP("E1005", Employees!A:G, 4, FALSE)

Aqui:

• Employees!A:G busca na aba Employees

• 4 retorna a coluna Department

A fórmula retorna o departamento de E1005.

Referenciando outra aba no VLOOKUP(). Imagem do autor.

Quando o nome da aba tem espaços

Se o nome da aba tiver espaços, coloque-o entre aspas simples, assim:

=VLOOKUP("E1005", 'Employee Data'!A:G, 7, FALSE)

Sem as aspas, a fórmula não funciona.

VLOOKUP() vs. INDEX MATCH no Google Sheets

VLOOKUP() busca em uma coluna fixa e retorna dados com base na posição, enquanto INDEX MATCH encontra valores usando referências de linha e coluna diretamente, então continua funcionando mesmo se a estrutura da tabela mudar.

VLOOKUP: rápido de escrever, fácil de quebrar

Você já viu que =VLOOKUP("E1005", A:G, 7, FALSE) encontra o salário de E1005.

Funciona bem quando:

• A coluna de busca está à esquerda
• A estrutura da tabela não muda

Os problemas começam quando a estrutura muda.

Por exemplo:

• Você insere uma nova coluna
• A coluna de salário passa de 7 para 8
• A fórmula continua usando 7

Agora ela retorna o valor errado sem mostrar erro.

INDEX MATCH: mais longo, porém estável

Veja a mesma busca usando INDEX MATCH:

=INDEX(G:G, MATCH("E1005", A:A, 0))

Aqui:

• MATCH() encontra a posição de E1005 na coluna A

• INDEX() retorna o valor da coluna G nessa posição

Esse método não depende de números de coluna, então continua funcionando mesmo que a tabela mude.

INDEX MATCH lida melhor com os dados do que VLOOKUP(). Imagem do autor.

Onde realmente ajuda

Use INDEX MATCH quando seus dados não estiverem organizados da esquerda para a direita. Suponha que a coluna A contenha Employee ID e a coluna C contenha Last Name. Se você quiser buscar por Last Name e retornar o Employee ID, isso seria uma busca da direita para a esquerda.

VLOOKUP() não consegue fazer isso sem mudar a tabela, mas INDEX MATCH resolve diretamente:

=INDEX(A:A, MATCH("Wilson", C:C, 0))

Sem precisar reorganizar seus dados.

VLOOKUP() vs XLOOKUP no Google Sheets

VLOOKUP() busca dentro de uma estrutura fixa e tem limitações, enquanto XLOOKUP() permite buscas em qualquer direção. Ele foi adicionado ao Google Sheets em 2022 e hoje é a melhor opção em muitos casos.

Digamos que você queira encontrar o Employee ID usando o Last Name Wilson. Isso é uma busca da direita para a esquerda. VLOOKUP() não dá conta sem reorganizar a tabela, mas XLOOKUP() resolve:

=XLOOKUP("Wilson", C:C, A:A)

Essa fórmula:

• Busca Last Name (coluna C)
• Retorna o Employee ID (coluna A)

XLOOKUP() no Google Sheets. Imagem do autor.

XLOOKUP() é melhor porque:

• Funciona em qualquer direção (esquerda ou direita)
• Não usa números de coluna
• Retorna correspondências exatas por padrão
• Permite saída personalizada quando nada é encontrado

Considerações finais

Se eu pudesse dar um conselho: use VLOOKUP() em uma planilha de verdade, que você realmente se importa, e não só numa planilha de teste. Os erros “doem” diferente quando o dado é importante. Você nunca mais esquece por que FALSE existe depois da primeira vez que TRUE te dá o salário errado de alguém, em silêncio.

Quando estiver confortável, teste tipos de correspondência diferentes, ajuste seus intervalos e repare quando os resultados deixarem de fazer sentido. Normalmente, é aí que uma opção mais flexível como INDEX MATCH() ou XLOOKUP() passa a fazer mais sentido.