SUMIF() i Excel: En nybörjarguide

För att använda SUMIF() i Excel skriver du =SUMIF(range, criteria, [sum_range]), där range är cellerna som ska kontrolleras, criteria är villkoret som ska matchas och sum_range är cellerna som ska summeras. Det här låter dig summera värden som uppfyller ett specifikt villkor utan att manuellt filtrera eller lägga till rader för hand.

I den här artikeln går vi igenom SUMIF()-syntaxen i detalj, visar ett steg-för-steg-exempel, jämför SUMIF() med relaterade funktioner som SUMIFS() och COUNTIF(), och tar upp de misstag som förvirrar de flesta nybörjare.

Vad är funktionen SUMIF() i Excel?

SUMIF() är en Excel-funktion som summerar tal, men bara de som uppfyller ett villkor du anger. Enkelt uttryckt: du talar om för Excel vad det ska leta efter, och det lägger bara ihop de värden som matchar.

En enkel SUM()-formel lägger till allt i ett område. SUMIF() är däremot mer selektiv. Den kontrollerar varje cell mot ditt villkor och lägger bara till dem som passerar. Om en cell inte matchar hoppar Excel över den.

Till exempel kan du använda formeln när:

• Du driver en butik och vill veta hur mycket du tjänade på just en produkt.
• Du följer dina utgifter och vill ha totalen för en kategori, som mat eller hyra.
• Du leder ett team och vill summera arbetade timmar för en anställd.

SUMIF() passar perfekt i varje fall eftersom du inte är intresserad av totalen; du vill bara ha en delmängd av den.

SUMIF()-syntax

Formeln SUMIF() följer denna struktur:

=SUMIF(range, criteria, [sum_range])

I denna syntax: 

• range: Detta är cellområdet som Excel kontrollerar mot ditt villkor. Det är här Excel tittar för att avgöra vad som matchar och vad som inte gör det. 

• criteria: Talar om för Excel vad det ska leta efter i området. Det kan vara ett ord, ett tal eller en symbol som ">100".

• sum_range (valfritt): Här hämtas siffrorna som ska summeras när en matchning hittas. Om du hoppar över denna del summerar Excel helt enkelt värdena i själva området.

Här är ett snabbt exempel på hur de tre delarna samverkar:

=SUMIF(A2:A11, "Apples", B2:B11)

I denna formel 

• A2:A10 är området, eftersom det är där vi letar efter Apples. 

• Apples är kriteriet, det exakta ord vi vill matcha. 

• B2:B10 är sum_range, eftersom det är där de matchande försäljningssiffrorna finns.

Så vi kontrollerar kolumn A efter Apples. Varje gång det finns en matchning läggs motsvarande tal från kolumn B till.

Använd SUMIF() för att summera värden baserat på ett kriterium. Bild av författaren.

Hur du använder SUMIF() i Excel

För att använda SUMIF() i Excel gör du så här: 

Steg 1: Identifiera området

Vi använder följande dataset i vårt exempel: 

Dataset för SUMIF(). Bild av författaren.

Välj området där du vill tillämpa villkoret. I det här fallet vill vi söka efter Apples, vilket finns i kolumnen Product så området är A2:A11.

Steg 2: Ange kriteriet

Eftersom vi vill ha Apples är kriteriet Apples.

Du kan skriva kriteriet direkt i formeln eller referera till en cell som innehåller det. Här skriver vi det direkt, så det måste omges av citattecken eftersom det är text.

Steg 3: Ange summeringsområdetSummeringsområdet är där de faktiska siffrorna finns. Vi vill summera försäljning, så summeringsområdet är B2:B11.

Summeringsområdet behöver inte vara samma storlek eller position som området du sökte i. Det måste bara linjera rad för rad, så att värdet SUMIF() lägger till motsvarar samma rad där kriteriet matchade.

Nu ser formeln ut så här:

=SUMIF(A2:A11, "Apples", B2:B11)

Så här kommer den att fungera:

• Rad 2 har Apples, så 120 läggs till. 
• Rad 3 har Oranges, så den hoppas över. 
• Rad 4 har Apples igen, så 150 läggs till. 
• Likadant för raderna 8 och 11, så 90 och 130 läggs till

Slutresultatet är 490

Summera produkternas försäljning med SUMIF(). Bild av författaren.

Exempel på SUMIF()

Nu tittar vi på några fler situationer där SUMIF() kan vara till hjälp. Var och en använder en lite annan typ av kriterium, så vi går igenom dem ett i taget.

Summera tal större än eller mindre än ett värde

Ibland vill vi inte matcha ett specifikt ord. Istället vill vi fånga allt över eller under ett visst tal.

För att få totalen av all försäljning större än 100 skriver vi:

=SUMIF(B2:B11, ">100", B2:B11)

I vår tabell är värdena större än 100 120, 150, 110 och 130. Lägger vi ihop dem får vi 510.

Observera att området och summeringsområdet är samma här. Det beror på att vi kontrollerar själva siffrorna, inte matchar dem mot en separat kolumn.

För försäljning mindre än 50 skulle formeln vara:

=SUMIF(B2:B11, "<50", B2:B11)

I vår tabell är ingenting under 50, så denna returnerar 0 istället för ett fel – bara inga träffar.

Summera tal som matchar större än- eller mindre än-kriterier. Bild av författaren.

Summera datum

Datum fungerar lite annorlunda eftersom Excel lagrar dem som tal. Varje datum är ett serienummer som räknas från en fast startpunkt. Därför kan vi använda jämförelsesymboler med datum också, på samma sätt som vi gjorde med vanliga tal.

Säg att vi har en kolumn med orderdatum i kolumn C och vi vill ha den totala försäljningen efter 1 mars 2026. Formeln skulle se ut så här:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

I skärmdumpen nedan har jag markerat de matchande datumen och totalen de summerar till.

Vi använder funktionen DATE() här istället för att skriva datumet direkt. Detta undviker fel, eftersom Excel kan läsa datum olika beroende på dina regioninställningar.

Om vi ville ha utgifter under en specifik månad, säg mars 2026, skulle vi behöva två villkor istället för ett, eftersom vi kontrollerar ett intervall snarare än en enskild punkt. 

Det är faktiskt där SUMIF() når sin gräns — vi kommer till det i jämförelsesektionen som kommer strax.

Summa av försäljning som matchar datakriteriet med SUMIF(). Bild av författaren.

Använd cellreferenser som kriterier

Hittills har vi skrivit våra kriterier direkt i formeln, som "Apples" eller ">100". Det fungerar fint, men är inte särskilt flexibelt. Om vi vill kontrollera en annan produkt måste vi redigera formeln varje gång.

Ett bättre sätt är att referera till en cell istället. Anta att cell A6 innehåller ordet Grapes. Vår formel skulle se ut så här:

=SUMIF(A2:A11, A6, B2:B11)

Detta summerar alla värden för Grapes. Nu, om vi vill kontrollera en annan produkt, ändrar vi bara vad som står i A6; vi behöver inte röra formeln alls.

Använd cellreferens istället för att hårdkoda kriteriet. Bild av författaren.

Hur man använder jokertecken med SUMIF()

Jokertecken matchar mönster när vi inte vet exakt text. Till exempel, du vet inte det exakta ordet men vet att ordet börjar på B. 

SUMIF() stöder två jokertecken: 

• * står för valfritt antal tecken. Det kan vara noll tecken, ett tecken eller hundra tecken.

• ? står för exakt ett tecken.

Låt oss se hur dessa fungerar med vår produkttabell.

Produkter som börjar med "A"

Säg att vi vill ha den totala försäljningen för varje produkt som börjar på A. Istället för att skriva fyra separata formler för Apples, Apricots, Avocados och Almonds hanterar en jokerteckenformel alla:

=SUMIF(A2:A8, "A*", B2:B8)

Asterisken efter A talar om för formeln att matcha A följt av vad som helst. Varje produkt i vår tabell som börjar på A fångas här. Det är 120 plus 90 plus 60 plus 75, vilket ger 345.

Produkter som börjar på bokstaven A med jokertecknet *. Bild av författaren.

Namn som innehåller viss text

Jokertecken fungerar också i mitten av ett ord. Säg att vi vill ha varje produkt som innehåller ”an” någonstans i namnet. Det fångar både Bananas och Oranges. 

För detta blir formeln:

=SUMIF(A2:A8, "*an*", B2:B8)

Asterisk på båda sidor betyder att vi inte bryr oss om vad som kommer före eller efter an. Så länge an finns någonstans i texten räknas det som en match. 

Kör vi detta på vår tabell summeras försäljningen från både Bananas och Oranges, vilket ger 175. 

* hittar produkten som innehåller specifika tecken. Bild av författaren.

När ska man använda ? istället för *

? matchar exakt ett tecken. Om vi har produktkoder och bara vill ha koder med exakt en siffra efter bokstaven A skriver vi:

=SUMIF(A2:A7, "A?", B2:B7)

Detta matchar A1, A2 och A3, men inte A10 eller A11, eftersom de har två tecken efter A, inte ett.

Matcha mönstret med jokertecknet ?. Bild av författaren.

Alltså:

• Använd * när textlängden varierar. 

• Använd ? när du vet exakt hur många tecken du kan förvänta dig.

SUMIF() vs. SUMIFS()

SUMIFS() gör samma jobb som SUMIF(): 

• SUMIF() kontrollerar ett villkor åt gången. 

• SUMIFS() kontrollerar flera villkor samtidigt.

Här är en snabb jämförelse.

Syntaxen för SUMIFS() är:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Skillnaden mot SUMIF() är att sum_range kommer sist. I SUMIFS() kommer det först. 

Låt oss se detta med ett exempel. 

I vår försäljningstabell vill vi ha total försäljning för Apples, men bara där försäljningen var över 100. Det är två villkor. 

Till skillnad från SUMIF() kan SUMIFS() hantera det. Så här: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Här är B2:B11 sum_range, listat först. Sedan har vi våra villkorspar: A2:A11 med Apples och B2:B11 med >100. Excel kontrollerar båda villkoren för varje rad och lägger bara till försäljningssiffran när båda är sanna.

SUMIFS() kontrollerar flera villkor samtidigt. Bild av författaren.

SUMIF() vs. COUNTIF()

SUMIF() och COUNTIF() ser likadana ut, eftersom båda kontrollerar ett villkor innan de gör något. Men de gör inte samma jobb.

• SUMIF() summerar värden som matchar ett villkor. 

• COUNTIF() räknar hur många celler som matchar ett villkor. 

Här är en snabb jämförelse.

Den ena ger dig en summa. Den andra ger dig ett antal. Låt oss se detta sida vid sida med vår ursprungliga försäljningstabell.

Här vill vi veta två saker om Apples. 

1. Hur mycket sålde vi totalt
2. Hur många gånger förekommer Apples i listan?

För den totala försäljningen använder vi SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

Detta summerar varje försäljningssiffra där produkten är Apples och ger 490.

För antalet använder vi COUNTIF():

=COUNTIF(A2:A11, "Apples")

Detta räknar hur många rader som har Apples i sig, och ger 4.

COUNIF() räknar hur många förekomster som visas i en cell. Bild av författaren.

COUNTIF() behöver bara ett område och ett kriterium, eftersom det inte finns något att summera. Men SUMIF() behöver också ett summeringsområde, eftersom den hämtar tal någonstans ifrån för att summera dem.

Vanliga misstag med SUMIF()

Även med en enkel formel smyger sig små fel in. Här är de misstag vi oftast ser, tillsammans med hur man löser dem.

Att använda fel område

Detta händer när området och summeringsområdet inte linjerar rad för rad. Säg att ditt område är A2:A11, men ditt summeringsområde är B2:B10. Excel har nu en rad som inte stämmer överens, och summorna blir fel, ibland utan något felmeddelande alls.

Så här löser du det: se till att båda områdena börjar och slutar på samma rader. Om ditt område är A2:A11, ska ditt summeringsområde också gå från rad 2 till rad 11.

Att glömma summeringsområdet

Säg att du vill summera kolumn B, men ditt villkor kontrollerar kolumn A. Om du skriver formeln med bara A2:A11 och kriteriet, och utelämnar summeringsområdet, antar Excel att du vill summera kolumn A självt, inte kolumn B. Resultatet blev fel.

Så här löser du det: inkludera alltid summeringsområdet när kolumnen du kontrollerar skiljer sig från kolumnen du summerar. Om båda kolumnerna råkar vara desamma kan du tekniskt sett hoppa över det. Det är ändå värt att lägga till, bara för tydlighetens skull.

Felaktig kriteriesyntax

Skriv >100 utan citattecken och det ger ett fel. Det måste skrivas som ">100", med dubbla citattecken runt. Enkla citattecken ger också fel.

Så här löser du det: alla kriterier som använder text eller jämförelsesymboler behöver citattecken. Om du matchar ett exakt tal, som talet 100 i sig, behöver du inte citattecken. Så fort en symbol eller ett ord ingår i kriteriet krävs citattecken.

Tal lagrade som text

Ibland ser tal i ett kalkylblad ut som tal, men Excel behandlar dem faktiskt som text. Detta händer oftast när data importeras från en annan källa, som en CSV-fil eller en systemexport. 

Du märker detta om talen är vänsterjusterade istället för högerjusterade, vilket är Excels vanliga sätt att visa text.

När detta händer fungerar SUMIF() med en jämförelse som ">100" inte korrekt, eftersom Excel inte kan jämföra textvärden på samma sätt som faktiska tal.

Så här löser du det: konvertera texten tillbaka till tal. Gå till fliken Start > gruppen Tal och välj Allmänt eller Tal i rullgardinsmenyn.

Extra blanksteg i textvärden

Säg att en cell har "Apples" och en annan har "Apples " med ett avslutande blanksteg. För ögat ser de likadana ut. För SUMIF() gör de inte det, och formeln kommer inte räkna dem som en matchning.

Så här löser du det: kapsla in din formel i funktionen TRIM() för att ta bort extra blanksteg innan du kör den. Då behandlas "Apples" och "Apples " äntligen som samma sak.

Bästa praxis för SUMIF()

Några vanor gör SUMIF() lättare att arbeta med, särskilt när dina kalkylblad växer. Här är våra rekommendationer.

• Använd cellreferenser istället för hårdkodade kriterier: Att skriva "Apples" direkt i en formel fungerar, men det innebär att du måste redigera formeln varje gång du vill kontrollera något annat. Peka på en cell istället, så behöver du bara ändra värdet i den cellen; formeln förblir orörd.

• Håll områden lika stora: Ditt område och ditt summeringsområde ska alltid omfatta samma antal rader. Om det ena går från rad 2 till rad 11 och det andra stannar vid rad 10 kommer summorna inte att linjera korrekt.

• Använd Excel-tabeller för växande dataset: Ett vanligt område som A2:A11 inkluderar inte automatiskt nya rader när dina data växer. Konvertera dina data till en Excel-tabell för att lösa detta. Tabeller expanderar då av sig själva när du lägger till rader, och din SUMIF()-formel växer i takt med det; inga manuella uppdateringar behövs.

• Testa formler med enkla exempel: Använd fem eller sex rader där du redan vet svaret och bekräfta att formeln ger vad du förväntar dig. Detta fångar fel tidigt, innan de sprids över hundratals rader.

• Använd SUMIFS() när mer än ett villkor behövs: Så fort du behöver kontrollera två saker samtidigt, som en produkt och ett datumintervall, byt till SUMIFS(). Att försöka tvinga SUMIF() att göra det jobbet leder oftast till lösningar som är svårare att läsa och lättare att förstöra.

Avslutande tankar

SUMIF() är det enklaste sättet att summera värden som uppfyller ett villkor. Ge den ett område, ett kriterium och ett summeringsområde, så sköter den resten.

Börja med enkla villkor, såsom att matcha ett produktnamn eller ett tal som är större än ett visst värde. När det känns bekvämt gör jokertecken och cellreferenser formeln mer flexibel utan att ändra hur den fungerar under ytan.

Om du någon gång märker att du behöver kontrollera två saker samtidigt, är det ett tecken på att gå vidare till SUMIFS().