Excel'de SUMIFS() İşlevi: Birden Fazla Ölçüte Göre Toplama

Excel'deki SUMIFS() işlevi, birden fazla koşula göre sayıları toplayarak hesaplamalar üzerinde hassas kontrol sağlar. Tek bir koşulu kontrol eden SUMIF()'ten farklı olarak, SUMIFS() aynı anda birkaç koşulu işleyebilir.

Bu yazıda, SUMIFS()'i gelişmiş örneklerle ve sorun giderme ipuçlarıyla nasıl kullanacağınızı göstereceğim. Yazının sonunda, hesaplamalarınızı daha doğru ve verimli hale getirmek için SUMIFS()'i nasıl kullanacağınızı biliyor olacaksınız.

Kısa Cevap

Excel'de SUMIFS() işlevini kullanmak için:

• İşlevi başlatmak için =SUMIFS( yazın.

• Toplanacak değerleri içeren aralığı seçin.

• Koşulun uygulanacağı aralığı seçin.

• Eşleştirilecek koşulu girin.

• Parantezi kapatın ve Enter'a basın.

Burada, 200'den büyük tüm satışları topladım.

=SUMIFS(B2:B8, B2:B8, ">200")

SUMIFS() ile değerleri toplayın. Görsel: Yazar.

SUMIFS() İşlevini Anlamak

Excel'deki SUMIFS() işlevi, yalnızca belirtilen tüm koşullar karşılandığında değerleri toplar. Büyüktür >, küçüktür <, eşittir = ve eşit değildir <> gibi mantıksal işleçleri; ayrıca kısmi eşleşmeler için joker karakterleri destekler. İşlev sayılar, metinler ve tarihlerle çalışır.

SUMIFS() Sözdizimi

SUMIFS() işlevi önce toplanacak değerlerin aralığını, ardından koşul aralığı ve ölçütten oluşan ikilileri tanımlar. Dikkat edin, SUMIFS() birden fazla mantıksal koşulu işleyebilir.

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Burada:

• sum_range, toplamak istediğiniz hücre aralığıdır.

• criteria_range1, bir koşulun kontrol edildiği ilk aralıktır.

• criteria1, criteria_range1'e uygulanan koşuldur.

• [criteria_range2, criteria2], … isteğe bağlıdır. Daha fazla aralık ve koşul çifti ekleyebilirsiniz. Her çift, karşılanması gereken başka bir koşul ekler.

Koşulların kontrol edildiği criteria_range'in, toplama yapılan sum_range ile aynı satır ve sütun sayısına sahip olması gerektiğini unutmayın.

SUMIFS() örneği

Basit bir örnek deneyelim. Meyvelerin miktarları ve satışlarının olduğu bir veri kümesine sahibim. Ve Miktar 5'ten büyük olan Elmaların toplam satışını bulmak istiyorum. Dolayısıyla formülüm şöyle olur:

=SUMIFS(C2:C8, A2:A8, "Apples", B2:B8, ">5")

Burada C2:C8 toplanacak değerlerin aralığıdır (Sales ($)). A2:A8, "Apples" yalnızca ürünün Elma olduğu satırları dahil etme koşuludur. Ve B2:B8, ">5" yalnızca Miktarın 5'i aştığı satırları dahil etme koşuludur.

Koşula göre satışları toplamak için SUMIFS() formülü. Görsel: Yazar.

SUMIF() ve SUMIFS()

SUMIF() ile SUMIFS() arasındaki temel fark, kullandıkları koşul sayısıdır. SUMIF() tek bir koşulu işler. Ancak SUMIFS() birden çok koşulu işleyebilir. 

Excel'de SUMIFS() için Kullanım Senaryoları

Artık SUMIFS() işlevinin nasıl çalıştığını bildiğinize göre, bunu gerçek dünyada kullanabileceğimiz bazı ileri düzey durumlara bakalım.

SUMIFS()'i farklı veri türleriyle kullanma

SUMIFS() sayılar, metinler ve tarihler gibi farklı veri türleriyle çalışabilir. Diyelim ki bir satış raporum var, ancak bazı satırlarda müşteri adları eksik. Ve yalnızca müşteri adının bulunduğu satırları toplamak istiyorum. Bunun için şu formülü kullanıyorum:

=SUMIFS(C2:C5, A2:A5, "<>")

Bu formül Customer sütununa bakar, boş olmayan hücreleri kontrol eder ve ardından karşılık gelen satışları toplar.

SUMIFS() işleviyle boş olmayan hücreleri toplayın. Görsel: Yazar.

Müşteri adlarının eksik olduğu satışları toplamak için ise şu formülü kullanıyorum:  

=SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

SUMIFS() işleviyle boş hücreleri toplayın. Görsel: Yazar.

Koşulu sabitlemek yerine başka bir hücrede saklayabiliriz. Sarah Lee için satışları toplamak istiyorsam, bunu E3 hücresine yazar ve şu formülü kullanırım:

=SUMIFS(C2:C5, A2:A5, E3)

E3'teki değer her değiştiğinde, toplam otomatik olarak güncellenir. 

Hücre başvurusu kullanarak değerleri toplamak için SUMIFS() kullanın. Görsel: Yazar.

SUMIFS()'te VEYA mantığını uygulama

SUMIFS()'in yalnızca AND mantığını kullandığını biliyoruz; yani belirlediğimiz tüm koşulların sağlanması gerekir. Ancak, birden fazla koşuldan herhangi biri sağlandığında değerleri toplamak istediğimiz OR mantığını kullanmak istersek, bunu birden fazla SUMIFS()'i birleştirerek yapabiliriz.

Örneğin, John Doe YA DA Drake White için satışları toplamak istiyorsam, iki SUMIFS() formülünü şöyle birleştiririm:

=SUMIFS(C2:C8, A2:A8, "John Doe") + SUMIFS(C2:C8, A2:A8, "Drake White")

Drake White listede olmadığından, formülün o kısmı 0 döndürür. Toplam yalnızca John Doe için satışları içerir; bu da OR mantığının nasıl çalıştığını gösterir.

SUMIFS() işlevinde VEYA mantığını kullanın. Görsel: Yazar.

Excel 365 veya sonrasında, bunu bir dizi formülüyle basitleştirebilir ve aynı sonucu elde edebiliriz.

=SUMIFS(C2:C8,A2:A8,{"John Doe","Drake White"})

SUMIFS() dizi formülünü kullanın. Görsel: Yazar.

Adlandırılmış aralıklarla SUMIFS()

Hücre başvuruları A2:A5 veya C2:C5 yerine adlandırılmış aralıkları da kullanabiliriz. Bu örnekte, A2:A5'i seçip Customer_list, C2:C5'i seçip Sales_list olarak adlandırıyorum. Artık John'un toplam satışlarını bulmak için şu formülü kullanıyorum: 

=SUMIFS(Sales_list, Customer_list, "John")

Adlandırılmış aralıklarla SUMIFS() kullanarak değerleri toplayın. Görsel: Yazar.

Kısmi eşleşmeler için joker karakterler kullanma

Joker karakterler (* veya ?), metin aramalarında ve desen eşleştirmede bilinmeyen veya değişken karakterleri temsil eden özel karakterlerdir: 

• * sıfır dahil herhangi bir sayıda karakterle eşleşir.

• ? tam olarak bir karakterle eşleşir.

Nasıl çalıştıklarına örnek: 

• A*, A ile başlayan tüm hücrelerle eşleşir.

• *A, A ile biten tüm hücrelerle eşleşir.

• *A*, A'yı herhangi bir yerde içeren tüm hücrelerle eşleşir.

SUMIFS() işlevi, joker karakterler aracılığıyla metin eşleştirme yetenekleri sunar. Belirli metin kalıplarıyla başlayan, biten veya bunları içeren değerleri tanımlar. Diyelim ki ABC ile başlayan Ürün Kodları için satışları toplamak istiyorum. Bu durumda formülüm şöyle olur:

=SUMIFS(D2:D8, C2:C8, "ABC*")

00 ile biten satışları toplamak için, şunu yazarım:

=SUMIFS(B2:B7, A2:A7, "*00")

SUMIFS() içinde joker karakterleri kullanın. Görsel: Yazar.

Tarih aralıklarına göre toplama

SUMIFS() belirli bir tarih aralığı içindeki değerleri de toplayabilir. Ocak 2023'teki tüm satışları bilmek istersem, şu formülü kullanırım: 

=SUMIFS(D2:D8, B2:B8, ">=01-Jan-2023", B2:B8, "<=31-Jan-2023") 

Bu formül 1 Ocak 2023 ile 31 Ocak 2023 arasındaki tarihleri kontrol eder ve ardından tüm satışları toplar. 

SUMIFS() kullanarak tarih aralığını toplayın. Görsel: Yazar.

Birden çok sayısal koşula göre toplama

SUMIFS() işlevi, belirli sayısal aralıklara düşen değerleri toplayabilir. Burada rastgele bir veri kümesi var ve Satış'ın 100'den büyük fakat 300'den küçük olduğu değerleri toplamak istiyorum. Bunun için şu formülü kullanıyorum:  

=SUMIFS(C2:C5, C2:C5, ">100", C2:C5, "<300")

Bu formül ilk bağımsız değişken olarak toplanacak hücre aralığını (C2:C5) belirtir. Ardından, yukarıda açıklanan iki koşulu aynı aralığa uygular. SUMIFS() işlevi, aralıktaki her hücreyi her iki ölçüte göre eşzamanlı olarak değerlendirir. Ve yalnızca 100 ile 300 arasındaki (uçlar hariç) değerlerin toplama dahil edildiğini görebilirsiniz. 

SUMIFS() kullanarak bir sayı aralığındaki değerleri toplayın. Görsel: Yazar.

SUMIFS() Çalışmıyorsa Sorun Giderme

Eğer SUMIFS() işleviniz beklediğiniz gibi çalışmıyorsa, aşağıdaki sorunları kontrol edin:

Eşleşmeyen aralık boyutları 

SUMIFS() formülünüz bir hata döndürüyorsa, bunun nedeni aralık boyutlarının uyuşmaması olabilir. SUMIFS()'te seçtiğiniz tüm aralıkların, örneğin sum_range ve criteria_range'lerin, aynı sayıda satır ve sütuna sahip olması gerekir.

Örneğin, bu formülde toplam aralığı B2:B8, ancak ölçüt aralığı A2:A7 ve bir satır eksik:

=SUMIFS(B2:B8, A2:A7, "Drake White")

Bu uyumsuzluk bir #VALUE! hatası verir. Bu nedenle, tüm aralıkların aynı boyutta olduğundan emin olun, örneğin şöyle:

=SUMIFS(B2:B8, A2:A8, "John Doe")

Metin ölçütlerinin yanlış biçimlendirilmesi 

SUMIFS()'te metin ölçütlerini tırnak içine almalısınız. Bunu yapmazsanız, yanlış sonuçlar verebilir. Örneğin, bu formül 0 döndürür çünkü Excel Drake White'ı metin değil, bir ad veya değişken olarak görür: 

=SUMIFS(B2:B8, A2:A8, Drake White)

Düzeltmek için Drake White'ı şu şekilde tırnak içine alın; doğru çıktıyı verecektir:

=SUMIFS(B2:B8, A2:A8, "Drake White")

Beklenmeyen sıfır değerleri

Formül beklenen bir sonuç yerine 0 döndürüyorsa, bunun nedeni sayısal veya tarihe dayalı koşulların yanlış biçimlendirilmesi olabilir. SUMIFS()'te >100 veya <01-Jan-2023 gibi koşullar, tırnak içinde metin dizeleri olarak yazılmalıdır. Aksi halde, koşul tırnak içinde olmadığı için hata veya 0 döndürülebilir.

Ya da tarihi ayrı bir hücrede (ör. C1) saklayıp şunu kullanabiliriz:

=SUMIFS(B2:B8, A2:A8, ">="&C1)

Dizi dönüşümleriyle SUMIFS() çalışmıyor

SUMIFS() formül içinde veriden belirli bileşenleri çıkarmak gibi bazı dönüşümleri desteklemez. Örneğin, Ocak ve Mart aylarının satışlarını toplamak istiyorsam, SUMIFS() doğrudan {"January","March"} gibi dizi ölçütleriyle çalışmaz. 

Bunu göstermek için, A sütununda aylar (January, February, March, April) ve B sütununda satış değerleri (100, 200, 300, 400) olduğunu varsayalım. Şu formül

=SUMIFS(B2:B5, A2:A5, {"January","March"})

beklenen 400 (100 + 300) toplamını döndürmez. Bunun yerine, ya SUMPRODUCT() kullanabiliriz:

=SUMPRODUCT((A2:A5={"January","March"})*B2:B5)

ya da SUMIFS()'i SUM() ile şöyle sarmalayabiliriz:

=SUM(SUMIFS(B2:B5, A2:A5, {"January","March"}))

Her iki çözüm de dizi ölçütlerini doğru şekilde işler ve Ocak ile Mart için satışların toplamını döndürür.

SUMIFS() Kullanımı için En İyi Uygulamalar

SUMIFS() işlevinden en iyi şekilde yararlanmak için, şu en iyi uygulamaları izleyerek yaygın hatalardan kaçınmalıyız: 

• Esnek filtreleme için joker karakterler kullanın: Verilerimiz her zaman kusursuz şekilde düzenlenmemiş olabilir; ürün adları her zaman aynı yazılmayabilir veya fazladan boşluklar olabilir. Joker karakterler, tam metne ihtiyaç duymadan desenleri eşleştirmenize yardımcı olur.

• Koşulları sabitlemekten kaçının: Koşulları doğrudan formüle yazmak yerine ayrı bir hücrede saklayın. "Drake White" veya ">100" gibi bir koşulu sabitlerseniz, her değişiklikte formülü düzenlemeniz gerekir. Hücre başvurularıyla ise formül otomatik güncellenir.

• Formülleri kopyalarken mutlak başvuru kullanın: Bir SUMIFS() formülünü başka hücrelere kopyaladığınızda Excel hücre başvurularını otomatik olarak ayarlar. Bunun olmasını istemiyorsanız, $ ekleyerek hücreleri sabitleyin.

Son Düşünceler

SUMIFS(), belirli ölçütlerle eşleşen sayıları filtreleyip toplayarak verileri analiz etmemize yardımcı olan bir Excel işlevdir. Bölgelere göre satış takibi, kategoriye göre giderleri özetleme veya ürün türüne göre stok sayımı gibi görevler için idealdir. SUMIFS()'e alıştıktan sonra, zaman kazandırdığını ve karmaşık çözümlere ihtiyaç duymadan verilerinizdeki önemli eğilimleri fark etmenize yardımcı olduğunu göreceksiniz.

Bu becerilerinizi geliştirmek isterseniz, Excel ile Veri Analizi kursumuza, Excel ile Veri Hazırlama kursumuza ve Excel ile Veri Görselleştirme kursumuza veya Excel Fundamentals yetkinlik yoluna göz atın. Mevcut becerilerinizi tazelemenize yardımcı olacaklardır.