Leeftijdsformule in Excel: Eenvoudige methoden voor leeftijdsberekening

Leeftijd berekenen in Excel is een veelvoorkomende taak voor HR-professionals die personeelsdossiers beheren, onderzoekers die enquêtedata analyseren, of iedereen die persoonlijke datasets bijhoudt. Hoewel Excel geen aparte "AGE"-functie heeft, kun je met een paar eenvoudige formules iemands leeftijd nauwkeurig bepalen. Deze gids laat je verschillende methoden zien om leeftijd in Excel te berekenen, van simpele aanpakken tot meer gedetailleerde formules die exacte jaren, maanden en dagen kunnen geven.

Voor wie nieuw is met Excel behandelt onze cursus Introduction to Excel basisvaardigheden zoals navigeren door de interface, gegevensindelingen begrijpen en werken met basisfuncties. Wil je je analytische vaardigheden verder uitbouwen dan alleen leeftijdsberekeningen, dan leer je in onze cursus Data Analysis in Excel werken met draaitabellen en geavanceerde logische functies voor diepere inzichten. 

Basisformule voor leeftijd in Excel

De eenvoudigste manier om leeftijd in Excel te berekenen is door de geboortedatum van de datum van vandaag af te trekken en te delen door 365. Als in cel A2 bijvoorbeeld een geboortedatum staat, kun je gebruiken:

=(TODAY()-A2)/365

Deze formule geeft de leeftijd in jaren met een decimaal deel dat een gedeelte van een jaar weergeeft. Hoewel deze aanpak makkelijk is toe te passen, is hij niet altijd nauwkeurig. Delen door 365 houdt geen rekening met schrikkeljaren, wat kan leiden tot kleine fouten die zich in de loop der tijd opstapelen. Daarnaast houdt deze methode geen rekening met variabele maandlengtes.

Zo kan deze formule voor iemand die op 15 januari 1990 is geboren bijvoorbeeld 35,3 jaar tonen in plaats van precies 35 jaar en 3 maanden. Dit verschil wordt zichtbaarder naarmate de periode toeneemt, waardoor het minder geschikt is voor precieze leeftijdsregistratie of juridische documentatie.

Nauwkeurige methoden voor leeftijdsberekening

INT() en YEARFRAC() gebruiken voor betere nauwkeurigheid

De functie YEARFRAC() kan meer precisie bieden bij het berekenen van leeftijden, maar de nauwkeurigheid hangt af van hoe je deze gebruikt. Hoewel YEARFRAC() rekening kan houden met schrikkeljaren en variabele maandlengtes, is dit afhankelijk van de optionele parameter basis: 

=INT(YEARFRAC(A2,TODAY(),1))

Elk onderdeel heeft een specifiek doel:

• YEARFRAC(start_date, end_date, basis) berekent de fractie jaren tussen twee datums

• De basis-parameter (1) vertelt Excel dat het werkelijke dagen moet gebruiken in berekeningen

• TODAY() geeft de huidige datum

• INT() verwijdert het decimale gedeelte en geeft alleen volledige jaren

Zonder de basis-parameter te specificeren, gebruikt YEARFRAC() standaard basis=0 (U.S. 30/360), waarbij elke maand 30 dagen heeft en geen rekening wordt gehouden met werkelijke maandlengtes of schrikkeljaren. Door basis=1 in te stellen, gebruik je de actual/actual-methode, waarbij de werkelijke dagen in elke maand en elk jaar voor de berekening worden gebruikt.

Deze methode heeft in de meeste situaties de voorkeur vanwege de balans tussen eenvoud en nauwkeurigheid. Als iemand bijvoorbeeld op 15 maart 1995 is geboren, toont deze formule hun leeftijd in volledige jaren op de juiste manier.

DATEDIF() gebruiken voor exacte leeftijd

De functie DATEDIF() (Date Difference) is specifiek ontworpen om tijdsintervallen tussen datums te berekenen. Voor het berekenen van leeftijd in volledige jaren gebruik je:

=DATEDIF(A2,TODAY(),"Y")

De parameter "Y" instrueert Excel om alleen volledige jaren te tellen. Deze functie geeft je precies het aantal volledige jaren en werkt goed wanneer je een nette, gehele uitkomst nodig hebt. Het voordeel van DATEDIF() is de precisie: het telt een jaar pas mee als het volledig is voltooid, wat het perfect maakt voor officiële leeftijdsberekeningen.

Meerdere DATEDIF()-functies gebruiken

Met deze methode kun je de exacte leeftijd in jaren, maanden en dagen berekenen door drie DATEDIF()-functies te combineren:

Voor jaren:

=DATEDIF(A2,TODAY(),"Y")

Voor maanden na het laatste volledige jaar:

=DATEDIF(A2,TODAY(),"YM")

Voor dagen na de laatste volledige maand:

=DATEDIF(A2,TODAY(),"MD")

Om ze samen in één cel weer te geven:

=DATEDIF(A2,TODAY(),"Y")&" years, "&DATEDIF(A2,TODAY(),"YM")&" months, "&DATEDIF(A2,TODAY(),"MD")&" days"

Deze methode creëert een duidelijke, gedetailleerde uitsplitsing van de leeftijd. Voor een nettere weergave kun je IF-verklaringen toevoegen om nullen te verbergen:

=IF(DATEDIF(A2,TODAY(),"Y")=0,"",DATEDIF(A2,TODAY(),"Y")&" years, ")&IF(DATEDIF(A2,TODAY(),"YM")=0,"",DATEDIF(A2,TODAY(),"YM")&" months, ")&IF(DATEDIF(A2,TODAY(),"MD")=0,"",DATEDIF(A2,TODAY(),"MD")&" days")

Deze formule toont "35 years, 3 months, 18 days" in plaats van "35 years, 0 months, 0 days" wanneer dat van toepassing is.

Bijzondere gebruikssituaties voor leeftijdsberekening

Leeftijd berekenen op een specifieke datum

Soms moet je leeftijd berekenen op een andere datum dan vandaag, zoals een toekomstige indiensttredingsdatum of een historisch moment. Vervang om de formules aan te passen voor een specifieke referentiedatum simpelweg TODAY() door je doeldatum:

=DATEDIF(A2,DATE(2024,12,31),"Y")

Deze formule berekent hoe oud iemand is op 31 december 2024. Voor een volledige uitsplitsing op een specifieke datum kun je vergelijkbaar doen:

=DATEDIF(A2,DATE(2024,12,31),"Y")&" years, "&DATEDIF(A2,DATE(2024,12,31),"YM")&" months, "&DATEDIF(A2,DATE(2024,12,31),"MD")&" days"

Deze aanpak is handig voor HR-planning, verzekeringsberekeningen of het analyseren van historische datapunten.

Leeftijd in een bepaald jaar berekenen

Als alleen een jaar is gegeven en je iemands leeftijd in dat jaar moet berekenen, kun je de functie DATE() gebruiken om maand- en dagwaarden in te stellen:

=DATEDIF(A2,DATE(2030,12,31),"Y")

Of voor berekeningen halverwege het jaar:

=DATEDIF(A2,DATE(2030,6,30),"Y")

Dit helpt bij langetermijnplanning waarbij exacte datums niet nodig zijn, maar alleen de leeftijd in een specifiek jaar.

De datum vinden waarop iemand een bepaalde leeftijd bereikt

Om te vinden op welke datum iemand een specifieke leeftijd bereikt (zoals pensioengerechtigdheid), gebruik je:

=DATE(YEAR(A2)+65,MONTH(A2),DAY(A2))

Deze formule telt 65 jaar op bij de geboortedatum om te vinden wanneer iemand 65 wordt. Het resultaat is een Excel-datumwaarde die precies aangeeft wanneer die mijlpaal wordt bereikt.

Voor complexere scenario’s waarin je moet vinden wanneer iemand een bepaalde leeftijd plus maanden bereikt:

=DATE(YEAR(A2)+30,MONTH(A2)+6,DAY(A2))

Deze formule bepaalt wanneer iemand 30 jaar en 6 maanden oud is, wat handig kan zijn voor toelatingscriteria met zowel jaar- als maandspecificaties.

Leeftijden markeren op basis van drempelwaarden

Voorwaardelijke opmaak biedt een visuele manier om leeftijden te identificeren die in specifieke categorieën vallen. Hoewel deze formules TRUE of FALSE zouden retourneren als je ze direct in cellen invoert, passen ze in voorwaardelijke opmaak automatisch de door jou gekozen stijlen toe.

Jonger dan 18 markeren

Zo stel je voorwaardelijke opmaak in die cellen markeert van personen jonger dan 18 jaar:

1. Selecteer je gegevensbereik
2. Ga naar Start → Voorwaardelijke opmaak → Nieuwe regel
3. Kies Klassiek onder Stijl
4. Kies Een formule gebruiken om te bepalen welke cellen worden opgemaakt
5. Voer deze formule in:

=DATEDIF(A2, TODAY(), "Y")<18

6.   Klik op Opmaak en kies je gewenste markeerstijl (kleur, lettertype, enz.)

Wanneer deze regel is toegepast, evalueert Excel de formule voor elke cel. Als het resultaat TRUE is (de persoon is jonger dan 18), past Excel automatisch de door jou gekozen opmaak toe.

Tussen 18 en 65 markeren

Om mensen in de werkzame leeftijd te identificeren:

1. Volg dezelfde stappen als hierboven
2. Gebruik deze formule in de regel voor voorwaardelijke opmaak:

=AND(DATEDIF(A2, TODAY(), "Y")>=18, DATEDIF(A2, TODAY(), "Y")<=65)

3. Kies een andere opmaakstijl voor deze groep

Ouder dan 65 markeren

Om senioren te identificeren die mogelijk in aanmerking komen voor pensioenvoordelen:

1. Maak nog een regel voor voorwaardelijke opmaak
2. Gebruik deze formule:

=DATEDIF(A2, TODAY(), "Y")>65

3. Pas een derde, onderscheidende opmaakstijl toe

Het voordeel van voorwaardelijke opmaak is dat het achter de schermen werkt: je werkelijke celwaarden blijven ongewijzigd terwijl Excel op basis van je regels visuele aanwijzingen toepast.

Belangrijke punten om te onthouden

Houd bij het berekenen van leeftijden in Excel deze belangrijke tips in gedachten:

• Gebruik DATEDIF() of YEARFRAC() voor optimale nauwkeurigheid. DATEDIF() is speciaal gebouwd voor datumverschillen, terwijl YEARFRAC() met basis=1 rekening houdt met werkelijke kalenderdagen.

• Gebruik functies INT() of ROUNDDOWN() om decimale waarden te vermijden wanneer je hele getallen nodig hebt. Zo krijg je volledige jaren in plaats van gedeeltelijke jaren met decimalen.

• Let op schrikkeljaren en verschillende maandlengtes. De basisformule (delen door 365) houdt hier geen rekening mee, wat in de loop der tijd tot kleine onnauwkeurigheden leidt.

• Zorg dat datumindelingen kloppen. Excel moet je datums herkennen als echte datumwaarden, niet als tekst. Als je formules onverwachte resultaten geven, controleer dan of je datums correct zijn opgemaakt als datums in Excel.

• Overweeg voor datumcalculaties in grote datasets om je formules als benoemde bereiken op te slaan of een apart berekeningsblad te maken. Dit maakt je werkbladen beter beheersbaar en makkelijker te updaten.

• Test je leeftijdsberekeningen met bekende voorbeelden om de nauwkeurigheid te verifiëren. Probeer leeftijden te berekenen van mensen die op een schrikkeldag (29 februari) zijn geboren of dicht bij maandgrenzen om te controleren of je formules randgevallen goed afhandelen.

Conclusie

Leeftijd berekenen in Excel is eenvoudig zodra je de juiste methode voor jouw behoeften kiest. Voor basis-toepassingen biedt de functie DATEDIF() een nette, nauwkeurige oplossing. Voor meer gedetailleerde analyses kunnen gecombineerde formules exacte uitsplitsingen geven in jaren, maanden en dagen.

Voor grote datasets kun je deze berekeningen automatiseren door formules in sjablonen op te nemen of gebruik te maken van geavanceerdere tools van Excel zoals Power Query. Deze automatisering is vooral handig voor HR-databases of demografische studies waarin duizenden records leeftijdsberekeningen nodig hebben.

Wil je een breder pakket aan Excel-vaardigheden ontwikkelen dan alleen leeftijdsberekeningen, dan biedt onze vaardigheidstrack Excel Fundamentals een gestructureerd leerpad dat je meeneemt van basisfuncties naar geavanceerde data-analysetechnieken. Door de juiste formule te kiezen op basis van je specifieke eisen, zorg je ervoor dat je leeftijdsberekeningen precies en betrouwbaar blijven, of je nu basiswaarden nodig hebt, gedetailleerde uitsplitsingen of gespecialiseerde analyses voor specifieke datums en drempels.