DAX SUMMARIZE(): una guida al raggruppamento e al riepilogo dei dati

DAX SUMMARIZE() e raggruppamento dei dati

Ecco come la funzione SUMMARIZE() crea tabelle riepilogative in base alle colonne e alle aggregazioni specificate:

SUMMARIZE (<table>, <groupBy_columnName>[, <groupBy_columnName>]…[, <name>, <expression>]…)

Nella sintassi sopra:

• table è la tabella di origine dei tuoi dati.

• groupBy_columnName è la o le colonne per cui vuoi raggruppare.

• name è il nome della nuova colonna calcolata.

• expression è il calcolo che vuoi eseguire.

Puoi usare SUMMARIZE() con qualsiasi tabella o colonna del tuo dataset, il che la rende molto versatile.

Raggruppamento di base

Vediamo un semplice esempio di raggruppamento di base con SUMMARIZE().

Per prima cosa, importa il dataset in Power BI. Per farlo, vai alla scheda Home > Get Data. Seleziona dal menu a discesa l’opzione corrispondente al file salvato e caricalo. In questo esempio ho un dataset con colonne per Year, Product e SalesAmount. Ora lo importerò in Power BI.

Una tabella chiamata sales. Immagine dell’autore.

Una volta importati i dati, vai alla scheda Modeling > New table. Quindi inserisci la seguente formula per raggruppare per la colonna Year e aggregare le Total Sales.

	SummaryTable =
	SUMMARIZE(
	    sales,
	    sales[Year],
	    "Total Sales", SUM(sales[SalesAmount])
	)

Barra delle formule. Immagine dell’autore.

In questa formula:

• SummarizedTable crea una nuova tabella.

• SUMMARIZE( avvia il raggruppamento e il riepilogo dei dati.

• SalesData, è la tabella di origine.

• SalesData[Year], raggruppa per la colonna Year.

• "Total Sales", SUM(SalesData[SalesAmount]) crea una nuova colonna chiamata Total Sales che somma SalesAmount per ogni anno.

Risultati riepilogati. Immagine dell’autore.

Qui la funzione SUMMARIZE() crea una tabella riepilogativa raggruppando i dati per Year e calcola le Total Sales sommando SalesAmount per ciascun anno.

Raggruppamenti multipli

SUMMARIZE() può anche gestire raggruppamenti più complessi. Capciamolo con un esempio. Qui ho un dataset con colonne per Year, Product, Region e SalesAmount.

Una tabella chiamata sales_data. Immagine dell’autore.

Qui sto raggruppando per Year e Region per calcolare le Total Sales per ogni combinazione.

	SummarizedTable =
	SUMMARIZE(
	    sales_data,
	    sales_data[Year],
	    sales_data[Region],
	    "Total Sales", SUM(sales_data[SalesAmount])
	)

In questa formula: 

• sales_data è la tabella in cui sono archiviati i dati.

• sales_data[Year] è la prima colonna su cui eseguire il raggruppamento per Year.

• sales_data[Region] è la seconda colonna su cui raggruppare per Region.

• "Total Sales" è il nome della colonna personalizzata per la somma delle vendite.

• SUM(SalesData[SalesAmount]) somma le vendite per ciascun gruppo.

Riepilogo di più colonne. Immagine dell’autore.

Qui il raggruppamento multiplo ci ha aiutato a visualizzare l’andamento delle vendite per Region e per Year. Le regioni North e East mostrano crescita dal 2021 al 2023. Il South ha avuto vendite elevate nel 2022, mentre il West ha dati solo per il 2022-2023. 

Tecniche avanzate con DAX SUMMARIZE()

Sebbene SUMMARIZE() sia utile, puoi combinarla con altre funzioni DAX per ottenere capacità di analisi dei dati ancora più sofisticate. Esploriamo alcuni esempi per vedere come le tecniche avanzate possano sfruttare SUMMARIZE() per aggregazioni e riepiloghi complessi.

Usare SUMMARIZE() con ROLLUP()

La funzionalità ROLLUP() all’interno di SUMMARIZE() aggiunge righe di subtotale alle tue tabelle riepilogative per mostrare subtotali a diversi livelli di raggruppamento e fornire riepiloghi gerarchici più dettagliati. Se lavori in finanza o in ruoli di analisi affini, è particolarmente utile per eseguire aggregazioni multilivello.

1. Aggiungi la parola chiave ROLLUP() dopo le colonne di raggruppamento in SUMMARIZE().

2. Specifica quali colonne includere nel calcolo di ROLLUP().

SUMMARIZE(<table>, <groupBy_columnName>[, <groupBy_columnName>]…[, ROLLUP(<groupBy_columnName>[,< groupBy_columnName>…])][, <name>, <expression>]…)

Per esempio, questo dataset mostra le Sales e la Quantity di ciascun Product in una determinata Region. Ora devo trovare il riepilogo delle vendite per Region e Product, con subtotali e totale generale.

Una tabella chiamata sales_rollup. Immagine dell’autore.

Per farlo, uso la seguente formula:

	SalesWithRollup =
	SUMMARIZE(
	    sales_rollup,
	    ROLLUP(sales_rollup[Region], sales_rollup[Product]),
	    "Total Sales", SUM(sales_rollup[Sales]),
	    "Total Quantity", SUM(sales_rollup[Quantity])
	)

Uso della funzione ROLLUP(). Immagine dell’autore.

Come puoi vedere, qui la funzione SUMMARIZE() raggruppa i dati di vendita per Region e Product per calcolare Total Sales e Total Quantity. ROLLUP() aggiunge righe di subtotale e totale complessivo per fornire un riepilogo gerarchico delle performance di vendita a diversi livelli di dettaglio.

Combinare SUMMARIZE() con ADDCOLUMNS()

Puoi anche estendere SUMMARIZE() con ADDCOLUMNS() per includere colonne calcolate personalizzate all’interno dei dati raggruppati. Questo è utile se vuoi aggiungere misure o calcoli complessi alla tua tabella di riepilogo.

Per esempio, uso lo stesso dataset e applico la seguente formula per aggiungere questa volta una nuova colonna:

	SalesWithAddColumns =
	ADDCOLUMNS(
	    SUMMARIZE(
	        sales_rollup,
	        sales_rollup[Region],
	        sales_rollup[Product],
	        "Total Sales", SUM(sales_rollup[Sales]),
	        "Total Quantity", SUM(sales_rollup[Quantity])
	    ),
	    "Average Sales per Unit",
	        DIVIDE(SUM(sales_rollup[Sales]), SUM(sales_rollup[Quantity]), 0)
	)

Combinare SUMMARIZE() e ADDCOLUMNS(). Immagine dell’autore.

Qui la funzione SUMMARIZE() raggruppa le vendite per Region e Product per calcolare Total Sales e Total Quantity. ADDCOLUMNS() quindi calcola le Average Sales per Unit dividendo le vendite totali per la quantità totale di ciascun gruppo.

Problemi comuni in DAX e come risolverli

Usando SUMMARIZE() potresti imbatterti in alcuni problemi. Ma non preoccuparti, è capitato a tutti — ti guiderò tra le difficoltà più comuni e come affrontarle.

Evitare risultati ambigui

A volte SUMMARIZE() può restituire risultati che non tornano del tutto. Spesso accade quando il tuo modello dati o le relazioni non sono chiare. Ecco come evitarlo:

1. Ricontrolla il modello dati: assicurati che tutte le tabelle siano collegate correttamente.

2. Usa nomi di colonna chiari: evita nomi duplicati tra tabelle diverse.

3. Specifica i nomi delle tabelle: quando fai riferimento alle colonne, includi il nome della tabella (ad esempio Orders[OrderDate]) per evitare ambiguità.

Considerazioni sulle prestazioni

Sebbene SUMMARIZE() sia utile, può essere impegnativa in termini di risorse e rallentare l’elaborazione di dataset molto grandi. Questo significa che i tuoi report possono metterci un po’ di più ad aggiornarsi, soprattutto se usi la funzione in misure complesse o con molte colonne di raggruppamento.

Ecco alcuni consigli per mantenere le query veloci:

• Valuta colonne calcolate: per riepiloghi usati spesso, crea colonne calcolate invece di usare SUMMARIZE() ogni volta.

• Rimuovi colonne non necessarie: elimina le colonne irrilevanti per l’analisi, come chiavi primarie o colonne calcolabili da altre.

• Usa i filtri: usa DAX SUMMARIZE() con Filter() prima del riepilogo per ridurre la quantità di dati elaborati.

Alternative DAX a SUMMARIZE()

Sebbene SUMMARIZE() sia una funzione utile, a volte altri strumenti possono svolgere meglio il lavoro. Vediamo un paio di alternative e quando potresti volerle usare.

SUMMARIZECOLUMNS()

SUMMARIZECOLUMNS() è un’altra funzione DAX che rende più semplice creare tabelle riepilogative quando lavori con grandi quantità di dati o situazioni complicate. È simile a SUMMARIZE(), ma con alcune differenze.

• Puoi aggiungere filtri direttamente a SUMMARIZECOLUMNS(), il che la rende più veloce.

• Con SUMMARIZECOLUMNS() puoi includere direttamente le misure nell’output. Non serve ricorrere a funzioni extra come ADDCOLUMNS().

• SUMMARIZECOLUMNS() gestisce automaticamente le righe vuote, così non devi preoccupartene.

SUMMARIZECOLUMNS(
    <groupBy_columnName> [, <groubBy_columnName>] …, [<filterTable>] … [, <name>, <expression>] …
)

Per esempio, ho un dataset e voglio riassumere gli stipendi dei dipendenti per Region e Department filtrando per i dipendenti con nome Raven. Userò la funzione SUMMARIZECOLUMNS() per calcolare lo stipendio totale di Raven nelle diverse regioni e dipartimenti.

Una tabella chiamata employee_data. Immagine dell’autore.

Per questo uso la seguente formula:  

	SalarySummary =
	SUMMARIZECOLUMNS(
	    employee_data[Name],
	    employee_data[Region],
	    employee_data[Department],
	    FILTER(employee_data, employee_data[Name] = "Raven"),
	    "Total Salary", SUM(employee_data[Salary])
	)

Nella formula sopra: 

• SalarySummary è il nome assegnato alla tabella calcolata che viene creata.

• SUMMARIZECOLUMNS(...) crea una tabella riepilogativa in base alle colonne e ai calcoli specificati.

• employee_data[Name], employee_data[Region], employee_data[Department] sono le colonne per cui i dati verranno raggruppati.

• FILTER(employee_data, employee_data[Name] = "Raven") limita i risultati includendo solo le righe in cui il Name è Raven.

• "Total Salary", SUM(employee_data[Salary]) crea una colonna calcolata nel risultato.

• SUM(employee_data[Salary]) calcola la somma di tutti i valori di Salary per ciascun gruppo.

Usa SUMMARIZECOLUMNS per riassumere i risultati. Immagine dell’autore.

Puoi vedere i risultati: la funzione SUMMARIZECOLUMNS() filtra il dataset e calcola i totali degli stipendi di Raven nelle diverse sedi e nei vari dipartimenti. 

GROUPBY()

GROUPBY() è un’altra funzione che a volte può sostituire SUMMARIZE() quando ti serve solo raggruppare i dati ed eseguire calcoli su quei gruppi. Può essere più efficiente di SUMMARIZE() per operazioni di raggruppamento semplici.

Mentre SUMMARIZE() può operare tra tabelle correlate, GROUPBY() si concentra sul raggruppamento e l’aggregazione all’interno di una singola tabella, migliorando le prestazioni in determinati scenari.

Vediamo un esempio. Devo creare un dataset di inventario per tenere traccia di articoli, categorie, unità vendute e prezzi unitari, quindi raggruppare i dati per categoria per calcolare il ricavo totale per ciascuna.

Tabella Inventory. Immagine dell’autore.

Per questo uso la seguente formula:  

	SummaryGroupBY =
	GROUPBY(
	    Inventory,
	    Inventory[Category],
	    "Total Revenue",
	    SUMX(
	        CURRENTGROUP(),
	        Inventory[Units Sold] * Inventory[Unit Price]
	    )
	)

Nella formula sopra:

• GROUPBY() raggruppa i dati per Category.

• CURRENTGROUP() si riferisce a ciascun gruppo di categoria (ad es. elettronica, arredamento o elettrodomestici).

• SUMX() calcola il ricavo totale per ogni gruppo moltiplicando le Units Sold per il Unit Price.

Uso di GROUPBY per raggruppare i dati. Immagine dell’autore. 

Come puoi vedere, la funzione GROUPBY() calcola facilmente il Total Revenue moltiplicando le Units Sold per il Unit Price per ogni articolo nella categoria e riassumendo questi ricavi individuali. 

Considerazioni finali su DAX SUMMARIZE()

Ora sai come la funzione SUMMARIZE() in DAX può aiutarti a raggruppare e analizzare i dati in Power BI, Excel e altri strumenti. Dal raggruppamento di base alle tecniche avanzate come ROLLUP() e ADDCOLUMNS(), SUMMARIZE() aiuta a creare riepiloghi efficaci.

Poiché la pratica rende perfetti, prova queste tecniche con i tuoi dati per vedere come possono aiutarti a far emergere insight utili. Se vuoi affinare ancora le tue competenze DAX, iscriviti al nostro Introduction to DAX in Power BI per diventare un vero power user.