Excel'de Yaş Formülü: Yaş Hesaplama için Kolay Yöntemler

Excel'de yaş hesaplamak; çalışan kayıtlarını yöneten İK uzmanları, anket verilerini analiz eden araştırmacılar veya kişisel veri setlerini tutan herkes için yaygın bir görevdir. Excel'de özel bir "AGE" (YAŞ) işlevi bulunmasa da, bir kişinin yaşını hassas bir şekilde belirlemenize yardımcı olacak birkaç basit formül vardır. Bu rehber, Excel'de yaşı hesaplamanın basit yaklaşımlardan tam yıl, ay ve gün verebilen daha ayrıntılı formüllere kadar çeşitli yöntemlerini adım adım gösterecektir.

Excel'e yeni başlayanlar için, Introduction to Excel kursumuz; arayüzde gezinme, veri biçimlerini anlama ve temel işlevlerle çalışma gibi temel becerileri kapsar. Yaş hesaplamanın ötesinde analitik yeteneklerinizi geliştirmek istiyorsanız, Data Analysis in Excel kursumuz PivotTable'larla ve daha derin içgörüler için gelişmiş mantıksal işlevlerle çalışmayı öğretir. 

Excel'de Temel Yaş Formülü

Excel'de yaşı hesaplamanın en basit yolu, doğum tarihini bugünün tarihinden çıkarmak ve 365'e bölmektir. Örneğin, A2 hücresi bir doğum tarihi içeriyorsa şu formülü kullanabilirsiniz:

=(TODAY()-A2)/365

Bu formül, ondalık bir bileşenle birlikte yaşı yıl cinsinden verir ve bu ondalık kısım tamamlanmamış yılları temsil eder. Bu yaklaşımın uygulanması kolay olsa da, her zaman doğru değildir. 365'e bölme artık yılları hesaba katmaz; bu da zamanla biriken küçük hatalara yol açabilir. Ayrıca bu yöntem, ay uzunluklarındaki farklılıkları da doğru şekilde işlemez.

Örneğin, 15 Ocak 1990 doğumlu biri için bu formül 35 yıl 3 ay yerine 35,3 yıl gösterebilir. Bu fark, zaman aralığı uzadıkça daha belirgin hale gelir ve kesin yaş takibi veya yasal belgeler için daha az uygun olur.

Doğru Yaş Hesaplama Yöntemleri

Daha iyi doğruluk için INT() ve YEARFRAC() kullanma

YEARFRAC() işlevi, yaş hesaplamalarında daha yüksek hassasiyet sağlayabilir; ancak doğruluğu, nasıl kullandığınıza bağlıdır. YEARFRAC() artık yılları ve değişken ay uzunluklarını hesaba katabilir; bu da isteğe bağlı basis parametresine bağlıdır: 

=INT(YEARFRAC(A2,TODAY(),1))

Her bir bileşen belirli bir amaç için hizmet eder:

• YEARFRAC(start_date, end_date, basis) iki tarih arasındaki yıl kesrini hesaplar

• Basis parametresi (1), Excel'e hesaplamalarda gerçek günleri kullanmasını söyler

• TODAY() bugünün tarihini sağlar

• INT() ondalık kısmı kaldırır ve yalnızca tamamlanmış yılları verir

Basis parametresi belirtilmediğinde, YEARFRAC() varsayılan olarak basis=0 (ABD 30/360) kullanır; bu da her ayı 30 gün kabul eder ve gerçek ay uzunluklarını veya artık yılları hesaba katmaz. Basis=1 olarak ayarlamak, Excel'e hesaplamada her ay ve yıldaki gerçek günleri kullanan actual/actual yöntemini kullanmasını söyler.

Bu yöntem, basitlik ve doğruluk arasındaki dengesi sayesinde çoğu senaryo için tercih edilir. Örneğin, 15 Mart 1995 doğumlu biri için bu formül tamamlanmış yıl sayısını doğru şekilde gösterecektir.

Tam yaş için DATEDIF() kullanma

DATEDIF() işlevi (Date Difference), tarihler arasındaki zaman aralıklarını hesaplamak için özel olarak tasarlanmıştır. Tamamlanmış yıllarda yaşı hesaplamak için şunu kullanın:

=DATEDIF(A2,TODAY(),"Y")

"Y" parametresi, Excel'e yalnızca tamamlanmış yılları saymasını söyler. Bu işlev size tam yıl sayısını hassas biçimde verir ve temiz bir tam sayı sonucu gerektiğinde iyi çalışır. DATEDIF()'in avantajı hassasiyetidir—bir yılı yalnızca tamamen tamamlandığında sayar; bu da resmi yaş hesaplamaları için idealdir.

Birden fazla DATEDIF() işlevi kullanma

Bu yöntem, üç DATEDIF() işlevini birleştirerek tam yıl, ay ve gün cinsinden yaşı hesaplamanıza yardımcı olur:

Yıllar için:

=DATEDIF(A2,TODAY(),"Y")

Son tamamlanmış yıldan sonraki aylar için:

=DATEDIF(A2,TODAY(),"YM")

Son tamamlanmış aydan sonraki günler için:

=DATEDIF(A2,TODAY(),"MD")

Bunları tek bir hücrede birlikte göstermek için:

=DATEDIF(A2,TODAY(),"Y")&" years, "&DATEDIF(A2,TODAY(),"YM")&" months, "&DATEDIF(A2,TODAY(),"MD")&" days"

Bu yöntem, net ve ayrıntılı bir yaş dökümü oluşturur. Daha temiz bir görünüm için, sıfır değerleri gizlemek üzere IF ifadeleri ekleyebilirsiniz:

=IF(DATEDIF(A2,TODAY(),"Y")=0,"",DATEDIF(A2,TODAY(),"Y")&" years, ")&IF(DATEDIF(A2,TODAY(),"YM")=0,"",DATEDIF(A2,TODAY(),"YM")&" months, ")&IF(DATEDIF(A2,TODAY(),"MD")=0,"",DATEDIF(A2,TODAY(),"MD")&" days")

Bu formül, uygun olduğunda "35 years, 3 months, 18 days" yerine "35 years, 0 months, 0 days" ifadesi yerine "35 years, 3 months, 18 days" gösterir.

Yaş Hesaplamada Özel Kullanım Durumları

Belirli bir tarihte yaşı hesaplama

Bazen bugünden farklı bir tarihte, örneğin gelecekteki bir işe alım tarihi veya geçmişte belirli bir zamanda yaşı hesaplamanız gerekir. Formülleri belirli bir referans tarihine uyarlamak için TODAY()'i hedef tarihinizle değiştirmeniz yeterlidir:

=DATEDIF(A2,DATE(2024,12,31),"Y")

Bu formül, bir kişinin 31 Aralık 2024 tarihinde kaç yaşında olacağını hesaplar. Benzer şekilde, belirli bir tarihte tam yaş dökümü için:

=DATEDIF(A2,DATE(2024,12,31),"Y")&" years, "&DATEDIF(A2,DATE(2024,12,31),"YM")&" months, "&DATEDIF(A2,DATE(2024,12,31),"MD")&" days"

Bu yaklaşım, İK planlaması, sigorta hesaplamaları veya tarihsel veri noktalarını analiz etmek için kullanışlıdır.

Belirli bir yıldaki yaşı hesaplama

Yalnızca bir yıl verildiğinde ve birinin o yıl içindeki yaşını hesaplamanız gerektiğinde, ay ve gün değerlerini ayarlamak için DATE() işlevini kullanabilirsiniz:

=DATEDIF(A2,DATE(2030,12,31),"Y")

Yıl ortası hesaplamaları için ise:

=DATEDIF(A2,DATE(2030,6,30),"Y")

Bu, kesin tarihlere ihtiyaç duyulmadığı; yalnızca belirli bir yıldaki yaşın gerektiği uzun vadeli planlama senaryolarında yardımcı olur.

Bir kişinin belirli bir yaşa ulaştığı tarihi bulma

Birinin belirli bir yaşa (ör. emeklilik uygunluğu) ulaştığı tarihi bulmak için şunu kullanın:

=DATE(YEAR(A2)+65,MONTH(A2),DAY(A2))

Bu formül, 65 yaşına ne zaman ulaşacaklarını bulmak için doğum tarihlerine 65 yıl ekler. Sonuç, bu dönüm noktasına tam olarak ne zaman ulaşacaklarını gösteren bir Excel tarih değeridir.

Aylar da içeren belirli bir yaşa ulaşıldığı zamanı bulmanız gereken daha karmaşık senaryolar için:

=DATE(YEAR(A2)+30,MONTH(A2)+6,DAY(A2))

Bu formül, birinin 30 yıl 6 aylık olacağı tarihi bulur; yıl ve ay şartları içeren uygunluk gereksinimleri için kullanışlı olabilir.

Yaş Eşiklerine Göre Yaşları Vurgulama

Koşullu biçimlendirme, belirli kategorilere giren yaşları görsel olarak belirlemenin bir yolunu sunar. Bu formüller hücrelere doğrudan girildiğinde TRUE veya FALSE döndürse de, koşullu biçimlendirmede kullanıldığında seçtiğiniz biçimlendirme stillerini otomatik olarak uygularlar.

18 yaş altını vurgulama

18 yaşın altındaki kişileri içeren hücreleri vurgulayan koşullu biçimlendirmeyi ayarlamak için:

1. Veri aralığınızı seçin
2. Home → Conditional Formatting → New Rule yolunu izleyin
3. Style altında Classic'i seçin
4. Use a formula to determine which cells to format seçeneğini tercih edin
5. Şu formülü girin:

=DATEDIF(A2, TODAY(), "Y")<18

6.   Format'a tıklayın ve istediğiniz vurgulama stilini seçin (renk, yazı tipi vb.)

Bu kural uygulandığında, Excel formülü her hücre için değerlendirir. Sonuç TRUE ise (kişi 18 yaşın altındaysa), Excel seçtiğiniz biçimlendirmeyi otomatik olarak uygular.

18 ile 65 arasını vurgulama

Çalışma çağındaki bireyleri belirlemek için:

1. Yukarıdaki adımların aynısını izleyin
2. Koşullu biçimlendirme kuralına bu formülü girin:

=AND(DATEDIF(A2, TODAY(), "Y")>=18, DATEDIF(A2, TODAY(), "Y")<=65)

3. Bu grup için farklı bir biçimlendirme stili seçin

65 yaş üstünü vurgulama

Emeklilik hakkı kazanabilecek kişileri belirlemek için:

1. Başka bir koşullu biçimlendirme kuralı oluşturun
2. Şu formülü kullanın:

=DATEDIF(A2, TODAY(), "Y")>65

3. Üçüncü bir ayrı biçimlendirme stili uygulayın

Koşullu biçimlendirmenin avantajı, arka planda çalışmasıdır - gerçek hücre değerleriniz değişmeden Excel, kurallarınıza göre görsel ipuçlarını uygular.

Unutulmaması Gereken Noktalar

Excel'de yaş hesaplarken şu önemli ipuçlarını aklınızda bulundurun:

• En iyi doğruluk için DATEDIF() veya YEARFRAC() kullanın. DATEDIF() özellikle tarih farkları için oluşturulmuştur; YEARFRAC() ise basis=1 ile gerçek takvim günlerini dikkate alır.

• Tam sayı gerektiğinde ondalık değerlerden kaçınmak için INT() veya ROUNDDOWN() işlevlerini kullanın. Bu, ondalık noktalı kısmi yıllar yerine tamamlanmış yıllar elde etmenizi sağlar.

• Artık yıllar ve farklı ay uzunluklarına dikkat edin. Temel formül (365'e bölme) bu değişkenleri hesaba katmaz ve zaman içinde küçük tutarsızlıklara yol açar.

• Tarih biçimlerinin doğru olduğundan emin olun. Excel'in, tarihlerinizin metin değil gerçek tarih değerleri olduğunu tanıması gerekir. Formülleriniz beklenmedik sonuçlar veriyorsa, tarihlerinizin Excel'de tarih olarak düzgün biçimlendirildiğini kontrol edin.

• Büyük veri setlerinde tarih hesaplamaları için formüllerinizi adlandırılmış aralıklar olarak saklamayı veya özel bir hesaplama sayfası oluşturmayı düşünün. Bu, çalışma sayfalarınızı daha bakımı kolay ve güncellenebilir hale getirir.

• Doğruluğu teyit etmek için yaş hesaplamalarınızı bilinen örneklerle test edin. Artık günlerde (29 Şubat) doğanlar veya ay sınırlarına yakın doğanlar için yaşları hesaplamayı deneyin; böylece formüllerinizin uç durumları doğru şekilde ele aldığından emin olursunuz.

Sonuç

İhtiyaçlarınıza uygun doğru yöntemi seçtiğinizde Excel'de yaş hesaplamak oldukça basittir. Temel uygulamalar için DATEDIF() işlevi temiz ve doğru bir çözüm sunar. Daha ayrıntılı analizler için, birleştirilmiş formüller yıllar, aylar ve günler cinsinden tam dökümler sağlayabilir.

Büyük veri setlerinde, bu hesaplamaları şablonlara formül gömerek veya Excel'in Power Query gibi daha gelişmiş araçlarını kullanarak otomatikleştirebilirsiniz. Bu otomasyon, binlerce kaydın yaş hesaplaması gerektirebileceği İK veritabanları veya demografik çalışmalar için özellikle faydalıdır.

Yaş hesaplamalarının ötesine geçen daha kapsamlı bir Excel beceri seti geliştirmek istiyorsanız, Excel Fundamentals beceri yolumuz; temel işlevlerden ileri düzey veri analizi tekniklerine uzanan yapılandırılmış bir öğrenme yolu sunar. Özel gereksinimlerinize göre doğru formülü seçerek, temel yaş değerleri, ayrıntılı dökümler veya belirli tarihler ve eşikler için özel analizlere ihtiyaç duyduğunuz her durumda yaş hesaplamalarınızın doğru ve güvenilir kalmasını sağlayabilirsiniz.