Så räknar du ord i Excel: 4 enkla metoder

Du kan räkna ord i Excel med hjälp av formler som mäter antalet mellanslag i en cell och omvandlar dem till en ordräkning. Excel har ingen inbyggd funktion för att räkna ord, så de flesta metoder förlitar sig på funktioner som LEN(), SUBSTITUTE() eller nyare funktioner som finns i moderna Excel-versioner.

I den här guiden går vi igenom flera enkla sätt att räkna ord i Excel med formler, moderna funktioner och AI-verktyg. Vi tittar också på vanliga misstag och specialfall som kan påverka resultatens noggrannhet.

Utmaningen med att räkna ord i Excel

Excel har ingen inbyggd funktion för ordräkning eftersom det är utformat för att arbeta med tal och strukturerad data snarare än textanalys. Att räkna ord kräver därför en omväg. 

Varför Excel saknar inbyggd ordräkning

Ordbehandlare som Microsoft Word fokuserar på meningar, stycken och språkliga regler. Excel fokuserar på beräkningar och strukturerad data. 

På grund av denna design:

• Excel lagrar text som cellvärden, inte som en del av ett dokument
• Excel känner inte igen ord som separata enheter
• Excel-funktioner arbetar med tecken snarare än språkstruktur

Definitionsproblemet och vad som räknas som ett ord

Definitionen av ett ord kan också skapa förvirring. 

Tänk till exempel på e-post­marknadsföring. Eller hur vissa verktyg behandlar sammanskrivna termer med bindestreck som ett ord, medan andra räknar dem som två. Akronymer skapar också specialfall.

Excel tillämpar inte språkliga regler för att lösa dessa fall. De flesta Excel-formler utgår från att mellanslag separerar ord. Det är därför Excel ibland ger en annan ordräkning än andra verktyg.

Vanliga användningsfall för ordräkning i Excel

Många av oss behöver fortfarande känna till ordräkningar för praktiska uppgifter.

Vanliga situationer kan vara:

• Kontroll av ordbegränsningar för titlar, beskrivningar eller annonstexter
• Granskning av svarslängd i enkäter eller formulär
• Granskning av innehåll vid datastädning
• Hantering av anteckningar eller dokumentation som lagras i kalkylblad

I dessa situationer kan du använda formler för att uppskatta ordräkningar.

Så räknar du ord i Excel

För att räkna ord i Excel kombinerar du funktionerna LEN() och SUBSTITUTE(). De räknar orden i en cell. 

Anta att texten finns i cell A2. Skriv in den här formeln i en annan cell, till exempel B2:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1

Så här fungerar formeln:

• LEN(A2) räknar alla tecken i cellen

• SUBSTITUTE(A2," ","") tar bort mellanslag från texten

• LEN(SUBSTITUTE(...)) räknar tecken efter att mellanslag tagits bort

• Skillnaden mellan de två räkningarna ger antalet mellanslag

• Genom att lägga till +1 omvandlas antalet mellanslag till en ordräkning

Total ordräkning i en cell. Bild av författaren.

Eftersom Excel räknar tecken och inte ord fungerar mellanslag som en signal som separerar ord.

Ta texten "The little cat slept" i cell A2 som exempel: 

• Det finns ett mellanslag mellan "The" och "little"
• Ett mellanslag mellan "little" och "cat"
• Ett mellanslag mellan "cat" och "slept"

Den här meningen innehåller tre mellanslag och fyra ord. För tydlighet: Antal ord = antal mellanslag + 1

Formeln räknar först mellanslag och lägger sedan till ett för att returnera den slutliga ordräkningen.

Förbättrad formel som hanterar tomma celler och extra mellanslag

Ibland har celler extra mellanslag, eller så är vissa celler tomma. I sådana fall fungerar inte ovanstående formel eftersom extra mellanslag skapar två vanliga problem:

• Tomma celler returnerar 1 i stället för 0.

• Flera mellanslag mellan ord blåser upp räkningen.

För att åtgärda detta kombinerar du LEN() och SUBSTITUTE() med TRIM(): 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)

I den här formeln: 

• TRIM(A2) tar bort inledande, efterföljande och extra mellanslag mellan ord

• LEN(TRIM(A2))=0 kontrollerar om cellen är tom eller bara innehåller mellanslag

• Om cellen är tom returnerar formeln 0

• Annars räknar den ord med samma logik baserad på mellanslag

Använd TRIM-LEN-SUBSTITUTE för att räkna ord utan extra mellanslag. Bild av författaren 

Tillämpa formeln på flera celler och områden

När formeln fungerar för en cell kan du tillämpa den över många rader. Låt oss titta på tre huvudsätt att göra det: 

Kopiera formeln nedför en kolumn

För att kopiera formeln nedför en kolumn: 

1. Markera cellen som innehåller formeln
2. Flytta markören till det nedre högra hörnet tills fyllningshandtaget visas
3. Dra fyllningshandtaget nedåt eller dubbelklicka på det

Då uppdaterar Excel referenserna automatiskt:

• A2 blir A3

• A3 blir A4

• Och så vidare

Varje rad beräknar sin egen ordräkning.

Dra eller dubbelklicka på fyllningshandtaget för att kopiera formeln nedåt. Bild av författaren.

Räkna ord i en hel kolumn

För att räkna det totala antalet ord över flera celler adderar du de individuella räkningarna. Om ordräkningarna till exempel finns i B2:B4 använder du:

=SUM(B2:B4)

Detta ger dig total ordräkning för hela området.

Räkna totala ord över en hel kolumn. Bild av författaren.

Räkna ord i en Excel-tabell

Excel-tabeller kopierar automatiskt formler över rader, vilket gör dem användbara för strukturerad data. För att räkna ord i en tabell: 

1. Markera dina data
2. Gå till Infoga > Tabell
3. Lägg till en ny kolumn som heter Word Count

Skriv den här formeln i den första raden i den nya kolumnen:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Obs: Mitt kolumnnamn är Text så ersätt det med ditt kolumnnamn i formeln ovan.

Räkna ord i en Excel-tabell. Bild av författaren.

När du är klar fyller Excel i formeln automatiskt för varje rad i tabellen. Denna uppsättning fungerar bra när du spårar ordräkningar över stora dataset.

Så räknar du specifika ord i Excel

Du kan räkna hur många gånger ett specifikt ord förekommer i en cell genom att kombinera funktionerna LEN() och SUBSTITUTE(). 

Betrakta denna formel: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Den här formeln räknar hur många gånger ordet cat förekommer i cell A2.

Så här fungerar den:

• SUBSTITUTE(A2,"cat","") tar bort varje förekomst av ordet cat

• LEN(A2) räknar det ursprungliga antalet tecken

• LEN(SUBSTITUTE(...)) räknar tecken efter borttagningen

• Skillnaden mellan de två längderna visar hur många tecken som togs bort

• Genom att dividera med LEN("cat") omvandlas de borttagna tecknen till antalet gånger ordet förekommer

Räkna ett specifikt ord i en cell. Bild av författaren.

Skiftlägesokänslig ordräkning

Excel-formler behandlar ofta text exakt som den skrivs. Om du vill att formeln ska ignorera skillnader mellan stora och små bokstäver, konvertera texten till samma skiftläge.

Det kan du göra med LOWER() eller UPPER().

Exempel med LOWER():

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")

Exempel med UPPER():

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")

Båda formlerna konverterar först texten till samma skiftläge, så Cat, CAT och cat räknas som samma ord.

Räkna en specifik fras

Samma metod fungerar också för fraser. Om du till exempel vill räkna little cat, ersätt ordet i formeln:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")

Excel tar bort frasen, mäter skillnaden i tecken och omvandlar den skillnaden till antalet gånger frasen förekommer.

Räkna specifika ord över ett område

För att räkna ett specifikt ord över flera celler tillämpar du formeln på varje rad och summerar sedan resultaten.

Anta att din text finns i A2:A10 och att du vill räkna ordet cat. Skriv in den här formeln i B2:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Tryck på Enter och dra sedan formeln ned till B10. Varje rad returnerar hur många gånger ordet förekommer i den cellen.

Räkna det specifika ordet. Bild av författaren.

Räkna partiella träffar

Ibland räknar Excel ett ord även när det förekommer inuti ett längre ord. Detta kallas en partiell träff.

Om du till exempel söker efter "cat" kan Excel också räkna:

• "catalog"
• "cats"
• "category"

Du kan använda den här formeln för att räkna förekomster:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Räkna partiella träffar. Bild av författaren.

Begränsningar att känna till

Excel-formler kan inte upptäcka ordgränser. De söker bara efter matchande tecken i texten.

På grund av denna begränsning kan formler räkna partiella träffar.

I många kalkylbladsuppgifter är detta beteende acceptabelt. Det fungerar bra när du vill ha en snabb uppskattning eller när strikta språkliga regler inte är nödvändiga.

Så räknar du ord över flera celler och områden

Du kan fortfarande beräkna en enda ordräkning även när text förekommer i många celler. Denna metod bygger på samma formel som används för att räkna ord i en enskild cell.

Summera ordräkningar över ett område

För att summera ordräkningar över ett område räknar du målordet i varje cell. Addera sedan resultaten över området.

Anta att din text finns i A2:A10. Du kan beräkna det totala antalet förekomster av cat med följande formel:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))

Den här formeln kontrollerar varje cell i området, räknar hur många gånger ordet förekommer och returnerar en enda totalsiffra.

Om du vill ignorera skillnader mellan stora och små bokstäver konverterar du först texten:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))

Denna version behandlar Cat, CAT och cat som samma ord.

Räkna ord över flera celler med SUMPRODUCT. Bild av författaren.

Få total ordräkning för en hel kolumn eller tabell

Ett annat alternativ använder en hjälpkolumn.

Anta att texten finns i A2:A10 och att A1 innehåller rubriken.

1. Ange ordräkningsformeln i B2

2. Dubbelklicka på fyllningshandtaget för att kopiera formeln nedför kolumnen

3. Summera resultaten med: =SUM(B2:B10)

Excel adderar ordräkningarna från varje rad och returnerar totalen för kolumnen.

Räkna ord i hela kolumnen och summera dem. Bild av författaren.

Räkna ord i en Excel-tabell

Excel-tabeller gör processen enklare eftersom formler automatiskt tillämpas på nya rader:

1. Markera ditt dataset
2. Gå till Infoga > Tabell
3. Lägg till en ny kolumn som heter Word Count

I den första raden i den nya kolumnen anger du:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Räkna ord i en Excel-tabell. Bild av författaren.

Ersätt Text med det faktiska kolumnnamnet i din tabell. Excel fyller automatiskt i formeln för varje rad. För att beräkna total ordräkning för hela tabellen använder du:

=SUM(Table2[Word Count])

Ersätt Table2 med ditt tabellnamn och Word Count med kolumnrubriken som används i ditt blad.

Felsökning av vanliga fel vid ordräkning i Excel

Formler för ordräkning i Excel fungerar vanligtvis bra. Men små problem i data eller i hur formeln ställs in kan ge felaktiga resultat. Följande åtgärder tar upp de vanligaste problemen.

Vanliga misstag och hur du åtgärdar dem

Här är några vanliga fel och deras lösningar: 

Använda ett felaktigt område

Ibland inkluderar formler tomma rader eller rubrikceller. Detta kan blåsa upp totalen eller göra beräkningar långsammare.

Så åtgärdar du det: Begränsa området till faktiska datarader. Använd till exempel A2:A100 i stället för A:A.

Felaktiga cellreferenser när formler kopieras

Om en formel pekar på en fast cell returnerar varje rad samma resultat.

Så åtgärdar du det: Använd relativa referenser som A2 i stället för $A$2 om du inte vill att formeln ska referera till samma cell i varje rad.

Saknad TRIM() i formeln

Extra mellanslag mellan ord kan öka ordräkningen.

Så åtgärdar du det: Omslut texten med TRIM() innan du tillämpar formeln så att Excel tar bort inledande, efterföljande och upprepade mellanslag.

Hantering av tomma celler, icke-textdata och specialfall

Låt oss nu se hur man hanterar specialfall vid ordräkning: 

Tomma celler eller celler med enbart mellanslag

Cellar som innehåller dolda mellanslag kan returnera 1 i stället för 0. Använd den här formeln för att returnera 0 för tomma celler:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)

TRIM() tar bort extra mellanslag innan Excel beräknar ordräkningen.

Använd TRIM för att hantera tomma celler när du räknar ord. Bild av författaren.

Celler med tal eller formler

Excel räknar tecken även i numeriska celler, vilket kan påverka resultat. Använd funktionen ISTEXT() för att begränsa räkningen till textceller:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)

Den här formeln returnerar 0 när cellen inte innehåller text.

Använd ISTEXT() för att hantera tal i celler när du räknar ord. Bild av författaren.

Flerradig text i en cell

Text som kopieras från andra källor kan innehålla radbrytningar eller dolda tecken. Dessa kan påverka räkningen.

För att förhindra detta, använd TRIM() eller CLEAN() eftersom de tar bort onödiga tecken innan du kör formeln för ordräkning.

Sammanslagna celler

Sammanslagna celler kan förstöra formler som förlitar sig på konsekventa områden. Undvik därför sammanslagna celler när du gör beräkningar över stora dataset.

Datavalidering för korrekt ordräkning

Korrekt ordräkning beror på ren indata. Några enkla kontroller kan förhindra fel innan de uppstår.

Rensa texten innan du räknar

Text som har kopierats eller importerats innehåller ofta extra mellanslag eller dolda tecken. Använd en hjälpkolumn som applicerar TRIM() för att rensa texten innan du beräknar ordräkningen.

Standardisera text när du räknar specifika ord

Samma ord kan förekomma i olika skiftlägen. Konvertera text till gemener eller versaler med LOWER() eller UPPER() innan du kör formler som räknar specifika ord.

Använd hjälpkolumner för stora dataset

Stora dataset kan göra komplexa formler svåra att granska. Dela upp processen i steg:

• En kolumn för att rensa texten
• En kolumn för att räkna ord
• En cell för att beräkna totaler

Denna struktur gör fel enklare att upptäcka och förbättrar prestandan.

Använd datavalidering för att förhindra tomma inmatningar

Du kan också förhindra tomma inmatningar med Excels datavalidering:

1. Markera inmatningsområdet, till exempel A2:A100

2. Gå till Data > Dataverifiering

3. Under Tillåt väljer du Textlängd

4. Under Data väljer du större än och sätter värdet till 0

Datavalidering för att undvika tomma celler. Bild av författaren.

Excel blockerar nu helt tomma inmatningar och visar ett felmeddelande om någon försöker lämna cellen tom.

Moderna lösningar och AI-driven textanalys

Nyare versioner av Excel innehåller moderna textfunktioner och inbyggda AI-funktioner. Dessa verktyg gör det enklare att analysera text och uppskatta ordräkningar utan att enbart förlita sig på traditionella formler.

TEXTSPLIT() i Excel

Moderna Excel-versioner innehåller nya textfunktioner som förenklar många uppgifter för stränghantering. I stället för att räkna mellanslag manuellt kan du dela upp text i enskilda ord och räkna dem direkt.

TEXTSPLIT() delar upp text i flera värden baserat på en avgränsare. Du kan använda ett mellanslag som avgränsare för att separera ord.

Anta att texten finns i cell A2. Ange följande formel i B2:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))

Så här fungerar det:

• TRIM(A2) tar bort extra mellanslag

• TEXTSPLIT(...," ") delar texten där ett mellanslag förekommer

• COUNTA() räknar de resulterande orden

Detta tillvägagångssätt är lättare att läsa än traditionella formler som räknar mellanslag.

Det fungerar bäst när:

• Du använder moderna versioner av Excel (Microsoft 365 eller Excel 2021+)
• Texten har ren avståndsättning mellan orden
• Datasetet innehåller kort eller medellång text

Om texten innehåller radbrytningar eller ovanliga avgränsare kan du behöva ytterligare städning innan du delar upp den. 

Copilot i Excel och AI-drivna metoder

Microsoft Excel innehåller nu AI-stöd via Copilot. Copilot kan analysera kalkylbladsdata och svara på frågor i naturligt språk, inklusive frågor om text.

Till exempel kan du be Copilot:

Count the number of words in this column.

Copilot analyserar data och returnerar ett resultat utan att du behöver några formler.

I enkla tester ger Copilot oftast en rimlig uppskattning. Siffran stämmer dock inte alltid överens med resultatet från Excel-formler.

Varför siffrorna kan skilja sig

AI-system analyserar ofta text med hjälp av token i stället för traditionella ord. En token representerar en textbit som modellen bearbetar. Token sammanfaller inte alltid med ordgränser.

Till exempel:

• Ett långt ord kan delas upp i flera token
• Korta ord eller skiljetecken kan dela en token
• Specialtecken kan ändra hur text delas upp

På grund av detta kan Copilot tolka texten något annorlunda än Excel-formler som förlitar sig på mellanslag för att uppskatta ord.

Avslutande tankar

Använd dessa metoder för ordräkning som en del av ett enkelt arbetsflöde när du arbetar med text i Excel. Rensa texten först, tillämpa en tydlig formel och kontrollera resultaten över ditt dataset. Denna vana hjälper när du granskar enkätsvar, auditerar innehållsfält eller analyserar anteckningar som lagras i kalkylblad.

Du kan bygga vidare på dessa färdigheter genom att öva på Excel-funktioner och databeredningstekniker.