Funzione SUMIFS() in Excel: sommare dati con criteri multipli

La funzione SUMIFS() in Excel somma i numeri in base a più condizioni, dandoci un controllo preciso sui calcoli. A differenza di SUMIF(), che verifica una sola condizione, SUMIFS() gestisce più condizioni contemporaneamente.

In questo articolo ti mostrerò come usare SUMIFS() con esempi avanzati e consigli per la risoluzione dei problemi. Alla fine saprai usare SUMIFS() per rendere i tuoi calcoli più accurati ed efficienti.

La risposta rapida

Per usare la funzione SUMIFS() in Excel:

• Digita =SUMIFS( per iniziare la funzione.

• Seleziona l'intervallo che contiene i valori da sommare.

• Seleziona l'intervallo su cui applicare la condizione.

• Inserisci la condizione da verificare.

• Chiudi la parentesi e premi Invio.

Qui ho sommato tutte le vendite superiori a 200.

=SUMIFS(B2:B8, B2:B8, ">200")

Somma i valori usando SUMIFS(). Immagine dell'autore.

Capire la funzione SUMIFS()

La funzione SUMIFS() in Excel somma i valori solo quando sono soddisfatte tutte le condizioni specificate. Supporta operatori logici come maggiore di >, minore di <, uguale a = e diverso da <>, oltre a caratteri jolly per i confronti parziali. La funzione lavora con numeri, testo e date.

Sintassi di SUMIFS()

La funzione SUMIFS() definisce prima l'intervallo di valori da sommare, seguito da coppie di intervalli dei criteri e criteri. Nota che SUMIFS() può gestire più di una condizione logica.

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Qui:

• sum_range è l'intervallo di celle che vuoi sommare.

• criteria_range1 è il primo intervallo in cui verifichiamo una condizione.

• criteria1 è la condizione applicata a criteria_range1.

• [criteria_range2, criteria2], … sono opzionali. Puoi aggiungere altre coppie di intervalli e condizioni. Ogni coppia aggiunge un'altra condizione che deve essere soddisfatta.

Nota che il criteria_range (l'intervallo in cui vengono verificate le condizioni) deve avere lo stesso numero di righe e colonne di sum_range (l'intervallo da sommare).

Esempio di SUMIFS()

Proviamo un esempio di base. Ho un dataset di frutta con quantità e vendite. E voglio trovare il totale delle vendite delle Mele dove la Quantità è maggiore di 5. Quindi la mia formula diventa:

=SUMIFS(C2:C8, A2:A8, "Apples", B2:B8, ">5")

Qui C2:C8 è l'intervallo di valori da sommare (Sales ($)). A2:A8, "Apples" è la condizione per includere solo le righe in cui il prodotto è Apples. E B2:B8, ">5" è la condizione per includere solo le righe in cui la Quantità supera 5.

Formula SUMIFS() per sommare le vendite in base a una condizione. Immagine dell'autore.

SUMIF() vs. SUMIFS()

La differenza principale tra SUMIF() e SUMIFS() è il numero di condizioni utilizzate. SUMIF() gestisce una singola condizione. Invece SUMIFS() può gestire più condizioni. 

Casi d'uso di SUMIFS() in Excel

Ora che sai come funziona la funzione SUMIFS(), vediamo alcuni casi avanzati in cui possiamo usarla nel mondo reale.

Uso di SUMIFS() con diversi tipi di dati

SUMIFS() può lavorare con diversi tipi di dati come numeri, testo e date. Supponiamo di avere un report vendite, ma in alcune righe mancano i nomi dei clienti. E voglio sommare solo quelle in cui abbiamo il nome del cliente. Per questo uso la seguente formula:

=SUMIFS(C2:C5, A2:A5, "<>")

Questa formula guarda la colonna Customer, controlla le celle non vuote e poi somma le vendite corrispondenti.

Somma tutte le celle non vuote con la funzione SUMIFS(). Immagine dell'autore.

Per sommare le vendite in cui mancano i nomi dei clienti, uso questa formula:  

=SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Somma le celle vuote con la funzione SUMIFS(). Immagine dell'autore.

Invece di scrivere la condizione nella formula, possiamo salvarla in un'altra cella. Se voglio sommare le vendite per Sarah Lee, la scrivo nella cella E3 e uso questa formula:

=SUMIFS(C2:C5, A2:A5, E3)

Ogni volta che il valore in E3 cambia, il totale si aggiorna automaticamente. 

Usa SUMIFS() per sommare valori con un riferimento di cella. Immagine dell'autore.

Applicare la logica OR in SUMIFS()

Sappiamo che SUMIFS() usa solo la logica AND, il che significa che tutte le condizioni impostate devono essere vere per sommare i valori. Tuttavia, se vogliamo usare la logica OR, che somma i valori anche quando è soddisfatta una sola tra più condizioni, possiamo farlo combinando più SUMIFS().

Per esempio, se voglio sommare le vendite per John Doe OPPURE Drake White, combino due formule SUMIFS() così:

=SUMIFS(C2:C8, A2:A8, "John Doe") + SUMIFS(C2:C8, A2:A8, "Drake White")

Dato che Drake White non è nell'elenco, quella parte della formula restituisce 0. Il totale include solo le vendite di John Doe, mostrando come funziona la logica OR.

Usa la logica OR nella funzione SUMIFS(). Immagine dell'autore.

In Excel 365 o versioni successive, possiamo semplificare con una formula di matrice e otterremo lo stesso risultato.

=SUMIFS(C2:C8,A2:A8,{"John Doe","Drake White"})

Usa la formula di matrice di SUMIFS(). Immagine dell'autore.

SUMIFS() con intervalli denominati

Possiamo anche usare gli intervalli denominati invece dei riferimenti di cella come A2:A5 o C2:C5. In questo esempio, seleziono A2:A5 e lo chiamo Customer_list e seleziono C2:C5 e lo chiamo Sales_list. Ora per trovare il totale delle vendite di John, uso questa formula: 

=SUMIFS(Sales_list, Customer_list, "John")

Somma i valori con SUMIFS() usando gli intervalli denominati. Immagine dell'autore.

Uso dei caratteri jolly per corrispondenze parziali

I caratteri jolly sono caratteri speciali (* o ?) che rappresentano caratteri sconosciuti o variabili nelle ricerche di testo e nel pattern matching: 

• * corrisponde a qualsiasi numero di caratteri (incluso zero).

• ? corrisponde esattamente a un carattere.

Ecco come funzionano: 

• A* corrisponderà a tutte le celle che iniziano con A.

• *A corrisponderà a tutte le celle che finiscono con A.

• *A* corrisponderà a tutte le celle che contengono A in qualsiasi punto.

La funzione SUMIFS() offre capacità di confronto su testo tramite caratteri jolly. Identifica valori che iniziano, finiscono o contengono specifici pattern di testo. Diciamo che voglio sommare le vendite per i codici prodotto che iniziano con ABC. In questo caso, la mia formula è così:

=SUMIFS(D2:D8, C2:C8, "ABC*")

Per sommare le vendite che finiscono con 00, scrivo:

=SUMIFS(B2:B7, A2:A7, "*00")

Usa i caratteri jolly in SUMIFS(). Immagine dell'autore.

Somma in base a intervalli di date

SUMIFS() può anche sommare valori all'interno di un intervallo di date specifico. Se voglio conoscere tutte le vendite di gennaio 2023, uso la seguente formula: 

=SUMIFS(D2:D8, B2:B8, ">=01-Jan-2023", B2:B8, "<=31-Jan-2023") 

Questa formula controllerà le date dal 1° gennaio 2023 al 31 gennaio 2023 e poi sommerà tutte le vendite. 

Somma l'intervallo di date usando SUMIFS(). Immagine dell'autore.

Somma di valori con più condizioni numeriche

La funzione SUMIFS() può sommare valori che rientrano in specifici intervalli numerici. Qui ho un dataset casuale e voglio sommare i valori in cui le Vendite sono maggiori di 100 ma inferiori a 300. Per questo uso la seguente formula:  

=SUMIFS(C2:C5, C2:C5, ">100", C2:C5, "<300")

Questa formula specifica prima l'intervallo di celle da sommare (C2:C5) come primo argomento. Poi applica due condizioni descritte sopra allo stesso intervallo. La funzione SUMIFS() valuta simultaneamente ogni cella dell'intervallo rispetto a entrambi i criteri. E puoi vedere che solo le celle con valori compresi tra 100 e 300 (esclusi) sono incluse nella somma. 

Somma i valori all'interno di un intervallo numerico usando SUMIFS(). Immagine dell'autore.

Risoluzione dei problemi se SUMIFS() non funziona

Se la tua funzione SUMIFS() non funziona come previsto, verifica i seguenti aspetti:

Dimensioni degli intervalli non corrispondenti 

Se la tua formula SUMIFS() restituisce un errore, potrebbe essere dovuto a intervalli di dimensioni diverse. In SUMIFS(), tutti gli intervalli che selezioni, come il sum_range e i criteria_ranges, devono avere lo stesso numero di righe e colonne.

Per esempio, in questa formula l'intervallo di somma è B2:B8, ma l'intervallo dei criteri è A2:A7, che ha una riga in meno:

=SUMIFS(B2:B8, A2:A7, "Drake White")

Questa mancata corrispondenza darà un errore #VALUE!. Quindi, assicurati che tutti gli intervalli abbiano la stessa dimensione, così:

=SUMIFS(B2:B8, A2:A8, "John Doe")

Formattazione scorretta dei criteri di testo 

In SUMIFS(), devi inserire i criteri di testo tra virgolette. Se non lo fai, potresti ottenere risultati scorretti. Per esempio, questa formula restituirà 0 perché Excel vede Drake White come un nome o una variabile, non come testo: 

=SUMIFS(B2:B8, A2:A8, Drake White)

Per risolvere, racchiudi Drake White tra virgolette in questo modo e otterrai l'output corretto:

=SUMIFS(B2:B8, A2:A8, "Drake White")

Valori zero inattesi

Se la formula restituisce 0 quando ti aspetti un risultato, potrebbe dipendere da una formattazione scorretta dei criteri numerici o basati su date. In SUMIFS(), condizioni come >100 o <01-Jan-2023 devono essere scritte come stringhe di testo tra virgolette. Altrimenti restituirà un errore o 0 perché la condizione non è tra virgolette.

Oppure possiamo salvare la data in una cella separata (ad es., C1) e usare questo:

=SUMIFS(B2:B8, A2:A8, ">="&C1)

SUMIFS() non funziona con trasformazioni di matrici

SUMIFS() non supporta alcune trasformazioni come l'estrazione di componenti specifiche dai dati all'interno della formula. Per esempio, se voglio sommare le vendite di gennaio e marzo, SUMIFS() non funzionerà direttamente con criteri di matrice {"January","March"}. 

Per mostrarlo, supponi di avere i mesi nella colonna A (January, February, March, April) e i valori di vendita nella colonna B (100, 200, 300, 400). La formula

=SUMIFS(B2:B5, A2:A5, {"January","March"})

non restituirà la somma attesa di 400 (100 + 300). Invece, possiamo usare SUMPRODUCT():

=SUMPRODUCT((A2:A5={"January","March"})*B2:B5)

oppure racchiudere SUMIFS() in SUM() usando questa formula:

=SUM(SUMIFS(B2:B5, A2:A5, {"January","March"}))

Entrambe le soluzioni gestiranno correttamente i criteri di matrice e restituiranno la somma delle vendite di gennaio e marzo.

Buone pratiche per usare SUMIFS()

Per ottenere il massimo dalla funzione SUMIFS(), dobbiamo evitare errori comuni seguendo queste buone pratiche: 

• Usa i caratteri jolly per filtri flessibili: è una buona pratica usare i caratteri jolly quando filtri i dati perché a volte i nostri dati non sono perfettamente organizzati. Magari i nomi dei prodotti non sono sempre scritti allo stesso modo o ci sono spazi extra. I caratteri jolly ti aiutano a trovare pattern senza richiedere testo esatto.

• Evita di scrivere i criteri nella formula: invece di digitare le condizioni direttamente nella formula, salvale in una cella separata. Se scrivi nella formula una condizione come "Drake White" o ">100", dovrai modificarla ogni volta che vuoi cambiarla. Con i riferimenti di cella, invece, la formula si aggiornerà automaticamente.

• Usa riferimenti assoluti quando copi le formule: quando copi una formula SUMIFS() in altre celle, Excel regola automaticamente i riferimenti. Se non vuoi che accada, usa riferimenti assoluti aggiungendo $ per bloccare le celle.

Considerazioni finali

SUMIFS() è una funzione di Excel che ci aiuta ad analizzare i dati filtrando e sommando i numeri che corrispondono a criteri specifici. È ottima per attività come monitorare le vendite per area, riassumere le spese per categoria o contare l'inventario per tipo di prodotto. Una volta che ti abitui a SUMIFS(), ti renderai conto che fa risparmiare tempo e ti aiuta a individuare tendenze importanti nei tuoi dati senza soluzioni complicate.

Se vuoi approfondire queste competenze, dai un'occhiata al nostro corso Data Analysis in Excel, al corso Data Preparation in Excel e al corso Data Visualization in Excel o al percorso di abilità Excel Fundamentals. Ti aiuteranno a rinfrescare le competenze esistenti.