Les 20 formules Excel essentielles à connaître

Découvrez les formules Excel essentielles avec des exercices pratiques dans notre cours Introduction to Excel.

Pourquoi les formules Excel sont-elles importantes ?

Les formules Excel sont essentielles pour plusieurs raisons :

1. Efficacité : elles automatisent les tâches répétitives, font gagner du temps et réduisent les erreurs manuelles.
2. Analyse de données : la variété des formules permet des analyses sophistiquées, indispensables pour des décisions éclairées.
3. Précision : elles garantissent des résultats cohérents et fiables, cruciaux en finance et en comptabilité.
4. Manipulation des données : elles facilitent le tri, le filtrage et la transformation de grands volumes de données.
5. Accessibilité : Excel propose une interface conviviale qui rend l’analyse avancée accessible aux non‑techniciens.
6. Polyvalence : omniprésentes dans de nombreux secteurs, les compétences Excel renforcent l’employabilité et l’évolution de carrière.
7. Personnalisation : Excel offre des options de formules personnalisables pour répondre à des besoins spécifiques.

En résumé, les formules Excel sont un socle indispensable pour une gestion des données, des analyses et une prise de décision efficaces.

Comment utiliser les formules Excel

Ajouter une formule Excel est relativement simple. Si vous connaissez un outil de business intelligence, cela vous paraîtra naturel.  

La méthode la plus rapide et efficace consiste à saisir les formules manuellement. Dans l’exemple ci‑dessous, nous calculons l’IMC (indice de masse corporelle) des athlètes affichés dans le tableau.

BMI = weight (KG)/ (Height (m))^2 Propulsé par

1. Choisissez la cellule de sortie du résultat. Sélectionnez-la à la souris ou déplacez-vous avec les flèches. 

2. Tapez = dans la cellule. Le signe égal apparaît dans la cellule et dans la barre de formule. 

3. Saisissez la référence de la cellule à utiliser dans le calcul. Ici, E2 (poids/KG).

4. Ajoutez le signe de division /

5. Pour convertir la taille de centimètres en mètres, divisez D2 par 100.

6. Élevez la taille au carré ^2 et appuyez sur Entrée. 

7. La formule finale ressemble à ceci : =E2/(D2/100)^2.

Remarque : pour obtenir la référence d’une cellule, repérez le nom de la colonne (A, B, C, …) et combinez-le avec le numéro de ligne (1, 2, 3, …). Par exemple, A2, B5, C12.   

Et voilà, nous avons calculé l’IMC de A Dijiang.

Ajout d’une formule Excel | Auteur

On peut aussi ajouter une formule via l’interface assistée. C’est simple. 

Dans l’exemple ci‑dessous, nous utilisons l’interface pour ajouter une fonction IF() afin de convertir « M » en « Male » et « F » en « Female ».

1. Cliquez sur le bouton fx à côté de la barre de formule.

2. Une fenêtre s’ouvre avec les fonctions les plus utilisées.

3. Recherchez une formule précise ou parcourez la liste. Ici, nous sélectionnons la fonction IF(). 

4. Ajoutez la logique B2="M" dans l’argument logical_test.

5. Ajoutez “Male” dans value_if_true et “Female” dans value_if_false. 

Le fonctionnement est similaire à une structure if-else. Si logical_test est TRUE, la formule renvoie « Male », sinon « Female ».

Formule Excel via l’interface | Auteur

Comment appliquer une formule à toute une colonne dans Excel

Nous avons vu comment ajouter une formule à une seule ligne. Voyons maintenant comment l’appliquer à une colonne entière. 

Plusieurs méthodes existent : 

• Faire glisser la poignée de recopie : en sélectionnant la cellule, un petit carré vert apparaît en bas à droite. C’est la poignée de recopie. Cliquez, maintenez et faites glisser jusqu’à la dernière ligne. C’est la méthode la plus courante pour étendre des formules. 
• Double‑cliquer la poignée : sélectionnez la cellule contenant la formule et double‑cliquez sur la poignée. En quelques secondes, la formule s’applique à toute la colonne. 
• Raccourci : sélectionnez la cellule avec la formule et les cellules vides en dessous. Appuyez sur CTRL + D pour propager la formule. Veillez à ne pas sélectionner de cellules au‑dessus. 
• Copier‑coller : copiez la cellule avec la formule (CTRL + C), sélectionnez les lignes vides de la colonne, puis collez (CTRL + V). Évitez d’utiliser la poignée pour sélectionner les lignes. 

Le visuel ci‑dessous illustre toutes les façons d’appliquer une formule à plusieurs cellules. 

Formule pour une colonne entière | Auteur

Formules de base dans Excel 

Passons en revue les formules importantes d’Excel. Nous commençons par les fonctions courantes et essentielles, qui sont des opérations intégrées à utiliser dans vos formules pour réaliser des tâches précises.

Pour cette section, nous utilisons un petit extrait du jeu de données Olympics de DataCamp. Pour simplifier, nous utiliserons principalement les colonnes nom, sexe, âge, taille et poids des enregistrements de quatre athlètes. Pour chaque cas, vous écrirez le nom de la fonction et ses arguments. Rien de compliqué. 

1. SUM()

La fonction SUM() additionne les nombres des cellules sélectionnées. Elle fonctionne sur des cellules numériques et peut prendre une cellule, une plage ou plusieurs plages.

Ici, nous appliquons SUM() à la plage C2:C5 et stockons le résultat en C6. Elle additionnera 24, 23, 21 et 31. Vous pouvez aussi l’appliquer à plusieurs colonnes.

=SUM(C2:C5)Propulsé par

Consultez notre guide complet pour additionner dans Excel pour aller plus loin.

2. MIN() et MAX()

MIN() prend une plage de cellules et renvoie la plus petite valeur. Par exemple, pour afficher le poids minimum parmi tous les athlètes en E6, MIN() renverra 60.

=MIN(E2:E5)Propulsé par

MAX() fait l’inverse de MIN() : elle renvoie la valeur maximale de la plage sélectionnée. Ici, elle renverra 82. 

=MAX(E2:E5)Propulsé par

3. AVERAGE()

AVERAGE() calcule la moyenne des cellules sélectionnées. Vous pouvez fournir une plage (C2:C5) ou des cellules individuelles (C2, C3, C5).

Pour calculer la moyenne d’âge des athlètes, sélectionnez la colonne age, appliquez AVERAGE() et renvoyez le résultat en C7. Excel additionne les valeurs puis les divise par 4.

=AVERAGE(C2:C5) Propulsé par

Nous avons aussi un guide détaillé sur AVERAGE() dans Excel.

4. COUNT()

COUNT() compte combien de cellules sélectionnées contiennent des nombres. Elle ignore les vides et le texte.

Ici, nous comptons le nombre de poids d’athlètes : le résultat est 4, car il n’y a ni valeur manquante ni texte. 

=COUNT(E2:E5)Propulsé par

Pour compter tous types de cellules (date-heure, texte, numérique), utilisez COUNTA(). 

COUNTA() ne compte pas les valeurs manquantes. Pour les cellules vides, utilisez COUNTBLANK().

Pour d’autres exemples sur COUNT() dans Excel, consultez notre guide dédié. 

5. POWER()

Au début, nous avons utilisé l’accent circonflexe ^ pour la puissance, une alternative à la fonction POWER(). Utilisez indifféremment x^y ou POWER(x,y) ; POWER est souvent plus lisible dans des formules imbriquées pour mettre au carré, au cube, etc.

Ici, nous divisons D2 par 100 pour obtenir la taille en mètres, puis nous élevons au carré avec POWER() en mettant 2 comme second argument.   

=POWER(D2/100,2)Propulsé par

6. CEILING() et FLOOR()

Comme nous l’expliquons dans notre guide sur ROUND() dans Excel, la fonction CEILING() arrondit un nombre par excès au multiple spécifié le plus proche. Par exemple :

• =CEILING(3.24, 1) arrondit 3,24 à 4.

• =CEILING(3.24, 5) arrondit 3,24 à 5.

Voyons un exemple appliqué ci‑dessous. Nous arrondissons F2 au multiple de 1 et obtenons 4. 

=CEILING(F2,1)Propulsé par

Option : =CEILING.MATH(F2,1)

À l’inverse, FLOOR() arrondit un nombre par défaut au multiple spécifié. Par exemple :

• =FLOOR(3.24, 1) arrondit 3,24 à 3.

• =FLOOR(3.24, 5) arrondit 3,24 à 0.

Comme on le voit ci‑dessous, au lieu de convertir 3,24 en 4, le nombre est arrondi à 3. 

=FLOOR(F2,1)Propulsé par

Option : =FLOOR.MATH(F2,1)

Ces fonctions sont particulièrement utiles avec des intervalles standardisés, par exemple pour arrondir des prix, des durées ou des quantités à des unités fixes.

7. CONCAT()

La fonction CONCAT() assemble des chaînes de caractères. Préférez CONCAT ou TEXTJOIN à l’ancienne CONCATENATE ; utilisez TEXTJOIN si vous avez besoin d’un délimiteur ou pour ignorer les vides. Par exemple, pour joindre l’âge et le sexe des athlètes, nous utiliserons CONCAT(). La fonction convertit automatiquement l’âge en texte et le combine. 

« 24 » & « M » = « 24M »

=CONCAT(C2,B2)Propulsé par

Pour en savoir plus, consultez notre guide d’utilisation de CONCAT() dans Excel.

8. TRIM()

Comme détaillé dans notre guide complet sur TRIM() dans Excel, cette fonction supprime les espaces en trop au début, au milieu et à la fin. Elle est souvent utilisée pour repérer de faux doublons créés par des espaces superflus.  

Par exemple :

1. Il y a deux espaces en trop en A3 « A   Lamusi », supprimés avec succès par TRIM().
2. En A4 «  Christine Jacoba Aaftink », un espace en trop au début est supprimé, sans fonction complexe, grâce à TRIM(). 

=TRIM(A4)Propulsé par

9. REPLACE() et SUBSTITUTE()

REPLACE() remplace une partie d’un texte par un nouveau texte.

REPLACE(old_text, start_num, num_chars, new_text)Propulsé par

• old_text : le texte d’origine ou la cellule qui le contient.

• start_num : la position de départ pour remplacer des caractères. 

• num_chars : le nombre de caractères à remplacer.

• new_text : le nouveau texte qui remplace l’ancien.

Par exemple, nous changeons A Dijiang en B Dijiang en indiquant la position 1, le nombre de caractères à remplacer (1) et le nouveau caractère « B ». 

=REPLACE(A2,1,1,"B")Propulsé par

SUBSTITUTE() est proche de REPLACE(), mais au lieu d’indiquer une position et une longueur, on fournit uniquement l’ancien et le nouveau texte. 

SUBSTITUTE(text, old_text, new_text, [instance_num])Propulsé par

Note : utilisez instance_num pour ne remplacer qu’une occurrence spécifique

Ici, nous remplaçons "Jacoba" par "Rahim" afin d’afficher en A4 « Christine Rahim Aaftink ».

SUBSTITUTE() ne modifie que les cellules qui contiennent le texte ciblé. La cellule A5, « Per Knut Aaland », ne contient pas « Jacoba », elle reste inchangée. REPLACE() fonctionne par position : il remplace les caractères à la position donnée, qu’ils correspondent ou non.

=SUBSTITUTE(A4,"Jacoba","Rahim")Propulsé par

10. LEFT(), RIGHT() et MID()

LEFT() renvoie un nombre de caractères à partir du début d’un texte. 

Par exemple, pour afficher le prénom à partir de « Christine Jacoba Aaftink », utilisez LEFT() avec 9 caractères. Le résultat affiche « Christine ».

=LEFT(A2,9)Propulsé par

MID() nécessite une position de départ et une longueur pour extraire des caractères au milieu. 

Par exemple, pour afficher le second prénom, commencez à « J » (11e position) et indiquez une longueur de 6 pour « Jacoba ».

=MID(A2,11,6)Propulsé par

RIGHT() renvoie un nombre de caractères à partir de la fin. Il suffit d’indiquer le nombre de caractères. 

Par exemple, pour afficher le nom « Aaftink », utilisez RIGHT() avec 7 caractères. 

=RIGHT(A2,7)Propulsé par

11. UPPER(), LOWER() et PROPER()

UPPER(), LOWER() et PROPER() sont des opérations de base sur les chaînes. On retrouve des équivalents dans Tableau ou Python. Ces fonctions prennent un texte, une cellule ou une plage de cellules contenant du texte. 

UPPER() met tout le texte en majuscules. 

=UPPER(A1)Propulsé par

LOWER() met le texte sélectionné en minuscules.

=LOWER(A1)Propulsé par

PROPER() met le texte en casse de titre : la première lettre de chaque mot en majuscule, le reste en minuscules. 

=PROPER(A1)Propulsé par

12. NOW() et TODAY()

NOW() renvoie la date et l’heure actuelles, et TODAY() renvoie uniquement la date du jour. Nous les utiliserons pour extraire le jour, le mois, l’année, les heures et les minutes d’une date/heure. 

L’exemple ci‑dessous renvoie la date et l’heure actuelles.

=NOW()Propulsé par

Pour extraire les secondes, utilisez la fonction SECOND(). 

=SECOND(NOW())Propulsé par

De même, TODAY() renvoie la date du jour uniquement. 

=TODAY()Propulsé par

Pour extraire le jour, utilisez la fonction DAY().

Vous pouvez également extraire le mois, l’année, le jour de la semaine, les heures et les minutes à partir d’un champ date/heure. 

=DAY(TODAY())Propulsé par

13. DATEDIF()

DATEDIF() calcule la différence entre deux dates et la renvoie en jours, mois ou années selon l’unité choisie.

Attention : DATEDIF est une fonction héritée de compatibilité et peut être inexacte pour certaines unités (p. ex. « MD »). Envisagez DAYS(), YEARFRAC() ou des opérations avec DATE si possible.

Dans l’exemple ci‑dessous, nous renvoyons l’écart en jours en passant « d » comme unité. Assurez‑vous que le premier argument est la date de début et le second la date de fin. 

start_date < end_date

=DATEDIF(A2,B2,"d")Propulsé par

14. VLOOKUP() et HLOOKUP()

La feuille worksheet1 utilisée ici contient l’ensemble des données du jeu Olympics.

worksheet1

VLOOKUP() recherche une valeur dans la première colonne de la matrice et renvoie la valeur de la même ligne dans la colonne indiquée. 

Note : VLOOKUP() et HLOOKUP() sont des fonctions héritées. Microsoft recommande XLOOKUP() pour les nouveaux usages : elle remplace les deux, renvoie par défaut des correspondances exactes, recherche dans n’importe quel sens et propose un argument if_not_found. Lisez notre guide sur l’usage de XLOOKUP et notre comparatif XLOOKUP vs VLOOKUP.

VLOOKUP(lookup_value, table_array, col_index, range_lookup)

• lookup_value : la valeur recherchée présente dans la première colonne. 

• table_array : la plage du tableau, de la feuille ou des cellules sélectionnées avec plusieurs colonnes. 

• col_index : l’indice de la colonne dont extraire la valeur.

• range_lookup : « TRUE » pour une approximation (par défaut), « FALSE » pour une correspondance exacte.

Ici, nous cherchons A Dijiang (A2) dans les colonnes et lignes sélectionnées de worksheet1 (B2:H20). VLOOKUP() parcourt la colonne des noms de worksheet1 et renvoie la 6e colonne, soit l’équipe « China ».

=VLOOKUP(A2,worksheet1!B2:H20,6,FALSE)Propulsé par

HLOOKUP() recherche la valeur dans la première ligne (et non la première colonne) et renvoie la valeur de la colonne identifiée et de la ligne indiquée. 

HLOOKUP(lookup_value, table_array, row_index, range_lookup)

Ici, nous affichons le sexe de A Dijiang en D8. HLOOKUP() cherche le nom en première ligne et renvoie « M » depuis la 2e ligne de la même colonne. Dans les deux cas, range_lookup est à FALSE pour une correspondance exacte. 

=HLOOKUP(B1, B1:E5, 2, FALSE)Propulsé par

15. IF()

La fonction IF() est simple. Comme en programmation, vous fournissez une condition : si elle est vraie, un certain résultat est renvoyé, sinon un autre. 

Par exemple, si l’IMC d’un athlète est inférieur à 24,9, la formule renvoie « Below 24.9 », sinon « 24.9 or above ». Très utile pour transformer des valeurs numériques en catégories.

=IF(G2<24.9,"Below 24.9","24.9 or above")Propulsé par

16. SUMIF()

La fonction SUMIF() additionne uniquement les cellules qui respectent un critère. Elle prend trois arguments :

SUMIF(range, criteria, [sum_range])Propulsé par

• range : les cellules à comparer au critère.

• criteria : le critère, par exemple « M » ou « >10 ». Placez le texte et les opérateurs de comparaison entre guillemets.

• sum_range : les cellules à additionner. Si omis, Excel additionne range lui‑même.

Par exemple, pour additionner le poids des athlètes masculins, on vérifie la colonne sexe (B2:B5) pour « M » et on additionne les valeurs correspondantes de la colonne poids (E2:E5). Le résultat est 215.

=SUMIF(B2:B5,"M",E2:E5)Propulsé par

Pour appliquer plusieurs critères simultanément, utilisez SUMIFS().

17. COUNTIF()

COUNTIF() compte les cellules qui respectent un critère. Contrairement à COUNT(), elle fonctionne aussi avec du texte. Elle prend deux arguments :

COUNTIF(range, criteria)Propulsé par

• range : les cellules à comparer au critère.

• criteria : le critère, par exemple « M » ou « >24 ». Placez le texte et les opérateurs de comparaison entre guillemets.

Par exemple, pour compter les athlètes masculins, on vérifie la colonne sexe (B2:B5) pour « M ». Le résultat est 3.

=COUNTIF(B2:B5,"M")Propulsé par

Pour compter avec plusieurs critères, utilisez COUNTIFS().

18. ROUND()

ROUND() arrondit un nombre au nombre de décimales choisi. Elle prend deux arguments :

ROUND(number, num_digits)Propulsé par

• number : la valeur ou la cellule à arrondir.

• num_digits : le nombre de décimales à conserver. Un entier positif conserve ce nombre de décimales, 0 arrondit à l’entier, un entier négatif arrondit à gauche de la virgule (‑1 arrondit à la dizaine la plus proche).

Par exemple, F2 contient 3,24. Pour arrondir à une décimale, utilisez 1 comme second argument. Le résultat est 3,2.

=ROUND(F2,1)Propulsé par

ROUND() arrondit toujours à la valeur la plus proche. Pour forcer l’arrondi vers le haut ou le bas, utilisez ROUNDUP() ou ROUNDDOWN(). Pour plus d’exemples, consultez notre guide sur ROUND() dans Excel.

19. IFERROR()

IFERROR() teste une formule et renvoie une valeur de votre choix si cette formule produit une erreur. S’il n’y a pas d’erreur, vous obtenez le résultat normal de la formule. Elle prend deux arguments :

IFERROR(value, value_if_error)Propulsé par

• value : la formule ou la cellule à vérifier.

• value_if_error : ce qu’il faut afficher si la formule renvoie une erreur (texte, nombre ou chaîne vide «  »).

Par exemple, reprenons la formule d’IMC. Si la taille d’un athlète manque, la formule divise par zéro et affiche #DIV/0!. En l’enveloppant dans IFERROR(), on affiche « Missing data » à la place.

=IFERROR(E2/(D2/100)^2,"Missing data")Propulsé par

IFERROR() intercepte tous les types d’erreurs, y compris #N/A, #VALUE! et #REF! ; il peut donc masquer de vraies erreurs. Utilisez‑le quand vous savez quelle erreur attendre, puis vérifiez vos résultats.

20. XLOOKUP()

XLOOKUP() recherche une valeur dans une plage et renvoie la valeur correspondante depuis une autre plage. C’est le remplaçant moderne de VLOOKUP() et HLOOKUP(). Elle prend trois arguments obligatoires et trois optionnels :

XLOOKUP(lookup_value, lookup_array, return_array, [if_not_found], [match_mode], [search_mode])Propulsé par

• lookup_value : la valeur recherchée.

• lookup_array : la plage dans laquelle chercher.

• return_array : la plage depuis laquelle renvoyer le résultat.

• if_not_found : ce qu’il faut afficher en l’absence de correspondance, par exemple « Not found ». Si omis, Excel affiche #N/A.

• match_mode : optionnel. Par défaut, XLOOKUP() cherche une correspondance exacte.

• search_mode : optionnel. Par défaut, la recherche se fait du premier au dernier élément.

Par exemple, nous cherchons A Dijiang (A2) dans la colonne des noms de worksheet1 (B2:B20) et renvoyons la valeur correspondante de la colonne équipe (G2:G20). Le résultat est « China », comme avec VLOOKUP().

=XLOOKUP(A2,worksheet1!B2:B20,worksheet1!G2:G20)Propulsé par

Contrairement à VLOOKUP(), vous n’avez pas à compter les positions de colonnes et la colonne de recherche n’a pas besoin d’être la plus à gauche. Pour afficher un message personnalisé si rien n’est trouvé, ajoutez le quatrième argument :

=XLOOKUP(A2,worksheet1!B2:B20,worksheet1!G2:G20,"Not found")Propulsé par

XLOOKUP() est disponible dans Microsoft 365 et Excel 2021 et versions ultérieures. Dans les versions plus anciennes, utilisez VLOOKUP(). Pour en savoir plus, lisez notre guide d’utilisation de XLOOKUP() et notre comparaison XLOOKUP() vs VLOOKUP().

Autres types de formules dans Excel

Voyons maintenant d’autres types de formules Excel, notamment les formules avec opérateurs, les formules matricielles et le formatage conditionnel basé sur des formules.

Formules avec opérateurs

Même une expression aussi simple que A1 + A2 est une formule, car elle effectue un calcul à l’aide de références de cellules et d’un opérateur. Excel met aussi le résultat à jour dynamiquement si A1 ou A2 change. Tout cela constitue des formules :

• Addition : =A1 + B1

• Soustraction : =A1 - B1

• Multiplication : =A1 * B1

• Division : =A1 / B1

Cela peut sembler basique, mais c’est le fondement de schémas plus avancés comme les suites et les calculs récursifs. Voici comment créer une suite de Fibonacci :

• Saisissez 0 en A1 et 1 en A2.
• En A3, entrez =A1+A2, puis faites glisser la poignée de recopie vers le bas. Chaque nouvelle cellule additionne les deux cellules au‑dessus.

Formules matricielles

Les formules matricielles effectuent plusieurs calculs à la fois et renvoient un résultat unique ou plusieurs valeurs réparties sur une plage de cellules. Elles sont particulièrement utiles avec plusieurs conditions ou sur de grands jeux de données.

Exemple : la somme des carrés d’une plage : =SUM(A1:A5^2). Utile, par exemple, pour une régression dans Excel. C’est bien une formule (elle commence par « = » et calcule), mais elle va au‑delà de l’exemple SUM() précédent grâce à l’accent circonflexe.  

Formatage conditionnel basé sur des formules

Excel permet d’appliquer un formatage conditionnel à l’aide de formules personnalisées plutôt que de règles prédéfinies. Par exemple, une formule qui applique un formatage en fonction de conditions par ligne sur plusieurs colonnes ne fonctionnerait pas comme formule de cellule classique, mais fonctionne en formatage conditionnel. 

Exemple : nous surlignons une ligne entière si une cellule respecte une condition. Imaginons une table où la colonne C contient des statuts (« Pending » ou « Shipped ») et où nous voulons surligner les lignes ayant le statut « Pending ». Étapes :

1. Sélectionnez toute la plage du tableau (par ex. A2:E100).

2. Allez dans Accueil > Mise en forme conditionnelle > Nouvelle règle.

3. Sélectionnez Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué.

4. Saisissez cette formule : =$C2="Pending"

5. Cliquez sur Format, choisissez une couleur de remplissage et validez par OK.

Cette formule ressemble à une formule de cellule, mais ici elle s’applique relativement à chaque ligne, sur toute la plage sélectionnée. Dans une cellule, =$C2="Pending" renverrait simplement TRUE ou FALSE. En formatage conditionnel, Excel applique dynamiquement le style aux lignes selon la logique.

Combiner des fonctions dans des formules

Jusqu’ici, nous avons utilisé une fonction à la fois. En pratique, les formules les plus utiles en combinent plusieurs.

Une fonction est une opération intégrée avec un nom et des arguments, comme SUM() ou IF(). Une formule est tout ce que vous saisissez après le signe égal. Elle peut contenir une ou plusieurs fonctions, des références de cellules, des nombres et des opérateurs comme +, / et ^.

Reprenons la formule d’IMC, arrondie :

=ROUND(E2/(D2/100)^2,1)Propulsé par

• = indique à Excel qu’il s’agit d’une formule.

• ROUND est la fonction.

• E2 et D2 sont des références de cellules.

• / et ^ sont des opérateurs.

• 100, 2 et 1 sont des constantes.

Excel procède de l’intérieur vers l’extérieur. Quand une fonction est imbriquée dans une autre, la fonction interne s’exécute d’abord et transmet son résultat à l’externe. Les exemples ci‑dessous se construisent progressivement.

Arrondir un calcul

Notre formule d’IMC renvoie un long décimal. Enveloppez‑la dans ROUND() pour conserver une décimale.

=ROUND(E2/(D2/100)^2,1)Propulsé par

Excel divise d’abord le poids par la taille au carré, puis arrondit le résultat.

Gérer les données manquantes

Si la taille d’un athlète est vide, l’exemple 1 renvoie #DIV/0!. Enveloppez l’ensemble dans IFERROR().

=IFERROR(ROUND(E2/(D2/100)^2,1),"Missing data")Propulsé par

Il y a maintenant trois couches : le calcul, ROUND(), puis IFERROR().

Nettoyer un texte en une étape

TRIM() supprime les espaces superflus et PROPER() corrige la casse. Combinez‑les pour nettoyer A3, « A Lamusi », en une seule étape.

=PROPER(TRIM(A3))Propulsé par

TRIM() s’exécute d’abord, puis PROPER() met en forme le résultat.

Catégoriser des valeurs

Imbriquez un IF() dans un autre pour regrouper les valeurs d’IMC en trois catégories.

=IF(G2<18.5,"Below 18.5",IF(G2<25,"18.5 to 24.9","25 or above"))Propulsé par

Si le premier test est vrai, Excel renvoie « Below 18.5 ». Sinon, il passe au second IF().

Utiliser le résultat d’une fonction dans un calcul

Vous pouvez utiliser le résultat d’une fonction dans un calcul. Pour trouver la part du poids total due aux athlètes masculins, divisez un SUMIF() par un SUM().

=SUMIF(B2:B5,"M",E2:E5)/SUM(E2:E5)Propulsé par

Formatez la cellule en pourcentage pour visualiser le résultat.

Sécuriser une recherche

Si VLOOKUP() ne trouve pas de correspondance, elle renvoie #N/A. Enveloppez‑la dans IFERROR() pour afficher un message plus clair.

=IFERROR(VLOOKUP(A2,worksheet1!B2:H20,6,FALSE),"Not found")Propulsé par

XLOOKUP() propose déjà cet argument en quatrième paramètre, donc pas besoin de IFERROR().

Conseils pour construire des formules longues

• Construisez de l’intérieur vers l’extérieur. Faites fonctionner la fonction imbriquée seule dans une cellule, puis encapsulez‑la.
• Surveillez les parenthèses. Chaque parenthèse ouvrante doit être fermée. Excel colorie les paires correspondantes à la saisie.
• Restez lisible. Si une formule dépasse deux ou trois niveaux, scindez‑la avec des colonnes d’aide.

Former vos équipes sur Excel

Nous avons couvert les formules Excel indispensables, mais faire monter en compétences plusieurs personnes n’est pas toujours simple. Nous avons un guide dédié à la formation Excel en entreprise, à lire en complément.

Excel n’est pas qu’un tableur : c’est souvent essentiel pour la gestion des données, l’analyse financière et la décision. Investir dans la formation Excel augmente la productivité, la précision et l’efficacité de vos équipes. Parmi les bénéfices clés :

• Analyse de données : des compétences avancées permettent des interprétations plus fines et de meilleures décisions.

• Efficience : l’automatisation via les feuilles réduit le travail manuel et les erreurs.

• Précision financière : la maîtrise de fonctions comme VLOOKUP() et des tableaux croisés dynamiques améliore le pilotage financier.

• Fluidification opérationnelle : les outils de manipulation des données optimisent le traitement de grands volumes.

• Avantage concurrentiel : la maîtrise d’Excel affine les processus et accélère la génération d’insights.

Pour former vos équipes, des bases aux formules avancées, DataCamp For Business est l’outil idéal. Que votre équipe compte 2 ou 10 000 personnes, DataCamp For Business propose de nombreux contenus dédiés aux feuilles de calcul et à Excel, la création de parcours personnalisés pour adapter et déployer la formation à grande échelle, ainsi que des rapports détaillés pour mesurer l’impact de vos formations. Demandez une démo dès aujourd’hui pour démarrer. 

Conclusion

Microsoft Excel est une application puissante et simple d’utilisation pour l’analyse et le reporting. Dans cet article, nous avons vu l’importance des formules de base et comment elles étendent vos capacités de calcul. Nous avons également passé en revue plusieurs façons d’ajouter des formules et détaillé les formules essentielles. 

Pour approfondir Excel et l’analyse des données avec ces formules, suivez notre cours Data Analysis in Excel. Vous y apprendrez les bases de l’exploration, du traitement et de l’analyse des données. Si vous êtes adepte de l’écosystème Google et utilisez Google Sheets, essayez Data Analysis in Spreadsheet.

Vous pouvez aussi aller plus loin avec les fundamentals des feuilles de calcul : analyse de données, manipulation avancée, tableaux croisés et visualisation. Enfin, consultez notre aide‑mémoire Excel pour une référence rapide et découvrez les types de données dans Excel.