SUMIF() en Excel: guía para principiantes

Para usar SUMIF() en Excel, escribe =SUMIF(range, criteria, [sum_range]), donde range es el rango a comprobar, criteria es la condición a cumplir y sum_range son las celdas que se van a sumar. Así podrás obtener el total de los valores que cumplen una condición concreta sin filtrar ni sumar manualmente.

En este artículo desgranamos la sintaxis de SUMIF(), vemos un ejemplo paso a paso, comparamos SUMIF() con funciones relacionadas como SUMIFS() y COUNTIF(), y repasamos los errores que más confunden al principio.

¿Qué es la función SUMIF() en Excel?

SUMIF() es una función de Excel que suma números, pero solo aquellos que cumplen una condición que tú defines. En pocas palabras: le dices a Excel qué buscar y suma solo los valores que coinciden.

Una fórmula SUM() simple suma todo en un rango. En cambio, SUMIF() es más selectiva. Comprueba cada celda frente a tu condición y solo suma las que la cumplen. Si una celda no coincide, Excel la omite.

Por ejemplo, puedes usar esta fórmula si:

• Tienes una tienda y quieres saber cuánto has vendido de un producto concreto.
• Controlas tus gastos y quieres el total de una categoría (por ejemplo, supermercado o alquiler).
• Gestionas un equipo y quieres sumar las horas trabajadas por una persona.

SUMIF() es perfecta en estos casos porque no te interesa el total global, sino una parte concreta.

Sintaxis de SUMIF()

La fórmula SUMIF() sigue esta estructura:

=SUMIF(range, criteria, [sum_range])

En esta sintaxis: 

• range: es el conjunto de celdas que Excel comprueba con tu condición. Ahí es donde decide qué coincide y qué no. 

• criteria: indica a Excel qué buscar en el rango. Puede ser una palabra, un número o un símbolo como ">100".

• sum_range (opcional): de aquí se toman los números a sumar cuando hay coincidencia. Si lo omites, Excel suma los valores del propio range.

Aquí tienes un ejemplo rápido para ver cómo encajan las tres partes:

=SUMIF(A2:A11, "Apples", B2:B11)

En esta fórmula, 

• A2:A10 es el rango, porque ahí buscamos Apples. 

• Apples es el criterio, la palabra exacta que queremos coincidir. 

• B2:B10 es el sum_range, donde están los importes de ventas a sumar.

Así, comprobamos la columna A para Apples. Cada vez que hay coincidencia, se suma el número correspondiente de la columna B.

Aplica SUMIF() para sumar valores según un criterio. Imagen del autor.

Cómo usar SUMIF() en Excel

Para usar SUMIF() en Excel, sigue estos pasos: 

Paso 1: identifica el rango

Usaremos este conjunto de datos en el ejemplo: 

Conjunto de datos para SUMIF(). Imagen del autor.

Selecciona el rango donde quieres aplicar la condición. En este caso, queremos buscar Apples, que está en la columna Product, así que el rango es A2:A11.

Paso 2: define el criterio

Como buscamos Apples, el criterio es Apples.

Puedes escribir el criterio directamente en la fórmula o hacer referencia a una celda que lo contenga. Aquí lo escribimos directamente, así que debe ir entre comillas porque es texto.

Paso 3: define el rango a sumar. El rango de suma es donde están los números reales. Queremos sumar las ventas, así que el rango de suma es B2:B11.

El rango de suma no tiene por qué tener el mismo tamaño o posición que el rango que buscas. Solo debe estar alineado por filas, para que el valor que SUMIF() suma corresponda a la misma fila donde se cumple el criterio.

Ahora la fórmula queda así:

=SUMIF(A2:A11, "Apples", B2:B11)

Así funciona:

• La fila 2 tiene Apples, así que se suma 120. 
• La fila 3 tiene Oranges, así que se omite. 
• La fila 4 tiene de nuevo Apples, así que se suma 150. 
• Igual con las filas 8 y 11: se suman 90 y 130

El resultado final es 490

Suma las ventas del producto con SUMIF(). Imagen del autor.

Ejemplos de SUMIF()

Veamos algunas situaciones más en las que SUMIF() puede ser útil. Cada una usa un tipo de criterio ligeramente distinto, así que las revisamos una a una.

Sumar números mayores o menores que un valor

A veces no queremos coincidir con una palabra concreta, sino capturar todo lo que esté por encima o por debajo de cierto número.

Para obtener el total de todas las ventas mayores que 100, escribimos:

=SUMIF(B2:B11, ">100", B2:B11)

En nuestra tabla, los valores mayores que 100 son 120, 150, 110 y 130. Si los sumamos, obtenemos 510.

Observa que aquí el rango y el rango de suma son el mismo. Es porque estamos comprobando los propios números, no comparándolos con otra columna.

Para ventas menores que 50, la fórmula sería:

=SUMIF(B2:B11, "<50", B2:B11)

En nuestra tabla no hay valores por debajo de 50, así que devuelve 0: no es un error, simplemente no hay coincidencias.

Sumar números que cumplen criterios de mayor que o menor que. Imagen del autor.

Sumar por fechas

Las fechas funcionan de forma algo distinta, porque Excel las guarda como números. Cada fecha es un número de serie desde un punto inicial fijo. Por eso podemos usar símbolos de comparación con fechas igual que con números.

Supongamos que tenemos una columna de fechas de pedido en la columna C y queremos el total de ventas posteriores a 1 de marzo de 2026. La fórmula sería:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

En la captura de pantalla de abajo, he destacado las fechas coincidentes y el total que suman.

Aquí usamos la función DATE() en lugar de teclear la fecha directamente. Así evitamos errores, ya que Excel puede interpretar las fechas de forma distinta según la configuración regional.

Si quisiéramos gastos durante un mes concreto, por ejemplo marzo de 2026, necesitaríamos dos condiciones en lugar de una, porque comprobamos un rango y no un único punto. 

Ahí es donde SUMIF() llega a su límite: lo veremos en la comparación más adelante.

Suma de ventas que cumplen el criterio de fecha con SUMIF(). Imagen del autor.

Usar referencias de celda como criterio

Hasta ahora hemos tecleado el criterio directamente en la fórmula, como "Apples" o ">100". Funciona, pero no es muy flexible: si quieres comprobar otro producto, tendrías que editar la fórmula cada vez.

Una mejor opción es referenciar una celda. Supón que la celda A6 contiene la palabra Grapes. La fórmula quedaría así:

=SUMIF(A2:A11, A6, B2:B11)

Esto suma todos los valores de Grapes. Ahora, si quieres comprobar otro producto, solo cambias el contenido de A6; no hace falta tocar la fórmula.

Usa referencias de celda en lugar de escribir el criterio a mano. Imagen del autor.

Cómo usar comodines con SUMIF()

Los comodines permiten buscar por patrón cuando no conocemos el texto exacto. Por ejemplo, no sabes la palabra exacta pero sí que empieza por B. 

SUMIF() admite dos comodines: 

• * representa cualquier número de caracteres (cero, uno o muchos).

• ? representa exactamente un carácter.

Veamos cómo funcionan con nuestra tabla de productos.

Productos que empiezan por "A"

Queremos el total de ventas de todos los productos que empiezan por A. En lugar de escribir cuatro fórmulas separadas para Apples, Apricots, Avocados y Almonds, un único comodín lo resuelve:

=SUMIF(A2:A8, "A*", B2:B8)

El asterisco después de A indica que coincida A seguida de cualquier cosa. Todos los productos de la tabla que empiezan por A quedan capturados. Es decir, 120 más 90 más 60 más 75, que dan 345.

Productos que empiezan por la letra A con el comodín *. Imagen del autor.

Nombres que contienen cierto texto

Los comodines también funcionan en medio de una palabra. Queremos todos los productos que contengan “an” en su nombre. Eso incluye Bananas y Oranges. 

Para ello, la fórmula sería:

=SUMIF(A2:A8, "*an*", B2:B8)

El asterisco a ambos lados indica que no nos importa qué haya antes o después de an. Mientras an aparezca en el texto, cuenta como coincidencia. 

En nuestra tabla, esto suma las ventas de Bananas y Oranges, dando 175. 

* encuentra productos que contienen ciertos caracteres. Imagen del autor.

Cuándo usar ? en lugar de *

? coincide con exactamente un carácter. Si tenemos códigos de producto y queremos solo los códigos con exactamente una cifra tras la letra A, escribiríamos:

=SUMIF(A2:A7, "A?", B2:B7)

Esto coincide con A1, A2 y A3, pero no con A10 o A11, porque esos tienen dos caracteres tras la A, no uno.

Haz coincidir el patrón con el comodín ?. Imagen del autor.

Entonces:

• Usa * cuando la longitud del texto varía. 

• Usa ? cuando sabes exactamente cuántos caracteres esperar.

SUMIF() vs. SUMIFS()

SUMIFS() hace el mismo trabajo que SUMIF(): 

• SUMIF() comprueba una sola condición. 

• SUMIFS() comprueba varias condiciones a la vez.

Aquí va una comparación rápida.

La sintaxis de SUMIFS() es:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

La diferencia con SUMIF() es que el sum_range va al final; en SUMIFS(), va al principio. 

Veámoslo con un ejemplo. 

En nuestra tabla, queremos el total de ventas de Apples, pero solo donde las ventas fueron superiores a 100. Son dos condiciones. 

A diferencia de SUMIF(), SUMIFS() puede con ello. Así: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Aquí, B2:B11 es el sum_range y va primero. Luego vienen los pares de condición: A2:A11 con Apples, y B2:B11 con >100. Excel comprueba ambas condiciones en cada fila y solo suma cuando las dos son verdaderas.

SUMIFS() comprueba varias condiciones a la vez. Imagen del autor.

SUMIF() vs. COUNTIF()

SUMIF() y COUNTIF() se parecen porque ambas comprueban una condición antes de hacer algo. Pero no hacen lo mismo.

• SUMIF() suma valores que cumplen una condición. 

• COUNTIF() cuenta cuántas celdas cumplen una condición. 

Aquí va una comparación rápida.

Una te da un total. La otra, un recuento. Veámoslo lado a lado con la tabla de ventas original.

Aquí queremos saber dos cosas sobre Apples. 

1. Cuánto hemos vendido en total
2. Cuántas veces aparece Apples en la lista

Para el total de ventas, usamos SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

Suma cada importe de venta donde el producto es Apples y nos da 490.

Para el recuento, usamos COUNTIF():

=COUNTIF(A2:A11, "Apples")

Cuenta cuántas filas contienen Apples y nos da 4.

COUNTIF() cuenta el número de apariciones en una celda. Imagen del autor.

COUNTIF() solo necesita un rango y un criterio, porque no hay nada que sumar. SUMIF(), en cambio, también necesita el rango de suma, ya que debe tomar de algún sitio los números que va a totalizar.

Errores comunes con SUMIF()

Incluso con una fórmula sencilla pueden colarse pequeños fallos. Estos son los más habituales y cómo solucionarlos.

Usar el rango equivocado

Ocurre cuando el rango y el rango de suma no están alineados fila a fila. Por ejemplo, tu rango es A2:A11, pero el de suma es B2:B10. Excel tiene una fila desajustada y los totales salen mal, a veces sin mostrar ningún error.

Solución: asegúrate de que ambos rangos empiecen y terminen en las mismas filas. Si tu rango es A2:A11, el rango de suma también debe ir de la fila 2 a la 11.

Olvidar el rango de suma

Imagina que quieres sumar la columna B, pero tu condición comprueba la columna A. Si escribes la fórmula solo con A2:A11 y el criterio, y omites el rango de suma, Excel asumirá que quieres sumar la columna A, no la B. El resultado será incorrecto.

Solución: incluye siempre el rango de suma cuando la columna que compruebas es distinta de la que sumas. Si ambas columnas son la misma, técnicamente puedes omitirlo, pero es preferible añadirlo para mayor claridad.

Sintaxis incorrecta en el criterio

Si escribes >100 sin comillas, dará error. Debe escribirse como ">100", con comillas dobles. Las comillas simples también provocan error.

Solución: cualquier criterio que incluya texto o símbolos de comparación necesita comillas. Si coincides con un número exacto (por ejemplo, 100 a secas), no hacen falta. En cuanto haya un símbolo o palabra en el criterio, las comillas son obligatorias.

Números almacenados como texto

A veces los números parecen números, pero Excel los trata como texto. Suele ocurrir al importar datos de otra fuente, como un archivo CSV o una exportación de sistema. 

Lo notarás si los números están alineados a la izquierda (como el texto) en lugar de a la derecha.

Cuando pasa esto, SUMIF() con comparaciones como ">100" no funcionará bien, porque Excel no compara textos como compara números reales.

Solución: convierte el texto en números. Ve a la pestaña Inicio > grupo Número y, en el desplegable, selecciona General o Número.

Espacios extra en valores de texto

Imagina que una celda tiene "Apples" y otra "Apples " con un espacio final. A simple vista son iguales. Para SUMIF() no lo son, y la fórmula no las contará como coincidencia.

Solución: envuelve tu fórmula con la función TRIM() para eliminar espacios extra antes de ejecutar. Así "Apples" y "Apples " se tratarán como lo mismo.

Buenas prácticas con SUMIF()

Hay algunos hábitos que facilitan trabajar con SUMIF(), sobre todo cuando la hoja crece. Te recomendamos lo siguiente:

• Usa referencias de celda en lugar de criterios fijos: Escribir "Apples" directamente funciona, pero obliga a editar la fórmula cada vez que quieras comprobar otra cosa. Señala a una celda y solo tendrás que cambiar su contenido; la fórmula permanece igual.

• Mantén los rangos del mismo tamaño: Tu rango y tu rango de suma deben cubrir siempre el mismo número de filas. Si uno va de la fila 2 a la 11 y el otro se queda en la 10, los totales no cuadrarán.

• Usa tablas de Excel en datos que crecen: Un rango normal como A2:A11 no incluye filas nuevas automáticamente. Convierte los datos en una tabla de Excel. Las tablas se expanden solas al añadir filas y tu SUMIF() crecerá con ellas sin cambios manuales.

• Prueba las fórmulas con ejemplos sencillos: Usa cinco o seis filas cuyo resultado ya conoces y confirma que la fórmula devuelve lo esperado. Así detectas errores pronto, antes de aplicarla a cientos de filas.

• Usa SUMIFS() cuando necesites más de una condición: En cuanto tengas que comprobar dos cosas a la vez, como un producto y un rango de fechas, cambia a SUMIFS(). Forzar SUMIF() suele llevar a apaños menos claros y más frágiles.

Conclusiones

SUMIF() es la forma más sencilla de sumar valores que cumplen una condición. Dale un rango, un criterio y un rango de suma, y hace el resto.

Empieza con condiciones simples, como coincidir con un nombre de producto o un número mayor que cierto valor. Cuando te sientas cómodo, los comodines y las referencias de celda harán la fórmula más flexible sin cambiar cómo funciona por debajo.

Si alguna vez necesitas comprobar dos cosas a la vez, es la señal para pasar a SUMIFS().