SUMIF() in Excel: een beginnersgids

Om SUMIF() in Excel te gebruiken, voer je =SUMIF(range, criteria, [sum_range]) in, waarbij range de cellen zijn die je wilt controleren, criteria de voorwaarde is waarop je wilt matchen, en sum_range de cellen zijn die je wilt optellen. Zo kun je waarden optellen die aan een specifieke voorwaarde voldoen zonder handmatig te filteren of rijen met de hand op te tellen.

In dit artikel bespreken we de syntaxis van SUMIF() in detail, lopen we door een stapsgewijs voorbeeld, vergelijken we SUMIF() met verwante functies zoals SUMIFS() en COUNTIF(), en behandelen we de fouten die de meeste beginners in de war brengen.

Wat is de functie SUMIF() in Excel?

SUMIF() is een Excel-functie die getallen optelt, maar alleen de getallen die voldoen aan een voorwaarde die jij instelt. Simpel gezegd: je vertelt Excel waar het naar moet zoeken, en het telt alleen de overeenkomende waarden op.

Een simpele SUM()-formule telt alles op in een bereik. Terwijl SUMIF() selectiever is. Het controleert elke cel aan de hand van jouw voorwaarde en telt alleen de cellen op die voldoen. Als een cel niet overeenkomt, slaat Excel die over.

Je kunt deze formule bijvoorbeeld gebruiken als:

• Je een winkel runt en wilt weten hoeveel je hebt verdiend met slechts één product.
• Je je uitgaven bijhoudt en het totaal wilt voor één categorie, zoals boodschappen of huur.
• Je een team beheert en de gewerkte uren van één medewerker wilt optellen.

SUMIF() is hiervoor perfect, omdat je niet geïnteresseerd bent in het totaal; je wilt slechts een deel daarvan.

SUMIF()-syntaxis

De SUMIF()-formule volgt deze structuur:

=SUMIF(range, criteria, [sum_range])

In deze syntaxis: 

• range: Dit is de groep cellen die Excel controleert op jouw voorwaarde. Hier kijkt Excel om te bepalen wat wel en niet overeenkomt. 

• criteria: Dit vertelt Excel waarnaar het in het bereik moet zoeken. Het kan een woord, een getal of een symbool zijn zoals ">100".

• sum_range (optioneel): Dit haalt de getallen op die moeten worden opgeteld zodra er een match is gevonden. Als je dit deel overslaat, telt Excel gewoon de waarden in het bereik zelf op.

Hier is een snel voorbeeld om te zien hoe de drie onderdelen samenwerken:

=SUMIF(A2:A11, "Apples", B2:B11)

In deze formule 

• A2:A10 is het bereik, want daar zoeken we naar Apples. 

• Apples is het criterium, het exacte woord dat we willen matchen. 

• B2:B10 is de sum_range, want daar staan de bijbehorende verkoopcijfers.

We controleren dus kolom A op Apples. Elke keer dat er een match is, wordt het overeenkomstige getal uit kolom B opgeteld.

Pas SUMIF() toe om waarden op te tellen op basis van een criterium. Afbeelding door de auteur.

Hoe gebruik je SUMIF() in Excel

Volg deze stappen om SUMIF() in Excel te gebruiken: 

Stap 1: Bepaal het bereik

We gebruiken de volgende dataset in ons voorbeeld: 

Dataset voor SUMIF(). Afbeelding door de auteur.

Selecteer het bereik waarop je de voorwaarde wilt toepassen. In dit geval willen we zoeken naar Apples, wat in de kolom Product staat, dus het bereik is A2:A11.

Stap 2: Stel het criterium in

Omdat we Apples willen, is het criterium Apples.

Je kunt het criterium rechtstreeks in de formule typen of verwijzen naar een cel die het bevat. Hier typen we het direct, dus moet het tussen aanhalingstekens staan omdat het tekst is.

Stap 3: Stel het sommeerbereik inHet sommeerbereik is waar de daadwerkelijke getallen staan. We willen de verkopen optellen, dus het sommeerbereik is B2:B11.

Het sommeerbereik hoeft niet dezelfde grootte of positie te hebben als het bereik waarin je zocht. Het moet alleen rij voor rij uitlijnen, zodat de waarde die SUMIF() optelt correspondeert met dezelfde rij waar het criterium matchte.

Nu ziet de formule er zo uit:

=SUMIF(A2:A11, "Apples", B2:B11)

Zo zal het werken:

• Rij 2 heeft Apples, dus 120 wordt opgeteld. 
• Rij 3 heeft Oranges, dus die wordt overgeslagen. 
• Rij 4 heeft weer Apples, dus 150 wordt opgeteld. 
• Evenzo rijen 8 en 11, dus 90 en 130 worden opgeteld

Het eindresultaat is 490

Tel de productverkopen op met SUMIF(). Afbeelding door de auteur.

Voorbeelden van SUMIF()

Laten we nu nog een paar situaties bekijken waarin SUMIF() handig kan zijn. Elk voorbeeld gebruikt een iets ander type criterium, dus we lopen ze één voor één door.

Getallen optellen die groter of kleiner zijn dan een waarde

Soms willen we niet een specifiek woord matchen. In plaats daarvan willen we alles pakken boven of onder een bepaald getal.

Om het totaal te krijgen van alle verkopen groter dan 100, schrijven we:

=SUMIF(B2:B11, ">100", B2:B11)

In onze tabel zijn de waarden groter dan 100 120, 150, 110 en 130. Tel die bij elkaar op en we krijgen 510.

Merk op dat het bereik en het sommeerbereik hier hetzelfde zijn. Dat komt omdat we de getallen zelf controleren, en ze niet matchen met een aparte kolom.

Voor verkopen kleiner dan 50 zou de formule zijn:

=SUMIF(B2:B11, "<50", B2:B11)

In onze tabel staat niets onder de 50, dus deze geeft 0 terug in plaats van een fout, gewoon geen matches.

Getallen optellen die voldoen aan groter-dan of kleiner-dan criteria. Afbeelding door de auteur.

Datums optellen

Datums werken net iets anders, omdat Excel ze als getallen opslaat. Elke datum is een serienummer dat telt vanaf een vast begintpunt. Daarom kunnen we vergelijkingssymbolen ook met datums gebruiken, net zoals met gewone getallen.

Stel dat we een kolom met besteldatums in kolom C hebben en we willen de totale verkoop na 1 maart 2026. De formule ziet er dan zo uit:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

In de onderstaande screenshot heb ik de overeenkomende datums en het totaal dat ze opleveren gemarkeerd.

We gebruiken hier de DATE()-functie in plaats van de datum direct te typen. Dit voorkomt fouten, omdat Excel datums verschillend kan lezen afhankelijk van je regionale instellingen.

Als we uitgaven in een specifieke maand willen, bijvoorbeeld maart 2026, hebben we twee voorwaarden nodig in plaats van één, omdat we een bereik controleren in plaats van één punt. 

Daar ligt eigenlijk de grens van SUMIF() — daar komen we zo op terug in de vergelijkingssectie.

Som van verkopen die voldoen aan het datumcriterium met SUMIF(). Afbeelding door de auteur.

Celverwijzingen als criteria gebruiken

Tot nu toe hebben we onze criteria rechtstreeks in de formule getypt, zoals "Apples" of ">100". Dat werkt prima, maar is niet erg flexibel. Als we een ander product willen controleren, moeten we elke keer de formule aanpassen.

Een betere aanpak is om in plaats daarvan te verwijzen naar een cel. Stel dat cel A6 het woord Grapes bevat. Onze formule ziet er dan zo uit:

=SUMIF(A2:A11, A6, B2:B11)

Dit telt alle waarden van Grapes op. Als we nu een ander product willen controleren, veranderen we alleen wat er in A6 staat; de formule hoeven we helemaal niet aan te raken.

Gebruik een celverwijzing in plaats van het criterium hard te coderen. Afbeelding door de auteur.

Hoe gebruik je wildcards met SUMIF()

Wildcards matchen het patroon als we de exacte tekst niet weten. Je weet bijvoorbeeld niet het exacte woord, maar wel dat het woord begint met B. 

SUMIF() ondersteunt twee wildcards: 

• * staat voor een willekeurig aantal tekens. Dat kan nul tekens zijn, één teken of honderd tekens.

• ? staat voor precies één teken.

Laten we zien hoe deze werken met onze producttabel.

Producten die beginnen met "A"

Stel dat we de totale verkoop willen voor elk product dat begint met A. In plaats van vier aparte formules te schrijven voor Apples, Apricots, Avocados en Almonds, handelt één wildcardformule ze allemaal af:

=SUMIF(A2:A8, "A*", B2:B8)

De asterisk na A vertelt de formule om A te matchen gevolgd door willekeurig wat. Elk product in onze tabel dat met A begint, wordt hier opgepikt. Dat is 120 plus 90 plus 60 plus 75, wat ons 345 oplevert.

Producten die beginnen met de letter A met de *-wildcard. Afbeelding door de auteur.

Namen die bepaalde tekst bevatten

Wildcards werken ook midden in een woord. Stel dat we elk product willen dat ergens in de naam “an” bevat. Dat pakt zowel Bananas als Oranges mee. 

Daarvoor wordt de formule:

=SUMIF(A2:A8, "*an*", B2:B8)

De asterisk aan beide kanten betekent dat het ons niet uitmaakt wat er vóór of na an komt. Zolang an ergens in de tekst voorkomt, telt het als match. 

Als we dit op onze tabel draaien, worden de verkopen van zowel Bananas als Oranges opgeteld, wat ons 175 oplevert. 

* vindt het product dat specifieke teken(s) bevat. Afbeelding door de auteur.

Wanneer ? gebruiken in plaats van *

? matcht precies één teken. Als we productcodes hebben en we alleen codes willen met precies één cijfer na de letter A, schrijven we:

=SUMIF(A2:A7, "A?", B2:B7)

Dit matcht A1, A2 en A3, maar niet A10 of A11, omdat die twee tekens na de A hebben, niet één.

Match het patroon met de ?-wildcard. Afbeelding door de auteur.

Dus:

• Gebruik * wanneer de tekstlengte varieert. 

• Gebruik ? wanneer je precies weet hoeveel tekens je kunt verwachten.

SUMIF() vs. SUMIFS()

SUMIFS() doet hetzelfde werk als SUMIF(): 

• SUMIF() controleert één voorwaarde tegelijk. 

• SUMIFS() controleert meerdere voorwaarden tegelijk.

Hier is een snelle vergelijking.

De syntaxis van SUMIFS() is:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Het verschil met SUMIF() is dat de sum_range daar als laatste komt. In SUMIFS() komt die eerst. 

Laten we dit met een voorbeeld bekijken. 

In onze verkooptabel willen we de totale verkoop voor Apples, maar alleen waar de verkoop boven de 100 lag. Dat zijn twee voorwaarden. 

In tegenstelling tot SUMIF() kan SUMIFS() dit aan. Zo doe je dat: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Hier is B2:B11 de sum_range, als eerste genoemd. Daarna volgen onze voorwaardelijke paren: A2:A11 met Apples, en B2:B11 met >100. Excel controleert beide voorwaarden voor elke rij en telt de verkoop alleen op wanneer beide waar zijn.

SUMIFS() controleert meerdere voorwaarden tegelijk. Afbeelding door de auteur.

SUMIF() vs. COUNTIF()

SUMIF() en COUNTIF() lijken op elkaar, omdat beide eerst een voorwaarde controleren. Maar ze doen niet hetzelfde.

• SUMIF() telt waarden op die aan een voorwaarde voldoen. 

• COUNTIF() telt hoeveel cellen aan een voorwaarde voldoen. 

Hier is een snelle vergelijking.

De één geeft je een totaal. De ander geeft je een aantal. Laten we dit naast elkaar zien met onze oorspronkelijke verkooptabel.

Hier willen we twee dingen weten over Apples. 

1. Hoeveel we in totaal hebben verkocht
2. Hoe vaak Apples in de lijst voorkomt

Voor de totale verkoop gebruiken we SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

Dit telt elk verkoopcijfer op waarbij het product Apples is, wat ons 490 geeft.

Voor het aantal gebruiken we COUNTIF():

=COUNTIF(A2:A11, "Apples")

Dit telt hoeveel rijen Apples bevatten, wat ons 4 geeft.

COUNIF() telt hoe vaak iets in een cel voorkomt. Afbeelding door de auteur.

COUNTIF() heeft alleen een bereik en een criterium nodig, omdat er niets op te tellen valt. Maar SUMIF() heeft ook een sommeerbereik nodig, omdat het ergens getallen vandaan haalt om ze op te tellen.

Veelgemaakte fouten met SUMIF()

Zelfs met een eenvoudige formule sluipen kleine fouten erin. Dit zijn de fouten die we het vaakst zien, met daarbij hoe je ze oplost.

Het verkeerde bereik gebruiken

Dit gebeurt wanneer het bereik en het sommeerbereik niet rij voor rij op elkaar aansluiten. Stel dat je bereik A2:A11 is, maar je sommeerbereik is B2:B10. Excel heeft nu één rij verschil en de totalen kloppen niet, soms zonder foutmelding.

Oplossing: zorg dat beide bereiken op dezelfde rijen beginnen en eindigen. Als je bereik A2:A11 is, moet je sommeerbereik ook van rij 2 tot en met rij 11 lopen.

Het sommeerbereik vergeten

Stel dat je kolom B wilt optellen, maar je voorwaarde controleert kolom A. Als je de formule schrijft met alleen A2:A11 en het criterium, en je laat het sommeerbereik weg, gaat Excel ervan uit dat je kolom A zelf wilt optellen, niet kolom B. Het resultaat klopt dan niet.

Oplossing: neem altijd het sommeerbereik op wanneer de kolom die je controleert anders is dan de kolom die je optelt. Als beide kolommen toevallig hetzelfde zijn, kun je het technisch gezien overslaan. Toch is het de moeite waard om het toe te voegen, voor de duidelijkheid.

Onjuiste criteriumsynthaxis

Schrijf >100 zonder aanhalingstekens en je krijgt een fout. Het moet worden geschreven als ">100", met dubbele aanhalingstekens eromheen. Enkele aanhalingstekens geven ook een fout.

Oplossing: elk criterium met tekst of vergelijkingssymbolen heeft aanhalingstekens nodig. Als je een exact getal matcht, zoals het getal 100 op zichzelf, heb je geen aanhalingstekens nodig. Zodra er een symbool of woord onderdeel is van het criterium, zijn aanhalingstekens vereist.

Getallen opgeslagen als tekst

Soms lijken getallen in een spreadsheet op getallen, maar behandelt Excel ze eigenlijk als tekst. Dit gebeurt meestal wanneer gegevens zijn geïmporteerd uit een andere bron, zoals een CSV-bestand of een systeemexport. 

Je merkt dit als de getallen links zijn uitgelijnd in plaats van rechts, wat Excel’s gebruikelijke weergave voor tekst is.

Als dit gebeurt, werkt SUMIF() met een vergelijking zoals ">100" niet correct, omdat Excel tekstwaarden niet op dezelfde manier kan vergelijken als echte getallen.

Oplossing: zet de tekst terug om naar getallen. Ga naar het tabblad Start > groep Getal en kies in de vervolgkeuzelijst Standaard of Getal.

Extra spaties in tekstwaarden

Stel dat in de ene cel "Apples" staat en in een andere "Apples " met een spatie aan het einde. Voor jou lijken ze hetzelfde. Voor SUMIF() niet, en de formule zal ze niet als match tellen.

Oplossing: omhul je formule met de TRIM()-functie om extra spaties te verwijderen voordat je deze uitvoert. Zo worden "Apples" en "Apples " eindelijk als hetzelfde behandeld.

Best practices voor SUMIF()

Een paar gewoontes maken SUMIF() makkelijker om mee te werken, vooral naarmate je spreadsheets groeien. Dit raden we aan.

• Gebruik celverwijzingen in plaats van hardgecodeerde criteria: "Apples" direct in een formule typen werkt, maar betekent dat je de formule elke keer moet aanpassen als je iets anders wilt controleren. Verwijs in plaats daarvan naar een cel en je hoeft alleen de waarde in die cel te wijzigen; de formule blijft ongewijzigd.

• Houd bereiken even groot: Je bereik en je sommeerbereik moeten altijd hetzelfde aantal rijen beslaan. Als de een van rij 2 tot rij 11 loopt en de ander stopt bij rij 10, komen de totalen niet goed uit.

• Gebruik Excel-tabellen voor uitbreidende datasets: Een gewoon bereik zoals A2:A11 neemt niet automatisch nieuwe rijen op als je gegevens groeien. Zet je gegevens om in een Excel-tabel om dit op te lossen. Tabellen breiden vanzelf uit wanneer je rijen toevoegt, en je SUMIF()-formule groeit mee; geen handmatige updates nodig.

• Test formules met simpele voorbeelden: Gebruik vijf of zes rijen waarvan je het antwoord al weet, en controleer of de formule teruggeeft wat je verwacht. Zo vang je fouten vroeg, voordat ze zich over honderden rijen verspreiden.

• Gebruik SUMIFS() wanneer meer dan één voorwaarde nodig is: Zodra je twee dingen tegelijk moet controleren, zoals een product en een datumbereik, stap je over op SUMIFS(). Proberen SUMIF() dat werk te laten doen leidt meestal tot omwegen die lastiger te lezen zijn en sneller stuk gaan.

Tot slot

SUMIF() is de eenvoudigste manier om waarden op te tellen die aan één voorwaarde voldoen. Geef het een bereik, een criterium en een sommeerbereik en de rest doet het zelf.

Begin met eenvoudige voorwaarden, zoals het matchen van een productnaam of een getal dat groter is dan een bepaalde waarde. Zodra dat vertrouwd voelt, maken wildcards en celverwijzingen de formule flexibeler zonder te veranderen hoe deze onder de motorkap werkt.

Als je ooit twee dingen tegelijk moet controleren, is dat het teken om door te gaan naar SUMIFS().