Die 20 wichtigsten Excel-Formeln, die alle kennen sollten

Entdecke wichtige Excel-Formeln mit praxisnahen Übungen in unserem Kurs Introduction to Excel.

Warum sind Excel-Formeln wichtig?

Excel-Formeln sind aus mehreren Gründen unverzichtbar:

1. Effizienz: Sie automatisieren Routineaufgaben, sparen Zeit und reduzieren manuelle Fehler.
2. Datenanalyse: Die Vielzahl an Formeln ermöglicht anspruchsvolle Analysen – Grundlage für fundierte Entscheidungen.
3. Genauigkeit: Formeln liefern konsistente, präzise Ergebnisse – essenziell etwa in Finanz- und Rechnungswesen.
4. Datenaufbereitung: Große Datensätze lassen sich schnell sortieren, filtern und transformieren.
5. Zugänglichkeit: Excel ist benutzerfreundlich – komplexe Analysen werden auch für Nicht-Techniker greifbar.
6. Vielseitigkeit: In vielen Branchen Standard – Excel-Kompetenz verbessert Jobchancen und Karriere.
7. Individualisierung: Formeln lassen sich flexibel an spezifische Anforderungen anpassen.

Kurz gesagt: Excel-Formeln sind ein Grundwerkzeug für wirksames Datenmanagement, Analysen und Entscheidungen.

So nutzt du Excel-Formeln

Formeln in Excel einzugeben, ist einfach. Wenn du mit Business-Intelligence-Tools vertraut bist, geht es dir schnell in Fleisch und Blut über.

Am effektivsten und schnellsten arbeitest du, wenn du Formeln manuell eingibst. Im folgenden Beispiel berechnen wir den BMI (Body-Mass-Index) der Athletinnen und Athleten in der Tabelle.

BMI = weight (KG)/ (Height (m))^2 Bereitgestellt von

1. Wähle die Zelle für das Ergebnis. Du kannst sie mit der Maus markieren oder mit den Pfeiltasten ansteuern.

2. Tippe = in die Zelle. Das Gleichheitszeichen erscheint in Zelle und Bearbeitungsleiste.

3. Gib die Adresse der Zelle ein, die wir für die Berechnung nutzen wollen. In unserem Fall ist es E2 (weight/KG).

4. Füge das Divisionszeichen / hinzu.

5. Um die Größe von Zentimetern in Meter umzuwandeln, teilen wir D2 durch 100.

6. Quadriere die Größe mit ^2 und drücke Enter.

7. Die fertige Formel sieht so aus: =E2/(D2/100)^2.

Hinweis: Die Zelladresse setzt sich aus dem Spaltenbuchstaben (A, B, C, …) und der Zeilennummer (1, 2, 3, …) zusammen. Beispiele: A2, B5, C12.

Fertig – wir haben den BMI von A Dijiang berechnet.

Excel-Formel hinzufügen | Autor

Du kannst Formeln auch über die unterstützende GUI hinzufügen. Das ist simpel.

Im nächsten Beispiel nutzen wir die GUI, um eine IF()-Funktion hinzuzufügen, die „M“ in „Male“ und „F“ in „Female“ umwandelt.

1. Klicke auf die Schaltfläche fx neben der Bearbeitungsleiste.

2. Es öffnet sich ein Fenster mit den meistgenutzten Funktionen.

3. Suche nach der gewünschten Funktion oder scrolle zur Auswahl. In unserem Fall wählen wir IF().

4. Füge die Logik B2="M" in das Argument logical_test ein.

5. Trage “Male” in value_if_true und “Female” in value_if_false ein.

Das funktioniert wie eine If-Else-Anweisung. Ist logical_test TRUE, gibt die Formel „Male“ zurück, sonst „Female“.

Excel-Formel über UI | Autor

Formeln für eine ganze Spalte einfügen

Wir haben die Formel für eine einzelne Zeile hinzugefügt. Jetzt wenden wir dieselbe Formel auf eine ganze Spalte an.

Es gibt mehrere Wege:

• Mit dem Ausfüllkästchen ziehen: Wenn du die Zelle auswählst, erscheint unten rechts ein kleines grünes Quadrat – das Ausfüllkästchen. Klicke, halte und ziehe es bis zur letzten Zeile.
• Doppelklick auf das Ausfüllkästchen: Doppelklicke auf das Ausfüllkästchen der Zelle mit der Formel. So überträgst du sie in Sekunden auf die ganze Spalte.
• Tastenkürzel: Markiere die Zelle mit der Formel und die leeren Zellen darunter. Drücke STRG + D, um die Formel nach unten zu füllen. Achte darauf, nichts oberhalb der Formelzelle zu markieren.
• Kopieren und Einfügen: Kopiere die Zelle mit der Formel (STRG + C), markiere die leeren Zeilen in der Spalte und füge ein (STRG + V). Nutze zum Markieren nicht das Ausfüllkästchen.

Die folgende Visualisierung zeigt alle Wege, wie du Formeln auf mehrere Zellen anwenden kannst.

Formel für eine ganze Spalte | Autor

Grundlegende Formeln in Excel

Schauen wir uns nun wichtige Formeln in Excel an. Wir starten mit häufig genutzten und zentralen Funktionen – also integrierten Operationen, die du in Formeln für bestimmte Aufgaben verwenden kannst.

Für diesen Abschnitt nutzen wir einen kleinen Ausschnitt des Olympics-Datensatzes von DataCamp. Zur Vereinfachung arbeiten wir hauptsächlich mit Name, Geschlecht, Alter, Größe und Gewicht von vier Athletinnen und Athleten. Für jede Aufgabe gibst du Funktionsname und Argumente ein – das war’s.

1. SUM()

Die Funktion SUM() addiert die Zahlen in den von dir ausgewählten Zellen. Sie funktioniert mit numerischen Zellen; du kannst einzelne Zellen, einen Bereich oder mehrere Bereiche übergeben.

Wir wenden SUM() auf den Bereich C2 bis C5 an und schreiben das Ergebnis in C6. Addiert werden 24, 23, 21 und 31. Du kannst die Funktion auch über mehrere Spalten nutzen.

=SUM(C2:C5)Bereitgestellt von

Mehr dazu in unserem ausführlichen Guide zum Addieren in Excel.

2. MIN() und MAX()

MIN() benötigt einen Zellbereich und liefert den kleinsten Wert. Beispiel: Wir möchten das minimale Gewicht aller Athleten in E6 anzeigen. MIN() findet den kleinsten Wert und gibt 60 zurück.

=MIN(E2:E5)Bereitgestellt von

MAX() ist das Gegenstück zu MIN() und liefert den größten Wert im Bereich. Hier ist das Ergebnis 82.

=MAX(E2:E5)Bereitgestellt von

3. AVERAGE()

AVERAGE() berechnet den Mittelwert der ausgewählten Zellen. Du kannst einen Bereich (C2:C5) oder einzelne Zellen (C2, C3, C5) angeben.

Für den Durchschnitt der Athleten wählen wir die Spalte age, wenden AVERAGE() an und schreiben das Ergebnis in C7. Excel summiert die Werte und teilt durch 4.

=AVERAGE(C2:C5) Bereitgestellt von

Einen detaillierten Guide zu AVERAGE() in Excel findest du hier.

4. COUNT()

COUNT() zählt, wie viele der ausgewählten Zellen Zahlen enthalten. Leere Zellen und Text werden ignoriert.

Wir zählen die Anzahl der Gewichte und erhalten 4, da keine Werte fehlen.

=COUNT(E2:E5)Bereitgestellt von

Um alle Zelltypen (Datum/Uhrzeit, Text, Zahlen) zu zählen, nutze COUNTA().

COUNTA() zählt keine leeren Zellen. Für leere Zellen verwende COUNTBLANK().

Noch mehr Beispiele, wie du COUNT() in Excel nutzt, findest du in unserem separaten Guide.

5. POWER()

Zu Beginn haben wir die Potenzierung mit ^ genutzt – eine Alternative zur Funktion POWER(). Du kannst also x^y oder POWER(x,y) verwenden; POWER ist in verschachtelten Formeln oft besser lesbar – etwa zum Quadrieren, Kubieren oder für beliebige Potenzen.

In unserem Fall teilen wir D2 durch 100 für die Größe in Metern und quadrieren dann mit POWER() und dem zweiten Argument 2.

=POWER(D2/100,2)Bereitgestellt von

6. CEILING() und FLOOR()

Wie wir in unserem Guide zu Excel ROUND() erläutern, rundet CEILING() eine Zahl nach oben auf das nächste angegebene Vielfache. Zum Beispiel:

• =CEILING(3.24, 1) rundet 3,24 auf 4.

• =CEILING(3.24, 5) rundet 3,24 auf 5.

Im Beispiel unten runden wir F2 auf ein Vielfaches von 1 und erhalten 4.

=CEILING(F2,1)Bereitgestellt von

Optional: =CEILING.MATH(F2,1)

Im Gegensatz dazu rundet FLOOR() nach unten auf das nächste Vielfache. Zum Beispiel:

• =FLOOR(3.24, 1) rundet 3,24 auf 3.

• =FLOOR(3.24, 5) rundet 3,24 auf 0.

Wie im Beispiel zu sehen, wird 3,24 nicht zu 4, sondern auf 3 abgerundet.

=FLOOR(F2,1)Bereitgestellt von

Optional: =FLOOR.MATH(F2,1)

Diese Funktionen sind besonders nützlich bei standardisierten Intervallen, etwa beim Runden von Preisen, Zeiten oder Mengen auf feste Einheiten.

7. CONCAT()

Die Excel-Funktion CONCAT() verknüpft Zeichenfolgen. Bevorzuge CONCAT oder TEXTJOIN gegenüber der Legacy-Funktion CONCATENATE; nutze TEXTJOIN, wenn du einen Trenner brauchst oder Leerzellen ignorieren willst. Wenn wir z. B. age und sex kombinieren, nutzen wir CONCAT(). Zahlen aus age werden automatisch in Text umgewandelt und verknüpft.

„24“ & „M“ = „24M“

=CONCAT(C2,B2)Bereitgestellt von

Mehr zur Funktion in unserem Guide zu Excel CONCAT().

8. TRIM()

Wie in unserem kompletten TRIM()-Guide beschrieben, entfernt die Funktion überflüssige Leerzeichen am Anfang, in der Mitte und am Ende. Häufig hilft sie dabei, vermeintliche Duplikate aufzuspüren, die sich nur durch zusätzliche Leerzeichen unterscheiden.

Zum Beispiel:

1. In A3 „A   Lamusi“ gibt es zwei zusätzliche Leerzeichen; TRIM() entfernt sie.
2. In A4 „ Christine Jacoba Aaftink“ steht ein Leerzeichen am Anfang; auch das entfernt TRIM() ohne komplexe Formel.

=TRIM(A4)Bereitgestellt von

9. REPLACE() und SUBSTITUTE()

REPLACE() ersetzt einen Teil eines Strings durch einen neuen Text.

REPLACE(old_text, start_num, num_chars, new_text)Bereitgestellt von

• old_text: Der ursprüngliche Text bzw. die Zelle mit dem Text.

• start_num: Die Position, an der das Ersetzen beginnen soll.

• num_chars: Anzahl der zu ersetzenden Zeichen.

• new_text: Der neue Text, der eingesetzt wird.

Beispiel: Wir ändern A Dijiang zu B Dijiang, indem wir die Position 1, die Anzahl 1 und den neuen Buchstaben „B“ angeben.

=REPLACE(A2,1,1,"B")Bereitgestellt von

SUBSTITUTE() ist ähnlich, arbeitet aber textbasiert statt positionsbasiert: Du gibst alten und neuen Text an.

SUBSTITUTE(text, old_text, new_text, [instance_num])Bereitgestellt von

Hinweis: Nutze instance_num, um nur ein bestimmtes Vorkommen zu ersetzen.

Hier ersetzen wir „Jacoba“ durch „Rahim“ und erhalten in A4 „Christine Rahim Aaftink“.

SUBSTITUTE() ändert nur Zellen, die den angegebenen Text enthalten. A5 („Per Knut Aaland“) enthält „Jacoba“ nicht und bleibt daher unverändert. REPLACE() arbeitet positionsbasiert und ersetzt die Zeichen an der angegebenen Stelle – unabhängig vom Inhalt.

=SUBSTITUTE(A4,"Jacoba","Rahim")Bereitgestellt von

10. LEFT(), RIGHT() und MID()

LEFT() gibt eine bestimmte Anzahl Zeichen vom Anfang eines Texts zurück.

Um aus „Christine Jacoba Aaftink“ den Vornamen zu zeigen, nutzen wir LEFT() mit 9 Zeichen. Ergebnis: „Christine“.

=LEFT(A2,9)Bereitgestellt von

MID() extrahiert Zeichen aus der Mitte: Startposition und Länge angeben.

Für den zweiten Namen starten wir bei „J“ an Position 11 und nehmen 6 Zeichen für „Jacoba“.

=MID(A2,11,6)Bereitgestellt von

RIGHT() gibt Zeichen vom Ende zurück. Du gibst nur die Anzahl der Zeichen an.

Um den Nachnamen „Aaftink“ zu erhalten, nutzen wir RIGHT() mit 7 Zeichen.

=RIGHT(A2,7)Bereitgestellt von

11. UPPER(), LOWER() und PROPER()

UPPER(), LOWER() und PROPER() sind einfache Textfunktionen – ähnliche findest du auch in Tableau oder Python. Sie benötigen nur den Text bzw. die Zelladresse(n).

UPPER() macht alle Buchstaben groß.

=UPPER(A1)Bereitgestellt von

LOWER() wandelt Text in Kleinbuchstaben um.

=LOWER(A1)Bereitgestellt von

PROPER() setzt Wörter in die sogenannte „Eigennamenform“: Der erste Buchstabe jedes Wortes ist groß, der Rest klein.

=PROPER(A1)Bereitgestellt von

12. NOW() und TODAY()

NOW() gibt aktuelles Datum und Uhrzeit zurück, TODAY() nur das aktuelle Datum. Wir nutzen sie, um aus Datums-/Zeitwerten Tag, Monat, Jahr, Stunden und Minuten zu extrahieren.

Das folgende Beispiel liefert das aktuelle Datum und die Uhrzeit.

=NOW()Bereitgestellt von

Um die Sekunden zu erhalten, verwendest du SECOND().

=SECOND(NOW())Bereitgestellt von

TODAY() gibt nur das aktuelle Datum zurück.

=TODAY()Bereitgestellt von

Für den Tag nutzt du DAY().

Ebenso lassen sich Monat, Jahr, Wochentag, Tagesnamen, Stunden und Minuten aus einem Datums-/Zeitwert extrahieren.

=DAY(TODAY())Bereitgestellt von

13. DATEDIF()

DATEDIF() berechnet die Differenz zwischen zwei Daten und gibt – je nach Einheit – Tage, Monate oder Jahre zurück.

Achtung: DATEDIF ist eine Legacy-/Kompatibilitätsfunktion und kann bei einigen Einheiten (z. B. „MD“) ungenau sein. Ziehe DAYS(), YEARFRAC() oder Datumsarithmetik vor, wenn möglich.

Im Beispiel unten geben wir „d“ als Einheit an und erhalten die Differenz in Tagen. Achte darauf, dass das erste Argument das Startdatum und das zweite das Enddatum ist.

start_date < end_date

=DATEDIF(A2,B2,"d")Bereitgestellt von

14. VLOOKUP() und HLOOKUP()

Das worksheet1, das wir hier verwenden, enthält alle Daten des Olympics-Datensatzes.

worksheet1

VLOOKUP() sucht den Wert in der linken Spalte eines Tabellenbereichs und gibt aus derselben Zeile den Wert aus der angegebenen Spalte zurück.

Hinweis: VLOOKUP() und HLOOKUP() sind Legacy-/Kompatibilitätsfunktionen. Microsoft empfiehlt XLOOKUP() für neue Arbeiten: ersetzt beide, liefert standardmäßig exakte Treffer, kann in alle Richtungen suchen und hat ein if_not_found-Argument. Lies unseren Guide zu XLOOKUP und den Vergleich XLOOKUP vs VLOOKUP.

VLOOKUP(lookup_value, table_array, col_index, range_lookup)

• lookup_value: Der gesuchte Wert, der in der ersten Spalte steht.

• table_array: Bereich der Tabelle, des Arbeitsblatts oder eine Zell-Auswahl mit mehreren Spalten.

• col_index: Die Spaltenposition, aus der der Wert zurückgegeben wird.

• range_lookup: „TRUE“ für ungefähre Übereinstimmung (Standard), „FALSE“ für exakte Übereinstimmung.

Wir suchen nach A Dijiang (A2) im ausgewählten Bereich aus worksheet1 (B2:H20). VLOOKUP() prüft die Namensspalte und gibt den Wert der 6. Spalte zurück: Team „China“.

=VLOOKUP(A2,worksheet1!B2:H20,6,FALSE)Bereitgestellt von

HLOOKUP() sucht statt in der ersten Spalte in der ersten Zeile und gibt aus derselben Spalte den Wert der angegebenen Zeile zurück.

HLOOKUP(lookup_value, table_array, row_index, range_lookup)

Wir zeigen in D8 das sex von A Dijiang an. HLOOKUP() sucht den Namen in der ersten Zeile und liefert „M“ aus der 2. Zeile derselben Spalte. range_lookup ist in beiden Fällen FALSE für exakte Treffer.

=HLOOKUP(B1, B1:E5, 2, FALSE)Bereitgestellt von

15. IF()

IF() ist selbsterklärend und ähnelt If-Else in Programmiersprachen. Du gibst die Logik vor: Trifft sie zu, wird ein Wert ausgegeben; andernfalls ein anderer.

Beispiel: Ist der BMI eines Athleten kleiner als 24,9, gibt die Funktion „Below 24.9“ zurück, sonst „24.9 or above“. So lassen sich numerische Werte in Kategorien einteilen.

=IF(G2<24.9,"Below 24.9","24.9 or above")Bereitgestellt von

16. SUMIF()

SUMIF() addiert nur die Zellen, die eine von dir gesetzte Bedingung erfüllen. Die Funktion hat drei Argumente:

SUMIF(range, criteria, [sum_range])Bereitgestellt von

• range: Die Zellen, die gegen die Bedingung geprüft werden.

• criteria: Die Bedingung, z. B. „M“ oder „>10“. Text und Vergleichsoperatoren in Anführungszeichen setzen.

• sum_range: Die Zellen, die addiert werden. Lässt du es weg, addiert Excel die Zellen in range.

Beispiel: Um das Gewicht der männlichen Athleten zu addieren, prüfen wir die Spalte sex (B2:B5) auf „M“ und addieren die passenden Werte aus E2:E5. Ergebnis: 215.

=SUMIF(B2:B5,"M",E2:E5)Bereitgestellt von

Für mehrere Bedingungen gleichzeitig nutze SUMIFS().

17. COUNTIF()

COUNTIF() zählt Zellen, die eine Bedingung erfüllen. Anders als COUNT() funktioniert es auch mit Text. Die Funktion hat zwei Argumente:

COUNTIF(range, criteria)Bereitgestellt von

• range: Die Zellen, die geprüft werden.

• criteria: Die Bedingung, z. B. „M“ oder „>24“. Text und Operatoren in Anführungszeichen setzen.

Beispiel: Um die männlichen Athleten zu zählen, prüfen wir B2:B5 auf „M“. Ergebnis: 3.

=COUNTIF(B2:B5,"M")Bereitgestellt von

Für Zählungen mit mehreren Bedingungen nutze COUNTIFS().

18. ROUND()

ROUND() rundet eine Zahl auf die gewünschte Anzahl Stellen. Zwei Argumente:

ROUND(number, num_digits)Bereitgestellt von

• number: Der zu rundende Wert bzw. die Zelle.

• num_digits: Anzahl zu behaltender Stellen. Positiv = Dezimalstellen, 0 = ganze Zahl, negativ = links vom Dezimalpunkt (-1 rundet auf Zehner).

Beispiel: In F2 steht 3,24. Mit 1 als zweitem Argument runden wir auf eine Nachkommastelle: 3,2.

=ROUND(F2,1)Bereitgestellt von

ROUND() rundet immer zum nächsten Wert. Erzwinge Auf- bzw. Abrunden mit ROUNDUP() oder ROUNDDOWN(). Weitere Beispiele findest du im Guide zu ROUND().

19. IFERROR()

IFERROR() prüft eine Formel und gibt einen von dir gewählten Wert zurück, wenn sie einen Fehler erzeugt. Ohne Fehler erscheint das normale Ergebnis. Zwei Argumente:

IFERROR(value, value_if_error)Bereitgestellt von

• value: Die zu prüfende Formel oder Zelle.

• value_if_error: Was bei einem Fehler angezeigt wird – etwa Text, Zahl oder ein leerer String (“”).

Beispiel: Beim BMI von vorhin führt fehlende Größe zu Division durch 0 und #DIV/0!. Mit IFERROR() zeigen wir stattdessen „Missing data“.

=IFERROR(E2/(D2/100)^2,"Missing data")Bereitgestellt von

IFERROR() fängt alle Fehlertypen ab – u. a. #N/A, #VALUE!, #REF! – und kann so auch echte Fehler verdecken. Nutze es gezielt und prüfe Ergebnisse nach dem Einsatz.

20. XLOOKUP()

XLOOKUP() durchsucht einen Bereich nach einem Wert und gibt den passenden Wert aus einem anderen Bereich zurück. Es ersetzt VLOOKUP() und HLOOKUP(). Drei Pflicht- und drei optionale Argumente:

XLOOKUP(lookup_value, lookup_array, return_array, [if_not_found], [match_mode], [search_mode])Bereitgestellt von

• lookup_value: Der gesuchte Wert.

• lookup_array: Der Bereich, in dem gesucht wird.

• return_array: Der Bereich, aus dem der Rückgabewert stammt.

• if_not_found: Was bei keinem Treffer angezeigt wird, z. B. „Not found“. Ohne Angabe zeigt Excel #N/A.

• match_mode: Optional. Standardmäßig sucht XLOOKUP() nach exakter Übereinstimmung.

• search_mode: Optional. Standardmäßig von oben nach unten.

Beispiel: Wir suchen A Dijiang (A2) in der Namensspalte von worksheet1 (B2:B20) und geben den passenden Teamwert aus (G2:G20). Ergebnis: „China“ – wie im VLOOKUP()-Beispiel.

=XLOOKUP(A2,worksheet1!B2:B20,worksheet1!G2:G20)Bereitgestellt von

Im Unterschied zu VLOOKUP() musst du keine Spaltenpositionen zählen, und die Suchspalte muss nicht links stehen. Für eine benutzerdefinierte Meldung bei keinem Treffer füge das vierte Argument hinzu:

=XLOOKUP(A2,worksheet1!B2:B20,worksheet1!G2:G20,"Not found")Bereitgestellt von

XLOOKUP() gibt es in Microsoft 365 und Excel 2021 oder neuer. In älteren Versionen nutze VLOOKUP(). Lies unseren Guide zur Nutzung von XLOOKUP() und den Vergleich XLOOKUP() vs VLOOKUP().

Weitere Arten von Formeln in Excel

Jetzt sehen wir uns weitere Formelkategorien an – darunter operatorbasierte Formeln, Matrixformeln und formelbasierte bedingte Formatierung.

Formeln mit Operatoren

Schon A1 + A2 ist eine Formel, weil eine Berechnung mit Zellbezügen und einem Operator stattfindet – und Excel das Ergebnis dynamisch aktualisieren kann. Alles Folgende sind Formeln:

• Addition: =A1 + B1

• Subtraktion: =A1 - B1

• Multiplikation: =A1 * B1

• Division: =A1 / B1

Das wirkt grundlegend, ist aber die Basis für fortgeschrittene Muster wie Sequenzen und rekursive Berechnungen. So erstellst du z. B. eine Fibonacci-Folge:

• Schreibe 0 in A1 und 1 in A2.
• In A3 gibst du =A1+A2 ein und ziehst dann das Ausfüllkästchen nach unten. Jede neue Zelle addiert die zwei Zellen darüber.

Matrixformeln

Matrixformeln führen mehrere Berechnungen gleichzeitig aus und geben entweder ein einzelnes Ergebnis oder mehrere Werte über einen Zellbereich zurück. Sie sind besonders nützlich bei mehreren Bedingungen oder großen Datensätzen.

Beispiel: Die Summe der quadrierten Werte in einem Bereich: =SUM(A1:A5^2). Nützlich etwa für Regression in Excel. Es ist eine Formel (beginnt mit = und rechnet), aber mehr als das frühere SUM()-Beispiel – wegen des Zirkumflex.

Formelbasierte bedingte Formatierung

Excel erlaubt benutzerdefinierte Formeln für bedingte Formatierung statt nur vordefinierter Regeln. So kannst du z. B. formatieren, wenn eine zeilenspezifische Bedingung über mehrere Spalten gilt – als normale Zellformel wäre das nicht möglich, in der bedingten Formatierung schon.

Beispiel: Wir heben eine ganze Zeile hervor, wenn eine Zelle eine Bedingung erfüllt. Angenommen, Spalte C enthält Bestellstatus („Pending“ oder „Shipped“) und wir wollen alle Zeilen mit „Pending“ markieren. So gehst du vor:

1. Markiere den gesamten Tabellenbereich (z. B. A2:E100).

2. Gehe zu Start > Bedingte Formatierung > Neue Regel.

3. Wähle Formel zur Ermittlung der zu formatierenden Zellen verwenden.

4. Gib diese Formel ein: =$C2="Pending"

5. Klicke auf Format, wähle eine Füllfarbe und bestätige mit OK.

Diese Formel ähnelt einer normalen Zellformel. In einer Zelle würde =$C2="Pending" nur TRUE oder FALSE ergeben. In der bedingten Formatierung wird die Logik jedoch zeilenweise auf den gesamten Bereich angewendet und ganze Zeilen werden dynamisch formatiert.

Funktionen zu Formeln kombinieren

Bisher haben wir jeweils nur eine Funktion genutzt. In der Praxis kombinieren nützliche Formeln oft mehrere.

Eine Funktion ist eine integrierte Operation mit Namen und Argumenten wie SUM() oder IF(). Eine Formel ist alles, was nach dem Gleichheitszeichen steht. Sie kann eine oder mehrere Funktionen, Zellbezüge, Zahlen und Operatoren wie +, / und ^ enthalten.

Nehmen wir die BMI-Formel von oben, jetzt gerundet:

=ROUND(E2/(D2/100)^2,1)Bereitgestellt von

• = kennzeichnet die Formel.

• ROUND ist die Funktion.

• E2 und D2 sind Zellbezüge.

• / und ^ sind Operatoren.

• 100, 2 und 1 sind Konstanten.

Excel arbeitet von innen nach außen. Steht eine Funktion in einer anderen, wird zuerst die innere berechnet und ihr Ergebnis an die äußere übergeben. Die folgenden Beispiele bauen aufeinander auf.

Eine Berechnung runden

Unsere BMI-Formel liefert viele Dezimalstellen. Mit ROUND() halten wir eine Nachkommastelle.

=ROUND(E2/(D2/100)^2,1)Bereitgestellt von

Excel teilt zuerst Gewicht durch Größe zum Quadrat und rundet dann.

Mit fehlenden Daten umgehen

Ist die Größe leer, liefert Beispiel 1 #DIV/0!. Wickle die Formel in IFERROR().

=IFERROR(ROUND(E2/(D2/100)^2,1),"Missing data")Bereitgestellt von

Jetzt gibt es drei Ebenen: die Berechnung, ROUND(), dann IFERROR().

Text in einem Schritt bereinigen

TRIM() entfernt Extra-Leerzeichen, PROPER() korrigiert die Groß-/Kleinschreibung. Kombiniere beides, um A3 („A Lamusi“) in einem Schritt zu säubern.

=PROPER(TRIM(A3))Bereitgestellt von

TRIM() läuft zuerst, dann formatiert PROPER() das Ergebnis.

Werte in Kategorien einteilen

Verschachtle IF(), um BMI-Werte in drei Gruppen zu sortieren.

=IF(G2<18.5,"Below 18.5",IF(G2<25,"18.5 to 24.9","25 or above"))Bereitgestellt von

Ist der erste Test wahr, gibt Excel „Below 18.5“ zurück. Andernfalls prüft es die zweite IF().

Ein Funktionsergebnis weiterverwenden

Du kannst das Ergebnis einer Funktion weiterverrechnen. Um den Gewichtsanteil der männlichen Athleten zu finden, teilst du eine SUMIF() durch eine SUM().

=SUMIF(B2:B5,"M",E2:E5)/SUM(E2:E5)Bereitgestellt von

Formatiere die Zelle als Prozentwert.

Ein Lookup robuster machen

Findet VLOOKUP() keinen Treffer, erscheint #N/A. Mit IFERROR() zeigst du etwas Freundlicheres.

=IFERROR(VLOOKUP(A2,worksheet1!B2:H20,6,FALSE),"Not found")Bereitgestellt von

XLOOKUP() hat das über sein viertes Argument bereits integriert – dort brauchst du IFERROR() nicht.

Tipps für längere Formeln

• Von innen nach außen bauen. Bringe zuerst die innere Funktion in einer eigenen Zelle zum Laufen und wickle dann die nächste darum.
• Klammern im Blick behalten. Jede öffnende Klammer braucht eine schließende. Excel markiert passende Paare farblich.
• Lesbarkeit wahren. Bei mehr als zwei bis drei Ebenen auf Hilfsspalten aufteilen.

Dein Team in Excel weiterbilden

Wir haben die Excel-Formeln behandelt, die alle kennen sollten. Mehrere Personen darin weiterzubilden, ist aber nicht immer trivial. In unserem separaten Guide zu Corporate-Excel-Training findest du dazu Details – hier die Kurzfassung.

Excel ist mehr als ein Tabellen-Tool – oft essenziell für Datenmanagement, Finanzanalysen und Entscheidungen. Eine Investition in Excel-Training steigert Produktivität, Genauigkeit und Effizienz deines Teams. Wichtige Vorteile:

• Datenanalyse: Fortgeschrittene Excel-Skills ermöglichen tiefere Insights für bessere Entscheidungen.

• Effizienz: Automatisierung in Tabellen reduziert manuelle Arbeit und Fehler.

• Finanzielle Präzision: Funktionen wie VLOOKUP() und Pivot-Tabellen verbessern das Finanzmanagement.

• Schlankere Abläufe: Tools zur Datenmanipulation erleichtern große Datensätze und optimieren Prozesse.

• Wettbewerbsvorteil: Excel-Kompetenz verschafft Vorsprung bei Prozessen und Erkenntnissen.

Wenn du dein Team – vom Einstieg bis zu fortgeschrittenen Formeln – in Excel schulen willst, ist DataCamp For Business ideal. Ob 2 oder 10.000 Personen: Du bekommst umfangreiche Excel- und Spreadsheet-Lerninhalte, kannst eigene Lernpfade erstellen und erhältst detaillierte Reports und Insights, um den Trainingserfolg zu messen. Fordere jetzt eine Demo an, um loszulegen.

Fazit

Microsoft Excel ist ein leistungsstarkes und einfach zu bedienendes Tool für Analyse und Reporting. In diesem Beitrag hast du gelernt, warum grundlegende Excel-Formeln so wichtig sind und wie sie komplexe Berechnungen ermöglichen. Außerdem haben wir verschiedene Wege zum Einfügen von Formeln gezeigt und die essenziellen Basisformeln im Detail betrachtet.

Wenn du mehr über Excel und den Einsatz dieser Formeln für Datenanalysen erfahren willst, besuche unseren Kurs Data Analysis in Excel. Er vermittelt dir die Grundlagen von Datenexploration, -aufbereitung und -analyse. Wenn du lieber mit dem Google-Stack arbeitest, probiere Data Analysis in Spreadsheet in Google Sheets.

Du kannst auch den nächsten Schritt gehen und die Fundamentals of a Spreadsheet lernen. Dort geht es um Datenanalyse, fortgeschrittene Datenmanipulation, Pivot-Tabellen und Visualisierung. Und für die schnelle Referenz hilft unser Excel-Formel-Cheat Sheet sowie mehr zu Datentypen in Excel.