Altersformel in Excel: Einfache Methoden zur Altersberechnung

Die Berechnung des Alters in Excel ist eine häufige Aufgabe für Personalverantwortliche, die Mitarbeiterdaten verwalten, für Forscher, die Umfragedaten analysieren, oder für alle, die persönliche Datensätze verwalten. Excel hat zwar keine eigene Funktion "ALTER", aber mit einigen einfachen Formeln kannst du das Alter einer Person genau bestimmen. In diesem Leitfaden lernst du verschiedene Methoden zur Altersberechnung in Excel kennen, von einfachen Ansätzen bis hin zu detaillierten Formeln, mit denen du genaue Jahre, Monate und Tage ermitteln kannst.

Für alle, die neu in Excel sind, vermittelt unser Kurs "Einführung in Excel" wichtige Fähigkeiten wie das Navigieren auf der Benutzeroberfläche, das Verstehen von Datenformaten und die Arbeit mit grundlegenden Funktionen. Wenn du deine analytischen Fähigkeiten über Altersberechnungen hinaus erweitern möchtest, lernst du in unserem Kurs Datenanalyse in Excel, wie du mit PivotTables und erweiterten logischen Funktionen arbeitest, um tiefere Einblicke zu erhalten. 

Grundlegende Altersformel in Excel

Die einfachste Art, das Alter in Excel zu berechnen, besteht darin, das Geburtsdatum vom heutigen Datum zu subtrahieren und durch 365 zu dividieren. Wenn Zelle A2 zum Beispiel ein Geburtsdatum enthält, könntest du es verwenden:

=(TODAY()-A2)/365

Mit dieser Formel erhältst du das Alter in Jahren mit einer Dezimalkomponente für Teiljahre. Dieser Ansatz ist zwar einfach zu implementieren, aber nicht immer genau. Bei der Division durch 365 werden Schaltjahre nicht berücksichtigt, was zu kleinen Fehlern führen kann, die sich mit der Zeit ansammeln. Außerdem geht diese Methode nicht richtig mit unterschiedlichen Monatslängen um.

Wenn du diese Formel zum Beispiel für jemanden anwendest, der am 15. Januar 1990 geboren wurde, kann es sein, dass du 35,3 Jahre statt genau 35 Jahre und 3 Monate alt wirst. Diese Diskrepanz macht sich mit zunehmender Zeitspanne bemerkbar und ist daher für eine genaue Altersbestimmung oder rechtliche Dokumentation weniger geeignet.

Genaue Methoden zur Altersberechnung

INT() und YEARFRAC() für eine bessere Genauigkeit verwenden

Die Funktion YEARFRAC() kann die Genauigkeit bei der Altersberechnung verbessern, aber die Genauigkeit hängt davon ab, wie du sie benutzt. YEARFRAC() kann zwar Schaltjahre und unterschiedliche Monatslängen berücksichtigen, aber das hängt von dem optionalen Parameter basis ab: 

=INT(YEARFRAC(A2,TODAY(),1))

Jede Komponente dient einem bestimmten Zweck:

• YEARFRAC(start_date, end_date, basis) Berechnet den Bruchteil der Jahre zwischen zwei Daten

• Der Basis-Parameter (1) weist Excel an, bei den Berechnungen die tatsächlichen Tage zu verwenden

• TODAY() liefert das aktuelle Datum

• INT() entfernt den Dezimalteil und gibt nur abgeschlossene Jahre an

Ohne Angabe des Basisparameters ist YEARFRAC() standardmäßig auf basis=0 (U.S.) eingestellt. 30/360), die jeden Monat als 30 Tage behandelt und die tatsächlichen Monatslängen oder Schaltjahre nicht berücksichtigt. Wenn du basis=1 einstellst, verwendet Excel die Ist-/Ist-Methode, bei der die tatsächlichen Tage in jedem Monat und Jahr für die Berechnung verwendet werden.

Diese Methode wird für die meisten Szenarien bevorzugt, da sie ein ausgewogenes Verhältnis zwischen Einfachheit und Genauigkeit bietet. Wenn jemand zum Beispiel am 15. März 1995 geboren wurde, würde diese Formel sein Alter korrekt in vollen Jahren anzeigen.

DATEDIF() für genaues Alter verwenden

Die Funktion DATEDIF() (Datumsdifferenz) wurde speziell für die Berechnung von Zeitabständen zwischen Daten entwickelt. Um das Alter in vollendeten Jahren zu berechnen, verwende:

=DATEDIF(A2,TODAY(),"Y")

Der Parameter "Y" weist Excel an, nur abgeschlossene Jahre zu zählen. Diese Funktion gibt dir die Anzahl der vollen Jahre genau an und funktioniert gut, wenn du ein sauberes ganzzahliges Ergebnis brauchst. Der Vorteil von DATEDIF() ist seine Genauigkeit - es zählt nur ein Jahr, wenn es vollständig ausgefüllt ist, was es perfekt für offizielle Altersberechnungen macht.

Mehrere DATEDIF()-Funktionen verwenden

Mit dieser Methode kannst du das genaue Alter in Jahren, Monaten und Tagen berechnen, indem du drei Funktionen von DATEDIF() kombinierst:

Seit Jahren:

=DATEDIF(A2,TODAY(),"Y")

Für Monate nach dem letzten abgeschlossenen Jahr:

=DATEDIF(A2,TODAY(),"YM")

Für Tage nach dem letzten abgeschlossenen Monat:

=DATEDIF(A2,TODAY(),"MD")

Um sie zusammen in einer einzigen Zelle anzuzeigen:

=DATEDIF(A2,TODAY(),"Y")&" years, "&DATEDIF(A2,TODAY(),"YM")&" months, "&DATEDIF(A2,TODAY(),"MD")&" days"

Mit dieser Methode wird eine klare, detaillierte Altersaufschlüsselung erstellt. Für eine sauberere Darstellung kannst du IF-Anweisungen hinzufügen, um Nullwerte auszublenden:

=IF(DATEDIF(A2,TODAY(),"Y")=0,"",DATEDIF(A2,TODAY(),"Y")&" years, ")&IF(DATEDIF(A2,TODAY(),"YM")=0,"",DATEDIF(A2,TODAY(),"YM")&" months, ")&IF(DATEDIF(A2,TODAY(),"MD")=0,"",DATEDIF(A2,TODAY(),"MD")&" days")

Diese Formel zeigt "35 Jahre, 3 Monate, 18 Tage" anstelle von "35 Jahre, 0 Monate, 0 Tage", wenn es angebracht ist.

Besondere Anwendungsfälle für die Altersberechnung

Berechnung des Alters an einem bestimmten Datum

Manchmal musst du das Alter an einem anderen Datum als heute berechnen, z. B. an einem zukünftigen Einstellungsdatum oder einem historischen Zeitpunkt. Um die Formeln für ein bestimmtes Bezugsdatum zu ändern, ersetze einfach TODAY() durch dein Zieldatum:

=DATEDIF(A2,DATE(2024,12,31),"Y")

Diese Formel berechnet, wie alt eine Person am 31. Dezember 2024 sein wird. Ähnlich verhält es sich mit einer vollständigen Altersaufschlüsselung zu einem bestimmten Datum:

=DATEDIF(A2,DATE(2024,12,31),"Y")&" years, "&DATEDIF(A2,DATE(2024,12,31),"YM")&" months, "&DATEDIF(A2,DATE(2024,12,31),"MD")&" days"

Dieser Ansatz ist nützlich für die Personalplanung, Versicherungsberechnungen oder die Analyse historischer Datenpunkte.

Berechnen des Alters in einem bestimmten Jahr

Wenn nur ein Jahr angegeben ist und du das Alter einer Person in diesem Jahr berechnen musst, kannst du die Funktion DATE() verwenden, um Monats- und Tageswerte festzulegen:

=DATEDIF(A2,DATE(2030,12,31),"Y")

Oder für Berechnungen zur Jahresmitte:

=DATEDIF(A2,DATE(2030,6,30),"Y")

Das hilft bei langfristigen Planungsszenarien, bei denen keine genauen Daten benötigt werden, sondern nur das Alter in einem bestimmten Jahr.

Das Datum herausfinden, an dem eine Person ein bestimmtes Alter erreicht

Um das Datum zu finden, an dem jemand ein bestimmtes Alter erreicht (z. B. die Rentenberechtigung), verwende:

=DATE(YEAR(A2)+65,MONTH(A2),DAY(A2))

Diese Formel addiert 65 Jahre zu ihrem Geburtsdatum, um herauszufinden, wann sie 65 Jahre alt werden. Das Ergebnis ist ein Excel-Datumswert, der genau anzeigt, wann sie diesen Meilenstein erreichen werden.

Für komplexere Szenarien, in denen du herausfinden musst, wann jemand ein bestimmtes Alter plus Monate erreicht:

=DATE(YEAR(A2)+30,MONTH(A2)+6,DAY(A2))

Mit dieser Formel lässt sich herausfinden, wann jemand 30 Jahre und 6 Monate alt wird, was bei Anspruchsvoraussetzungen mit Jahres- und Monatsangaben nützlich sein kann.

Hervorhebung von Altersgruppen anhand von Altersschwellenwerten

Die bedingte Formatierung bietet eine visuelle Möglichkeit, Altersgruppen zu identifizieren, die in bestimmte Kategorien fallen. Während diese Formeln TRUE oder FALSE zurückgeben würden, wenn sie direkt in die Zellen eingegeben werden, wenden sie bei der Verwendung in der bedingten Formatierung stattdessen automatisch die von dir gewählten Formatierungsstile an.

Highlight unter 18

Um eine bedingte Formatierung einzurichten, die Zellen mit Personen unter 18 Jahren hervorhebt:

1. Wähle deinen Datenbereich
2. Gehe zu Startseite → Bedingte Formatierung → Neue Regel
3. Wähle klassisch unter Stil
4. Wähle Eine Formel verwenden, um die zu formatierenden Zellen zu bestimmen
5. Gib diese Formel ein:

=DATEDIF(A2, TODAY(), "Y")<18

6.   Klicke auf Format und wähle den gewünschten Hervorhebungsstil (Farbe, Schriftart usw.).

Wenn diese Regel angewendet wird, wertet Excel die Formel für jede Zelle aus. Wenn das Ergebnis TRUE lautet (die Person ist unter 18), wendet Excel die von dir gewählte Formatierung automatisch an.

Highlight zwischen 18 und 65

Zur Identifizierung von Personen im erwerbsfähigen Alter:

1. Befolge die gleichen Schritte wie oben
2. Verwende diese Formel in der Regel für die bedingte Formatierung:

=AND(DATEDIF(A2, TODAY(), "Y")>=18, DATEDIF(A2, TODAY(), "Y")<=65)

3. Wähle einen anderen Formatierungsstil für diese Gruppe

Highlight über 65

Senioren zu identifizieren, die möglicherweise Anspruch auf Rentenleistungen haben:

1. Eine weitere bedingte Formatierungsregel erstellen
2. Verwende diese Formel:

=DATEDIF(A2, TODAY(), "Y")>65

3. Einen dritten Formatierungsstil anwenden

Der Vorteil der bedingten Formatierung ist, dass sie im Hintergrund funktioniert - deine tatsächlichen Zellwerte bleiben unverändert, während Excel visuelle Hinweise auf der Grundlage deiner Regeln anwendet.

Wichtige Punkte zur Erinnerung

Wenn du das Alter in Excel berechnest, solltest du diese wichtigen Tipps beachten:

• Verwende DATEDIF() oder YEARFRAC() für eine optimale Genauigkeit. DATEDIF() ist speziell für Datumsunterschiede entwickelt worden, während YEARFRAC() mit basis=1 die tatsächlichen Kalendertage berücksichtigt.

• Verwende die Funktionen INT() oder ROUNDDOWN(), um Dezimalwerte zu vermeiden, wenn du ganze Zahlen brauchst. So wird sichergestellt, dass du vollständige Jahre und keine Teiljahre mit Dezimalstellen erhältst.

• Achte auf Schaltjahre und unterschiedliche Monatslängen. Die Grundformel (Dividieren durch 365) berücksichtigt diese Schwankungen nicht, was im Laufe der Zeit zu kleinen Ungenauigkeiten führt.

• Stelle sicher, dass die Datumsformate korrekt sind. Excel muss deine Daten als echte Datumswerte erkennen, nicht als Text. Wenn deine Formeln unerwartete Ergebnisse liefern, überprüfe, ob deine Daten in Excel richtig als Datum formatiert sind.

• Für Datumsberechnungen in großen Datensätzen solltest du deine Formeln als benannte Bereiche speichern oder ein eigenes Berechnungsblatt erstellen. Das macht deine Arbeitsblätter pflegeleichter und einfacher zu aktualisieren.

• Teste deine Altersberechnungen mit bekannten Beispielen, um die Genauigkeit zu überprüfen. Versuche, das Alter von Menschen zu berechnen, die an Schalttagen (29. Februar) oder nahe an Monatsgrenzen geboren sind, um sicherzustellen, dass deine Formeln auch Grenzfälle korrekt behandeln.

Fazit

Die Berechnung des Alters in Excel ist ganz einfach, wenn du die richtige Methode für deine Bedürfnisse auswählst. Für einfache Anwendungen bietet die Funktion DATEDIF() eine saubere, genaue Lösung. Für detailliertere Analysen können kombinierte Formeln genaue Aufschlüsselungen in Jahren, Monaten und Tagen liefern.

Bei großen Datensätzen kannst du diese Berechnungen automatisieren, indem du Formeln in Vorlagen einbettest oder die fortgeschrittenen Tools von Excel wie Power Query verwendest. Diese Automatisierung ist besonders hilfreich für Personaldatenbanken oder demografische Studien, bei denen für Tausende von Datensätzen Altersberechnungen erforderlich sein können.

Wenn du dir umfassendere Excel-Kenntnisse aneignen möchtest, die über das Rechnen im Alter hinausgehen, bietet dir unser Lernpfad Excel-Grundlagen einen strukturierten Lernpfad, der dich von grundlegenden Funktionen zu fortgeschrittenen Datenanalysetechniken führt. Wenn du die richtige Formel für deine spezifischen Anforderungen auswählst, kannst du sicherstellen, dass deine Altersberechnungen präzise und zuverlässig bleiben, egal ob du grundlegende Alterswerte, detaillierte Aufschlüsselungen oder spezielle Analysen für bestimmte Daten und Schwellenwerte benötigst.