Fórmula de edad en Excel: Métodos sencillos para calcular la edad

Calcular la edad en Excel es una tarea habitual para los profesionales de RRHH que gestionan registros de empleados, los investigadores que analizan datos de encuestas o cualquiera que mantenga conjuntos de datos personales. Aunque Excel no incluye una función "EDAD" específica, varias fórmulas sencillas pueden ayudarte a determinar la edad de alguien con precisión. Esta guía te guiará a través de varios métodos para calcular la edad en Excel, desde enfoques sencillos hasta fórmulas más detalladas que pueden darte los años, meses y días exactos.

Para los nuevos en Excel, nuestro curso Introducción a Excel cubre habilidades esenciales como navegar por la interfaz, comprender los formatos de datos y trabajar con funciones básicas. Si quieres ampliar tus capacidades analíticas más allá de los cálculos de edad, nuestro curso de Análisis de Datos en Excel te enseña a trabajar con Tablas Dinámicas y funciones lógicas avanzadas para obtener conocimientos más profundos. 

Fórmula básica de edad en Excel

La forma más sencilla de calcular la edad en Excel consiste en restar la fecha de nacimiento a la fecha de hoy y dividirla por 365. Por ejemplo, si la celda A2 contiene una fecha de nacimiento, podrías utilizar

=(TODAY()-A2)/365

Esta fórmula te da la edad en años con un componente decimal que representa los años parciales. Aunque este enfoque es fácil de aplicar, no siempre es preciso. La división por 365 no tiene en cuenta los años bisiestos, lo que puede dar lugar a pequeños errores que se acumulan con el tiempo. Además, este método no gestiona adecuadamente la duración variable de los meses.

Por ejemplo, utilizando esta fórmula para alguien nacido el 15 de enero de 1990, podría mostrar 35,3 años en lugar de exactamente 35 años y 3 meses. Esta discrepancia se hace más notable a medida que aumenta el intervalo de tiempo, lo que lo hace menos ideal para un seguimiento preciso de la edad o para documentación legal.

Métodos precisos de cálculo de la edad

Utilizar INT() y YEARFRAC() para mayor precisión

La función YEARFRAC() puede ofrecer una mayor precisión en el cálculo de edades, pero su exactitud depende de cómo la utilices. Aunque YEARFRAC() puede tener en cuenta los años bisiestos y las distintas longitudes de los meses, esto depende del parámetro opcional basis: 

=INT(YEARFRAC(A2,TODAY(),1))

Cada componente tiene una función específica:

• YEARFRAC(start_date, end_date, basis) calcula la fracción de años entre dos fechas

• El parámetro base (1) indica a Excel que utilice días reales en los cálculos

• TODAY() proporciona la fecha actual

• INT() elimina la parte decimal, dando sólo los años completados

Sin especificar el parámetro base, YEARFRAC() tiene por defecto base=0 (EE.UU.). 30/360), que considera que cada mes tiene 30 días y no tiene en cuenta la duración real de los meses ni los años bisiestos. Establecer base=1 indica a Excel que utilice el método real/real, en el que los días reales de cada mes y año se utilizan en el cálculo.

Este método es el preferido para la mayoría de las situaciones, debido a su equilibrio entre sencillez y precisión. Por ejemplo, si alguien nació el 15 de marzo de 1995, esta fórmula mostraría correctamente su edad en años cumplidos.

Utilizar DATEDIF() para la edad exacta

La función DATEDIF() (Diferencia de fechas) está específicamente diseñada para calcular intervalos de tiempo entre fechas. Para calcular la edad en años cumplidos, utiliza:

=DATEDIF(A2,TODAY(),"Y")

El parámetro "Y" indica a Excel que sólo cuente los años completados. Esta función te da el número de años completos con precisión y funciona bien cuando necesitas un resultado entero limpio. La ventaja de DATEDIF() es su precisión: sólo cuenta un año una vez que se ha completado por completo, lo que lo hace perfecto para los cálculos oficiales de edad.

Utilizar varias funciones DATEDIF()

Este método puede ayudarte a calcular la edad exacta en años, meses y días combinando tres funciones DATEDIF():

Desde hace años:

=DATEDIF(A2,TODAY(),"Y")

Durante meses más allá del último año cumplido:

=DATEDIF(A2,TODAY(),"YM")

Para días posteriores al último mes completado:

=DATEDIF(A2,TODAY(),"MD")

Para mostrarlos juntos en una sola celda:

=DATEDIF(A2,TODAY(),"Y")&" years, "&DATEDIF(A2,TODAY(),"YM")&" months, "&DATEDIF(A2,TODAY(),"MD")&" days"

Este método crea un desglose por edades claro y detallado. Para una visualización más limpia, puedes añadir sentencias SI para ocultar los valores cero:

=IF(DATEDIF(A2,TODAY(),"Y")=0,"",DATEDIF(A2,TODAY(),"Y")&" years, ")&IF(DATEDIF(A2,TODAY(),"YM")=0,"",DATEDIF(A2,TODAY(),"YM")&" months, ")&IF(DATEDIF(A2,TODAY(),"MD")=0,"",DATEDIF(A2,TODAY(),"MD")&" days")

Esta fórmula muestra "35 años, 3 meses, 18 días" en lugar de "35 años, 0 meses, 0 días" cuando procede.

Casos de uso especiales para el cálculo de la edad

Calcular la edad en una fecha concreta

A veces necesitas calcular la edad en una fecha distinta a la de hoy, como una fecha de contratación futura o un momento histórico. Para modificar las fórmulas para una fecha de referencia concreta, sólo tienes que sustituir TODAY() por tu fecha objetivo:

=DATEDIF(A2,DATE(2024,12,31),"Y")

Esta fórmula calcula la edad que tendrá una persona el 31 de diciembre de 2024. Del mismo modo, para un desglose completo de la edad en una fecha concreta:

=DATEDIF(A2,DATE(2024,12,31),"Y")&" years, "&DATEDIF(A2,DATE(2024,12,31),"YM")&" months, "&DATEDIF(A2,DATE(2024,12,31),"MD")&" days"

Este enfoque es útil para la planificación de RRHH, los cálculos de seguros o el análisis de puntos de datos históricos.

Calcular la edad en un año determinado

Cuando sólo se da un año y necesitas calcular la edad de alguien en ese año, puedes utilizar la función DATE() para establecer los valores del mes y del día:

=DATEDIF(A2,DATE(2030,12,31),"Y")

O para cálculos a mitad de año:

=DATEDIF(A2,DATE(2030,6,30),"Y")

Esto ayuda en los escenarios de planificación a largo plazo en los que no se necesitan fechas exactas, sino sólo la edad en un año concreto.

Encontrar la fecha en que una persona alcanza una determinada edad

Para averiguar la fecha en la que alguien cumple una edad determinada (como el derecho a la jubilación), utiliza:

=DATE(YEAR(A2)+65,MONTH(A2),DAY(A2))

Esta fórmula añade 65 años a su fecha de nacimiento para saber cuándo cumplirá 65 años. El resultado es un valor de fecha de Excel que muestra exactamente cuándo alcanzarán ese hito.

Para situaciones más complejas en las que necesites averiguar cuándo alguien alcanza una determinada edad más meses:

=DATE(YEAR(A2)+30,MONTH(A2)+6,DAY(A2))

Esta fórmula determina cuándo alguien tendrá 30 años y 6 meses, lo que puede ser útil para los requisitos de elegibilidad con especificaciones tanto de año como de mes.

Resaltar edades según umbrales de edad

El formato condicional proporciona una forma visual de identificar las edades que pertenecen a categorías específicas. Aunque estas fórmulas devolverían TRUE o FALSE si se introdujeran directamente en las celdas, cuando se utilizan en formato condicional, aplican automáticamente los estilos de formato que elijas.

Destacar menores de 18 años

Para configurar un formato condicional que resalte las celdas que contengan personas menores de 18 años:

1. Selecciona tu rango de datos
2. Ir a Inicio → Formato condicional → Nueva regla
3. Elige un estilo clásico
4. Elige Utilizar una fórmula para determinar qué celdas formatear
5. Introduce esta fórmula:

=DATEDIF(A2, TODAY(), "Y")<18

6.   Haz clic en Formato y selecciona el estilo de resaltado que desees (color, fuente, etc.)

Cuando se aplica esta regla, Excel evalúa la fórmula de cada celda. Si el resultado es TRUE (la persona es menor de 18 años), Excel aplica automáticamente el formato que hayas elegido.

Destacar entre 18 y 65 años

Para identificar a las personas en edad de trabajar:

1. Sigue los mismos pasos que arriba
2. Utiliza esta fórmula en la regla de formato condicional:

=AND(DATEDIF(A2, TODAY(), "Y")>=18, DATEDIF(A2, TODAY(), "Y")<=65)

3. Elige un estilo de formato diferente para este grupo

Destacar más de 65

Identificar a los mayores que puedan tener derecho a prestaciones de jubilación:

1. Crea otra regla de formato condicional
2. Utiliza esta fórmula:

=DATEDIF(A2, TODAY(), "Y")>65

3. Aplicar un tercer estilo de formato distinto

La ventaja de utilizar el formato condicional es que funciona entre bastidores: los valores reales de tus celdas permanecen inalterados mientras Excel aplica indicaciones visuales basadas en tus reglas.

Puntos clave que debes recordar

Cuando calcules las edades en Excel, ten en cuenta estos importantes consejos:

• Utiliza DATEDIF() o YEARFRAC() para una precisión óptima. DATEDIF() se ha creado específicamente para las diferencias de fechas, mientras que YEARFRAC() con basis=1 tiene en cuenta los días naturales reales.

• Utiliza las funciones INT() o ROUNDDOWN() para evitar los valores decimales cuando necesites números enteros. Así te aseguras de obtener años completos en lugar de años parciales con decimales.

• Ten cuidado con los años bisiestos y las diferentes duraciones de los meses. La fórmula básica (dividir por 365) no tiene en cuenta estas variaciones, lo que provoca pequeñas inexactitudes a lo largo del tiempo.

• Asegúrate de que los formatos de fecha son correctos. Excel tiene que reconocer tus fechas como verdaderos valores de fecha, no como texto. Si tus fórmulas devuelven resultados inesperados, comprueba que tus fechas están correctamente formateadas como fechas en Excel.

• Para cálculos de fechas en grandes conjuntos de datos, considera almacenar tus fórmulas como rangos con nombre o crear una hoja de cálculo dedicada. Esto hace que tus hojas de cálculo sean más fáciles de mantener y actualizar.

• Comprueba tus cálculos de edad con ejemplos conocidos para verificar su exactitud. Intenta calcular las edades de las personas nacidas en días bisiestos (29 de febrero) o cerca de los límites de los meses para asegurarte de que tus fórmulas manejan correctamente los casos extremos.

Conclusión

Calcular la edad en Excel es sencillo una vez que seleccionas el método adecuado a tus necesidades. Para aplicaciones básicas, la función DATEDIF() ofrece una solución limpia y precisa. Para análisis más detallados, las fórmulas combinadas pueden proporcionar desgloses exactos en años, meses y días.

Para grandes conjuntos de datos, puedes automatizar estos cálculos incrustando fórmulas en plantillas o utilizando las herramientas más avanzadas de Excel, como Power Query. Esta automatización es especialmente útil para bases de datos de RRHH o estudios demográficos en los que miles de registros pueden necesitar cálculos de edad.

Si buscas desarrollar un conjunto más completo de habilidades de Excel que vaya más allá de los cálculos de edad, nuestro programa de habilidades Fundamentos de Excel proporciona un itinerario de aprendizaje estructurado que te lleva desde las funciones básicas hasta las técnicas avanzadas de análisis de datos. Si eliges la fórmula adecuada en función de tus requisitos específicos, te asegurarás de que tus cálculos de edad sigan siendo precisos y fiables, tanto si necesitas valores básicos de edad, desgloses detallados o análisis especializados para fechas y umbrales concretos.