Fórmula de idade no Excel: Métodos fáceis para o cálculo da idade

O cálculo da idade no Excel é uma tarefa comum para profissionais de RH que gerenciam registros de funcionários, pesquisadores que analisam dados de pesquisas ou qualquer pessoa que mantenha conjuntos de dados pessoais. Embora o Excel não inclua uma função "IDADE" dedicada, várias fórmulas simples podem ajudar você a determinar a idade de alguém com precisão. Este guia o guiará por vários métodos para calcular a idade no Excel, desde abordagens simples até fórmulas mais detalhadas que podem fornecer anos, meses e dias exatos.

Para você que está começando a usar o Excel, nosso curso de Introdução ao Excel abrange habilidades essenciais, como navegar pela interface, entender os formatos de dados e trabalhar com funções básicas. Se você deseja expandir seus recursos analíticos para além dos cálculos de idade, nosso curso Análise de dados no Excel ensina como trabalhar com tabelas dinâmicas e funções lógicas avançadas para obter insights mais profundos. 

Fórmula básica de idade no Excel

A maneira mais simples de calcular a idade no Excel envolve subtrair a data de nascimento da data de hoje e dividir por 365. Por exemplo, se a célula A2 contiver uma data de nascimento, você poderá usar:

=(TODAY()-A2)/365

Essa fórmula fornece a você a idade em anos com um componente decimal representando anos parciais. Embora essa abordagem seja fácil de implementar, ela nem sempre é precisa. A divisão por 365 não leva em conta os anos bissextos, o que pode levar a pequenos erros que se acumulam com o tempo. Além disso, esse método não lida adequadamente com a variação da duração dos meses.

Por exemplo, se você usar essa fórmula para alguém nascido em 15 de janeiro de 1990, poderá ver 35,3 anos em vez de exatamente 35 anos e 3 meses. Essa discrepância se torna mais perceptível à medida que o período de tempo aumenta, tornando-o menos ideal para o rastreamento preciso da idade ou para a documentação legal.

Métodos precisos de cálculo de idade

Usando INT() e YEARFRAC() para maior precisão

A função YEARFRAC() pode oferecer maior precisão ao calcular idades, mas sua exatidão depende de como você a utiliza. Embora o site YEARFRAC() possa levar em conta os anos bissextos e a variação da duração dos meses, isso depende do parâmetro opcional basis: 

=INT(YEARFRAC(A2,TODAY(),1))

Cada componente tem uma finalidade específica:

• YEARFRAC(start_date, end_date, basis) calcula a fração de anos entre duas datas

• O parâmetro de base (1) diz ao Excel para usar dias reais nos cálculos

• TODAY() fornece a data atual

• INT() remove a parte decimal, fornecendo apenas os anos completos

Sem especificar o parâmetro base, o padrão do site YEARFRAC() é base=0 (EUA). 30/360), que trata cada mês como tendo 30 dias e não leva em conta a duração real dos meses nem os anos bissextos. Se você definir basis=1, o Excel usará o método real/real, em que os dias reais em cada mês e ano são usados no cálculo.

Esse método é o preferido para a maioria dos cenários devido ao seu equilíbrio entre simplicidade e precisão. Por exemplo, se alguém nasceu em 15 de março de 1995, essa fórmula mostraria corretamente sua idade em anos completos.

Usando DATEDIF() para obter a idade exata

A função DATEDIF() (Date Difference) foi projetada especificamente para calcular intervalos de tempo entre datas. Para calcular a idade em anos completos, use:

=DATEDIF(A2,TODAY(),"Y")

O parâmetro "Y" instrui o Excel a contar apenas os anos concluídos. Essa função fornece o número de anos completos com precisão e funciona bem quando você precisa de um resultado inteiro limpo. A vantagem do site DATEDIF() é sua precisão - ele só conta um ano depois de totalmente concluído, o que o torna perfeito para cálculos oficiais de idade.

Uso de várias funções DATEDIF()

Esse método pode ajudar você a calcular a idade exata em anos, meses e dias, combinando três funções DATEDIF():

Durante anos:

=DATEDIF(A2,TODAY(),"Y")

Por meses após o último ano concluído:

=DATEDIF(A2,TODAY(),"YM")

Para dias após o último mês concluído:

=DATEDIF(A2,TODAY(),"MD")

Para exibi-los juntos em uma única célula:

=DATEDIF(A2,TODAY(),"Y")&" years, "&DATEDIF(A2,TODAY(),"YM")&" months, "&DATEDIF(A2,TODAY(),"MD")&" days"

Esse método cria um detalhamento claro e detalhado da idade. Para uma exibição mais limpa, você pode adicionar instruções IF para ocultar valores zero:

=IF(DATEDIF(A2,TODAY(),"Y")=0,"",DATEDIF(A2,TODAY(),"Y")&" years, ")&IF(DATEDIF(A2,TODAY(),"YM")=0,"",DATEDIF(A2,TODAY(),"YM")&" months, ")&IF(DATEDIF(A2,TODAY(),"MD")=0,"",DATEDIF(A2,TODAY(),"MD")&" days")

Essa fórmula mostra "35 anos, 3 meses, 18 dias" em vez de "35 anos, 0 meses, 0 dias" quando apropriado.

Casos de uso especiais para cálculo de idade

Cálculo da idade em uma data específica

Às vezes, você precisa calcular a idade em uma data diferente de hoje, como uma data de contratação futura ou um ponto histórico no tempo. Para modificar as fórmulas para uma data de referência específica, basta substituir TODAY() pela data de destino:

=DATEDIF(A2,DATE(2024,12,31),"Y")

Essa fórmula calcula a idade que uma pessoa terá em 31 de dezembro de 2024. Da mesma forma, para obter um detalhamento completo da idade em uma data específica:

=DATEDIF(A2,DATE(2024,12,31),"Y")&" years, "&DATEDIF(A2,DATE(2024,12,31),"YM")&" months, "&DATEDIF(A2,DATE(2024,12,31),"MD")&" days"

Essa abordagem é útil para planejamento de RH, cálculos de seguro ou análise de pontos de dados históricos.

Cálculo da idade em um determinado ano

Quando apenas um ano é fornecido e você precisa calcular a idade de alguém naquele ano, é possível usar a função DATE() para definir os valores de mês e dia:

=DATEDIF(A2,DATE(2030,12,31),"Y")

Ou para cálculos no meio do ano:

=DATEDIF(A2,DATE(2030,6,30),"Y")

Isso ajuda nos cenários de planejamento de longo prazo em que não são necessárias datas exatas, apenas a idade em um determinado ano.

Encontrar a data em que uma pessoa atinge uma determinada idade

Para encontrar a data em que alguém completa uma idade específica (como elegibilidade para aposentadoria), use:

=DATE(YEAR(A2)+65,MONTH(A2),DAY(A2))

Essa fórmula adiciona 65 anos à sua data de nascimento para saber quando você completará 65 anos. O resultado é um valor de data do Excel que mostra exatamente quando eles atingirão esse marco.

Para cenários mais complexos em que você precisa descobrir quando alguém atinge uma determinada idade mais meses:

=DATE(YEAR(A2)+30,MONTH(A2)+6,DAY(A2))

Essa fórmula determina quando alguém terá 30 anos e 6 meses de idade, o que pode ser útil para requisitos de elegibilidade com especificações de ano e mês.

Destaque de idades com base em limites de idade

A formatação condicional oferece uma maneira visual de identificar as idades que se enquadram em categorias específicas. Embora essas fórmulas retornassem TRUE ou FALSE se inseridas diretamente nas células, quando usadas na formatação condicional, elas aplicam automaticamente os estilos de formatação escolhidos por você.

Destaque para menores de 18 anos

Para configurar a formatação condicional que destaca as células que contêm indivíduos com menos de 18 anos de idade:

1. Selecione seu intervalo de dados
2. Ir para Home → Formatação condicional → Nova regra
3. Escolha o estilo clássico
4. Selecione Usar uma fórmula para determinar quais células você deve formatar
5. Insira esta fórmula:

=DATEDIF(A2, TODAY(), "Y")<18

6.   Clique em Format e selecione o estilo de destaque que você deseja (cor, fonte etc.)

Quando essa regra é aplicada, o Excel avalia a fórmula para cada célula. Se o resultado for TRUE (a pessoa é menor de 18 anos), o Excel aplicará automaticamente a formatação que você escolheu.

Destaque entre 18 e 65 anos

Para identificar pessoas em idade ativa:

1. Siga as mesmas etapas acima
2. Use essa fórmula na regra de formatação condicional:

=AND(DATEDIF(A2, TODAY(), "Y")>=18, DATEDIF(A2, TODAY(), "Y")<=65)

3. Escolha um estilo de formatação diferente para esse grupo

Destaque para maiores de 65 anos

Identificar idosos que possam se qualificar para benefícios de aposentadoria:

1. Criar outra regra de formatação condicional
2. Use esta fórmula:

=DATEDIF(A2, TODAY(), "Y")>65

3. Aplicar um terceiro estilo de formatação distinto

A vantagem de usar a formatação condicional é que ela funciona nos bastidores - os valores reais das células permanecem inalterados enquanto o Excel aplica dicas visuais com base nas regras que você definiu.

Pontos-chave a serem lembrados

Ao calcular idades no Excel, você deve ter em mente estas dicas importantes:

• Use DATEDIF() ou YEARFRAC() para obter a precisão ideal. DATEDIF() foi criado especificamente para diferenças de data, enquanto YEARFRAC() com basis=1 considera os dias reais do calendário.

• Use as funções INT() ou ROUNDDOWN() para evitar valores decimais quando você precisar de números inteiros. Isso garante que você obtenha anos completos em vez de anos parciais com pontos decimais.

• Fique atento aos anos bissextos e às diferentes durações dos meses. A fórmula básica (dividindo por 365) não leva em conta essas variações, o que leva a pequenas imprecisões ao longo do tempo.

• Verifique se os formatos de data estão corretos. O Excel precisa reconhecer suas datas como valores de data verdadeiros, não como texto. Se suas fórmulas retornarem resultados inesperados, verifique se as datas estão formatadas corretamente como datas no Excel.

• Para cálculos de datas em grandes conjuntos de dados, considere armazenar suas fórmulas como intervalos nomeados ou criar uma planilha de cálculo dedicada. Isso torna suas planilhas mais fáceis de manter e atualizar.

• Teste seus cálculos de idade com exemplos conhecidos para verificar a precisão. Tente calcular as idades das pessoas nascidas em dias bissextos (29 de fevereiro) ou perto dos limites do mês para garantir que suas fórmulas tratem corretamente os casos extremos.

Conclusão

O cálculo da idade no Excel é simples quando você seleciona o método certo para suas necessidades. Para aplicações básicas, a função DATEDIF() oferece uma solução limpa e precisa. Para análises mais detalhadas, as fórmulas combinadas podem fornecer divisões exatas em anos, meses e dias.

Para grandes conjuntos de dados, você pode automatizar esses cálculos incorporando fórmulas em modelos ou utilizando as ferramentas mais avançadas do Excel, como o Power Query. Essa automação é especialmente útil para bancos de dados de RH ou estudos demográficos em que milhares de registros podem precisar de cálculos de idade.

Se você deseja desenvolver um conjunto mais abrangente de habilidades em Excel que vá além dos cálculos de idade, nossa trilha de habilidades em Fundamentos do Excel oferece um caminho de aprendizagem estruturado que o leva das funções básicas às técnicas avançadas de análise de dados. Ao escolher a fórmula certa com base em seus requisitos específicos, você pode garantir que seus cálculos de idade permaneçam precisos e confiáveis, quer você precise de valores básicos de idade, análises detalhadas ou análises especializadas para datas e limites específicos.