Excel LAMBDA(): Wie man benutzerdefinierte Funktionen erstellt

Excel bietet mit der Funktion LAMBDA() die Möglichkeit, eigene Formeln zu verwenden. Damit kannst du jede Berechnung kapseln, ihr einen Namen geben und sie überall in deiner Arbeitsmappe wiederverwenden.

Das bedeutet, dass du nicht immer und immer wieder die gleiche Formel kopieren musst. Stattdessen kannst du LAMBDA() verwenden, um deine Tabellenkalkulationen sauberer und pflegeleichter zu machen, und wenn du mich fragst, ist das sogar noch ein bisschen einfacher als die Verwendung von VBA.

Warum Excel LAMBDA() verwenden?

Mit LAMBDA() kannst du jede Formel in eine von dir definierte Funktion verpacken. Du gibst Eingabeparameter an (genau wie die Argumente in SUM() oder VLOOKUP()) und rufst dann deine neue Funktion mit diesen Parametern auf, wenn du sie brauchst. Hier ist die Struktur:

=LAMBDA(parameter1, parameter2, ..., calculation)

Du kannst mit LAMBDA() Formeln direkt in einer Zelle experimentieren, aber die wirkliche Leistung kommt, wenn du sie als benannte Funktion speicherst. Nach der Benennung erscheint deine benutzerdefinierte Funktion in deiner Arbeitsmappe genau wie SUM(), AVERAGE() und andere. 

Hier sind einige überzeugende Gründe, LAMBDA() in deinen Arbeitsablauf einzubinden:

• Eliminiere sich wiederholende Formeln. Anstatt eine komplexe Formel überall neu zu schreiben, kannst du sie in eine Funktion umwandeln und sie mit ihrem Namen aufrufen.

• Gestalte deine Tabellen übersichtlicher. Benannte Funktionen sind für dich und deine Mitarbeiter viel einfacher zu verstehen als eine wiederholte, kryptische Formel.

• Kombiniere mit anderen neuen Funktionen. LAMBDA() lässt sich gut mit LET(), MAP(), REDUCE() und anderen modernen Excel-Funktionen kombinieren.

• Verringere die Anzahl der Fehler. Sobald deine Logik getestet und in eine LAMBDA() verpackt ist, kannst du sie wiederverwenden - keine Tippfehler mehr durch das Kopieren von Formeln.

Wie man eine Excel LAMBDA()-Funktion erstellt

Wie alles andere auch, braucht es dafür etwas Übung. Lass uns also unsere eigenen LAMBDA() Funktionen erstellen.

Stell dir vor, du berechnest die Fläche eines Kreises aus seinem Radius und ertappst dich dabei, dass du immer wieder =PI()*A1^2 eingibst.

Versuche zunächst, eine LAMBDA() Formel direkt in einer Zelle zu erstellen und auszuführen:

=LAMBDA(r, PI()*r^2)(3)

Hier haben wir eine Funktion LAMBDA() erstellt, die r als Parameter akzeptiert und die Fläche des Kreises zurückgibt. Das (3) am Ende liefert den Radius, also berechnet diese Formel die Fläche für einen Kreis mit Radius 3.

Natürlich ist es keine große Verbesserung gegenüber der ursprünglichen Formel, wenn du jedes Mal die LAMBDA() abtippst. Aber hab Geduld mit mir, denn hier kommen benannte Funktionen ins Spiel:

1. Gehe zu Formeln > Namensmanager > Neu.

2. Wähle einen Namen für deine Funktion, z. B. CircleArea.

3. Gib in das Feld Verweis auf ein:

=LAMBDA(r, PI()*r^2)

Jetzt kannst du deine benutzerdefinierte Funktion in deiner gesamten Arbeitsmappe verwenden:

=CircleArea(A1)

Jetzt hast du eine wiederverwendbare, benutzerdefinierte Funktion erstellt.

Excel LAMBDA() Syntax und Parameter

LAMBDA() kann eine beliebige Anzahl von Parametern akzeptieren (bis zur Excel-Grenze von 253), die jeweils durch ein Komma getrennt sind. (Nicht, dass du wirklich so viele benutzen würdest.) 

Es ist wichtig zu sehen, dass das letzte Argument immer die Berechnung selbst ist, die jeden der von dir definierten Parameter verwenden kann.

=LAMBDA(parameter1, parameter2, ..., calculation)

Wenn du zum Beispiel eine Funktion erstellen willst, die die größere von zwei Zahlen zurückgibt, könntest du schreiben:

=LAMBDA(a, b, IF(a > b, a, b))

Nachdem du diese Funktion unter einem Namen gespeichert hast - MaxOfTwo ist ein guter Name - kannst du sie wie jede andere Excel-Funktion verwenden:

=MaxOfTwo(7, 4)

Diese Formel liefert 7, den größeren der beiden Eingänge.

Spezifischere Excel LAMBDA() Beispiele

Lass uns weiter üben.

Excel LAMBDA() mit mehreren Parametern

Als Nächstes wollen wir mit Funktionen arbeiten, die mehrere Eingaben benötigen. Wie zuvor trennen wir unsere Parameter mit Kommas und geben die gleiche Anzahl von Argumenten an, wenn wir die Funktion aufrufen.

Um zwei Zahlen zu addieren:

=LAMBDA(a, b, a + b)(4, 9)

Dies ergibt 13.

Wenn du dich dafür entscheidest, dies in eine benannte Funktion namens AddTwo umzuwandeln, kannst du sie in deiner gesamten Arbeitsmappe wie folgt verwenden:

=AddTwo(A1, A2)

Du hast jetzt eine eigene Additionsfunktion.

Sich wiederholende Logik bereinigen

Angenommen, du berechnest die Provisionen mit dieser Formel an mehreren Stellen:

=IF(A2 > 1000, A2*0.1, 0)

Anstatt diese Formel überall zu kopieren, wo du sie verwenden musst, kannst du die Logik mit LAMBDA() kapseln:

=LAMBDA(amount, IF(amount > 1000, amount*0.1, 0))

Nenne diese Funktion Commission und du kannst sie jetzt verwenden:

=Commission(A2)

Wenn du jemals die Provisionslogik ändern musst, brauchst du nur die LAMBDA() an einer Stelle zu aktualisieren, und jede Formel, die Commission verwendet, wird ebenfalls aktualisiert.

Rekursion und verschachtelte Funktionen

LAMBDA() unterstützt Rekursion, d.h. eine Funktion kann sich selbst aufrufen. Das bringt neue Ideen hervor, wie z.B. benutzerdefinierte Aggregationen.

So könntest du zum Beispiel eine rekursive Faktor-Funktion definieren:

=LAMBDA(n, IF(n=1, 1, n*Factorial(n-1))) 

Du speicherst sie als benannte Funktion und sie funktioniert wie jede rekursive Funktion in der Programmierung. (Für den Namen würde ich etwas Eindeutiges wählen, wie Factorial.) 

LAMBDA() mit anderen dynamischen Array-Funktionen

LAMBDA() kann mit anderen dynamischen Excel-Funktionen wie LET(), MAP(), und REDUCE() kombiniert werden. 

LET() ermöglicht es dir, Variablen innerhalb deiner Formel zuzuweisen und wiederzuverwenden, während MAP() und REDUCE() LAMBDA() s auf Arrays oder Listen anwenden.

Zum Beispiel, um jeden Wert in einem Bereich zu verdoppeln:

=MAP(A1:A5, LAMBDA(x, IF(x>10, x*2, x)))

Hier wendet MAP() deine Funktion LAMBDA() auf jedes Element in A1:A5 an. Das ist sehr praktisch für Stapelberechnungen.

(Die obige Formel verdoppelt den entsprechenden Wert im Bereich nur, wenn der Wert größer als 10 ist).

(Ein weiterer Vorteil ist, dass du die Formel nur einmal in Zelle B1 schreiben musst und die Zellen darunter automatisch ausgefüllt werden).

Profi-Tipps mit Excel LAMBDA()

Hier sind einige Tipps aus Erfahrung.

Teste Excel LAMBDA()-Funktionen, bevor du sie benennst

Bevor du deine LAMBDA() benennst und speicherst, ist es klug, sie direkt in einer Zelle zu testen. Du kannst dies tun, indem du deine Testargumente in Klammern anhängst, genau wie beim Aufruf jeder Funktion:

=LAMBDA(x, x*2)(5)

Dies ergibt 10, das erwartete Ergebnis.

Wenn du beim Testen vergisst, ein Argument anzugeben, z. B. wenn du nur =LAMBDA(x, x*2) eingibst, zeigt Excel die Funktion selbst an und nicht das Ergebnis. Denke immer daran, die letzten Klammern mit deinen Eingabewerten hinzuzufügen.

Einige Vorbehalte

Halten wir inne und betrachten wir die Grenzen:

• LAMBDA() Funktionen sind in der Arbeitsmappe enthalten. Wenn du deine benutzerdefinierten Funktionen in einer anderen Arbeitsmappe verwenden möchtest, musst du sie kopieren oder die neue Funktion " Benannte Funktionen" von Excel nutzen, sofern sie verfügbar ist.

• Du kannst LAMBDA() nicht verwenden, um flüchtige Funktionen (wie NOW() oder RAND()) zu erstellen.

• Wenn du beim Aufruf von LAMBDA() die falsche Anzahl von Argumenten angibst, führt das zu einem #VALUE! Fehler. Überprüfe also immer deine Eingaben.

• Nicht alle Excel-Versionen unterstützen LAMBDA(). Um diese Funktionen nutzen zu können, brauchst du Microsoft 365 oder die neueste Webversion.

LAMDA() und andere Funktionen

Schließlich sollten wir LAMBDA() neben anderen Möglichkeiten betrachten. 

Wann solltest du Excel LAMBDA() verwenden?

Wenn du über alles nachdenkst, was wir bisher besprochen haben, fragst du dich vielleicht: Wann ist LAMBDA() das richtige Werkzeug für den Job? Greife nach LAMBDA(), wenn:

• Du hast komplexe oder sich wiederholende Formeln, die du vereinfachen möchtest.
• Es gibt eine Logik, die du gerne benennen und erklären würdest.
• Du möchtest benutzerdefinierte Berechnungen oder eine Logik, die Excel nicht von Haus aus bietet.

Meiner Meinung nach ist LAMBDA() besonders nützlich für Teams, vor allem wenn die Funktionsnamen eindeutig sind. Dann sehen die Teammitglieder genau, was die Logik macht, ohne dass sie die Berechnung durcharbeiten müssen, um sie zu verstehen. 

Verwandte Excel-Funktionen

Es ist hilfreich, mit anderen neuen Excel-Funktionen vertraut zu sein, die LAMBDA() ergänzen. Hier sind ein paar davon. Einige habe ich bereits erwähnt.

• LET(): Namen für Berechnungen innerhalb einer Formel zuweisen

• MAP(): Eine LAMBDA() auf jedes Element in einem Array anwenden

• REDUCE(): Falten Sie ein Array auf einen einzigen Wert herunter, indem Sie eine LAMBDA()

• BYROW(), BYCOL(): LAMBDA() nach Zeilen oder Spalten anwenden

Diese Funktionen ermöglichen in Verbindung mit LAMBDA() anspruchsvollere Logik und Datenumwandlungen. In unserem Kurs Excel-Funktionen für Fortgeschrittene lernst du die wirklich nützlichen Funktionen kennen, die Excel zu bieten hat.

Fazit

Wie wir gesehen und geübt haben, kannst du mit Excel LAMBDA() deine eigenen Arbeitsblattfunktionen erstellen, ohne VBA auch nur anfassen zu müssen. Verwende also LAMBDA(), wenn du regelmäßig dieselbe Berechnung an vielen Stellen schreibst oder komplizierte Formeln zähmen willst.

Und vergiss nicht, unseren Kurs Excel-Funktionen für Fortgeschrittene zu besuchen, um schneller und intelligenter mit Excel zu werden. Und wenn du ein Finanzanalyst bist oder einer werden willst, belege auch unseren Kurs Finanzmodellierung in Excel. Die LAMDA()-Funktionen werden vor allem in der Finanzwelt nützlich sein.