Como adicionar dias a uma data no Excel: Todos os métodos explicados

Métodos para adicionar dias a uma data no Excel

Nesta seção, vou comparar as abordagens mais comuns, começando pela opção mais simples e direta.

Método 1: Aritmética simples (somando ou tirando dias direto)

A maneira mais rápida de adicionar dias a uma data no Excel é usando aritmética básica. Como o Excel guarda datas como números, você pode adicionar ou subtrair dias como faria com qualquer outro valor numérico. Você pode fazer o seguinte com aritmética simples:

Adicionar dias com uma fórmula

Se a célul A2 e contiver uma data, você pode adicionar dias simplesmente adicionando um número. Por exemplo, a fórmula abaixo adiciona sete dias corridos à data em A2 e mostra a nova data.

=A2 + 7

Subtraia dias usando números negativos

Você também pode tirar um número de uma data pra achar uma data passada. Por exemplo, a fórmula abaixo antecipa a data em cinco dias.

=A2 - 5

Aplicando fórmulas em várias linhas

Para aplicar a mesma lógica a uma lista de datas:

• Digite a fórmula na primeira linha.
• Selecione a célula.
• Arrastea alça de preenchimento para baixo paracopiar a fórmula para outras linhas.

O Excel ajusta automaticamente as referências das células, tornando esse método eficiente para grandes conjuntos de dados.

Usando Colar Especial para ajustes rápidos

Se você não quiser usar fórmulas, pode usar Colar Especial seguindo os passos abaixo:

• Digite o número de dias que você quer adicionar em uma célula vazia.
• Copia essa célula.
• Selecione as células de data que você quer ajustar.
• Clique com o botão direito do mouse e escolha Colar especial → Adicionar. O Excel vai atualizar todas essas datas na hora e mantê-las como valores estáticos, em vez de fórmulas.

A limitação do método aritmético simples é que ele sempre conta todos os dias do calendário. Então, fins de semana e feriados estão incluídos, o que pode não ser legal para prazos comerciais, cronogramas de projetos ou cálculos de folha de pagamento. Nesses casos, você vai precisar de uma abordagem mais avançada, que eu vou mostrar mais adiante no tutorial.

Método 2: A função DATE() para cálculos estruturados e condicionais

A função DATE() é útil quando você precisa de mais controle sobre como as datas são criadas ou ajustadas. Isso o torna ideal para cálculos estruturados, lógica condicional e cenários em que as datas podem mudar dinamicamente. 

Estrutura e parâmetros da função DATE()

Abaixo está a sintaxe básica da função ` DATE() `.

=DATE(year, month, day)

Onde:

• ano: O valor do ano
• mês: O número do mês
• dia: O dia do mês

Então, dá pra reconstruir uma data tirando suas partes. Por exemplo, a fórmula abaixo adiciona dez dias à data em A2, mudando só a parte do dia, mas deixando o ano e o mês originais como estão.

=DATE(YEAR(A2), MONTH(A2), DAY(A2) + 10)
`

Lidando com os limites do final do mês e do final do ano

Um dos pontos fortes da função ` DATE() ` é que ela lida com o estouro automaticamente. Por exemplo, se você adicionar 5 dias a 29 de janeiro, o Excel sabe que o resultado é 3 de fevereiro.

A função ` DATE() ` também lida automaticamente com anos bissextos. Por exemplo, se você adicionar dias às datas em fevereiro, que é um ano bissexto, ele vai considerar corretamente o dia 29 de fevereiro, sem precisar de lógica extra.

Usando referências de células para fórmulas flexíveis

Em vez de codificar os valores, você pode referenciar as células para tornar a fórmula dinâmica e reutilizável em todas as linhas.

=DATE(YEAR(A2), MONTH(A2), DAY(A2) + B2)

Como lidar com datas em branco ou inválidas

Para evitar erros quando as células de origem estiverem vazias ou tiverem dados inválidos, você pode colocar a fórmula dentro de uma função IF() ou IFERROR(). Esses métodos mantêm sua planilha organizada e evitam mensagens de erro desnecessárias.

A fórmula abaixo mostra uma célula em branco se a célula de origem estiver vazia ou tiver um valor que não seja no formato de data.

=IFERROR(DATE(YEAR(A2), MONTH(A2), DAY(A2) + B2), "")

Método 3: A função EDATE() para adicionar meses e anos

A função EDATE() no Excel é importante nos cálculos de datas se você quiser ajustar suas datas por um mês ou ano inteiro.

Objetivo e sintaxe da função EDATE()

A função ` EDATE() ` altera uma data em um número específico de meses. Abaixo está a sintaxe:

=EDATE(start_date, months)

Onde: 

• start_date: A data original

• months: O número de meses a adicionar ou subtrair

A fórmula abaixo adiciona 3 meses à data atual:

=EDATE(A2, 3)

Da mesma forma, você pode tirar 3 meses usando a mesma lógica, mas com um valor negativo.

=EDATE(A2, -3)

Adicionando e subtraindo anos usando compensações mensais

Você pode adicionar ou subtrair anos usando a função EDATE() com o número de meses no argumento month. Por exemplo, a fórmula abaixo tira 2 anos (24 meses) da data na célul A2.

=EDATE(A2, -24)

Combinando EDATE() com aritmética simples

Você também pode juntar a função ` EDATE() ` com mês e dia para casos específicos. Por exemplo, a fórmula abaixo adiciona 2 meses e sete dias ao calendário à data na célula A2.

=EDATE(A2, 1) + 7

Método 4: WORKDAY() e WORKDAY.INTL() para calcular dias úteis

As funções WORKDAY() e WORKDAY.INTL() permitem adicionar ou subtrair dias, ignorando automaticamente os dias não úteis. Essas funções são perfeitas para cronogramas de projetos, prazos e agendas operacionais.

Usando a função WORKDAY() para ignorar fins de semana

A função WORKDAY() no Excel foi criada pra pular sábados e domingos automaticamente. Tem a seguinte sintaxe:

=WORKDAY(start_date, days)

Onde:

• start_date: A data original

• days: O número de dias a adicionar ou subtrair

Por exemplo, a fórmula abaixo adiciona cinco dias úteis à data em A2, pulando sábados e domingos automaticamente.

=WORKDAY(A2, 5)

Incluindo feriados com uma lista de feriados

Vamos supor que você queira adicionar dias no Excel, mas também queira levar em conta feriados e dias de folga em toda a empresa. Siga os passos abaixo para manter cálculos precisos:

• Crie uma lista de datas de feriados em um intervalo separado, como D2:D5.

• Adicione esse intervalo como o terceiro argumento na função ` WORKDAY() `.

=WORKDAY(A2, 5, D2:D5)

Usando esse método, todas as datas listadas no intervalo D2:D5 são excluídas do cálculo, mesmo que caiam em dias úteis.

Em vez de codificar as células de feriados, é melhor manter os feriados em uma coluna ou tabela dedicada. Como prática recomendada, use sempre um intervalo nomeado ou uma tabela do Excel. Essa abordagem mantém suas fórmulas organizadas e garante que todos os cálculos dos dias úteis fiquem consistentes em toda a pasta de trabalho.

Recomendo fazer nosso Funções Avançadas do Excel para aprender mais sobre deslocamento e intervalos dinâmicos no Excel.

Padrões personalizados para fins de semana com WORKDAY.INTL()

Como nem todos os horários de trabalho seguem o fim de semana de sábado e domingo, o Excel oferece a função “ WORKDAY.INTL() ” (Fim de semana personalizado), que permite definir padrões de fim de semana personalizados. A sintaxe é assim:

=WORKDAY.INTL(start_date, days, weekend, holidays)

Onde:

• start_date: A data a partir da qual o cálculo começa e não é considerada como um dia útil.

• days: O número de dias úteis a adicionar ou subtrair.

• weekend (opcional): Especifica quais dias são considerados fins de semana. Pode ser um número (1–17) que representa padrões de fim de semana pré-definidos [1 → sábado e domingo (padrão), 2 → domingo e segunda-feira, 7 → sexta-feira e sábado]. Ele também pode conter uma sequência de texto de 7 caracteres, como "0000011", em que 1 marca os dias de fim de semana e 0 marca os dias úteis, começando na segunda-feira.

• holidays (opcional): Um intervalo ou conjunto de datas que também devem ser excluídas dos dias úteis

Por exemplo, a fórmula abaixo mostra a data 10 dias úteis depois de 15 de janeiro de 2026, sem contar sábados, domingos e os feriados listados nas células D2:D5.

=WORKDAY.INTL("2026-01-15", 10, 1, D2:D5)

Funções relacionadas: NETWORKDAYS() e NETWORKDAYS.INTL()

Enquanto WORKDAY() e WORKDAY.INTL() retornam uma data, as funções NETWORKDAYS() e NETWORKDAYS.INTL() contam quantos dias úteis se passam entre duas datas. São úteis quando você precisa medir a duração, e não calcular um prazo.

A função NETWORKDAYS() conta os dias úteis entre duas datas, sem contar sábados, domingos e feriados opcionais. No exemplo abaixo, a fórmula retorna 7, que é o número de dias úteis entre 1º de janeiro e 10 de janeiro (sem contar os fins de semana).

=NETWORKDAYS("2026-01-01", "2026-01-10")

Da mesma forma, a função NETWORKDAYS.INTL() conta os dias úteis com regras personalizadas para fins de semana, o que é útil para regiões com fins de semana fora do padrão. Por exemplo, a fórmula abaixo mostra o número de dias úteis, considerando que sexta-feira e sábado são fins de semana.

=NETWORKDAYS.INTL("2026-01-01", "2026-01-10", 7)

Limitações a ter em conta

Embora as funções WORKDAY() e WORKDAY.INTL() do Excel funcionem bem para calendários comerciais padrão, elas têm as seguintes limitações:

• Eles não lidam com turnos rotativos ou jornadas de trabalho parciais.
• Eles não conseguem modelar calendários complexos com horários diários variáveis.
• O agendamento avançado pode precisar de colunas auxiliares ou lógica personalizada.

Uma observação sobre o sistema de datas do Excel

Ao trabalhar com datas no Excel, você pode se deparar com alguns resultados inesperados, geralmente não provenientes da fórmula utilizada. Nesta seção, vou te ajudar a entender o que está acontecendo nos bastidores e evitar armadilhas comuns.

O Excel guarda as datas como números de série.

O Excel guarda as datas como números de série, onde cada número inteiro representa um dia. Por exemplo, 1º de janeiro de 1900 é guardado como 1, 2 de janeiro de 1900 como 2 e assim por diante. Como as datas são valores numéricos, você pode adicionar ou subtrair dias usando aritmética simples, e é por isso que as fórmulas de data funcionam tão naturalmente no Excel.

Datas vs. valores de texto

Nem tudo que parece um encontro é realmente um encontro. Uma data verdadeira do Excel é um número com um formato de data aplicado. As datas em formato de texto, muitas vezes importadas de sistemas externos, não funcionam direito nos cálculos. Fórmulas que fazem referência a datas de texto podem retornar erros ou resultados incorretos.

Para verificar essa inconsistência, altere o formato da célula para Geral. Se você vir um número, é uma data real, mas se continuar igual, é texto.

Os sistemas de datação de 1900 e 1904

O Excel aceita dois sistemas de data: o sistema de data de 1900, que é o padrão no Windows, e o sistema de data de 1904, usado historicamente no macOS.

A diferença entre esses dois sistemas é de 1.462 dias. Então, é importante confirmar que todo mundo está usando o mesmo sistema de datas quando compartilhar pastas de trabalho com cálculos de datas, pra garantir a consistência.

Como o Excel lida com anos bissextos

O Excel considera automaticamente os anos bissextos ao fazer cálculos de datas. Mas, por causa de compatibilidade, o Excel considera 1900 como um ano bissexto, mesmo que não tenha sido. Esse ajuste pode explicar por que as datas antigas se comportam de forma inesperada, mas não afeta muito os fluxos de trabalho modernos.

Problemas comuns com formatos e configurações regionais

Pela minha experiência trabalhando com datas no Excel, percebi que os problemas mais comuns podem vir das seguintes situações:

• Configurações regionais que interpretam datas de forma diferente, como MM/DD/AAAA versus DD/MM/AAAA.
• Dados importados em que as datas são armazenadas como texto
• Formatação inconsistente entre as células

Esses problemas podem fazer com que as fórmulas falhem sem aviso ou deem resultados errados. Vou te mostrar como resolver esses erros na próxima seção.

Resolução de problemas relacionados ao cálculo de datas

Pelo que vimos, nem todos os erros nos cálculos de datas vêm de fórmulas erradas. Aqui estão alguns métodos para resolver problemas comuns com datas no Excel.

Identificando e convertendo datas em texto

Se uma data estiver salva como texto, funções como WORKDAY() ou EDATE() não vão funcionar. Muitas vezes, você pode converter datas em texto digitando a data de novo manualmente ou usando DATEVALUE() quando o formato do texto for reconhecível.

Você também pode usar o ferramenta Texto para Colunas para corrigir as datas importadas seguindo os passos abaixo:

Selecione a coluna afetada

Vá para Dados → Texto para colunas

Escolha Delimitado ou Largura fixa

Defina o tipo de dados da coluna como Data do . Selecione Concluir.

Problemas de formatação e números de série

Se uma célula mostrar um número em vez de uma data, o valor geralmente está certo, mas formatado de forma errada. Pra resolver isso, vá até aabaPágina inicial do , clique no menu suspenso Formato numérico e escolha Data curta.

Dá uma olhada na folha de dicas de atalhos do Excel para aprender como melhorar a produtividade aprendendo os atalhos para diferentes recursos do Excel.

Lidando com espaços extras e delimitadores não padrão

Os dados importados podem ter espaços à esquerda ou separadores diferentes, como " 01/21/2026". Você pode usar funções como TRIM() ou SUBSTITUTE() para tirar os espaços antes de fazer outras operações.

Ambiguidade do ano com dois dígitos

Os anos com dois dígitos podem ser interpretados de forma diferente dependendo das configurações do sistema. O Excel geralmente trata 00-29 como os anos 2000 e 30-99 como os anos 1900. Para evitar esse problema, sempre use anos com quatro dígitos, como 2029, ao inserir ou importar datas.

Gerenciando entradas mistas com uma coluna auxiliar

Se a sua coluna tiver uma mistura de datas e notas como “A definir”, seus cálculos não vão funcionar. Para evitar esse problema, use colunas auxiliares para limpar ou converter valores ou aplique a função IFERROR() para detectar entradas inválidas.

Cálculos avançados de datas e cenários dinâmicos

Depois que você se sentir à vontade com as funções básicas de data, o Excel permite que você crie cálculos mais dinâmicos e flexíveis. Nesta seção, vou mostrar como criar funções avançadas de data para automatizar seu trabalho.

Combinando desvios de ano, mês e dia

Você sempre pode ajustar várias partes de uma data em uma única fórmula combinando funções. Por exemplo, a fórmula abaixo adiciona um ano, dois meses e dez dias à data original em A2. O Excel lida automaticamente com qualquer excesso entre meses ou anos.

=DATE(YEAR(A2) + 1, MONTH(A2) + 2, DAY(A2) + 10)

Ano fiscal e lógica não calendária

Nem todas as organizações seguem um calendário de janeiro a dezembro. Você pode calcular os anos fiscais ajustando o mês antes de extrair o ano. Por exemplo, se o seu ano fiscal começa em abril, você pode calcular o “Ano Fiscal” a partir de uma data padrão usando a lógica abaixo para recuar a data em 3 meses:

=YEAR(EDATE(A2, -3))

Datas dinâmicas com TODAY() e NOW()

Se você lida com cálculos que precisam ser atualizados automaticamente todos os dias, pode usar as seguintes funções:

• =TODAY(): Mostra a data de hoje.

• =NOW(): Mostra a data e a hora exatas de hoje.

Gerando intervalos de datas com SEQUENCE()

Você pode usar a função SEQUENCE() se precisar criar rapidinho uma lista de datas seguidas. Por exemplo, =SEQUENCE(30, 1, TODAY(), 1) cria uma lista de 30 datas a partir de hoje.

Destacando datas com formatação condicional

Se você quiser chamar a atenção para datas importantes na sua planilha, pode usar a formatação condicional. Por exemplo, você pode usar a formatação pra destacar prazos que estão chegando, marcar tarefas atrasadas ou separar visualmente datas passadas e futuras.

Recomendo conferir nosso curso Formatação condicional no Google Sheets para aprender como aplicar formatação condicional para validar dados e obter insights rápidos.

Conclusão

O Excel tem várias maneiras de adicionar e gerenciar datas, e escolher o método certo depende do caso de uso. Para manter pastas de trabalho eficientes, use aritmética simples para dias de calendário, EDATE() para ciclos mensais e WORKDAY() para agendas comerciais, sempre verificando se suas datas estão armazenadas como números seriais reais, em vez de texto.

Se você quer melhorar suas habilidades no Excel, recomendo fazer nosso curso Análise de Dados no Excel. Este curso vai te ajudar a dominar análises avançadas e impulsionar sua carreira. Também recomendo fazer nosso curso Power Query Intermediário no Excel pra aprender sobretransformação de dados e usar a linguagem M pra criar funções dinâmicas.