SUMIF() trong Excel: Hướng dẫn cho người mới bắt đầu

Để dùng SUMIF() trong Excel, nhập =SUMIF(range, criteria, [sum_range]), trong đó range là vùng ô cần kiểm tra, criteria là điều kiện cần khớp, và sum_range là vùng ô cần cộng. Cách này giúp bạn cộng tổng các giá trị thỏa một điều kiện cụ thể mà không phải lọc thủ công hay cộng từng dòng.

Trong bài viết này, chúng ta sẽ phân tích chi tiết cú pháp SUMIF(), đi qua ví dụ từng bước, so sánh SUMIF() với các hàm liên quan như SUMIFS() và COUNTIF(), đồng thời đề cập những lỗi khiến người mới hay nhầm lẫn.

Hàm SUMIF() trong Excel là gì?

SUMIF() là một hàm Excel dùng để cộng các số, nhưng chỉ cộng những số đáp ứng điều kiện bạn đặt ra. Nói đơn giản, bạn cho Excel biết cần tìm gì và nó chỉ cộng các giá trị khớp.

Một công thức SUM() đơn giản cộng mọi thứ trong một vùng. Trong khi đó SUMIF() chọn lọc hơn. Nó kiểm tra từng ô theo điều kiện của bạn và chỉ cộng những ô đạt. Ô nào không khớp, Excel sẽ bỏ qua.

Ví dụ, bạn có thể dùng công thức này khi:

• Bạn vận hành một cửa hàng và muốn biết doanh thu từ một sản phẩm cụ thể.
• Bạn theo dõi chi tiêu và muốn tổng cho một danh mục, như thực phẩm hoặc tiền thuê nhà.
• Bạn quản lý đội nhóm và muốn cộng tổng số giờ làm của một nhân viên.

SUMIF() rất phù hợp trong từng trường hợp vì bạn không cần toàn bộ tổng; bạn chỉ cần một phần của nó.

Cú pháp SUMIF()

Công thức SUMIF() có cấu trúc như sau:

=SUMIF(range, criteria, [sum_range])

Trong cú pháp này: 

• range: Nhóm ô Excel sẽ kiểm tra theo điều kiện của bạn. Đây là nơi Excel xác định cái nào khớp và cái nào không. 

• criteria: Cho Excel biết cần tìm gì trong vùng. Có thể là một từ, một số, hoặc một ký hiệu như ">>100".

• sum_range (tùy chọn): Vùng số sẽ được cộng sau khi tìm thấy khớp. Nếu bỏ qua phần này, Excel sẽ cộng các giá trị ngay trong range.

Ví dụ nhanh để thấy ba phần hoạt động cùng nhau:

=SUMIF(A2:A11, "Apples", B2:B11)

Trong công thức này, 

• A2:A10 là vùng tìm kiếm vì chúng ta đang tìm Apples ở đó. 

• Apples là điều kiện, chính là từ cần khớp. 

• B2:B10 là sum_range, vì đó là nơi có các số liệu doanh số tương ứng.

Vậy ta đang kiểm tra cột A để tìm Apples. Mỗi lần khớp, số tương ứng ở cột B sẽ được cộng.

Áp dụng SUMIF() để cộng tổng theo một tiêu chí. Hình: Tác giả.

Cách dùng SUMIF() trong Excel

Để dùng SUMIF() trong Excel, thực hiện các bước sau: 

Bước 1: Xác định vùng

Chúng ta dùng tập dữ liệu sau trong ví dụ: 

Tập dữ liệu cho SUMIF(). Hình: Tác giả.

Chọn vùng bạn muốn áp điều kiện. Ở đây, ta muốn tìm Apples, nằm ở cột Product, nên vùng là A2:A11.

Bước 2: Đặt điều kiện

Vì chúng ta muốn Apples, điều kiện là Apples.

Bạn có thể gõ điều kiện trực tiếp vào công thức hoặc tham chiếu đến một ô chứa điều kiện. Ở đây, chúng ta gõ trực tiếp, nên cần đặt trong dấu ngoặc kép vì đó là văn bản.

Bước 3: Đặt vùng cần cộngVùng cộng là nơi có các số thực tế. Ta muốn cộng doanh số, nên vùng cộng là B2:B11.

Vùng cộng không nhất thiết phải cùng kích thước hoặc vị trí với vùng tìm kiếm. Chỉ cần thẳng hàng theo từng dòng, để giá trị SUMIF() cộng tương ứng đúng dòng nơi điều kiện khớp.

Giờ công thức sẽ như sau:

=SUMIF(A2:A11, "Apples", B2:B11)

Cách hoạt động:

• Dòng 2 có Apples, nên 120 được cộng. 
• Dòng 3 là Oranges, nên bị bỏ qua. 
• Dòng 4 lại là Apples, nên 150 được cộng. 
• Tương tự các dòng 8 và 11, nên 90 và 130 được cộng

Kết quả cuối cùng là 490

Cộng tổng doanh số sản phẩm bằng SUMIF(). Hình: Tác giả.

Ví dụ về SUMIF()

Giờ hãy xem thêm vài tình huống SUMIF() hữu ích. Mỗi tình huống dùng một kiểu điều kiện hơi khác, nên ta sẽ đi lần lượt.

Cộng các số lớn hơn hoặc nhỏ hơn một giá trị

Đôi khi ta không muốn khớp một từ cụ thể. Thay vào đó, ta muốn lấy mọi thứ lớn hơn hoặc nhỏ hơn một số nào đó.

Để lấy tổng tất cả doanh số lớn hơn 100, ta viết:

=SUMIF(B2:B11, ">100", B2:B11)

Trong bảng của chúng ta, các giá trị lớn hơn 100 là 120, 150, 110 và 130. Cộng lại, ta được 510.

Lưu ý vùng kiểm tra và vùng cộng giống nhau ở đây. Vì chúng ta đang kiểm tra chính các con số, không so với cột khác.

Với doanh số nhỏ hơn 50, công thức sẽ là:

=SUMIF(B2:B11, "<50", B2:B11)

Trong bảng của chúng ta, không có gì dưới 50, nên công thức trả về 0 chứ không lỗi — chỉ là không có khớp.

Cộng các số khớp điều kiện lớn hơn/nhỏ hơn. Hình: Tác giả.

Cộng theo ngày

Ngày hoạt động hơi khác vì Excel lưu ngày dưới dạng số. Mỗi ngày là một số sê-ri đếm từ một mốc cố định. Vì vậy ta có thể dùng các ký hiệu so sánh với ngày tương tự như với số.

Giả sử cột C là ngày đặt hàng, và ta muốn tổng doanh số sau ngày 1/3/2026. Công thức như sau:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

Trong ảnh bên dưới, tôi đã tô sáng các ngày khớp và tổng tương ứng.

Chúng ta dùng hàm DATE() thay vì gõ ngày trực tiếp để tránh lỗi, vì Excel có thể đọc ngày khác nhau tùy thiết lập vùng miền.

Nếu muốn chi phí trong một tháng cụ thể, như tháng 3/2026, ta cần hai điều kiện thay vì một, vì đang kiểm tra một khoảng thay vì một điểm. 

Đó chính là giới hạn của SUMIF() — chúng ta sẽ nói ở phần so sánh bên dưới.

Tổng doanh số khớp điều kiện ngày bằng SUMIF(). Hình: Tác giả.

Dùng tham chiếu ô làm điều kiện

Đến giờ, ta gõ điều kiện trực tiếp vào công thức, như "Apples" hoặc ">100". Cách này ổn nhưng không linh hoạt. Nếu muốn kiểm tra sản phẩm khác, bạn phải sửa công thức mỗi lần.

Cách hay hơn là tham chiếu đến một ô. Giả sử ô A6 chứa từ Grapes. Công thức sẽ như sau:

=SUMIF(A2:A11, A6, B2:B11)

Công thức này cộng tất cả giá trị của Grapes. Giờ nếu muốn kiểm tra sản phẩm khác, bạn chỉ cần đổi nội dung trong A6; không cần đụng đến công thức.

Dùng tham chiếu ô thay vì mã hóa cứng điều kiện. Hình: Tác giả.

Cách dùng ký tự đại diện với SUMIF()

Ký tự đại diện giúp khớp theo mẫu khi ta không biết chính xác văn bản. Ví dụ, bạn không biết chính xác từ nhưng biết từ đó bắt đầu bằng B. 

SUMIF() hỗ trợ hai ký tự đại diện: 

• * đại diện cho bất kỳ số lượng ký tự nào. Có thể là 0, 1 hoặc hàng trăm ký tự.

• ? đại diện cho đúng một ký tự.

Hãy xem chúng hoạt động thế nào với bảng sản phẩm của chúng ta.

Sản phẩm bắt đầu bằng "A"

Giả sử ta muốn tổng doanh số cho mọi sản phẩm bắt đầu bằng A. Thay vì viết bốn công thức riêng cho Apples, Apricots, Avocados và Almonds, một công thức với ký tự đại diện xử lý tất cả:

=SUMIF(A2:A8, "A*", B2:B8)

Dấu sao sau chữ A báo cho công thức khớp chữ A rồi đến bất cứ gì. Mọi sản phẩm trong bảng bắt đầu bằng A đều được tính. Tức là 120 cộng 90 cộng 60 cộng 75, ra 345.

Sản phẩm bắt đầu bằng chữ A với ký tự đại diện *. Hình: Tác giả.

Tên chứa một chuỗi ký tự nhất định

Ký tự đại diện cũng hoạt động ở giữa từ. Giả sử ta muốn mọi sản phẩm chứa "an" ở đâu đó trong tên. Điều này khớp cả Bananas lẫn Oranges. 

Công thức sẽ là:

=SUMIF(A2:A8, "*an*", B2:B8)

Dấu sao ở hai bên nghĩa là ta không quan tâm ký tự trước hay sau an. Chỉ cần an xuất hiện ở đâu đó trong văn bản là được coi là khớp. 

Chạy công thức này trên bảng sẽ cộng doanh số của cả Bananas và Oranges, cho ra 175. 

* tìm sản phẩm chứa ký tự cụ thể. Hình: Tác giả.

Khi nào dùng ? thay vì *

? khớp đúng một ký tự. Nếu có mã sản phẩm và ta chỉ muốn mã có đúng một chữ số sau chữ cái A, ta viết:

=SUMIF(A2:A7, "A?", B2:B7)

Công thức này khớp A1, A2 và A3, nhưng không khớp A10 hay A11, vì những mã đó có hai ký tự sau chữ A chứ không phải một.

Khớp mẫu bằng ký tự đại diện ?. Hình: Tác giả.

Vậy nên:

• Dùng * khi độ dài văn bản thay đổi. 

• Dùng ? khi bạn biết chính xác số ký tự mong đợi.

SUMIF() và SUMIFS()

SUMIFS() làm cùng một việc với SUMIF(): 

• SUMIF() kiểm tra một điều kiện tại một thời điểm. 

• SUMIFS() kiểm tra nhiều điều kiện cùng lúc.

Sau đây là so sánh nhanh.

Cú pháp của SUMIFS() là:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Điểm khác ở SUMIF() là sum_range đặt ở cuối. Còn trong SUMIFS(), nó đứng đầu. 

Hãy xem ví dụ. 

Trong bảng doanh số, ta muốn tổng doanh số của Apples, nhưng chỉ những dòng doanh số lớn hơn 100. Tức là hai điều kiện. 

Khác với SUMIF(), SUMIFS() xử lý được. Cách viết: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Ở đây, B2:B11 là sum_range, liệt kê đầu tiên. Sau đó là các cặp điều kiện: A2:A11 với Apples, và B2:B11 với >100. Excel kiểm tra cả hai điều kiện cho mỗi dòng và chỉ cộng doanh số khi cả hai đều đúng.

SUMIFS() kiểm tra nhiều điều kiện cùng lúc. Hình: Tác giả.

SUMIF() và COUNTIF()

SUMIF() và COUNTIF() trông giống nhau vì đều kiểm tra điều kiện trước khi thực hiện. Nhưng chúng không làm cùng một việc.

• SUMIF() cộng các giá trị khớp điều kiện. 

• COUNTIF() đếm số ô khớp điều kiện. 

Sau đây là so sánh nhanh.

Một hàm cho bạn một tổng. Hàm kia cho bạn một số đếm. Hãy xem cạnh nhau, dùng chính bảng doanh số ban đầu.

Ở đây ta muốn biết hai điều về Apples. 

1. Tổng số đã bán là bao nhiêu
2. Từ Apples xuất hiện bao nhiêu lần trong danh sách?

Với tổng doanh số, dùng SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

Công thức cộng mọi số doanh số nơi sản phẩm là Apples, ra 490.

Với số đếm, dùng COUNTIF():

=COUNTIF(A2:A11, "Apples")

Công thức đếm bao nhiêu dòng chứa Apples, cho ra 4.

COUNIF() đếm số lần xuất hiện trong ô. Hình: Tác giả.

COUNTIF() chỉ cần một vùng và một điều kiện, vì không có gì để cộng. Còn SUMIF() cần thêm vùng cộng, vì nó phải lấy số từ đâu đó để cộng tổng.

Lỗi thường gặp với SUMIF()

Ngay cả với công thức đơn giản, lỗi nhỏ vẫn có thể xảy ra. Dưới đây là những lỗi thường gặp nhất và cách khắc phục.

Dùng sai vùng

Lỗi này xảy ra khi vùng điều kiện và vùng cộng không thẳng hàng theo từng dòng. Ví dụ vùng điều kiện là A2:A11, nhưng vùng cộng là B2:B10. Excel sẽ bị lệch một dòng, và tổng bị sai, đôi khi không có thông báo lỗi.

Cách khắc phục: đảm bảo cả hai vùng bắt đầu và kết thúc ở cùng các dòng. Nếu vùng điều kiện là A2:A11, vùng cộng cũng phải chạy từ dòng 2 đến dòng 11.

Quên vùng cộng

Giả sử bạn muốn cộng cột B, nhưng điều kiện kiểm tra ở cột A. Nếu bạn viết công thức chỉ với A2:A11 và điều kiện, mà bỏ vùng cộng, Excel sẽ hiểu là bạn muốn cộng chính cột A, không phải cột B. Kết quả sẽ sai.

Cách khắc phục: luôn bao gồm vùng cộng khi cột bạn kiểm tra khác với cột bạn cộng. Nếu hai cột trùng nhau, về kỹ thuật bạn có thể bỏ qua. Tuy nhiên vẫn nên thêm vào để rõ ràng.

Cú pháp điều kiện không đúng

Viết >100 mà không có ngoặc kép sẽ gây lỗi. Cần viết là ">100" với dấu ngoặc kép. Dấu nháy đơn cũng gây lỗi.

Cách khắc phục: mọi điều kiện dùng văn bản hoặc ký hiệu so sánh cần có ngoặc kép. Nếu bạn khớp một số chính xác, như số 100 đứng riêng, thì không cần ngoặc kép. Nhưng hễ có ký hiệu hoặc chữ trong điều kiện, phải có ngoặc kép.

Số được lưu dưới dạng văn bản

Đôi khi số trông như số, nhưng Excel lại coi là văn bản. Thường xảy ra khi dữ liệu được nhập từ nguồn khác, như tệp CSV hoặc xuất từ hệ thống. 

Bạn sẽ nhận ra khi số canh trái thay vì canh phải — cách Excel hiển thị văn bản.

Khi đó, SUMIF() với so sánh như ">100" sẽ không hoạt động đúng, vì Excel không thể so sánh văn bản như so sánh số thực.

Cách khắc phục: chuyển văn bản về số. Vào thẻ Home > nhóm Number, và trong danh sách, chọn General hoặc Number.

Dư khoảng trắng trong giá trị văn bản

Giả sử một ô là "Apples" và ô khác là "Apples " có khoảng trắng thừa ở cuối. Với bạn chúng như nhau. Với SUMIF() thì không, và công thức sẽ không tính là khớp.

Cách khắc phục: bọc công thức trong hàm TRIM() để loại bỏ khoảng trắng thừa trước khi chạy. Như vậy "Apples" và "Apples " sẽ được coi là một.

Thực hành tốt với SUMIF()

Một vài thói quen sẽ giúp SUMIF() dễ dùng hơn, đặc biệt khi bảng tính của bạn lớn dần. Đây là khuyến nghị của chúng tôi.

• Dùng tham chiếu ô thay vì mã hóa cứng điều kiện: Gõ "Apples" trực tiếp thì được, nhưng mỗi lần kiểm tra mục khác bạn lại phải sửa công thức. Trỏ tới một ô thay thế, và bạn chỉ cần đổi giá trị trong ô; công thức không đổi.

• Giữ các vùng cùng kích thước: Vùng điều kiện và vùng cộng luôn phải bao phủ cùng số dòng. Nếu một vùng từ dòng 2 đến 11 còn vùng kia dừng ở dòng 10, tổng sẽ không khớp đúng.

• Dùng Excel Table cho dữ liệu mở rộng: Một vùng thường như A2:A11 sẽ không tự thêm dòng mới khi dữ liệu tăng. Hãy chuyển dữ liệu thành Excel Table để khắc phục. Bảng sẽ tự mở rộng khi bạn thêm dòng, và công thức SUMIF() cũng mở rộng theo; không cần cập nhật thủ công.

• Kiểm thử công thức với ví dụ đơn giản: Dùng 5–6 dòng mà bạn đã biết kết quả và xác nhận công thức trả về đúng như mong đợi. Việc này bắt lỗi sớm trước khi lan sang hàng trăm dòng.

• Dùng SUMIFS() khi cần hơn một điều kiện: Khi bạn cần kiểm tra hai thứ cùng lúc, như sản phẩm và khoảng ngày, hãy chuyển sang SUMIFS(). Cố ép SUMIF() làm việc đó thường dẫn đến cách lách rối và dễ hỏng.

Kết luận

SUMIF() là cách đơn giản nhất để cộng các giá trị thỏa một điều kiện. Cho nó một vùng, một điều kiện và một vùng cộng, còn lại nó sẽ xử lý.

Bắt đầu với những điều kiện đơn giản, như khớp tên sản phẩm hoặc số lớn hơn một ngưỡng. Khi đã quen, ký tự đại diện và tham chiếu ô sẽ giúp công thức linh hoạt hơn mà không đổi cách nó hoạt động bên trong.

Nếu bạn thấy mình cần kiểm tra hai thứ cùng lúc, đó là dấu hiệu để chuyển sang SUMIFS().