SUMIF() no Excel: guia para iniciantes

Para usar SUMIF() no Excel, digite =SUMIF(range, criteria, [sum_range]), onde range é o intervalo a verificar, criteria é a condição a corresponder e sum_range é o intervalo a somar. Isso permite somar apenas os valores que atendem a uma condição específica, sem precisar filtrar manualmente ou somar linha por linha.

Neste artigo, vamos detalhar a sintaxe de SUMIF(), passar por um exemplo passo a passo, comparar SUMIF() com funções relacionadas como SUMIFS() e COUNTIF(), e cobrir os erros que mais confundem iniciantes.

O que é a função SUMIF() no Excel?

SUMIF() é uma função do Excel que soma números, mas apenas aqueles que atendem à condição que você definir. Em outras palavras, você diz ao Excel o que procurar e ele soma só os valores correspondentes.

Uma fórmula SUM() simples soma tudo em um intervalo. Já SUMIF() é mais seletiva. Ela verifica célula por célula com base na sua condição e soma apenas as que passarem. Se a célula não corresponder, o Excel ignora.

Por exemplo, você pode usar esta fórmula quando:

• Tem uma loja e quer saber quanto faturou com um único produto.
• Controla seus gastos e quer o total de uma categoria, como mercado ou aluguel.
• Gerencia um time e quer somar as horas trabalhadas por um funcionário.

SUMIF() é perfeita para cada caso, porque você não quer o total geral; quer apenas um recorte dele.

Sintaxe de SUMIF()

A fórmula SUMIF() segue esta estrutura:

=SUMIF(range, criteria, [sum_range])

Nesta sintaxe: 

• range: é o conjunto de células que o Excel verifica para a sua condição. É onde o Excel decide o que corresponde e o que não corresponde. 

• criteria: indica ao Excel o que procurar no intervalo. Pode ser uma palavra, um número ou um símbolo como ">100".

• sum_range (opcional): é de onde vêm os números a somar quando há correspondência. Se você pular esta parte, o Excel soma os valores do próprio range.

Veja um exemplo rápido para entender como as três partes funcionam juntas:

=SUMIF(A2:A11, "Apples", B2:B11)

Nesta fórmula, 

• A2:A10 é o range, pois é onde estamos procurando Apples. 

• Apples é o criteria, a palavra exata que queremos corresponder. 

• B2:B10 é o sum_range, pois ali estão os números de vendas correspondentes.

Então, verificamos a coluna A por Apples. Sempre que houver correspondência, o número correspondente da coluna B é somado.

Aplique SUMIF() para somar valores com base em um critério. Imagem: Autor.

Como usar SUMIF() no Excel

Para usar SUMIF() no Excel, siga estes passos: 

Passo 1: identifique o intervalo

Usaremos o seguinte conjunto de dados no exemplo: 

Dataset para SUMIF(). Imagem: Autor.

Selecione o intervalo onde você vai aplicar a condição. Neste caso, queremos procurar por Apples, que está na coluna Product, então o intervalo é A2:A11.

Passo 2: defina o critério

Como queremos Apples, o critério é Apples.

Você pode digitar o critério diretamente na fórmula ou referenciar uma célula que o contenha. Aqui, estamos digitando diretamente, então precisa estar entre aspas, já que é texto.

Passo 3: defina o intervalo de somaO intervalo de soma é onde estão os números de fato. Queremos somar as vendas, então o intervalo de soma é B2:B11.

O intervalo de soma não precisa ter o mesmo tamanho ou estar na mesma posição do intervalo que você pesquisou. Ele só precisa alinhar linha a linha, para que o valor que SUMIF() soma corresponda à mesma linha em que o critério deu match.

Agora, a fórmula fica assim:

=SUMIF(A2:A11, "Apples", B2:B11)

É assim que ela funciona:

• A linha 2 tem Apples, então 120 é somado. 
• A linha 3 tem Oranges, então é ignorada. 
• A linha 4 tem Apples de novo, então 150 é somado. 
• Da mesma forma, as linhas 8 e 11, então 90 e 130 são somados

O resultado final é 490

Some as vendas do produto usando SUMIF(). Imagem: Autor.

Exemplos de SUMIF()

Agora vamos ver mais situações em que SUMIF() ajuda. Cada uma usa um tipo de critério um pouco diferente, então veremos uma por vez.

Somar números maiores ou menores que um valor

Às vezes não queremos corresponder uma palavra específica. Em vez disso, queremos pegar tudo acima ou abaixo de certo número.

Para obter o total de todas as vendas maiores que 100, escrevemos:

=SUMIF(B2:B11, ">100", B2:B11)

Na nossa tabela, os valores maiores que 100 são 120, 150, 110 e 130. Somando, obtemos 510.

Perceba que aqui o range e o intervalo de soma são os mesmos. Isso porque estamos checando os próprios números, e não comparando com outra coluna.

Para vendas menores que 50, a fórmula seria:

=SUMIF(B2:B11, "<50", B2:B11)

Na nossa tabela, nada está abaixo de 50, então o retorno é 0 — não é erro, apenas sem correspondências.

Somando números que atendem a critérios de maior que ou menor que. Imagem: Autor.

Somar datas

Datas funcionam de forma um pouco diferente, pois o Excel as armazena como números seriais. Cada data é um número sequencial a partir de um ponto inicial. Por isso também podemos usar símbolos de comparação com datas, como fizemos com números.

Suponha que tenhamos uma coluna de datas de pedido na coluna C e queremos o total de vendas após 1º de março de 2026. A fórmula ficaria assim:

=SUMIF(C2:C11, ">"&DATE(2026,3,1), B2:B11)

Na imagem abaixo, destaquei as datas que correspondem ao critério e o total somado.

Usamos a função DATE() em vez de digitar a data diretamente. Isso evita erros, já que o Excel pode interpretar datas de forma diferente conforme as configurações regionais.

Se quisermos despesas durante um mês específico, como março de 2026, precisamos de duas condições, já que estamos verificando um intervalo e não um único ponto. 

É justamente aí que SUMIF() chega ao limite — veremos isso na seção de comparação a seguir.

Soma das vendas que atendem ao critério de data usando SUMIF(). Imagem: Autor.

Usar referências de célula como critério

Até agora, digitamos os critérios diretamente na fórmula, como "Apples" ou ">100". Funciona, mas não é muito flexível. Se quisermos verificar outro produto, teremos que editar a fórmula toda vez.

Uma abordagem melhor é referenciar uma célula. Suponha que a célula A6 contenha a palavra Grapes. Nossa fórmula ficaria assim:

=SUMIF(A2:A11, A6, B2:B11)

Isso soma todos os valores de Grapes. Agora, se quisermos verificar outro produto, basta mudar o que está em A6; não precisamos tocar na fórmula.

Use referência de célula em vez de hardcode no critério. Imagem: Autor.

Como usar curingas com SUMIF()

Curingas ajudam quando não sabemos o texto exato, mas conhecemos o padrão. Por exemplo, você não sabe a palavra exata, mas sabe que começa com B. 

SUMIF() aceita dois curingas: 

• * representa qualquer quantidade de caracteres. Pode ser zero, um ou cem caracteres.

• ? representa exatamente um caractere.

Vamos ver como isso funciona na nossa tabela de produtos.

Produtos começando com "A"

Digamos que queremos o total de vendas de todo produto que começa com A. Em vez de escrever quatro fórmulas separadas para Apples, Apricots, Avocados e Almonds, um curinga resolve tudo:

=SUMIF(A2:A8, "A*", B2:B8)

O asterisco depois de A indica que a fórmula deve corresponder a A seguido de qualquer coisa. Todo produto na tabela que começa com A é capturado. Ou seja, 120 + 90 + 60 + 75, totalizando 345.

Produtos que começam com a letra A usando o curinga *. Imagem: Autor.

Nomes que contêm determinado texto

Curingas também funcionam no meio da palavra. Digamos que queremos todo produto que contenha “an” em algum lugar do nome. Isso pega Bananas e Oranges. 

Para isso, a fórmula fica:

=SUMIF(A2:A8, "*an*", B2:B8)

O asterisco dos dois lados significa que não nos importamos com o que vem antes ou depois de an. Desde que an apareça em algum lugar do texto, conta como correspondência. 

Rodando isso na nossa tabela, somamos as vendas de Bananas e Oranges, totalizando 175. 

* encontra o produto que contém caractere(s) específico(s). Imagem: Autor.

Quando usar ? em vez de *

? corresponde a exatamente um caractere. Se temos códigos de produto e queremos apenas códigos com exatamente um dígito após a letra A, escreveríamos:

=SUMIF(A2:A7, "A?", B2:B7)

Isso corresponde a A1, A2 e A3, mas não a A10 ou A11, pois essas têm dois caracteres após o A, não um.

Corresponda ao padrão usando o curinga ?. Imagem: Autor.

Então:

• Use * quando o tamanho do texto variar. 

• Use ? quando você souber exatamente quantos caracteres esperar.

SUMIF() vs. SUMIFS()

SUMIFS() faz o mesmo trabalho que SUMIF(): 

• SUMIF() verifica uma condição por vez. 

• SUMIFS() verifica várias condições ao mesmo tempo.

Aqui vai uma comparação rápida.

A sintaxe de SUMIFS() é:

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

A diferença em SUMIF() é que o sum_range vem por último. Em SUMIFS(), ele vem primeiro. 

Vamos ver isso em um exemplo. 

Na nossa tabela, queremos o total de vendas de Apples, mas apenas onde as vendas foram acima de 100. São duas condições. 

Diferente de SUMIF(), SUMIFS() dá conta. Veja: 

=SUMIFS(B2:B11, A2:A11, "Apples", B2:B11, ">100")

Aqui, B2:B11 é o sum_range, listado primeiro. Depois vêm os pares de condição: A2:A11 com Apples e B2:B11 com >100. O Excel verifica ambas as condições em cada linha e só soma quando as duas forem verdadeiras.

SUMIFS() verifica várias condições de uma só vez. Imagem: Autor.

SUMIF() vs. COUNTIF()

SUMIF() e COUNTIF() parecem semelhantes, pois ambas verificam uma condição antes de fazer algo. Mas não fazem a mesma coisa.

• SUMIF() soma valores que atendem a um critério. 

• COUNTIF() conta quantas células atendem a um critério. 

Aqui vai uma comparação rápida.

Uma dá a você um total. A outra dá uma contagem. Vamos ver lado a lado, usando a nossa tabela original de vendas.

Aqui queremos saber duas coisas sobre Apples. 

1. Quanto vendemos no total
2. Quantas vezes Apples aparece na lista?

Para o total de vendas, usamos SUMIF():

=SUMIF(A2:A11, "Apples", B2:B11)

Isso soma cada valor de vendas em que o produto é Apples, resultando em 490.

Para a contagem, usamos COUNTIF():

=COUNTIF(A2:A11, "Apples")

Isso conta quantas linhas têm Apples, resultando em 4.

COUNTIF() conta o número de ocorrências em um intervalo. Imagem: Autor.

COUNTIF() precisa apenas de um intervalo e de um critério, já que não há nada a somar. Já SUMIF() exige também um intervalo de soma, pois é de lá que vêm os números para totalizar.

Erros comuns com SUMIF()

Mesmo com uma fórmula simples, pequenos deslizes acontecem. Aqui estão os erros mais comuns e como corrigir cada um.

Usar o intervalo errado

Isso ocorre quando o range e o intervalo de soma não se alinham linha a linha. Suponha que seu range seja A2:A11, mas o intervalo de soma seja B2:B10. O Excel fica com uma linha desencontrada e os totais saem errados — às vezes sem mostrar erro algum.

Como corrigir: garanta que ambos os intervalos comecem e terminem nas mesmas linhas. Se seu range é A2:A11, o intervalo de soma também deve ir da linha 2 à 11.

Esquecer o intervalo de soma

Digamos que você quer somar a coluna B, mas sua condição está na coluna A. Se você escrever a fórmula só com A2:A11 e o critério, e omitir o intervalo de soma, o Excel vai supor que você quer somar a própria coluna A, não a B. O resultado sai errado.

Como corrigir: sempre inclua o intervalo de soma quando a coluna que você verifica for diferente da que você soma. Se ambas forem a mesma, tecnicamente você pode pular — ainda assim, vale a pena manter para deixar claro.

Sintaxe incorreta no critério

Escrever >100 sem aspas gera erro. Precisa ser ">100", com aspas duplas. Aspas simples também geram erro.

Como corrigir: qualquer critério que use texto ou símbolos de comparação precisa de aspas. Se você estiver correspondendo um número exato, como 100 sozinho, não precisa de aspas. No momento em que houver símbolo ou palavra no critério, as aspas são obrigatórias.

Números armazenados como texto

Às vezes os números parecem números, mas o Excel os trata como texto. Isso geralmente acontece quando os dados são importados de outra fonte, como um arquivo CSV ou um export do sistema. 

Você percebe isso quando os números ficam alinhados à esquerda, que é como o Excel exibe texto por padrão.

Quando isso acontece, SUMIF() com uma comparação como ">100" não funciona corretamente, porque o Excel não compara texto da mesma forma que compara números reais.

Como corrigir: converta o texto de volta para número. Vá em Início > grupo Número e, no menu, selecione Geral ou Número.

Espaços extras em valores de texto

Suponha que uma célula tenha "Apples" e outra tenha "Apples " com um espaço no fim. Aos seus olhos, parecem iguais. Para SUMIF(), não — e a fórmula não vai contar como correspondência.

Como corrigir: envolva sua fórmula com a função TRIM() para remover espaços extras antes de rodar. Assim "Apples" e "Apples " finalmente são tratados como a mesma coisa.

Boas práticas com SUMIF()

Alguns hábitos tornam SUMIF() mais fácil de usar, especialmente quando suas planilhas crescem. Aqui vão nossas recomendações.

• Use referências de célula em vez de critério fixo: Digitar "Apples" direto na fórmula funciona, mas você terá que editar sempre que quiser checar outra coisa. Aponte para uma célula e troque apenas o valor nela; a fórmula fica intacta.

• Mantenha intervalos do mesmo tamanho: Seu range e seu intervalo de soma devem cobrir o mesmo número de linhas. Se um vai da linha 2 à 11 e o outro para na 10, os totais não vão se alinhar.

• Use Tabelas do Excel para dados que crescem: Um intervalo comum como A2:A11 não inclui novas linhas automaticamente. Converta seus dados em uma Tabela do Excel. Tabelas se expandem sozinhas quando você adiciona linhas, e sua fórmula SUMIF() cresce junto — sem ajustes manuais.

• Teste fórmulas com exemplos simples: Use cinco ou seis linhas cujo resultado você já saiba e confirme se a fórmula retorna o esperado. Isso pega erros cedo, antes de se espalharem por centenas de linhas.

• Use SUMIFS() quando precisar de mais de uma condição: No momento em que você precisar verificar duas coisas ao mesmo tempo — como produto e intervalo de datas —, troque para SUMIFS(). Tentar forçar SUMIF() geralmente leva a gambiarras difíceis de ler e fáceis de quebrar.

Considerações finais

SUMIF() é a forma mais simples de somar valores que atendem a uma condição. Dê a ela um range, um critério e um intervalo de soma, e o Excel faz o resto.

Comece com condições simples, como corresponder um nome de produto ou um número maior que certo valor. Quando já estiver confortável, curingas e referências de célula deixam a fórmula mais flexível sem mudar seu funcionamento.

Se em algum momento você precisar verificar duas coisas de uma vez, é o sinal para partir para SUMIFS().