VLOOKUP() en Google Sheets: cómo usarla + ejemplos

VLOOKUP() es una función de Google Sheets que busca un valor en una columna y devuelve el valor coincidente de otra columna en la misma fila. Le indicas qué buscar, dónde mirar y te trae justo el dato que necesitas.

Es especialmente útil cuando trabajas con conjuntos de datos grandes, donde buscar y emparejar información a mano llevaría demasiado tiempo. Pero siempre que necesites conectar dos tablas mediante un valor compartido, VLOOKUP() es la función de referencia.

En esta guía verás su sintaxis, cómo usarla paso a paso, qué provoca resultados incorrectos y cuándo conviene optar por alternativas como INDEX MATCH() o XLOOKUP().

¿Cuál es la sintaxis de VLOOKUP() en Google Sheets?

La sintaxis de VLOOKUP() es:

=VLOOKUP(search_key, range, index, [is_sorted])

Donde: 

• search_key es el valor que quieres buscar

• range es la tabla donde se realiza la búsqueda

• index es el número de columna desde la que devolver el resultado

• [is_sorted] define si quieres una coincidencia exacta o no

¿Cómo hacer un VLOOKUP() en Google Sheets?

Para hacer un VLOOKUP() en Google Sheets:

1. Decide qué valor quieres buscar: puede ser un ID, un nombre o cualquier valor único.

2. Identifica el rango de tu tabla: asegúrate de que la columna que contiene el valor de búsqueda sea la primera del rango.

3. Elige qué dato quieres devolver: es la columna con el resultado (p. ej., nombre, precio, estado).

4. Escribe la fórmula VLOOKUP() en una celda nueva: referencia tu valor de búsqueda, el rango de la tabla y la columna que quieres devolver.

5. Usa coincidencia exacta o aproximada (FALSE o TRUE): en la mayoría de casos, te interesa la coincidencia exacta para evitar resultados erróneos (lo veremos más adelante).

Si tienes esta tabla:

Y quieres encontrar el nombre del ID 102, usa:

=VLOOKUP(102, A2:B4, 2, FALSE)

Esto le dice a Google Sheets que:

• Busque 102 en la columna A
• Devuelva el valor de la columna B
• Use coincidencia exacta

Como resultado, obtendrás Sarah.

Ejemplo de VLOOKUP(). Imagen del autor.

Cómo funciona VLOOKUP() (lógica paso a paso)

VLOOKUP() sigue un proceso de búsqueda vertical sencillo. Siempre empieza en la primera columna del rango seleccionado y recorre hacia abajo, fila a fila, hasta encontrar la primera coincidencia.

Cuando la encuentra, se queda en esa fila, se desplaza a la columna que indicaste y devuelve ese valor.

Así funciona paso a paso:

• Empieza en la primera columna del rango
• Busca hacia abajo en la columna
• Encuentra la primera coincidencia
• Se mueve por la misma fila
• Devuelve el dato de la columna indicada

Imagina que quieres encontrar el puesto de trabajo del empleado con ID E1007. Para ello, usa esta fórmula:

=VLOOKUP("E1007", A:G, 5, FALSE)

VLOOKUP() en Google Sheets. Imagen del autor.

Esta fórmula:

• Busca E1007 en la columna A

• Se mueve por esa misma fila

• Devuelve la columna 5 (Job Title)

• Y da como resultado Software Engineer.

Nota: VLOOKUP() solo puede buscar de izquierda a derecha. Si tu columna de búsqueda no es la primera del rango, la función no funcionará. En ese caso, tendrás que reorganizar los datos o usar otra función. Lo veremos más adelante.

Coincidencia exacta vs aproximada en VLOOKUP()

La coincidencia exacta devuelve un resultado solo cuando el valor es idéntico. La coincidencia aproximada devuelve el valor más cercano disponible cuando no encuentra una coincidencia exacta, normalmente sobre datos ordenados.

En VLOOKUP(), esto se controla con el último argumento. Ese último argumento, FALSE o TRUE, es el que más se confunde porque TRUE parece inofensivo y no lo es.

• FALSE significa solo coincidencia exacta. Si el valor no existe, verás #N/A, que en realidad es útil.
• TRUE devuelve el valor inmediatamente inferior más cercano cuando no hay coincidencia exacta. Suena a solución de emergencia, pero se describe mejor como una respuesta incorrecta silenciosa. Además, asume que tus datos están ordenados. Si no lo están, el resultado es impredecible.

Yo usaría TRUE solo para búsquedas por tramos, como rangos de impuestos o bandas de notas, donde lo aproximado es el comportamiento correcto por diseño. Para todo lo demás, usa FALSE.

Coincidencia exacta (FALSE)

Esto le dice a VLOOKUP(): «Solo devuelve un resultado si encuentras este valor exacto». Por ejemplo, esta fórmula =VLOOKUP("E1005", A:G, 7, FALSE) busca E1005, devuelve el salario de la columna 7 y da como resultado 90000.

Si el valor no existe, obtendrás un error #N/A.

Coincidencia exacta en VLOOKUP(). Imagen del autor.

Coincidencia aproximada (TRUE)

Esto le dice a VLOOKUP(): «Si no encuentras una coincidencia exacta, devuelve el valor más cercano por debajo». Puede sonar útil —a veces lo es—, pero otras veces te da la respuesta equivocada sin avisar.

Por ejemplo, E1011 no existe en nuestro conjunto de datos. El último ID de empleado es E1010. Así que si usas esta fórmula =VLOOKUP("E1011", A:G, 7, TRUE), VLOOKUP() no devolverá un error. En su lugar, te devolverá el valor de la coincidencia inferior más cercana, que es E1010. La celda mostrará 88000.

Así que, aunque falte E1011, VLOOKUP() sigue devolviendo un resultado porque TRUE permite coincidencia aproximada.

Coincidencia aproximada en VLOOKUP(). Imagen del autor.

Ahora imagina que los datos están desordenados e introduzco en la fórmula el ID de empleado disponible, así: =VLOOKUP("E1011", A:G, 7, TRUE).

Esta vez la fórmula devuelve un salario incorrecto porque la columna de búsqueda no está ordenada y la coincidencia aproximada depende de que los datos estén ordenados.

La coincidencia aproximada de VLOOKUP() falla por una lista sin ordenar. Imagen del autor.

Errores comunes en VLOOKUP() y cómo solucionarlos

Veamos los problemas más habituales con VLOOKUP() y cómo resolverlos:

Error #N/A

Un #N/A significa que VLOOKUP() no ha podido encontrar el valor que pediste.

Supón que tienes esta fórmula: =VLOOKUP("E9999", A:G, 7, FALSE)

Si E9999 no está en la primera columna del rango, la fórmula devuelve #N/A.

También puede pasar si el valor está escrito de forma diferente en la hoja, por ejemplo, con espacios extra o problemas de formato de texto.

Para solucionarlo:

• Asegúrate de que el valor existe en la primera columna del rango

• Usa la referencia de celda correcta en lugar de teclear el valor a mano siempre que puedas

• Añade comillas si escribes un texto directamente en la fórmula

• Elimina espacios en blanco al principio o al final de los datos

• Usa FALSE solo cuando necesites una coincidencia exacta

Índice de columna incorrecto

El índice de columna le indica a VLOOKUP() desde qué columna devolver el valor dentro del rango seleccionado. Si el número de índice es demasiado grande, la fórmula devuelve #REF!.

Esta =VLOOKUP("E1005", A:G, 8, FALSE) devuelve #REF! porque el rango A:G solo tiene 7 columnas.

Índice de columna incorrecto provoca un error. Imagen del autor.

También puedes obtener un resultado equivocado si el número de columna es válido pero apunta a la columna incorrecta.

Por ejemplo:

=VLOOKUP("E1005", A:G, 5, FALSE)

Esto devuelve el puesto, no el salario.

Para solucionarlo:

• Cuenta las columnas desde la primera columna del rango seleccionado
• Comprueba que el número de columna corresponde al valor que quieres devolver
• Asegúrate de que la columna existe dentro del rango

Problemas con la coincidencia aproximada

Si usas TRUE, VLOOKUP() busca la coincidencia inferior más cercana en lugar de exigir una exacta.

Si escribes =VLOOKUP("E1011", A:G, 7, TRUE) y no existe E1011 en el conjunto de datos, en lugar de devolver un error, la fórmula devuelve 88000, que pertenece a E1010.

Ese resultado puede parecer correcto, pero no es una coincidencia exacta.

Para solucionarlo:

• Usa FALSE cuando necesites un resultado exacto

• Usa TRUE solo cuando los datos estén ordenados y un resultado aproximado sea aceptable

Problemas de rango

VLOOKUP() también puede fallar cuando el rango seleccionado no se ajusta a lo que intenta hacer la fórmula.

Por ejemplo, =VLOOKUP("E1005", A:C, 7, FALSE) devuelve #REF! porque el rango A:C tiene solo 3 columnas, pero la fórmula pide la columna 7.

Otro problema común aparece cuando la columna de búsqueda no es la primera del rango.

Mira esta fórmula:

=VLOOKUP("E1005", B:G, 7, FALSE)

Aquí, la primera columna del rango es la B, no la A. Como VLOOKUP() solo busca en la primera columna del rango seleccionado, no puede encontrar E1005.

Para solucionarlo:

• Asegúrate de que la columna de búsqueda sea la primera del rango
• Verifica que el rango incluya la columna que quieres devolver
• Revisa el rango seleccionado antes de finalizar la fórmula

Un rango incorrecto provoca un error. Imagen del autor.

VLOOKUP() entre hojas en Google Sheets

Puedes usar VLOOKUP() para traer datos de otra hoja añadiendo el nombre de la hoja antes del rango.

El formato es así:

=VLOOKUP(search_key, SheetName!range, index, FALSE)

La parte SheetName! le indica a la fórmula en qué hoja buscar.

Supón que tus datos están en una hoja llamada Employees y estás trabajando en otra hoja. Para encontrar el departamento del empleado con ID E1005, usa:

=VLOOKUP("E1005", Employees!A:G, 4, FALSE)

Aquí:

• Employees!A:G busca en la hoja Employees

• 4 devuelve la columna Department

La fórmula devuelve el departamento de E1005.

Referenciar otra hoja en VLOOKUP(). Imagen del autor.

Cuando los nombres de hoja tienen espacios

Si el nombre de la hoja contiene espacios, enciérralo entre comillas simples así: 

=VLOOKUP("E1005", 'Employee Data'!A:G, 7, FALSE)

Sin las comillas, la fórmula no funcionará.

VLOOKUP() vs. INDEX MATCH en Google Sheets

VLOOKUP() busca en una columna fija y devuelve datos en función de la posición, mientras que INDEX MATCH encuentra valores usando referencias de fila y columna directamente, por lo que funciona aunque cambie la estructura de la tabla.

VLOOKUP: rápido de escribir, fácil de romper

Ya has visto que =VLOOKUP("E1005", A:G, 7, FALSE) encuentra el salario de E1005.

Funciona bien cuando:

• La columna de búsqueda está a la izquierda
• La estructura de la tabla no cambia

Los problemas empiezan cuando la estructura cambia.

Por ejemplo:

• Insertas una columna nueva
• La columna de salario pasa de la 7 a la 8
• La fórmula sigue usando 7

Ahora devuelve un valor incorrecto sin mostrar error.

INDEX MATCH: más largo, pero estable

Ahora mira la misma búsqueda con INDEX MATCH:

=INDEX(G:G, MATCH("E1005", A:A, 0))

Aquí:

• MATCH() encuentra la posición de E1005 en la columna A

• INDEX() devuelve el valor de la columna G en esa posición

Este método no depende de números de columna, así que sigue funcionando aunque cambie la tabla.

INDEX MATCH gestiona mejor los datos que VLOOKUP(). Imagen del autor.

Dónde realmente ayuda

Usa INDEX MATCH cuando tus datos no estén organizados de izquierda a derecha. Supón que la columna A contiene el ID de empleado y la columna C contiene el apellido. Si quieres buscar por apellido y devolver el ID de empleado, sería una búsqueda de derecha a izquierda.

VLOOKUP() no puede hacerlo sin cambiar la tabla, pero INDEX MATCH lo resuelve directamente:

=INDEX(A:A, MATCH("Wilson", C:C, 0))

No hace falta reorganizar tus datos.

VLOOKUP() vs XLOOKUP en Google Sheets

VLOOKUP() busca dentro de una estructura fija y tiene limitaciones, mientras que XLOOKUP() permite búsquedas en cualquier dirección. Llegó a Google Sheets en 2022 y ahora es la mejor opción en muchos casos.

Imagina que quieres encontrar el ID de empleado usando el apellido Wilson. Es una búsqueda de derecha a izquierda. VLOOKUP() no puede con esto sin reordenar la tabla, pero XLOOKUP() sí:

=XLOOKUP("Wilson", C:C, A:A)

Esta fórmula:

• Busca el apellido (columna C)
• Devuelve el ID de empleado (columna A)

XLOOKUP() en Google Sheets. Imagen del autor.

XLOOKUP() es mejor porque:

• Funciona en cualquier dirección (izquierda o derecha)
• No usa números de columna
• Devuelve coincidencias exactas por defecto
• Permite personalizar la salida cuando no hay coincidencias

Conclusión

Si tuviera que darte un solo consejo: construye VLOOKUP() en una hoja de cálculo real que te importe, no en una de práctica. Los errores se sienten de otra manera cuando el dato es importante. Recordarás por qué existe FALSE la primera vez que TRUE te dé en silencio el salario equivocado de alguien.

Cuando te sientas cómodo, prueba diferentes tipos de coincidencia, ajusta tus rangos y fíjate en cuándo los resultados dejan de tener sentido. Normalmente ese es el punto en el que una opción más flexible como INDEX MATCH() o XLOOKUP() tiene más sentido.