Excel에서 단어 수 세기: 4가지 쉬운 방법

Excel에서 단어 수를 세려면 수식을 사용해 셀의 공백 개수를 측정하고 이를 단어 수로 변환할 수 있습니다. Excel에는 기본 제공되는 단어 수 기능이 없으므로, 대부분의 방법은 LEN(), SUBSTITUTE() 같은 함수나 최신 Excel 버전에서 제공되는 새로운 함수에 의존합니다.

이 가이드에서는 수식, 최신 함수, 그리고 AI 도구를 사용해 Excel에서 단어 수를 세는 간단한 방법들을 다룹니다. 또한 결과의 정확도에 영향을 줄 수 있는 흔한 실수와 경계 사례도 살펴봅니다.

Excel에서 단어 수를 세는 일이 어려운 이유

Excel은 텍스트 분석보다는 숫자와 구조화된 데이터를 다루도록 설계되었기 때문에 기본 단어 수 기능을 포함하지 않습니다. 따라서 단어 수를 세려면 우회 방법이 필요합니다. 

Excel에 네이티브 단어 수 기능이 없는 이유

Microsoft Word 같은 워드 프로세서는 문장, 문단, 언어 규칙에 초점을 맞춥니다. Excel은 계산과 구조화된 데이터에 초점을 둡니다. 

이러한 설계 때문에:

• Excel은 텍스트를 문서의 일부가 아니라 셀 값으로 저장합니다
• Excel은 단어를 개별 단위로 인식하지 않습니다
• Excel 함수는 언어 구조가 아닌 문자 단위로 작동합니다

정의의 문제: 무엇을 단어로 볼 것인가

단어의 정의 자체가 혼란을 일으킬 수 있습니다. 

예를 들어 이메일 마케팅을 생각해 보세요. 하이픈으로 연결된 용어를 어떤 도구는 한 단어로, 다른 도구는 두 단어로 계산합니다. 또한 약어도 경계 사례를 만듭니다.

Excel은 이런 사례를 해결하기 위해 언어 규칙을 적용하지 않습니다. 대부분의 Excel 수식은 공백이 단어를 구분한다고 가정합니다. 그래서 Excel의 단어 수가 다른 도구에서 보이는 값과 다른 경우가 생깁니다.

Excel에서 단어 수가 필요한 일반적인 사용 사례

여전히 많은 실무 작업에서 단어 수를 알아야 할 때가 있습니다.

대표적인 상황은 다음과 같습니다:

• 제목, 설명, 광고 문구의 단어 제한 확인
• 설문조사나 양식의 응답 길이 검토
• 데이터 정리 중 콘텐츠 감사
• 스프레드시트에 저장된 메모나 문서 관리

이런 상황에서는 수식을 사용해 단어 수를 추정할 수 있습니다.

Excel에서 단어 수 세는 방법

Excel에서 단어 수를 세려면 LEN()과 SUBSTITUTE() 함수를 결합하세요. 이들은 하나의 셀에 있는 단어를 셉니다. 

예를 들어 텍스트가 A2 셀에 있다고 가정합시다. 다른 셀(예: B2)에 다음 수식을 입력합니다:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1

수식이 작동하는 방식은 다음과 같습니다:

• LEN(A2)는 셀의 모든 문자를 셉니다

• SUBSTITUTE(A2," ","")는 텍스트에서 공백을 제거합니다

• LEN(SUBSTITUTE(...))는 공백 제거 후 문자를 셉니다

• 두 길이의 차이는 공백 수를 의미합니다

• +1을 더해 공백 수를 단어 수로 변환합니다

셀의 전체 단어 수. 이미지: 작성자.

Excel은 단어가 아니라 문자를 세므로, 공백은 단어를 구분하는 신호 역할을 합니다.

A2 셀의 텍스트가 "The little cat slept"라고 해봅시다. 

• "The"와 "little" 사이에 공백 하나
• "little"과 "cat" 사이에 공백 하나
• "cat"과 "slept" 사이에 공백 하나

이 문장은 공백 3개와 단어 4개를 포함합니다. 정리하면: 단어 수 = 공백 수 + 1

이 수식은 먼저 공백을 세고, 거기에 1을 더해 최종 단어 수를 반환합니다.

빈 셀과 여분 공백을 처리하는 향상된 수식

때로는 셀에 여분의 공백이 있거나, 일부 셀은 비어 있습니다. 이런 경우 위 수식은 제대로 작동하지 않습니다. 여분 공백은 두 가지 흔한 문제를 만듭니다:

• 빈 셀이 0이 아니라 1을 반환함

• 단어 사이의 다중 공백으로 인해 단어 수가 부풀려짐

이를 해결하려면 LEN()과 SUBSTITUTE()에 TRIM()을 결합합니다: 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)

이 수식에서: 

• TRIM(A2)는 단어 앞뒤의 공백과 중복 공백을 제거합니다

• LEN(TRIM(A2))=0은 셀이 비었거나 공백만 있는지 확인합니다

• 셀이 비어 있으면 수식은 0을 반환합니다

• 그 외에는 동일한 공백 기반 논리로 단어를 셉니다

여분 공백을 제외하고 단어 수를 세려면 TRIM-LEN-SUBSTITUTE를 사용하세요. 이미지: 작성자 

여러 셀과 범위에 수식 적용하기

한 셀에서 수식이 잘 작동하면, 여러 행에 걸쳐 적용할 수 있습니다. 주요 방법 세 가지를 살펴봅시다. 

열 아래로 수식 복사

열 아래로 수식을 복사하려면: 

1. 수식이 들어 있는 셀을 선택합니다
2. 마우스를 우하단 모서리로 이동해 채우기 핸들이 나타날 때까지 둡니다
3. 채우기 핸들을 드래그하거나 더블 클릭합니다

이렇게 하면 Excel이 참조를 자동으로 업데이트합니다:

• A2 → A3

• A3 → A4

• 이와 같은 방식으로 계속

각 행이 자신의 단어 수를 계산합니다.

수식을 아래로 복사하려면 채우기 핸들을 드래그하거나 더블 클릭하세요. 이미지: 작성자.

열 전체의 단어 수 합계 구하기

여러 셀에 걸친 전체 단어 수를 세려면 개별 계산값을 더하면 됩니다. 예를 들어 단어 수가 B2:B4에 있다면 다음을 사용하세요:

=SUM(B2:B4)

이렇게 하면 범위 전체의 총 단어 수가 계산됩니다.

열 전체의 총 단어 수. 이미지: 작성자.

Excel 표에서 단어 수 세기

Excel 표는 수식을 자동으로 행 전체에 복사하므로 구조화된 데이터에 유용합니다. 표에서 단어 수를 세려면: 

1. 데이터를 선택합니다
2. 삽입 > 표로 이동합니다
3. 단어 수라는 새 열을 추가합니다

새 열의 첫 번째 행에 다음 수식을 입력합니다:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

참고: 제 열 이름은 Text입니다. 위 수식에서 본인의 열 이름으로 바꿔 사용하세요.

Excel 표에서 단어 수 세기. 이미지: 작성자.

입력이 끝나면 Excel이 표의 모든 행에 수식을 자동으로 채웁니다. 이 설정은 대규모 데이터셋에서 단어 수를 추적할 때 유용합니다.

특정 단어 수 세기

LEN()과 SUBSTITUTE() 함수를 결합하면 특정 단어가 셀에 몇 번 나타나는지 셀 수 있습니다. 

다음 수식을 보세요: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

이 수식은 A2 셀에서 cat이라는 단어가 몇 번 등장하는지 셉니다.

작동 방식은 다음과 같습니다:

• SUBSTITUTE(A2,"cat","")는 cat이라는 단어의 모든 등장 사례를 제거합니다

• LEN(A2)는 원래 문자의 개수를 셉니다

• LEN(SUBSTITUTE(...))는 제거 후 문자의 개수를 셉니다

• 두 길이의 차이는 제거된 문자 수를 보여줍니다

• LEN("cat")으로 나누면 제거된 문자를 단어 등장 횟수로 변환합니다

셀에서 특정 단어 세기. 이미지: 작성자.

대소문자 구분 없는 단어 수 세기

Excel 수식은 종종 텍스트를 그대로 처리합니다. 대소문자 차이를 무시하려면 텍스트를 동일한 대소문자로 변환하세요.

LOWER() 또는 UPPER()로 변환할 수 있습니다.

LOWER() 사용 예:

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")

UPPER() 사용 예:

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")

두 수식 모두 먼저 텍스트를 같은 대소문자로 변환하므로 Cat, CAT, cat이 모두 같은 단어로 계산됩니다.

특정 구절 세기

같은 접근 방식은 구절에도 적용됩니다. 예를 들어 little cat을 세고 싶다면 수식의 단어를 바꾸면 됩니다:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")

Excel은 해당 구절을 제거하고, 문자 수 차이를 측정해 그 차이를 구절 등장 횟수로 변환합니다.

범위 전체에서 특정 단어 세기

여러 셀에 걸쳐 특정 단어를 세려면 각 행에 수식을 적용한 뒤 결과를 합산하세요.

텍스트가 A2:A10에 있고 cat을 세고 싶다고 가정합시다. B2에 다음 수식을 입력합니다:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Enter를 누른 다음, 수식을 B10까지 내려 끌어옵니다. 각 행은 해당 셀에서 단어가 나타나는 횟수를 반환합니다.

특정 단어 세기. 이미지: 작성자.

부분 일치 세기

때로는 더 큰 단어 안에 포함된 경우에도 Excel이 단어를 센다고 느껴질 수 있습니다. 이를 부분 일치라고 합니다.

예를 들어 "cat"을 찾을 때 Excel은 다음도 셀 수 있습니다:

• "catalog"
• "cats"
• "category"

다음 수식을 사용해 등장 횟수를 셀 수 있습니다:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

부분 일치 세기. 이미지: 작성자.

알아두어야 할 한계

Excel 수식은 단어 경계를 감지할 수 없습니다. 텍스트 내에서 일치하는 문자를 찾을 뿐입니다.

이 제한 때문에 수식이 부분 일치를 셀 수 있습니다.

많은 스프레드시트 작업에서는 이러한 동작이 수용 가능합니다. 빠른 추정이 필요하거나 엄격한 언어 규칙이 필요 없는 경우에 잘 작동합니다.

여러 셀과 범위에 걸쳐 단어 수 세기

텍스트가 여러 셀에 분산되어 있어도 단일 단어 수를 계산할 수 있습니다. 이 접근 방식은 한 셀에서 단어 수를 세는 동일한 수식을 기반으로 확장합니다.

범위 전체의 단어 수 합계

범위 전체의 단어 수를 합산하려면 각 셀에서 대상 단어를 세고, 그 결과를 범위 전체에 걸쳐 더합니다.

텍스트가 A2:A10에 있다고 가정합니다. 다음 수식으로 cat의 전체 등장 횟수를 계산할 수 있습니다:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))

이 수식은 범위의 각 셀을 검사해 단어가 몇 번 나타나는지 세고, 하나의 합계로 반환합니다.

대소문자 차이를 무시하려면 텍스트를 먼저 변환하세요:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))

이 버전은 Cat, CAT, cat을 같은 단어로 처리합니다.

SUMPRODUCT로 여러 셀의 단어 수 세기. 이미지: 작성자.

열이나 표 전체의 총 단어 수 구하기

다른 방법으로 보조 열을 사용할 수 있습니다.

A2:A10에 텍스트가 있고 A1에 헤더가 있다고 가정합시다.

1. B2에 단어 수 수식을 입력합니다

2. 채우기 핸들을 더블 클릭해 열 아래로 수식을 복사합니다

3. 결과를 =SUM(B2:B10)으로 합산합니다

Excel은 각 행의 단어 수를 더해 열의 총합을 반환합니다.

열 전체의 단어 수를 세고 합산하기. 이미지: 작성자.

Excel 표에서 단어 수 세기

Excel 표는 새로운 행에도 수식이 자동 적용되어 이 과정을 더 쉽게 만듭니다:

1. 데이터셋을 선택합니다
2. 삽입 > 표로 이동합니다
3. 단어 수라는 새 열을 추가합니다

새 열의 첫 번째 행에 다음을 입력합니다:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Excel 표에서 단어 수 세기. 이미지: 작성자.

Text를 표의 실제 열 이름으로 바꾸세요. Excel은 모든 행에 수식을 자동으로 채웁니다. 표 전체의 총 단어 수를 계산하려면 다음을 사용합니다:

=SUM(Table2[Word Count])

Table2는 표 이름으로, Word Count는 시트에서 사용한 열 머리글로 바꿔주세요.

Excel에서 흔한 단어 수 오류 해결

Excel의 단어 수 수식은 대체로 잘 작동합니다. 하지만 데이터나 수식 설정의 작은 문제로 인해 잘못된 결과가 나올 수 있습니다. 아래 해결책은 가장 흔한 문제를 다룹니다.

흔한 실수와 해결 방법

다음은 흔한 오류와 그 해결책입니다: 

잘못된 범위 사용

때로 수식에 빈 행이나 헤더 셀을 포함시키는 경우가 있습니다. 이는 총합을 부풀리거나 계산을 느리게 할 수 있습니다.

해결 방법: 범위를 실제 데이터 행으로 제한하세요. 예를 들어 A:A 대신 A2:A100을 사용합니다.

수식 복사 시 잘못된 셀 참조

수식이 고정된 셀을 가리키면 모든 행이 같은 결과를 반환합니다.

해결 방법: 모든 행에서 같은 셀을 참조하려는 것이 아니라면 $A$2 대신 A2 같은 상대 참조를 사용하세요.

수식에서 TRIM() 누락

단어 사이의 여분 공백은 단어 수를 증가시킬 수 있습니다.

해결 방법: 수식을 적용하기 전에 텍스트에 TRIM()을 적용해 앞뒤 및 반복 공백을 제거하세요.

빈 셀, 비텍스트 데이터, 특수 사례 처리

이제 단어 수를 셀 때 특수 사례를 처리하는 방법을 살펴보겠습니다. 

빈 셀 또는 공백만 있는 셀

숨겨진 공백이 있는 셀은 0이 아니라 1을 반환할 수 있습니다. 빈 셀에 대해 0을 반환하려면 다음 수식을 사용하세요:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)

TRIM()은 Excel이 단어 수를 계산하기 전에 여분 공백을 제거합니다.

단어 수를 셀 때 빈 셀 처리를 위해 TRIM 사용. 이미지: 작성자.

숫자나 수식이 있는 셀

Excel은 숫자 셀의 문자도 세기 때문에 결과에 영향을 줄 수 있습니다. ISTEXT() 함수를 사용해 텍스트 셀로만 제한하세요:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)

이 수식은 셀에 텍스트가 없을 때 0을 반환합니다.

ISTEXT()로 숫자가 있는 셀을 처리하세요. 이미지: 작성자.

셀 내부의 여러 줄 텍스트

다른 소스에서 복사한 텍스트에는 줄 바꿈이나 숨은 문자가 포함될 수 있습니다. 이는 단어 수에 영향을 줍니다.

이를 방지하려면 단어 수 수식을 실행하기 전에 불필요한 문자를 제거하는 TRIM() 또는 CLEAN()을 적용하세요.

병합된 셀

병합된 셀은 일관된 범위에 의존하는 수식을 깨뜨릴 수 있습니다. 대규모 데이터셋에서 계산할 때는 병합된 셀을 피하세요.

정확한 단어 수를 위한 데이터 유효성 검사

정확한 단어 수는 깨끗한 입력 데이터에 달려 있습니다. 몇 가지 간단한 점검만으로도 오류를 사전에 방지할 수 있습니다.

세기 전에 텍스트 정리

복사하거나 가져온 텍스트에는 여분 공백이나 숨은 문자가 포함되는 경우가 많습니다. 단어 수를 계산하기 전에 TRIM()을 적용하는 보조 열을 사용해 텍스트를 정리하세요.

특정 단어를 셀 때 텍스트 표준화

같은 단어라도 대소문자가 다를 수 있습니다. 특정 단어 수를 세는 수식을 실행하기 전에 LOWER()나 UPPER()로 텍스트를 소문자 또는 대문자로 변환하세요.

대규모 데이터셋에는 보조 열 사용

대규모 데이터셋에서는 복잡한 수식을 검토하기 어려울 수 있습니다. 과정을 단계로 나누세요:

• 텍스트를 정리하는 열
• 단어를 세는 열
• 합계를 계산하는 셀

이 구조는 오류를 더 쉽게 찾고 성능을 향상시킵니다.

빈 입력을 방지하는 데이터 유효성 검사 사용

Excel의 데이터 유효성 검사 기능으로 빈 입력을 방지할 수도 있습니다:

1. A2:A100처럼 입력 범위를 선택합니다

2. 데이터 > 데이터 유효성 검사로 이동합니다

3. 허용 대상에서 텍스트 길이를 선택합니다

4. 데이터에서 보다 큼을 선택하고 값을 0으로 설정합니다

빈 셀을 방지하는 데이터 유효성 검사. 이미지: 작성자.

이제 Excel은 완전히 빈 입력을 차단하고, 누군가 셀을 비워 두려 하면 오류 메시지를 표시합니다.

최신 솔루션과 AI 기반 텍스트 분석

최신 버전의 Excel은 현대적인 텍스트 함수와 내장 AI 기능을 포함합니다. 이러한 도구를 사용하면 전통적인 수식에만 의존하지 않고도 텍스트를 더 쉽게 분석하고 단어 수를 추정할 수 있습니다.

Excel의 TEXTSPLIT()

최신 Excel 버전에는 문자열 처리 작업을 단순화하는 새로운 텍스트 함수가 포함되어 있습니다. 공백을 수동으로 세는 대신 텍스트를 개별 단어로 분리한 다음 직접 셀 수 있습니다.

TEXTSPLIT()은 구분 기호를 기준으로 텍스트를 여러 값으로 나눕니다. 단어를 구분하려면 구분 기호로 공백을 사용할 수 있습니다.

텍스트가 A2 셀에 있다고 가정합니다. B2에 다음 수식을 입력하세요:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))

작동 방식:

• TRIM(A2)가 여분 공백을 제거합니다

• TEXTSPLIT(...," ")가 공백이 있는 곳마다 텍스트를 분리합니다

• COUNTA()가 분리된 단어를 셉니다

이 방식은 전통적인 공백 계산 수식보다 읽기 쉽습니다.

다음과 같은 경우에 가장 잘 작동합니다:

• 최신 Excel 버전(Microsoft 365 또는 Excel 2021+)을 사용하는 경우
• 텍스트에서 단어 간 공백이 깔끔하게 유지되는 경우
• 데이터셋에 짧거나 중간 길이의 텍스트가 포함된 경우

텍스트에 줄 바꿈이나 특이한 구분자가 포함된 경우에는 분할 전에 추가 정리가 필요할 수 있습니다. 

Excel의 Copilot과 AI 기반 방법

Microsoft Excel에는 이제 Copilot을 통한 AI 지원이 포함됩니다. Copilot은 스프레드시트 데이터를 분석하고 자연어 요청에 응답할 수 있으며 텍스트 관련 질문도 처리합니다.

예를 들어 Copilot에 이렇게 요청할 수 있습니다:

이 열의 단어 수를 세어줘.

Copilot은 데이터를 분석해 수식 없이도 결과를 반환합니다.

간단한 테스트에서는 Copilot이 대체로 합리적인 추정치를 제공합니다. 다만 값이 Excel 수식의 결과와 항상 일치하지는 않을 수 있습니다.

값이 달라질 수 있는 이유

AI 시스템은 종종 전통적인 단어 대신 토큰 단위로 텍스트를 분석합니다. 토큰은 모델이 처리하는 텍스트 조각을 의미합니다. 토큰은 항상 단어 경계와 일치하지 않습니다.

예를 들어:

• 긴 단어가 여러 토큰으로 분할될 수 있음
• 짧은 단어 또는 문장 부호가 하나의 토큰을 공유할 수 있음
• 특수 문자가 텍스트 분할 방식을 바꿀 수 있음

이 때문에 Copilot이 공백에 의존해 단어를 추정하는 Excel 수식과 약간 다르게 텍스트를 해석할 수 있습니다.

맺음말

Excel에서 텍스트 작업을 할 때 이 단어 수 방법들을 간단한 워크플로로 활용하세요. 먼저 텍스트를 정리하고, 명확한 수식을 적용한 뒤, 데이터셋 전반에서 결과를 확인합니다. 이 습관은 설문 응답을 검토하거나 콘텐츠 필드를 감사하고, 스프레드시트에 저장된 메모를 분석할 때 도움이 됩니다.

이러한 역량은 Excel 함수와 데이터 준비 기법을 연습하며 확장할 수 있습니다.