Excel의 SUMIF(): 초보자 가이드

Excel에서 SUMIF()를 사용하려면 =SUMIF(range, criteria, [sum_range])를 입력하세요. 여기서 range는 확인할 셀 범위, criteria는 일치시킬 조건, sum_range는 합산할 셀 범위입니다. 이를 통해 조건을 충족하는 값만 합산할 수 있어, 수동으로 필터링하거나 행을 더하지 않아도 됩니다.

이 글에서는 SUMIF() 구문을 자세히 설명하고, 단계별 예제를 살펴본 뒤, SUMIF()를 SUMIFS(), COUNTIF() 같은 관련 함수와 비교하며, 초보자가 자주 헷갈리는 실수도 정리합니다.

Excel의 SUMIF() 함수란?

SUMIF()는 숫자를 더하되, 사용자가 지정한 조건을 만족하는 값만 합산하는 Excel 함수입니다. 간단히 말해, Excel에 무엇을 찾을지 알려주면 해당 조건과 일치하는 값만 더합니다.

기본 SUM() 수식은 범위의 모든 값을 합산합니다. 반면 SUMIF()는 더 선별적입니다. 각 셀을 조건에 대해 확인하고, 통과하는 값만 더합니다. 일치하지 않으면 Excel은 그 셀을 건너뜁니다.

예를 들어, 다음과 같은 경우에 이 공식을 사용할 수 있습니다:

• 가게를 운영하며 특정 제품에서 얼마를 벌었는지 알고 싶을 때
• 지출을 추적하며 식료품, 임대료 같은 특정 카테고리 합계를 구하고 싶을 때
• 팀을 관리하며 특정 직원의 근무 시간을 합산하고 싶을 때

SUMIF()는 전체 합계가 아니라 그중 일부만 필요한 이런 경우에 특히 유용합니다.

SUMIF() 구문

SUMIF() 수식은 다음 구조를 따릅니다:

=SUMIF(range, criteria, [sum_range])

이 구문에서: 

• range: 조건을 확인할 셀 범위입니다. 일치 여부를 판단하기 위해 Excel이 확인하는 곳입니다. 

• criteria: 범위에서 무엇을 찾을지 알려줍니다. 단어, 숫자, 또는 ">100" 같은 기호일 수 있습니다.

• sum_range (선택): 일치 항목을 찾은 뒤 합산할 숫자들이 있는 범위입니다. 이를 생략하면 Excel은 range 자체의 값을 더합니다.

세 부분이 함께 작동하는 간단한 예시는 다음과 같습니다:

=SUMIF(A2:A11, "Apples", B2:B11)

이 수식에서 

• A2:A10 이 range입니다. 여기에서 Apples를 찾기 때문입니다. 

• Apples가 criteria로, 정확히 일치시킬 단어입니다. 

• B2:B10 이 sum_range로, 일치하는 매출 숫자가 있는 곳입니다.

즉, A열에서 Apples를 확인하고, 일치할 때마다 해당 행의 B열 숫자를 더합니다.

조건을 기준으로 값을 합산하려면 SUMIF()를 사용하세요. 이미지: 작성자 제공.

Excel에서 SUMIF() 사용하는 방법

Excel에서 SUMIF()를 사용하려면 다음 단계를 따르세요. 

1단계: 범위 식별

예제에서는 다음 데이터셋을 사용합니다. 

SUMIF()용 데이터셋. 이미지: 작성자 제공.

조건을 적용할 범위를 선택합니다. 여기서는 Apples를 찾을 것이며, 이는 Product 열에 있으므로 범위는 A2:A11입니다.

2단계: 조건 설정

찾고자 하는 값이 Apples이므로 criteria는 Apples입니다.

조건은 수식에 직접 입력하거나 해당 값을 담은 셀을 참조할 수 있습니다. 여기서는 직접 입력하므로 텍스트이기 때문에 큰따옴표로 감싸야 합니다.

3단계: 합계 범위 설정합계 범위는 실제 숫자가 있는 곳입니다. 매출을 합산할 것이므로 합계 범위는 B2:B11입니다.

합계 범위는 검색 범위와 같은 크기나 위치일 필요는 없습니다. 다만 행 단위로 정확히 맞아야 하며, 그래야 SUMIF()가 더하는 값이 조건이 일치한 같은 행의 값이 됩니다.

이제 수식은 다음과 같습니다:

=SUMIF(A2:A11, "Apples", B2:B11)

작동 방식은 다음과 같습니다.

• 2행은 Apples이므로 120 이 더해집니다. 
• 3행은 Oranges이므로 건너뜁니다. 
• 4행은 다시 Apples 이므로 150 이 더해집니다. 
• 같은 방식으로 8행과 11행에서 90과 130이 더해집니다

최종 결과는 490

SUMIF()로 제품 매출을 합산합니다. 이미지: 작성자 제공.

SUMIF() 예제

이제 SUMIF()가 유용한 몇 가지 상황을 더 살펴보겠습니다. 각 예제는 약간씩 다른 조건을 사용하므로 하나씩 진행합니다.

특정 값보다 크거나 작은 수 합산

특정 단어와 일치시키지 말고, 어떤 숫자 기준 이상 또는 이하인 항목을 잡아낼 때가 있습니다.

예를 들어 100보다 큰 모든 매출의 합계를 구하려면 다음과 같이 작성합니다:

=SUMIF(B2:B11, ">100", B2:B11)

표에서 100을 초과하는 값은 120, 150, 110, 130입니다. 이들을 더하면 510이 됩니다.

여기서는 범위와 합계 범위가 동일합니다. 별도의 열과 매칭하는 것이 아니라, 숫자 자체를 기준으로 확인하기 때문입니다.

매출이 50 미만인 합계를 구하려면 수식은 다음과 같습니다:

=SUMIF(B2:B11, "<50", B2:B11)

표에 50 미만 값이 없으므로, 이 수식은 오류가 아닌 0을 반환합니다. 일치 항목이 없는 경우입니다.

크거나 작은 조건에 맞는 숫자 합산. 이미지: 작성자 제공.

날짜 합산

Excel은 날짜를 숫자로 저장하므로 약간 다르게 동작합니다. 각 날짜는 고정 시작점에서부터의 연속 번호입니다. 그래서 일반 숫자와 마찬가지로 날짜에도 비교 기호를 사용할 수 있습니다.

C열에 주문 날짜가 있고, 2026년 3월 1일 이후의 매출 합계를 구한다고 가정해 봅시다. 수식은 다음과 같습니다:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

아래 스크린샷에서는 일치한 날짜와 그 합계를 강조 표시했습니다.

여기서는 DATE() 함수를 사용합니다. 지역 설정에 따라 Excel이 날짜를 다르게 해석할 수 있기 때문에, 직접 날짜를 입력하는 것보다 오류를 줄일 수 있습니다.

특정 월, 예를 들어 2026년 3월의 지출을 원한다면, 한 지점이 아니라 범위를 확인해야 하므로 조건이 하나가 아닌 둘이 필요합니다. 

이는 사실 SUMIF()의 한계이기도 합니다. 곧 이어지는 비교 섹션에서 다룹니다.

SUMIF()로 날짜 조건에 맞는 매출 합계. 이미지: 작성자 제공.

조건으로 셀 참조 사용

지금까지는 "Apples"나 ">100"처럼 조건을 수식에 직접 입력했습니다. 이 방법도 가능하지만 유연하지 않습니다. 다른 제품을 확인하려면 매번 수식을 수정해야 합니다.

더 좋은 방법은 셀을 참조하는 것입니다. 예를 들어 A6 셀에 Grapes라는 단어가 있다면 수식은 다음과 같습니다:

=SUMIF(A2:A11, A6, B2:B11)

이 수식은 Grapes의 모든 값을 합산합니다. 이제 다른 제품을 확인하려면 A6의 내용만 바꾸면 됩니다. 수식은 건드릴 필요가 없습니다.

조건을 하드코딩하는 대신 셀 참조 사용. 이미지: 작성자 제공.

SUMIF()에서 와일드카드 사용 방법

와일드카드는 정확한 텍스트를 모를 때 패턴을 매칭하는 데 사용합니다. 예를 들어 정확한 단어는 모르지만 특정 글자 B로 시작하는 것은 알 때입니다. 

SUMIF()는 두 가지 와일드카드를 지원합니다: 

• * 임의 개수의 문자를 의미합니다. 0개, 1개, 혹은 매우 많은 문자도 포함할 수 있습니다.

• ? 정확히 1개의 문자를 의미합니다.

제품 표에서 어떻게 동작하는지 살펴보겠습니다.

"A"로 시작하는 제품

모든 제품 중 A로 시작하는 항목의 총매출을 구한다고 합시다. 그러면 Apples, Apricots, Avocados, Almonds에 대해 각각 수식을 네 번 쓰는 대신, 와일드카드 하나로 모두 처리할 수 있습니다:

=SUMIF(A2:A8, "A*", B2:B8)

문자 A 뒤의 별표는 A 다음에 어떤 문자가 오든 일치로 처리하라는 의미입니다. 표에서 A로 시작하는 모든 제품이 포함됩니다. 즉, 120 + 90 + 60 + 75 = 345입니다.

* 와일드카드로 A로 시작하는 제품 찾기. 이미지: 작성자 제공.

특정 텍스트를 포함하는 이름

와일드카드는 단어 중간에도 사용할 수 있습니다. 이름에 어딘가 an이 들어가는 모든 제품을 찾는다고 해봅시다. 그러면 Bananas와 Oranges가 모두 잡힙니다. 

이 경우 수식은 다음과 같습니다:

=SUMIF(A2:A8, "*an*", B2:B8)

앞뒤의 별표는 an 앞뒤에 무엇이 오든 상관하지 않겠다는 뜻입니다. 텍스트 어딘가에 an이 있으면 일치로 간주합니다. 

이 수식을 표에 적용하면 Bananas 와 Oranges의 매출이 합산되어 175가 됩니다. 

*는 특정 문자(열)를 포함하는 제품을 찾습니다. 이미지: 작성자 제공.

* 대신 ?를 사용할 때

?는 정확히 한 글자를 매칭합니다. 제품 코드가 있고, 문자 A 뒤에 숫자가 정확히 한 자리인 코드만 원한다면 다음과 같이 씁니다:

=SUMIF(A2:A7, "A?", B2:B7)

이 수식은 A1, A2, A3에는 일치하지만 A10이나 A11에는 일치하지 않습니다. 뒤에 문자가 두 개이기 때문입니다.

? 와일드카드로 패턴을 매칭합니다. 이미지: 작성자 제공.

정리하면:

• 텍스트 길이가 달라질 수 있을 때는 *를 사용하세요. 

• 기대하는 문자 수가 정확히 정해져 있을 때는 ?를 사용하세요.

SUMIF() vs. SUMIFS()

SUMIFS()는 SUMIF()와 같은 일을 합니다: 

• SUMIF()는 한 번에 하나의 조건만 확인합니다. 

• SUMIFS()는 여러 조건을 동시에 확인합니다.

간단히 비교해 보겠습니다.n.

The syntax of SUMIFS() is:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

SUMIF()와의 차이는 sum_range의 위치입니다. SUMIF()에서는 마지막에, SUMIFS()에서는 맨 앞에 옵니다. 

예제로 살펴보겠습니다. 

판매 표에서 Apples의 총매출을 구하되, 매출이 100을 초과한 경우만 포함하겠습니다. 조건이 두 개입니다. 

SUMIF()와 달리 SUMIFS()는 이를 처리할 수 있습니다. 방법은 다음과 같습니다. 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

여기서 B2:B11 이 먼저 나오는 sum_range입니다. 그다음 조건 쌍은 A2:A11 + Apples, 그리고 B2:B11 + >100입니다. Excel은 각 행에 대해 두 조건을 모두 확인하고, 둘 다 참일 때만 매출 금액을 더합니다.

SUMIFS()는 여러 조건을 한 번에 확인합니다. 이미지: 작성자 제공.

SUMIF() vs. COUNTIF()

SUMIF()와 COUNTIF()는 모두 조건을 확인한 뒤 작업을 수행하기 때문에 비슷해 보이지만, 하는 일은 다릅니다.

• SUMIF()는 조건에 맞는 값을 합산합니다. 

• COUNTIF()는 조건에 맞는 셀의 개수를 셉니다. 

간단히 비교해 보겠습니다.n.

하나는 총합을, 다른 하나는 개수를 제공합니다. 원래의 판매 표로 나란히 살펴보겠습니다.

여기서는 Apples에 대해 두 가지가 궁금합니다. 

1. 총 얼마를 판매했는가
2. 목록에서 Apples 가 몇 번 등장하는가

총매출에는 SUMIF()를 사용합니다:

=SUMIF(A2:A11, "Apples", B2:B11)

제품이 Apples인 모든 행의 매출을 합산하여 490을 얻습니다.

개수 계산에는 COUNTIF()를 사용합니다:

=COUNTIF(A2:A11, "Apples")

이는 Apples가 들어 있는 행이 몇 개인지 세어 4를 반환합니다.

COUNIF()는 셀에 나타난 횟수를 셉니다. 이미지: 작성자 제공.

COUNTIF()는 더할 것이 없으므로 범위와 조건만 필요합니다. 반면 SUMIF()는 합계 범위도 필요합니다. 합산할 숫자를 가져와야 하기 때문입니다.

자주 발생하는 SUMIF() 실수

간단한 수식이라도 작은 오류가 스며들 수 있습니다. 가장 흔한 실수와 그 해결 방법을 정리했습니다.

잘못된 범위 사용

range와 sum_range가 행 단위로 맞지 않을 때 발생합니다. 예를 들어 range가 A2:A11인데 sum_range가 B2:B10이면, 한 행씩 어긋나면서 합계가 잘못될 수 있고, 오류 메시지 없이 지나갈 수도 있습니다.

해결 방법: 두 범위가 같은 행에서 시작하고 같은 행에서 끝나도록 하세요. range가 A2:A11이면, sum_range도 2행부터 11행까지여야 합니다.

합계 범위를 빼먹음

B열을 합산하고 싶은데, 조건은 A열을 기준으로 확인한다고 합시다. 수식에 A2:A11과 조건만 쓰고 합계 범위를 생략하면, Excel은 A열 자체를 합산한다고 가정합니다. 결과가 엉뚱하게 나옵니다.

해결 방법: 확인하는 열과 합산하는 열이 다르면 항상 합계 범위를 포함하세요. 두 열이 같은 경우에는 생략해도 되지만, 명확성을 위해 넣는 것이 좋습니다.

잘못된 조건 구문

>100을 따옴표 없이 쓰면 오류가 납니다. ">100"처럼 큰따옴표로 감싸야 합니다. 작은따옴표도 오류를 유발합니다.

해결 방법: 텍스트나 비교 기호를 사용하는 조건은 모두 큰따옴표가 필요합니다. 숫자 100처럼 정확한 숫자만 일치시킬 때는 따옴표가 필요 없습니다. 하지만 기호나 단어가 조건에 포함되는 순간 따옴표가 필요합니다.

텍스트로 저장된 숫자

스프레드시트의 숫자가 숫자처럼 보이지만, Excel이 실제로는 텍스트로 취급하는 경우가 있습니다. 보통 CSV 파일이나 시스템에서 데이터를 가져올 때 발생합니다. 

숫자가 보통 텍스트처럼 왼쪽 정렬되어 있으면 이를 알아차릴 수 있습니다.

이 경우 ">100" 같은 비교 조건을 사용하는 SUMIF()는 제대로 작동하지 않습니다. Excel은 텍스트 값을 실제 숫자처럼 비교할 수 없기 때문입니다.

해결 방법: 텍스트를 숫자로 변환하세요. 리본의 홈 탭 > 표시 형식 그룹에서 드롭다운을 일반 또는 숫자로 변경합니다.

텍스트 값의 여분 공백

어떤 셀은 "Apples"이고, 다른 셀은 뒤에 공백이 있는 "Apples " 일 수 있습니다. 눈으로는 같아 보이지만, SUMIF()는 다르게 인식해 일치로 보지 않습니다.

해결 방법: 수식을 실행하기 전에 여분의 공백을 제거하기 위해 수식을 TRIM() 함수로 감싸세요. 그러면 "Apples" 과 "Apples " 이 동일하게 처리됩니다.

SUMIF() 모범 사례

스프레드시트가 커질수록 SUMIF()를 더 쉽게 다루는 몇 가지 습관이 도움이 됩니다. 다음을 권장합니다.

• 조건을 하드코딩하지 말고 셀 참조 사용: 수식에 직접 "Apples"를 입력하는 방법은 가능하지만, 다른 값을 확인할 때마다 수식을 수정해야 합니다. 셀을 가리키도록 만들면, 그 셀의 값만 바꾸면 되고 수식은 그대로 둘 수 있습니다.

• 범위 크기를 동일하게 유지: range와 sum_range는 항상 같은 행 수를 포함해야 합니다. 하나는 2행부터 11행까지인데 다른 하나가 10행에서 끝나면 합계가 제대로 맞지 않습니다.

• 데이터가 늘어나는 경우 Excel 표 사용: 일반 범위인 A2:A11 은 데이터가 늘어나도 새 행을 자동으로 포함하지 않습니다. 데이터를 Excel 표로 전환하세요. 표는 행을 추가하면 자동으로 확장되며, SUMIF() 수식도 함께 확장되어 수동 업데이트가 필요 없습니다.

• 간단한 예제로 수식 테스트: 결과를 이미 아는 5~6개 행으로 테스트해 기대한 값을 반환하는지 확인하세요. 이렇게 하면 수백 행으로 퍼지기 전에 실수를 조기에 잡을 수 있습니다.

• 둘 이상의 조건이 필요하면 SUMIFS() 사용: 제품명과 날짜 범위처럼 두 가지를 동시에 확인해야 하는 순간 SUMIFS()로 전환하세요. SUMIF()로 억지로 처리하려다 보면 가독성이 떨어지고 깨지기 쉬운 우회 방법이 생깁니다.

마무리

SUMIF()는 하나의 조건을 만족하는 값들을 합산하는 가장 간단한 방법입니다. 범위, 조건, 합계 범위를 지정하면 나머지는 자동으로 처리됩니다.

제품명 일치나 특정 값보다 큰 숫자처럼 간단한 조건부터 시작하세요. 익숙해지면 와일드카드와 셀 참조를 사용해 수식의 작동 방식은 그대로 유지하면서도 유연성을 높일 수 있습니다.

동시에 두 가지 이상을 확인해야 한다면, SUMIFS()로 넘어갈 때입니다.