SUMIF() in Excel: Der Einsteiger-Guide

Um SUMIF() in Excel zu verwenden, gib =SUMIF(range, criteria, [sum_range]) ein, wobei range der zu prüfende Zellbereich ist, criteria die zu erfüllende Bedingung und sum_range der zu summierende Bereich. So kannst du Werte, die eine bestimmte Bedingung erfüllen, addieren – ohne manuell zu filtern oder Zeilen zusammenzurechnen.

In diesem Artikel zerlegen wir die SUMIF()-Syntax im Detail, gehen ein Schritt-für-Schritt-Beispiel durch, vergleichen SUMIF() mit verwandten Funktionen wie SUMIFS() und COUNTIF() und schauen uns typische Anfängerfehler an.

Was macht die SUMIF()-Funktion in Excel?

SUMIF() ist eine Excel-Funktion, die Zahlen addiert – aber nur die, die eine von dir festgelegte Bedingung erfüllen. Einfach gesagt: Du sagst Excel, wonach es suchen soll, und es addiert nur die passenden Werte.

Eine einfache SUM()-Formel addiert alles in einem Bereich. SUMIF() ist dagegen selektiv: Jede Zelle wird gegen die Bedingung geprüft und nur passende Werte werden addiert. Passt eine Zelle nicht, wird sie übersprungen.

Zum Beispiel kannst du diese Formel verwenden, wenn:

• Du einen Laden betreibst und wissen willst, wie viel Umsatz nur ein bestimmtes Produkt gebracht hat.
• Du deine Ausgaben trackst und die Summe für eine Kategorie wie Lebensmittel oder Miete brauchst.
• Du ein Team leitest und die geleisteten Stunden einer bestimmten Person addieren willst.

SUMIF() ist perfekt dafür, weil du nicht die Gesamtsumme willst, sondern nur einen gezielten Ausschnitt.

SUMIF()-Syntax

Die SUMIF()-Formel hat diese Struktur:

=SUMIF(range, criteria, [sum_range])

In dieser Syntax: 

• range: Der Zellbereich, den Excel auf deine Bedingung prüft. Hier entscheidet Excel, was passt und was nicht. 

• criteria: Sagt Excel, wonach im Bereich gesucht werden soll. Das kann ein Wort, eine Zahl oder ein Ausdruck wie ">100" sein.

• sum_range (optional): Hier stehen die Zahlen, die addiert werden, sobald es einen Treffer gibt. Wenn du das weglässt, summiert Excel direkt die Werte im range.

Ein schnelles Beispiel, wie die drei Teile zusammenspielen:

=SUMIF(A2:A11, "Apples", B2:B11)

In dieser Formel 

• A2:A10 ist der Bereich, in dem wir nach Apples suchen. 

• Apples ist das Kriterium – das genaue Wort, das wir abgleichen. 

• B2:B10 ist die sum_range, denn dort stehen die passenden Verkaufszahlen.

Wir prüfen also Spalte A auf Apples. Bei jedem Treffer wird der entsprechende Wert aus Spalte B addiert.

SUMIF() anwenden, um Werte nach einem Kriterium zu summieren. Bild: Autorin.

So nutzt du SUMIF() in Excel

So verwendest du SUMIF() in Excel Schritt für Schritt: 

Schritt 1: Bereich festlegen

Wir nutzen folgendes Datenset im Beispiel: 

Datensatz für SUMIF(). Bild: Autorin.

Wähle den Bereich, in dem die Bedingung geprüft wird. Hier suchen wir nach Apples, das steht in der Spalte Product, also ist der Bereich A2:A11.

Schritt 2: Kriterium festlegen

Wir wollen Apples, also lautet das Kriterium Apples.

Du kannst das Kriterium direkt in die Formel schreiben oder auf eine Zelle verweisen, die es enthält. Hier tippen wir es direkt – als Text muss es in Anführungszeichen stehen.

Schritt 3: Summenbereich festlegenDer Summenbereich enthält die eigentlichen Zahlen. Wir addieren Verkäufe, also ist der Summenbereich B2:B11.

Der Summenbereich muss nicht dieselbe Größe oder Position haben wie der Suchbereich. Er muss nur zeilenweise ausgerichtet sein, damit der addierte Wert zur Zeile passt, in der das Kriterium erfüllt wurde.

Jetzt sieht die Formel so aus:

=SUMIF(A2:A11, "Apples", B2:B11)

So funktioniert sie:

• Zeile 2 hat Apples, also wird 120 addiert. 
• Zeile 3 hat Oranges, wird also übersprungen. 
• Zeile 4 hat wieder Apples, also werden 150 addiert. 
• Ebenso die Zeilen 8 und 11, also kommen 90 und 130 dazu.

Das Endergebnis ist 490

Produktsales mit SUMIF() summieren. Bild: Autorin.

SUMIF()-Beispiele

Schauen wir uns weitere Situationen an, in denen SUMIF() hilfreich ist. Jedes Beispiel nutzt einen leicht anderen Kriterientyp – wir gehen sie einzeln durch.

Zahlen größer/kleiner als ein Wert summieren

Manchmal suchen wir kein bestimmtes Wort, sondern alles über oder unter einem Grenzwert.

Um die Summe aller Verkäufe größer als 100 zu erhalten, schreiben wir:

=SUMIF(B2:B11, ">100", B2:B11)

In unserer Tabelle sind die Werte größer als 100: 120, 150, 110 und 130. Zusammen ergibt das 510.

Beachte: Bereich und Summenbereich sind hier identisch, weil wir direkt die Zahlen prüfen – nicht gegen eine andere Spalte abgleichen.

Für Verkäufe kleiner als 50 lautet die Formel:

=SUMIF(B2:B11, "<50", B2:B11)

In unserer Tabelle liegt nichts unter 50. Die Formel liefert daher 0 – kein Fehler, nur keine Treffer.

Zahlen nach Größer- oder Kleiner-als-Kriterien summieren. Bild: Autorin.

Daten nach Datum summieren

Mit Datumswerten ist es etwas anders, da Excel sie als Zahlen speichert. Jedes Datum ist eine fortlaufende Zahl ab einem Fixpunkt. Darum funktionieren Vergleichsoperatoren bei Daten genauso wie bei Zahlen.

Angenommen, die Bestelldaten stehen in Spalte C und wir wollen alle Verkäufe nach dem 1. März 2026. Die Formel sieht so aus:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

Im Screenshot unten sind die passenden Daten und die daraus resultierende Summe markiert.

Wir verwenden hier die DATE()-Funktion statt das Datum direkt zu tippen. So vermeidest du Fehler, weil Excel je nach Regionseinstellung Daten unterschiedlich interpretiert.

Wenn wir Ausgaben für einen bestimmten Monat wollen, z. B. März 2026, brauchen wir zwei Bedingungen statt einer, da wir einen Bereich und keinen einzelnen Stichtag prüfen. 

Hier stößt SUMIF() an seine Grenze – mehr dazu gleich im Vergleichsteil.

Summe der Verkäufe passend zum Datumskriterium mit SUMIF(). Bild: Autorin.

Zellbezüge als Kriterien verwenden

Bisher haben wir Kriterien direkt in die Formel geschrieben, etwa "Apples" oder ">100". Das funktioniert, ist aber unflexibel – für jedes andere Produkt müsstest du die Formel anpassen.

Besser ist es, stattdessen auf eine Zelle zu verweisen. Angenommen, Zelle A6 enthält Grapes. Die Formel lautet dann:

=SUMIF(A2:A11, A6, B2:B11)

So summierst du alle Werte für Grapes. Willst du ein anderes Produkt prüfen, änderst du nur den Inhalt von A6 – die Formel bleibt unverändert.

Zellbezug statt hart codiertem Kriterium verwenden. Bild: Autorin.

Wildcards mit SUMIF() nutzen

Wildcards helfen, wenn du den genauen Text nicht kennst, aber ein Muster. Zum Beispiel weißt du nur, dass das Wort mit B beginnt. 

SUMIF() unterstützt zwei Wildcards: 

• * steht für beliebig viele Zeichen – null, eins oder ganz viele.

• ? steht für genau ein Zeichen.

So funktionieren sie in unserer Produkttabelle.

Produkte, die mit "A" beginnen

Wir wollen die Verkäufe aller Produkte, die mit A anfangen. Statt vier separater Formeln für Apples, Apricots, Avocados und Almonds reicht eine Wildcard-Formel:

=SUMIF(A2:A8, "A*", B2:B8)

Das Sternchen nach A bedeutet: "A" gefolgt von beliebigem Text. Alle Produkte in unserer Tabelle, die mit A beginnen, werden erfasst. Das sind 120 plus 90 plus 60 plus 75, also 345.

Produkte, die mit A beginnen, mit dem *-Wildcard finden. Bild: Autorin.

Namen mit bestimmtem Textteil

Wildcards funktionieren auch in der Mitte eines Wortes. Wir wollen alle Produkte, die irgendwo „an“ enthalten – das trifft auf Bananas und Oranges zu. 

Dafür lautet die Formel:

=SUMIF(A2:A8, "*an*", B2:B8)

Die Sternchen links und rechts bedeuten: Es ist egal, was vor oder nach an steht. Hauptsache, an kommt irgendwo im Text vor.

In unserer Tabelle werden so die Verkäufe von Bananas und Oranges addiert – das ergibt 175. 

* findet Produkte mit bestimmten Zeichenfolgen. Bild: Autorin.

Wann ? statt * verwenden

? steht für genau ein Zeichen. Wenn wir Produktcodes haben und nur Codes wollen, bei denen auf den Buchstaben A genau eine Ziffer folgt, schreiben wir:

=SUMIF(A2:A7, "A?", B2:B7)

Das passt auf A1, A2 und A3, aber nicht auf A10 oder A11, da dort zwei Zeichen auf das A folgen.

Muster mit dem ?-Wildcard abgleichen. Bild: Autorin.

Also:

• Verwende *, wenn die Textlänge variieren kann. 

• Verwende ?, wenn du genau weißt, wie viele Zeichen zu erwarten sind.

SUMIF() vs. SUMIFS()

SUMIFS() erledigt denselben Job wie SUMIF(): 

• SUMIF() prüft eine einzige Bedingung. 

• SUMIFS() prüft mehrere Bedingungen gleichzeitig.

Hier ein schneller Vergleich.

Die Syntax von SUMIFS() ist:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Der Unterschied zu SUMIF(): Bei SUMIF() steht die sum_range am Ende, bei SUMIFS() am Anfang. 

Schauen wir das am Beispiel an. 

In unserer Verkaufstabelle wollen wir die Summe für Apples – aber nur, wenn der Verkauf über 100 lag. Das sind zwei Bedingungen. 

Anders als SUMIF() kann SUMIFS() das. So geht’s: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Hier ist B2:B11 der Summenbereich und steht zuerst. Dann folgen die Bedingungen als Paare: A2:A11 mit Apples und B2:B11 mit >100. Excel prüft pro Zeile beide Bedingungen und addiert nur, wenn beide wahr sind.

SUMIFS() prüft mehrere Bedingungen gleichzeitig. Bild: Autorin.

SUMIF() vs. COUNTIF()

SUMIF() und COUNTIF() wirken ähnlich, weil beide zuerst eine Bedingung prüfen. Sie haben aber unterschiedliche Aufgaben.

• SUMIF() addiert Werte, die ein Kriterium erfüllen. 

• COUNTIF() zählt, wie viele Zellen ein Kriterium erfüllen. 

Hier ein schneller Vergleich.

Die eine Funktion liefert dir eine Summe, die andere eine Anzahl. Sehen wir uns das anhand der ursprünglichen Verkaufstabelle an.

Wir wollen zwei Dinge zu Apples wissen. 

1. Wie viel haben wir insgesamt verkauft?
2. Wie oft kommt Apples in der Liste vor?

Für die Summe nutzen wir SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

Das addiert alle Verkaufswerte, bei denen das Produkt Apples ist – Ergebnis 490.

Für die Anzahl nutzen wir COUNTIF():

=COUNTIF(A2:A11, "Apples")

Das zählt, in wie vielen Zeilen Apples steht – Ergebnis 4.

COUNTIF() zählt, wie oft ein Eintrag vorkommt. Bild: Autorin.

COUNTIF() braucht nur Bereich und Kriterium, da nichts addiert wird. SUMIF() benötigt zusätzlich den Summenbereich, weil Werte zusammengezählt werden.

Häufige SUMIF()-Fehler

Auch bei einfachen Formeln schleichen sich kleine Fehler ein. Das sind die häufigsten – und so behebst du sie.

Falscher Bereich

Das passiert, wenn Suchbereich und Summenbereich nicht zeilenweise übereinstimmen. Wenn dein Bereich z. B. A2:A11 ist, der Summenbereich aber B2:B10, gibt es eine Zeile Versatz – die Summe ist falsch, oft ohne Fehlermeldung.

Lösung: Beide Bereiche müssen in derselben Zeile starten und enden. Ist dein Bereich A2:A11, sollte der Summenbereich ebenfalls Zeile 2 bis 11 umfassen.

Summenbereich vergessen

Du willst Spalte B addieren, prüfst aber ein Kriterium in Spalte A. Wenn du die Formel nur mit A2:A11 und dem Kriterium schreibst und den Summenbereich weglässt, nimmt Excel an, dass Spalte A summiert werden soll – nicht B. Das Ergebnis ist falsch.

Lösung: Immer einen Summenbereich angeben, wenn die zu prüfende Spalte eine andere ist als die zu summierende. Sind beide identisch, kannst du ihn weglassen – klarer ist es trotzdem, ihn anzugeben.

Falsche Kriteriensyntax

Schreibst du >100 ohne Anführungszeichen, gibt es einen Fehler. Es muss ">100" mit doppelten Anführungszeichen sein. Einzelne Anführungszeichen erzeugen ebenfalls Fehler.

Lösung: Alle Kriterien mit Text oder Vergleichsoperatoren brauchen Anführungszeichen. Prüfst du eine reine Zahl wie 100, sind keine Anführungszeichen nötig. Sobald ein Symbol oder Wort dabei ist, sind sie Pflicht.

Zahlen als Text gespeichert

Manchmal sehen Zahlen wie Zahlen aus, werden aber als Text behandelt – oft nach Importen aus einer CSV-Datei oder einem Systemexport. 

Du erkennst das oft daran, dass die Zahlen linksbündig stehen – Excels Standard für Text.

In diesem Fall funktionieren Vergleiche wie ">100" in SUMIF() nicht korrekt, da Excel Text nicht wie echte Zahlen vergleicht.

Lösung: Konvertiere den Text zurück in Zahlen. Registerkarte Start > Gruppe Zahl und im Dropdown Standard oder Zahl wählen.

Zusätzliche Leerzeichen in Texten

Steht in einer Zelle "Apples" und in einer anderen "Apples " mit nachgestelltem Leerzeichen, sehen beide gleich aus – für SUMIF() sind sie verschieden und werden nicht als Treffer gezählt.

Lösung: Nutze die TRIM()-Funktion, um überflüssige Leerzeichen vorab zu entfernen. So werden "Apples" und "Apples " endlich gleich behandelt.

Best Practices für SUMIF()

Mit ein paar Gewohnheiten arbeitest du entspannter mit SUMIF() – besonders bei wachsenden Tabellen. Unsere Empfehlungen:

• Zellbezüge statt hart codierter Kriterien verwenden: „Apples“ direkt in die Formel zu tippen, funktioniert, aber zwingt zu Formeländerungen. Verweise lieber auf eine Zelle – dann änderst du nur deren Inhalt, die Formel bleibt gleich.

• Bereiche gleich groß halten: Suchbereich und Summenbereich sollten immer gleich viele Zeilen umfassen. Sonst stimmen die Ergebnisse nicht.

• Excel-Tabellen für wachsende Datensätze nutzen: Ein normaler Bereich wie A2:A11 erweitert sich nicht automatisch. Wandle die Daten in eine Excel-Tabelle um: Sie wächst beim Hinzufügen von Zeilen mit – und deine SUMIF()-Formel gleich mit.

• Formeln mit kleinen Beispielen testen: Nimm fünf bis sechs Zeilen mit bekanntem Ergebnis und prüfe, ob die Formel das Erwartete liefert. So fängst du Fehler früh ab.

• SUMIFS() verwenden, sobald mehr als eine Bedingung nötig ist: Sobald du zwei Dinge gleichzeitig prüfen musst, z. B. Produkt und Datumsbereich, wechsle zu SUMIFS(). SUMIF() dafür zu verbiegen, führt zu schwer lesbaren Workarounds.

Fazit

SUMIF() ist der einfachste Weg, Werte nach genau einer Bedingung zu addieren. Bereich, Kriterium und Summenbereich angeben – den Rest übernimmt Excel.

Starte mit einfachen Bedingungen, etwa einem Produktnamen oder „größer als“-Vergleichen. Wenn das sitzt, machen Wildcards und Zellbezüge die Formel flexibler, ohne die Logik zu ändern.

Sobald du zwei Bedingungen gleichzeitig prüfen musst, ist das dein Signal für SUMIFS().