Lewati ke konten utama

Rumus Usia di Excel: Metode Mudah untuk Menghitung Usia

Pelajari cara menghitung usia di Excel menggunakan rumus yang sederhana dan akurat. Temukan metode dengan fungsi DATEDIF(), YEARFRAC(), dan INT() untuk menangani ulang tahun, tanggal tertentu, dan kasus khusus.
· 7 mnt Baca

Jelajahi bersama AI

Menghitung usia di Excel adalah tugas umum bagi profesional HR yang mengelola data karyawan, peneliti yang menganalisis data survei, atau siapa pun yang memelihara set data pribadi. Meskipun Excel tidak memiliki fungsi khusus "AGE", beberapa rumus sederhana dapat membantu Anda menentukan usia seseorang secara presisi. Panduan ini akan memandu Anda melalui berbagai metode untuk menghitung usia di Excel, mulai dari pendekatan sederhana hingga rumus yang lebih detail yang dapat memberikan hasil dalam tahun, bulan, dan hari secara tepat.

Bagi Anda yang baru menggunakan Excel, kursus Introduction to Excel kami membahas keterampilan penting seperti menavigasi antarmuka, memahami format data, dan bekerja dengan fungsi dasar. Jika Anda ingin memperluas kemampuan analitis melampaui perhitungan usia, kursus Data Analysis in Excel kami mengajarkan cara bekerja dengan PivotTable dan fungsi logika lanjutan untuk mendapatkan wawasan yang lebih mendalam. 

Rumus Usia Dasar di Excel

Cara termudah untuk menghitung usia di Excel adalah dengan mengurangkan tanggal lahir dari tanggal hari ini dan membaginya dengan 365. Misalnya, jika sel A2 berisi tanggal lahir, Anda dapat menggunakan:

=(TODAY()-A2)/365

Rumus ini memberi Anda usia dalam tahun dengan komponen desimal yang merepresentasikan tahun sebagian. Meskipun pendekatan ini mudah diterapkan, hasilnya tidak selalu akurat. Pembagian dengan 365 tidak memperhitungkan tahun kabisat, yang dapat menimbulkan kesalahan kecil yang terakumulasi seiring waktu. Selain itu, metode ini tidak menangani variasi panjang bulan dengan benar.

Sebagai contoh, menggunakan rumus ini untuk seseorang yang lahir pada 15 Januari 1990 mungkin menunjukkan 35,3 tahun alih-alih tepat 35 tahun 3 bulan. Ketidaksesuaian ini semakin terlihat seiring bertambahnya rentang waktu, sehingga kurang ideal untuk pelacakan usia yang presisi atau dokumentasi legal.

Metode Perhitungan Usia yang Akurat

Menggunakan INT() dan YEARFRAC() untuk akurasi lebih baik

Fungsi YEARFRAC() dapat memberikan presisi yang lebih baik saat menghitung usia, tetapi akurasinya bergantung pada cara Anda menggunakannya. Meskipun YEARFRAC() dapat memperhitungkan tahun kabisat dan variasi panjang bulan, hal ini bergantung pada parameter opsional basis: 

=INT(YEARFRAC(A2,TODAY(),1))

Setiap komponen memiliki tujuan spesifik:

  • YEARFRAC(start_date, end_date, basis) menghitung fraksi tahun antara dua tanggal

  • Parameter basis (1) memberi tahu Excel untuk menggunakan jumlah hari aktual dalam perhitungan

  • TODAY() memberikan tanggal saat ini

  • INT() menghapus bagian desimal, memberikan hanya tahun yang telah lengkap

Tanpa menentukan parameter basis, YEARFRAC() secara default menggunakan basis=0 (U.S. 30/360), yang memperlakukan setiap bulan memiliki 30 hari dan tidak memperhitungkan panjang bulan yang sebenarnya atau tahun kabisat. Mengatur basis=1 memberi tahu Excel untuk menggunakan metode actual/actual, di mana jumlah hari aktual pada setiap bulan dan tahun digunakan dalam perhitungan.

Metode ini lebih disukai untuk sebagian besar skenario karena seimbang antara kesederhanaan dan akurasi. Misalnya, jika seseorang lahir pada 15 Maret 1995, rumus ini akan menampilkan usia dalam tahun yang telah lengkap secara benar.

Menggunakan DATEDIF() untuk usia yang tepat

Fungsi DATEDIF() (Date Difference) dirancang khusus untuk menghitung interval waktu antar tanggal. Untuk menghitung usia dalam tahun yang telah lengkap, gunakan:

=DATEDIF(A2,TODAY(),"Y")

Parameter "Y" menginstruksikan Excel untuk menghitung hanya tahun yang telah lengkap. Fungsi ini memberikan jumlah tahun penuh secara presisi dan sangat cocok ketika Anda memerlukan hasil bilangan bulat yang bersih. Keunggulan DATEDIF() adalah presisinya—fungsi ini hanya menghitung satu tahun setelah benar-benar lengkap, sehingga ideal untuk perhitungan usia resmi.

Menggunakan beberapa fungsi DATEDIF()

Metode ini membantu Anda menghitung usia tepat dalam tahun, bulan, dan hari dengan menggabungkan tiga fungsi DATEDIF():

Untuk tahun:

=DATEDIF(A2,TODAY(),"Y")

Untuk bulan setelah tahun terakhir yang lengkap:

=DATEDIF(A2,TODAY(),"YM")

Untuk hari setelah bulan terakhir yang lengkap:

=DATEDIF(A2,TODAY(),"MD")

Untuk menampilkannya bersama dalam satu sel:

=DATEDIF(A2,TODAY(),"Y")&" years, "&DATEDIF(A2,TODAY(),"YM")&" months, "&DATEDIF(A2,TODAY(),"MD")&" days"

Metode ini menghasilkan rincian usia yang jelas dan detail. Untuk tampilan yang lebih rapi, Anda dapat menambahkan pernyataan IF untuk menyembunyikan nilai nol:

=IF(DATEDIF(A2,TODAY(),"Y")=0,"",DATEDIF(A2,TODAY(),"Y")&" years, ")&IF(DATEDIF(A2,TODAY(),"YM")=0,"",DATEDIF(A2,TODAY(),"YM")&" months, ")&IF(DATEDIF(A2,TODAY(),"MD")=0,"",DATEDIF(A2,TODAY(),"MD")&" days")

Rumus ini menampilkan "35 years, 3 months, 18 days" alih-alih "35 years, 0 months, 0 days" saat sesuai.

Kasus Penggunaan Khusus untuk Perhitungan Usia

Menghitung usia pada tanggal tertentu

Terkadang Anda perlu menghitung usia pada tanggal selain hari ini, seperti tanggal perekrutan di masa depan atau titik waktu historis. Untuk memodifikasi rumus bagi tanggal acuan tertentu, cukup ganti TODAY() dengan tanggal target Anda:

=DATEDIF(A2,DATE(2024,12,31),"Y")

Rumus ini menghitung usia seseorang pada 31 Desember 2024. Demikian pula, untuk rincian usia lengkap pada tanggal tertentu:

=DATEDIF(A2,DATE(2024,12,31),"Y")&" years, "&DATEDIF(A2,DATE(2024,12,31),"YM")&" months, "&DATEDIF(A2,DATE(2024,12,31),"MD")&" days"

Pendekatan ini bermanfaat untuk perencanaan HR, perhitungan asuransi, atau menganalisis titik data historis.

Menghitung usia pada tahun tertentu

Saat hanya tahun yang diberikan dan Anda perlu menghitung usia seseorang pada tahun tersebut, Anda dapat menggunakan fungsi DATE() untuk menetapkan nilai bulan dan hari:

=DATEDIF(A2,DATE(2030,12,31),"Y")

Atau untuk perhitungan pertengahan tahun:

=DATEDIF(A2,DATE(2030,6,30),"Y")

Ini membantu pada skenario perencanaan jangka panjang di mana tanggal pasti tidak diperlukan, cukup usia pada tahun tertentu.

Menemukan tanggal ketika seseorang mencapai usia tertentu

Untuk menemukan tanggal ketika seseorang mencapai usia tertentu (seperti kelayakan pensiun), gunakan:

=DATE(YEAR(A2)+65,MONTH(A2),DAY(A2))

Rumus ini menambahkan 65 tahun ke tanggal lahir untuk mengetahui kapan mereka berusia 65 tahun. Hasilnya adalah nilai tanggal Excel yang menunjukkan kapan tepatnya mereka mencapai tonggak tersebut.

Untuk skenario yang lebih kompleks saat Anda perlu menemukan kapan seseorang mencapai usia tertentu ditambah bulan:

=DATE(YEAR(A2)+30,MONTH(A2)+6,DAY(A2))

Rumus ini menemukan kapan seseorang berusia 30 tahun 6 bulan, yang dapat berguna untuk persyaratan kelayakan dengan ketentuan tahun dan bulan.

Menyorot Usia Berdasarkan Ambang Usia

Conditional formatting memberikan cara visual untuk mengidentifikasi usia yang masuk ke kategori tertentu. Meskipun rumus ini akan mengembalikan TRUE atau FALSE jika dimasukkan langsung di sel, saat digunakan dalam conditional formatting, rumus akan otomatis menerapkan gaya pemformatan yang Anda pilih.

Menyorot di bawah 18

Untuk menyiapkan conditional formatting yang menyorot sel yang berisi individu berusia di bawah 18 tahun:

  1. Pilih rentang data Anda
  2. Buka Home → Conditional Formatting → New Rule
  3. Pilih Classic di bawah Style
  4. Pilih Use a formula to determine which cells to format
  5. Masukkan rumus berikut:
=DATEDIF(A2, TODAY(), "Y")<18

6.   Klik Format dan pilih gaya sorotan yang diinginkan (warna, font, dll.)

Saat aturan ini diterapkan, Excel mengevaluasi rumus untuk setiap sel. Jika hasilnya TRUE (orang tersebut di bawah 18), Excel akan menerapkan pemformatan yang Anda pilih secara otomatis.

Menyorot antara 18 dan 65

Untuk mengidentifikasi individu usia kerja:

  1. Ikuti langkah yang sama seperti di atas
  2. Gunakan rumus ini dalam aturan conditional formatting:
=AND(DATEDIF(A2, TODAY(), "Y")>=18, DATEDIF(A2, TODAY(), "Y")<=65)
  1. Pilih gaya pemformatan lain untuk kelompok ini

Menyorot di atas 65

Untuk mengidentifikasi lansia yang mungkin memenuhi syarat manfaat pensiun:

  1. Buat aturan conditional formatting lainnya
  2. Gunakan rumus ini:
=DATEDIF(A2, TODAY(), "Y")>65
  1. Terapkan gaya pemformatan ketiga yang berbeda

Keuntungan menggunakan conditional formatting adalah bekerja di latar belakang—nilai sel Anda yang sebenarnya tetap tidak berubah sementara Excel menerapkan penanda visual berdasarkan aturan Anda.

Poin-Poin Kunci yang Perlu Diingat

Saat menghitung usia di Excel, ingat tips penting berikut:

  • Gunakan DATEDIF() atau YEARFRAC() untuk akurasi optimal. DATEDIF() dibuat khusus untuk selisih tanggal, sedangkan YEARFRAC() dengan basis=1 memperhitungkan hari kalender aktual.

  • Gunakan fungsi INT() atau ROUNDDOWN() untuk menghindari nilai desimal saat Anda memerlukan bilangan bulat. Ini memastikan Anda mendapatkan tahun yang telah lengkap, bukan tahun parsial dengan desimal.

  • Waspadai tahun kabisat dan perbedaan panjang bulan. Rumus dasar (membagi dengan 365) tidak memperhitungkan variasi ini, sehingga menimbulkan ketidakakuratan kecil dari waktu ke waktu.

  • Pastikan format tanggal sudah benar. Excel perlu mengenali tanggal Anda sebagai nilai tanggal sebenarnya, bukan teks. Jika rumus Anda mengembalikan hasil yang tidak terduga, periksa apakah tanggal Anda diformat dengan benar sebagai tanggal di Excel.

  • Untuk perhitungan tanggal pada set data besar, pertimbangkan menyimpan rumus sebagai named range atau membuat lembar perhitungan khusus. Ini membuat lembar kerja Anda lebih mudah dirawat dan diperbarui.

  • Uji perhitungan usia Anda dengan contoh yang diketahui untuk memverifikasi akurasi. Cobalah menghitung usia untuk orang yang lahir pada hari kabisat (29 Februari) atau dekat batas bulan untuk memastikan rumus Anda menangani kasus tepi dengan benar.

Kesimpulan

Menghitung usia di Excel menjadi mudah setelah Anda memilih metode yang tepat sesuai kebutuhan. Untuk aplikasi dasar, fungsi DATEDIF() menawarkan solusi yang bersih dan akurat. Untuk analisis yang lebih detail, gabungan rumus dapat memberikan rincian tepat dalam tahun, bulan, dan hari.

Untuk set data besar, Anda dapat mengotomatiskan perhitungan ini dengan menanamkan rumus ke dalam templat atau memanfaatkan alat Excel yang lebih canggih seperti Power Query. Otomatisasi ini sangat membantu untuk basis data HR atau studi demografis di mana ribuan catatan mungkin memerlukan perhitungan usia.

Jika Anda ingin mengembangkan keterampilan Excel yang lebih komprehensif melampaui perhitungan usia, jalur keterampilan Excel Fundamentals kami menyediakan jalur pembelajaran terstruktur dari fungsi dasar hingga teknik analisis data tingkat lanjut. Dengan memilih rumus yang tepat berdasarkan kebutuhan spesifik Anda, Anda dapat memastikan perhitungan usia tetap presisi dan andal, baik untuk nilai usia dasar, rincian terperinci, maupun analisis khusus untuk tanggal dan ambang tertentu.

Vinod Chugani

Penulis

Vinod Chugani

LinkedIn

Vinod Chugani memulai kariernya di Tokyo sebagai Kepala Meja Penjualan Hedge Fund termuda di JPMorgan dan kemudian mencetak rekor penjualan individu di Lehman Brothers, lalu membangun bisnis distribusi elektronik di 30 negara dengan pendapatan melampaui SG$100 juta sebelum beralih ke data. Lulusan Ekonomi Duke dan alumni NYC Data Science Academy, ia menjadi salah satu dari tiga penerima beasiswa dari lebih dari 100 pelamar untuk kursus Building AI Applications oleh Hugo Bowne-Anderson di Maven. Saat ini, ia menulis untuk DataCamp, KDnuggets, Machine Learning Mastery, dan Statology tentang topik mulai dari statistika hingga AI agensial, dan membimbing para profesional data di NYC Data Science Academy dengan lebih dari 1.000 sesi tatap muka atas namanya.

 

FAQs

Mengapa Excel tidak memiliki fungsi khusus untuk menghitung usia?

Excel mengandalkan fungsi perhitungan tanggalnya yang serbaguna seperti DATEDIF(), YEARFRAC(), dan DATE() alih-alih membuat fungsi khusus. Fungsi yang ada ini memberikan fleksibilitas untuk menangani berbagai skenario perhitungan usia.

Perhitungan usia saya tampil sebagai teks atau nilainya salah. Apa yang terjadi?

Periksa apakah tanggal Anda diformat sebagai tanggal Excel sebenarnya, bukan teks. Pilih sel, klik kanan, pilih Format Cells, dan atur ke format tanggal yang sesuai.

Apakah rumus perhitungan usia di Excel menangani ulang tahun 29 Februari dengan benar?

Ya, baik DATEDIF() maupun YEARFRAC() menangani tahun kabisat dan ulang tahun 29 Februari dengan benar. Pada tahun non-kabisat, Excel memperlakukan ulang tahun 29 Februari sebagai 1 Maret untuk perhitungan usia yang akurat.

Bisakah saya membuat perhitungan usia dinamis yang diperbarui secara otomatis?

Ya, rumus yang menggunakan TODAY() akan otomatis dihitung ulang setiap kali Anda membuka spreadsheet. Untuk solusi yang benar-benar dinamis yang memperbarui bahkan di antara waktu pembukaan, pertimbangkan menggunakan Data Model Excel dengan Power Query, yang menyegarkan data sesuai jadwal.

Bagaimana perhitungan usia Excel menangani format tanggal internasional yang berbeda?

Excel secara otomatis menggunakan setelan format tanggal sistem Anda untuk tampilan, tetapi secara internal menyimpan tanggal sebagai nomor seri. Saat memasukkan tanggal secara langsung, gunakan format sistem Anda (MM/DD/YYYY di AS atau DD/MM/YYYY di banyak negara lain), tetapi saat menggunakan fungsi DATE(), selalu gunakan urutan: DATE(year, month, day).

Topik

Excel

Terkait

blogs

Tutorial Korelasi di R

blogs

40 Pertanyaan Wawancara DBMS Teratas di 2026

blogs

Spaghetti Plot dan Jalur Badai

Lihat Selengkapnya →