SUMIF() w Excelu: przewodnik dla początkujących

Aby użyć SUMIF() w Excelu, wpisz =SUMIF(range, criteria, [sum_range]), gdzie range to komórki do sprawdzenia, criteria to warunek do dopasowania, a sum_range to komórki do zsumowania. Dzięki temu zsumujesz wartości spełniające konkretny warunek bez ręcznego filtrowania ani dodawania wierszy.

W tym artykule rozłożymy składnię SUMIF() na czynniki pierwsze, przejdziemy przez przykład krok po kroku, porównamy SUMIF() z pokrewnymi funkcjami, takimi jak SUMIFS() i COUNTIF(), oraz omówimy błędy, które mylą większość początkujących.

Czym jest funkcja SUMIF() w Excelu?

SUMIF() to funkcja Excela, która dodaje liczby, ale tylko te, które spełniają ustawiony przez ciebie warunek. Mówiąc prosto: mówisz Excelowi, czego szukać, a on dodaje tylko pasujące wartości.

Prosta formuła SUM() dodaje wszystko w zakresie. Natomiast SUMIF() jest bardziej selektywna. Sprawdza każdą komórkę względem twojego warunku i dodaje tylko te, które go spełniają. Jeśli komórka nie pasuje, Excel ją pomija.

Na przykład możesz użyć tej formuły, gdy:

• Prowadzisz sklep i chcesz wiedzieć, ile zarobiłeś na jednym produkcie.
• Śledzisz wydatki i chcesz sumę dla jednej kategorii, np. spożywcze lub czynsz.
• Zarządzasz zespołem i chcesz zsumować godziny przepracowane przez jednego pracownika.

SUMIF() sprawdza się w każdym z tych przypadków, bo nie interesuje cię całość, tylko wycinek całości.

Składnia SUMIF()

Formuła SUMIF() ma następującą strukturę:

=SUMIF(range, criteria, [sum_range])

W tej składni: 

• range: To grupa komórek, które Excel sprawdza pod kątem twojego warunku. To tutaj Excel sprawdza, co pasuje, a co nie. 

• criteria: Mówi Excelowi, czego szukać w zakresie. Może to być słowo, liczba lub symbol, np. „>100”.

• sum_range (opcjonalnie): Skąd pobrać liczby do zsumowania po znalezieniu dopasowania. Jeśli pominiesz tę część, Excel po prostu doda wartości z samego range.

Oto szybki przykład pokazujący, jak te trzy elementy działają razem:

=SUMIF(A2:A11, "Apples", B2:B11)

W tej formule 

• A2:A10 to zakres, bo tam szukamy Apples. 

• Apples to kryterium, czyli dokładne słowo, które chcemy dopasować. 

• B2:B10 to sum_range, bo tam znajdują się pasujące wartości sprzedaży.

Czyli sprawdzamy kolumnę A pod kątem Apples. Za każdym razem, gdy jest dopasowanie, dodawana jest odpowiadająca liczba z kolumny B.

Zastosuj SUMIF(), aby zsumować wartości na podstawie kryterium. Obraz: autor.

Jak używać SUMIF() w Excelu

Aby użyć SUMIF() w Excelu, wykonaj te kroki: 

Krok 1: Wskaż zakres

W przykładzie używamy następującego zestawu danych: 

Zestaw danych do SUMIF(). Obraz: autor.

Wybierz zakres, w którym chcesz zastosować warunek. W tym przypadku chcemy wyszukać Apples, które są w kolumnie Product, więc zakresem jest A2:A11.

Krok 2: Ustal kryterium

Ponieważ chcemy Apples, kryterium to Apples.

Kryterium możesz wpisać bezpośrednio w formułę albo odnieść się do komórki, która je zawiera. Tutaj wpisujemy je bezpośrednio, więc musi być ujęte w cudzysłów, ponieważ to tekst.

Krok 3: Ustal zakres sumowaniaZakres sumowania to miejsce, gdzie są właściwe liczby. Chcemy zsumować sprzedaż, więc sum_range to B2:B11.

Zakres sumowania nie musi mieć tego samego rozmiaru ani położenia co zakres, w którym szukasz. Musi się tylko zgadzać wiersz do wiersza, aby wartość, którą SUMIF() dodaje, odpowiadała temu samemu wierszowi, w którym spełniono kryterium.

Teraz formuła wygląda tak:

=SUMIF(A2:A11, "Apples", B2:B11)

Tak to zadziała:

• Wiersz 2 zawiera Apples, więc dodane zostaje 120 . 
• Wiersz 3 zawiera Oranges, więc jest pominięty. 
• Wiersz 4 zawiera znów Apples, więc dodane zostaje 150 . 
• Podobnie wiersze 8 i 11, więc dodane zostają 90 i 130.

Ostateczny wynik to 490

Zsumuj sprzedaż produktu za pomocą SUMIF(). Obraz: autor.

Przykłady SUMIF()

Przyjrzyjmy się teraz kilku sytuacjom, w których SUMIF() może się przydać. Każda używa nieco innego typu kryterium, więc omówimy je po kolei.

Sumowanie liczb większych lub mniejszych od danej wartości

Czasami nie chcemy dopasować konkretnego słowa. Zamiast tego chcemy wychwycić wszystko powyżej lub poniżej pewnej liczby.

Aby uzyskać sumę wszystkich sprzedaży większych niż 100, piszemy:

=SUMIF(B2:B11, ">100", B2:B11)

W naszej tabeli wartości większe niż 100 to 120, 150, 110 i 130. Dodając je, otrzymujemy 510.

Zauważ, że tutaj zakres i zakres sumowania są takie same. To dlatego, że sprawdzamy same liczby, a nie dopasowujemy je do osobnej kolumny.

Dla sprzedaży mniejszej niż 50 formuła wyglądałaby tak:

=SUMIF(B2:B11, "<50", B2:B11)

W naszej tabeli nic nie jest poniżej 50, więc ta zwróci 0 zamiast błędu — po prostu brak dopasowań.

Sumowanie liczb spełniających kryteria większe/mniejsze. Obraz: autor.

Sumowanie dat

Daty działają nieco inaczej, bo Excel przechowuje je jako liczby. Każda data to numer seryjny liczony od stałego punktu początkowego. Dlatego możemy używać znaków porównania także z datami, tak jak z zwykłymi liczbami.

Załóżmy, że mamy kolumnę dat zamówień w kolumnie C i chcemy sumę sprzedaży po 1 marca 2026 r. Formuła wyglądałaby tak:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

Na zrzucie ekranu poniżej zaznaczyłem pasujące daty i sumę, którą dają.

Używamy tu funkcji DATE() zamiast wpisywać datę ręcznie. To zapobiega błędom, bo Excel może różnie odczytywać daty w zależności od ustawień regionalnych.

Gdybyśmy chcieli wydatki w konkretnym miesiącu, np. w marcu 2026 r., potrzebowalibyśmy dwóch warunków zamiast jednego, bo sprawdzamy przedział, a nie pojedynczy punkt. 

I tu właśnie SUMIF() dochodzi do granic możliwości — wrócimy do tego w nadchodzącej sekcji porównania.

Suma sprzedaży spełniającej kryterium daty za pomocą SUMIF(). Obraz: autor.

Używanie odwołań do komórek jako kryteriów

Do tej pory wpisywaliśmy kryteria bezpośrednio do formuły, jak „Apples” czy „>100”. To działa, ale nie jest zbyt elastyczne. Gdy chcemy sprawdzić inny produkt, musielibyśmy za każdym razem edytować formułę.

Lepsze podejście to odwołać się do komórki. Załóżmy, że komórka A6 zawiera słowo Grapes. Nasza formuła będzie wyglądać tak:

=SUMIF(A2:A11, A6, B2:B11)

To sumuje wszystkie wartości dla Grapes. Jeśli teraz chcemy sprawdzić inny produkt, zmieniamy tylko zawartość A6; formuły nie trzeba w ogóle dotykać.

Użyj odwołania do komórki zamiast wpisywać kryterium na sztywno. Obraz: autor.

Jak używać symboli wieloznacznych (wildcards) z SUMIF()

Symbole wieloznaczne (wildcards) dopasowują wzorzec, gdy nie znamy dokładnego tekstu. Na przykład nie znasz dokładnego słowa, ale wiesz, że zaczyna się na B. 

SUMIF() obsługuje dwa symbole wieloznaczne: 

• * oznacza dowolną liczbę znaków. Może to być zero znaków, jeden znak lub sto znaków.

• ? oznacza dokładnie jeden znak.

Zobaczmy, jak działają z naszą tabelą produktów.

Produkty zaczynające się na „A”

Załóżmy, że chcemy sumę sprzedaży dla każdego produktu zaczynającego się na A. Zamiast pisać cztery osobne formuły dla Apples, Apricots, Avocados i Almonds, jedna formuła z symbolem wieloznacznym załatwi sprawę:

=SUMIF(A2:A8, "A*", B2:B8)

Gwiazdka po A mówi formule, by dopasowała A, po którym może nastąpić cokolwiek. Każdy produkt w naszej tabeli zaczynający się na A zostaje tu ujęty. To 120 plus 90 plus 60 plus 75, co daje 345.

Produkty zaczynające się na literę A przy użyciu symbolu *. Obraz: autor.

Nazwy zawierające określony tekst

Symbole wieloznaczne działają także w środku wyrazu. Załóżmy, że chcemy każdy produkt, który zawiera „an” gdziekolwiek w nazwie. To obejmuje zarówno Bananas, jak i Oranges. 

Do tego formuła będzie taka:

=SUMIF(A2:A8, "*an*", B2:B8)

Gwiazdka po obu stronach oznacza, że nie dbamy o to, co jest przed lub po an. Dopóki an pojawia się gdzieś w tekście, liczy się jako dopasowanie. 

Uruchomienie tego na naszej tabeli sumuje sprzedaż zarówno z Bananas jak i Oranges, dając 175. 

* znajduje produkt zawierający określone znaki. Obraz: autor.

Kiedy używać ? zamiast *

? dopasowuje dokładnie jeden znak. Jeśli mamy kody produktów i chcemy tylko kody z dokładnie jedną cyfrą po literze A, napiszemy:

=SUMIF(A2:A7, "A?", B2:B7)

To dopasowuje A1, A2 i A3, ale nie A10 czy A11, bo tam są dwa znaki po A, a nie jeden.

Dopasuj wzorzec za pomocą symbolu ?. Obraz: autor.

Czyli:

• Używaj *, gdy długość tekstu się zmienia. 

• Używaj ?, gdy wiesz dokładnie, ilu znaków się spodziewać.

SUMIF() vs. SUMIFS()

SUMIFS() robi to samo co SUMIF(): 

• SUMIF() sprawdza jeden warunek naraz. 

• SUMIFS() sprawdza wiele warunków jednocześnie.

Oto szybkie porównanie.

Składnia SUMIFS() to:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Różnica w SUMIF() polega na tym, że sum_range jest na końcu. W SUMIFS() jest na początku. 

Zobaczmy to na przykładzie. 

W naszej tabeli sprzedaży chcemy łączną sprzedaż dla Apples, ale tylko tam, gdzie sprzedaż była wyższa niż 100. To dwa warunki. 

W przeciwieństwie do SUMIF(), SUMIFS() to obsłuży. Oto jak: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Tutaj B2:B11 to sum_range, podane jako pierwsze. Następnie mamy pary warunków: A2:A11 z Apples oraz B2:B11 z >100. Excel sprawdza oba warunki w każdym wierszu i dodaje wartość sprzedaży tylko wtedy, gdy oba są spełnione.

SUMIFS() sprawdza wiele warunków jednocześnie. Obraz: autor.

SUMIF() vs. COUNTIF()

SUMIF() i COUNTIF() wyglądają podobnie, bo obie sprawdzają warunek przed wykonaniem działania. Ale nie robią tego samego.

• SUMIF() dodaje wartości spełniające warunek. 

• COUNTIF() liczy, ile komórek spełnia warunek. 

Oto szybkie porównanie.

Jedna daje ci sumę, druga — liczbę wystąpień. Zobaczmy to obok siebie, używając naszej pierwotnej tabeli sprzedaży.

Chcemy wiedzieć dwie rzeczy o Apples. 

1. Ile sprzedaliśmy łącznie
2. Ile razy Apples pojawia się na liście?

Do łącznej sprzedaży używamy SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

To dodaje każdą wartość sprzedaży, gdzie produkt to Apples, dając 490.

Do zliczania używamy COUNTIF():

=COUNTIF(A2:A11, "Apples")

To liczy, ile wierszy zawiera Apples, dając 4.

COUNIF() zlicza liczbę wystąpień w komórkach. Obraz: autor.

COUNTIF() potrzebuje tylko zakresu i kryterium, bo niczego nie sumuje. Ale SUMIF() potrzebuje także zakresu sumowania, bo pobiera skądś liczby do zsumowania.

Typowe błędy w SUMIF()

Nawet w prostej formule mogą wkradać się drobne błędy. Oto te najczęstsze i jak je naprawić.

Użycie niewłaściwego zakresu

Dzieje się tak, gdy zakres i zakres sumowania nie pokrywają się wiersz w wiersz. Załóżmy, że twój zakres to A2:A11, ale zakres sumowania to B2:B10. Excel ma teraz jeden wiersz niezgodności i sumy wychodzą błędne, czasem bez żadnego komunikatu o błędzie.

Jak to naprawić: upewnij się, że oba zakresy zaczynają się i kończą w tych samych wierszach. Jeśli twój zakres to A2:A11, zakres sumowania także powinien obejmować wiersze od 2 do 11.

Pomijanie zakresu sumowania

Załóżmy, że chcesz dodać wartości z kolumny B, ale warunek sprawdzasz w kolumnie A. Jeśli napiszesz formułę tylko z A2:A11 i kryterium, a pominiesz zakres sumowania, Excel założy, że chcesz dodać wartości z kolumny A, a nie z B. Wynik wyjdzie błędny.

Jak to naprawić: zawsze podawaj zakres sumowania, gdy kolumna sprawdzana różni się od kolumny sumowanej. Jeśli oba zakresy są takie same, technicznie możesz go pominąć — ale warto dodać dla jasności.

Nieprawidłowa składnia kryteriów

Jeśli napiszesz >100 bez cudzysłowów, pojawi się błąd. Musi być zapisane jako ">100", w podwójnym cudzysłowie. Pojedyncze cudzysłowy też powodują błąd.

Jak to naprawić: każde kryterium używające tekstu lub znaków porównania wymaga cudzysłowów. Jeśli dopasowujesz dokładną liczbę, jak sama liczba 100, cudzysłowy nie są potrzebne. Gdy tylko w kryterium pojawia się symbol lub słowo, cudzysłowy są wymagane.

Liczby zapisane jako tekst

Czasem liczby w arkuszu wyglądają jak liczby, ale Excel traktuje je jako tekst. Zwykle dzieje się tak przy imporcie danych z innego źródła, np. pliku CSV lub eksportu z systemu. 

Zauważysz to, jeśli liczby są wyrównane do lewej, a nie do prawej — tak Excel zwykle wyświetla tekst.

Gdy tak jest, SUMIF() z porównaniem typu ">100" nie zadziała prawidłowo, bo Excel nie może porównywać wartości tekstowych tak jak prawdziwych liczb.

Jak to naprawić: zamień tekst z powrotem na liczby. Przejdź do karty Home > grupa Number i z listy wybierz General lub Number.

Dodatkowe spacje w wartościach tekstowych

Załóżmy, że jedna komórka ma „Apples", a inna „Apples " z końcową spacją. Dla ciebie wyglądają tak samo. Dla SUMIF() — nie, i formuła nie policzy ich jako dopasowania.

Jak to naprawić: owiń formułę funkcją TRIM(), aby usunąć zbędne spacje przed uruchomieniem. Dzięki temu „Apples" i „Apples " w końcu są traktowane jako to samo.

Najlepsze praktyki dla SUMIF()

Kilka nawyków ułatwia pracę z SUMIF(), zwłaszcza gdy twoje arkusze rosną. Oto nasze rekomendacje.

• Używaj odwołań do komórek zamiast wpisywać kryteria na sztywno: Wpisanie „Apples” bezpośrednio w formułę działa, ale oznacza edytowanie formuły za każdym razem, gdy chcesz sprawdzić coś innego. Wskaż komórkę — i zmieniasz tylko jej wartość; formuła zostaje bez zmian.

• Utrzymuj zakresy w tym samym rozmiarze: Twój zakres i zakres sumowania zawsze powinny obejmować tę samą liczbę wierszy. Jeśli jeden biegnie od wiersza 2 do 11, a drugi kończy się na 10, sumy nie będą się zgadzać.

• Używaj tabel Excela dla rosnących zestawów danych: Zwykły zakres, np. A2:A11 nie obejmie automatycznie nowych wierszy, gdy dane rosną. Zamień dane na Tabelę Excela, aby to naprawić. Tabele rozszerzają się same wraz z dodawaniem wierszy, a twoja formuła SUMIF() rośnie razem z nimi — bez ręcznych zmian.

• Testuj formuły na prostych przykładach: Użyj pięciu–sześciu wierszy, dla których znasz wynik, i potwierdź, że formuła zwraca to, czego oczekujesz. Dzięki temu wcześnie wyłapiesz błędy, zanim rozleją się na setki wierszy.

• Używaj SUMIFS(), gdy potrzebny jest więcej niż jeden warunek: Gdy tylko musisz sprawdzić dwie rzeczy naraz, np. produkt i przedział dat, przełącz się na SUMIFS(). Próba wymuszenia tego na SUMIF() zwykle prowadzi do obejść, które są mniej czytelne i łatwiej je zepsuć.

Na koniec

SUMIF() to najprostszy sposób na dodanie wartości spełniających jeden warunek. Podaj zakres, kryterium i zakres sumowania, a resztą zajmie się formuła.

Zacznij od prostych warunków, takich jak dopasowanie nazwy produktu czy liczby większej niż dana wartość. Gdy to będzie dla ciebie naturalne, symbole wieloznaczne i odwołania do komórek zwiększą elastyczność formuły bez zmiany jej działania.

Jeśli kiedykolwiek musisz sprawdzić dwie rzeczy naraz, to znak, by przejść do SUMIFS().