Cách đếm số từ trong Excel: 4 phương pháp đơn giản

Bạn có thể đếm số từ trong Excel bằng cách dùng công thức đo số khoảng trắng trong một ô và chuyển đổi chúng thành số lượng từ. Excel không cung cấp tính năng đếm từ tích hợp, vì vậy hầu hết các phương pháp dựa vào các hàm như LEN(), SUBSTITUTE(), hoặc các hàm mới hơn có trong các phiên bản Excel hiện đại.

Trong hướng dẫn này, chúng tôi sẽ trình bày một số cách đơn giản để đếm từ trong Excel bằng công thức, các hàm hiện đại và công cụ AI. Chúng tôi cũng xem xét các lỗi phổ biến và trường hợp biên có thể ảnh hưởng đến độ chính xác của kết quả.

Thách thức khi đếm từ trong Excel

Excel không bao gồm tính năng đếm từ tích hợp vì nó được thiết kế để làm việc với số và dữ liệu có cấu trúc hơn là phân tích văn bản. Do đó, việc đếm từ cần một cách làm thay thế. 

Vì sao Excel thiếu chức năng đếm từ gốc

Trình xử lý văn bản như Microsoft Word tập trung vào câu, đoạn văn và quy tắc ngôn ngữ. Excel tập trung vào phép tính và dữ liệu có cấu trúc. 

Do đặc điểm thiết kế này:

• Excel lưu văn bản dưới dạng giá trị ô, không phải là một phần của tài liệu
• Excel không nhận diện từ như các đơn vị riêng biệt
• Các hàm của Excel làm việc với ký tự thay vì cấu trúc ngôn ngữ

Vấn đề định nghĩa và thế nào là một từ

Định nghĩa về một từ cũng có thể gây nhầm lẫn. 

Hãy xét email marketing, chẳng hạn. Hoặc xem cách một số công cụ coi các thuật ngữ có dấu gạch nối là một từ, trong khi công cụ khác đếm là hai. Ngoài ra, từ viết tắt cũng tạo ra các trường hợp biên.

Excel không áp dụng quy tắc ngôn ngữ để xử lý các trường hợp này. Hầu hết công thức Excel giả định rằng khoảng trắng phân tách các từ. Đó là lý do đôi khi số từ trong Excel khác với số bạn thấy ở công cụ khác.

Các trường hợp sử dụng phổ biến khi đếm từ trong Excel

Nhiều người trong chúng ta vẫn cần biết số lượng từ cho nhiều tác vụ thực tế.

Các tình huống phổ biến có thể bao gồm:

• Kiểm tra giới hạn từ cho tiêu đề, mô tả hoặc bài quảng cáo
• Xem lại độ dài câu trả lời từ khảo sát hoặc biểu mẫu
• Kiểm toán nội dung trong quá trình dọn dẹp dữ liệu
• Quản lý ghi chú hoặc tài liệu được lưu trong bảng tính

Trong các tình huống này, bạn có thể dùng công thức để ước tính số lượng từ.

Cách đếm số từ trong Excel

Để đếm số từ trong Excel, hãy kết hợp các hàm LEN() và SUBSTITUTE(). Chúng đếm số từ trong một ô. 

Giả sử văn bản nằm trong ô A2. Nhập công thức này vào ô khác, chẳng hạn B2:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1

Cách công thức hoạt động:

• LEN(A2) đếm tất cả ký tự trong ô

• SUBSTITUTE(A2," ","") xóa các khoảng trắng khỏi văn bản

• LEN(SUBSTITUTE(...)) đếm ký tự sau khi đã xóa khoảng trắng

• Hiệu giữa hai phép đếm cho ra số lượng khoảng trắng

• Thêm +1 chuyển số khoảng trắng thành số lượng từ

Tổng số từ trong một ô. Ảnh: Tác giả.

Vì Excel đếm ký tự chứ không phải từ, các khoảng trắng đóng vai trò tín hiệu phân tách từ.

Lấy ví dụ văn bản "The little cat slept" trong ô A2: 

• Có một khoảng trắng giữa "The" và "little"
• Một khoảng trắng giữa "little" và "cat"
• Một khoảng trắng giữa "cat" và "slept"

Câu này có ba khoảng trắng và bốn từ. Cho rõ ràng: Số từ = số khoảng trắng + 1

Công thức đếm khoảng trắng trước, sau đó cộng một để trả về tổng số từ.

Công thức cải tiến xử lý ô trống và khoảng trắng thừa

Đôi khi các ô có khoảng trắng thừa, hoặc một số ô để trống. Trong các trường hợp đó, công thức trên sẽ không hoạt động vì khoảng trắng thừa gây ra hai vấn đề phổ biến:

• Ô trống trả về 1 thay vì 0.

• Nhiều khoảng trắng giữa các từ làm tăng số đếm.

Để khắc phục, hãy kết hợp LEN() và SUBSTITUTE() với TRIM(): 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)

Trong công thức này: 

• TRIM(A2) xóa khoảng trắng ở đầu, cuối và khoảng trắng thừa giữa các từ

• LEN(TRIM(A2))=0 kiểm tra xem ô có trống hoặc chỉ chứa khoảng trắng hay không

• Nếu ô trống, công thức trả về 0

• Nếu không, công thức đếm từ dựa trên logic khoảng trắng như cũ

Dùng TRIM-LEN-SUBSTITUTE để đếm từ, loại trừ khoảng trắng thừa. Ảnh: Tác giả 

Áp dụng công thức cho nhiều ô và vùng

Sau khi công thức hoạt động với một ô, bạn có thể áp dụng cho nhiều hàng. Hãy xem ba cách chính để làm điều đó: 

Sao chép công thức xuống một cột

Để sao chép công thức xuống cột: 

1. Chọn ô chứa công thức
2. Di chuyển con trỏ đến góc dưới bên phải cho đến khi xuất hiện tay cầm điền
3. Kéo tay cầm điền xuống hoặc nhấp đúp vào nó

Làm như vậy, Excel tự động cập nhật tham chiếu:

• A2 thành A3

• A3 thành A4

• Và cứ thế

Mỗi hàng sẽ tính số từ của riêng mình.

Kéo hoặc nhấp đúp tay cầm điền để sao chép công thức xuống. Ảnh: Tác giả.

Đếm từ trên toàn bộ một cột

Để đếm tổng số từ trên nhiều ô, hãy cộng các số đếm riêng lẻ lại. Ví dụ, nếu số từ nằm ở B2:B4, hãy dùng:

=SUM(B2:B4)

Điều này cho bạn tổng số từ của toàn bộ vùng.

Đếm tổng số từ trên toàn bộ một cột. Ảnh: Tác giả.

Đếm từ trong một bảng Excel

Bảng Excel tự động sao chép công thức qua các hàng, hữu ích cho dữ liệu có cấu trúc. Để đếm từ trong một bảng: 

1. Chọn dữ liệu của bạn
2. Vào Insert > Table
3. Thêm cột mới tên là Word Count

Nhập công thức này vào hàng đầu tiên của cột mới:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Lưu ý: Tên cột của tôi là Text nên hãy thay bằng tên cột của bạn trong công thức trên.

Đếm từ trong một bảng Excel. Ảnh: Tác giả.

Sau khi xong, Excel sẽ tự động điền công thức cho mọi hàng trong bảng. Cách thiết lập này hiệu quả khi bạn theo dõi số từ trên các bộ dữ liệu lớn.

Cách đếm từ cụ thể trong Excel

Bạn có thể đếm số lần một từ cụ thể xuất hiện trong một ô bằng cách kết hợp các hàm LEN() và SUBSTITUTE(). 

Xem công thức này: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Công thức này đếm số lần từ cat xuất hiện trong ô A2.

Cách hoạt động:

• SUBSTITUTE(A2,"cat","") xóa mọi lần xuất hiện của từ cat

• LEN(A2) đếm số ký tự ban đầu

• LEN(SUBSTITUTE(...)) đếm số ký tự sau khi xóa

• Hiệu giữa hai độ dài cho thấy có bao nhiêu ký tự đã bị xóa

• Chia cho LEN("cat") chuyển số ký tự bị xóa thành số lần từ xuất hiện

Đếm một từ cụ thể trong một ô. Ảnh: Tác giả.

Đếm không phân biệt hoa thường

Công thức Excel thường xử lý văn bản đúng như được viết. Nếu bạn muốn công thức bỏ qua khác biệt chữ hoa và chữ thường, hãy chuyển văn bản về cùng một dạng chữ.

Bạn có thể làm điều đó với LOWER() hoặc UPPER().

Ví dụ dùng LOWER():

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")

Ví dụ dùng UPPER():

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")

Cả hai công thức đều chuyển văn bản về cùng dạng chữ trước, nên Cat, CAT và cat đều được tính là cùng một từ.

Đếm một cụm từ cụ thể

Cách tiếp cận tương tự cũng hoạt động cho cụm từ. Ví dụ, nếu bạn muốn đếm cụm little cat, hãy thay từ trong công thức:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")

Excel sẽ xóa cụm từ, đo chênh lệch số ký tự và chuyển chênh lệch đó thành số lần cụm từ xuất hiện.

Đếm từ cụ thể trên một vùng

Để đếm một từ cụ thể trên nhiều ô, hãy áp dụng công thức cho từng hàng rồi cộng tổng kết quả.

Giả sử văn bản nằm trong A2:A10 và bạn muốn đếm từ cat. Nhập công thức này vào B2:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Nhấn Enter, sau đó kéo công thức xuống B10. Mỗi hàng sẽ trả về số lần từ xuất hiện trong ô đó.

Đếm từ cụ thể. Ảnh: Tác giả.

Đếm khớp một phần

Đôi khi Excel đếm một từ ngay cả khi nó xuất hiện bên trong một từ dài hơn. Điều này gọi là khớp một phần.

Ví dụ, nếu bạn tìm "cat", Excel cũng có thể đếm:

• "catalog"
• "cats"
• "category"

Bạn có thể dùng công thức này để đếm số lần xuất hiện:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Đếm khớp một phần. Ảnh: Tác giả.

Hạn chế cần lưu ý

Công thức Excel không thể phát hiện ranh giới từ. Chúng chỉ tìm các ký tự khớp trong văn bản.

Do hạn chế này, công thức có thể đếm cả các khớp một phần.

Trong nhiều tác vụ bảng tính, hành vi này chấp nhận được. Nó hoạt động tốt khi bạn cần ước tính nhanh hoặc khi không cần tuân thủ nghiêm ngặt quy tắc ngôn ngữ.

Cách đếm từ trên nhiều ô và vùng

Bạn vẫn có thể tính một con số tổng dù văn bản xuất hiện trên nhiều ô. Cách tiếp cận này dựa trên cùng công thức dùng để đếm từ trong một ô.

Cộng số đếm từ trên một vùng

Để cộng số đếm từ trên một vùng, hãy đếm từ mục tiêu trong mỗi ô. Sau đó cộng kết quả trong vùng.

Giả sử văn bản nằm trong A2:A10. Bạn có thể tính tổng số lần xuất hiện của cat với công thức sau:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))

Công thức này kiểm tra từng ô trong vùng, đếm số lần từ xuất hiện và trả về một tổng duy nhất.

Nếu bạn muốn bỏ qua khác biệt chữ hoa và chữ thường, hãy chuyển văn bản trước:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))

Phiên bản này coi Cat, CAT và cat là cùng một từ.

Đếm từ trên nhiều ô bằng SUMPRODUCT. Ảnh: Tác giả.

Lấy tổng số từ cho toàn bộ cột hoặc bảng

Một lựa chọn khác là dùng cột trợ giúp.

Giả sử văn bản nằm trong A2:A10 và A1 chứa tiêu đề.

1. Nhập công thức đếm từ vào B2

2. Nhấp đúp tay cầm điền để sao chép công thức xuống cột

3. Cộng kết quả bằng: =SUM(B2:B10)

Excel cộng số từ từ mỗi hàng và trả về tổng cho cột.

Đếm số từ của toàn bộ cột và cộng lại. Ảnh: Tác giả.

Đếm từ trong một bảng Excel

Bảng Excel giúp quy trình này dễ hơn vì công thức tự động áp dụng cho hàng mới:

1. Chọn tập dữ liệu của bạn
2. Vào Insert > Table
3. Thêm cột mới tên Word Count

Ở hàng đầu tiên của cột mới, nhập:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Đếm từ trong một bảng Excel. Ảnh: Tác giả.

Thay Text bằng tên cột thực tế trong bảng của bạn. Excel tự động điền công thức cho mọi hàng. Để tính tổng số từ cho toàn bộ bảng, dùng:

=SUM(Table2[Word Count])

Thay Table2 bằng tên bảng của bạn và Word Count bằng tiêu đề cột dùng trong trang tính.

Khắc phục lỗi đếm từ thường gặp trong Excel

Các công thức đếm từ trong Excel thường hoạt động tốt. Tuy nhiên, những vấn đề nhỏ trong dữ liệu hoặc cách thiết lập công thức có thể tạo ra kết quả sai. Các cách khắc phục sau đây giải quyết những lỗi phổ biến nhất.

Lỗi thường gặp và cách sửa

Dưới đây là một số lỗi phổ biến và cách giải quyết: 

Dùng sai vùng dữ liệu

Đôi khi công thức bao gồm cả hàng trống hoặc ô tiêu đề. Điều này có thể làm tăng tổng số đếm hoặc làm chậm tính toán.

Để sửa: Giới hạn vùng dữ liệu vào các hàng thực tế. Ví dụ, dùng A2:A100 thay vì A:A.

Tham chiếu ô không đúng khi sao chép công thức

Nếu công thức trỏ đến một ô cố định, mọi hàng sẽ trả về cùng một kết quả.

Để sửa: Dùng tham chiếu tương đối như A2 thay vì $A$2 trừ khi bạn muốn công thức luôn tham chiếu cùng một ô ở mọi hàng.

Thiếu TRIM() trong công thức

Khoảng trắng thừa giữa các từ có thể làm tăng số đếm.

Để sửa: Bọc văn bản bằng TRIM() trước khi áp dụng công thức để Excel xóa khoảng trắng đầu, cuối và lặp lại.

Xử lý ô trống, dữ liệu không phải văn bản và các trường hợp đặc biệt

Giờ hãy xem cách xử lý các trường hợp đặc biệt khi đếm từ: 

Ô trống hoặc ô chỉ có khoảng trắng

Các ô chứa khoảng trắng ẩn có thể trả về 1 thay vì 0. Dùng công thức này để trả về 0 cho ô trống:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)

TRIM() xóa khoảng trắng thừa trước khi Excel tính số từ.

Dùng TRIM để xử lý ô trống khi đếm từ. Ảnh: Tác giả.

Ô có số hoặc công thức

Excel cũng đếm ký tự trong ô dạng số, có thể ảnh hưởng kết quả. Dùng hàm ISTEXT() để giới hạn chỉ đếm ở ô văn bản:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)

Công thức này trả về 0 khi ô không chứa văn bản.

Dùng ISTEXT() để xử lý số trong ô khi đếm từ. Ảnh: Tác giả.

Văn bản nhiều dòng trong một ô

Văn bản sao chép từ nguồn khác có thể bao gồm xuống dòng hoặc ký tự ẩn. Những thứ này có thể ảnh hưởng số đếm.

Để ngăn điều này, hãy áp dụng TRIM() hoặc CLEAN() vì chúng loại bỏ các ký tự không cần thiết trước khi chạy công thức đếm từ.

Ô hợp nhất

Ô hợp nhất có thể làm hỏng công thức dựa vào các vùng nhất quán. Vì vậy hãy tránh ô hợp nhất khi tính toán trên bộ dữ liệu lớn.

Xác thực dữ liệu để đếm từ chính xác

Độ chính xác của số lượng từ phụ thuộc vào dữ liệu đầu vào sạch. Một vài kiểm tra đơn giản có thể ngăn lỗi xuất hiện ngay từ đầu.

Làm sạch văn bản trước khi đếm

Văn bản được sao chép hoặc nhập thường có khoảng trắng thừa hoặc ký tự ẩn. Hãy dùng cột trợ giúp áp dụng TRIM() để làm sạch văn bản trước khi tính số từ.

Chuẩn hóa văn bản khi đếm từ cụ thể

Cùng một từ có thể xuất hiện ở các dạng chữ khác nhau. Hãy chuyển văn bản về chữ thường hoặc chữ hoa bằng LOWER() hoặc UPPER() trước khi chạy công thức đếm từ cụ thể.

Dùng cột trợ giúp cho bộ dữ liệu lớn

Bộ dữ liệu lớn có thể khiến công thức phức tạp khó rà soát. Hãy chia quy trình thành các bước:

• Một cột để làm sạch văn bản
• Một cột để đếm từ
• Một ô để tính tổng

Cấu trúc này giúp dễ phát hiện lỗi và cải thiện hiệu năng.

Dùng xác thực dữ liệu để ngăn đầu vào trống

Bạn cũng có thể ngăn nhập trống bằng tính năng xác thực dữ liệu của Excel:

1. Chọn vùng nhập, chẳng hạn A2:A100

2. Vào Data > Data Validation

3. Tại Allow, chọn Text length

4. Tại Data, chọn greater than và đặt giá trị 0

Xác thực dữ liệu để tránh ô trống. Ảnh: Tác giả.

Giờ đây Excel sẽ chặn hoàn toàn việc nhập trống và hiển thị thông báo lỗi nếu ai đó cố để ô trống.

Giải pháp hiện đại và phân tích văn bản dùng AI

Các phiên bản Excel mới hơn bao gồm các hàm văn bản hiện đại và tính năng AI tích hợp. Những công cụ này giúp phân tích văn bản và ước tính số từ dễ dàng hơn mà không chỉ dựa vào các công thức truyền thống.

TEXTSPLIT() trong Excel

Các phiên bản Excel hiện đại có các hàm văn bản mới đơn giản hóa nhiều tác vụ xử lý chuỗi. Thay vì đếm khoảng trắng thủ công, bạn có thể tách văn bản thành từng từ và đếm trực tiếp.

TEXTSPLIT() chia văn bản thành nhiều giá trị dựa trên một dấu phân tách. Bạn có thể dùng khoảng trắng làm dấu phân tách để tách từ.

Giả sử văn bản nằm trong ô A2. Nhập công thức sau vào B2:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))

Cách hoạt động:

• TRIM(A2) xóa khoảng trắng thừa

• TEXTSPLIT(...," ") tách văn bản tại mọi vị trí có khoảng trắng

• COUNTA() đếm các từ thu được

Cách này dễ đọc hơn so với các công thức đếm khoảng trắng truyền thống.

Hiệu quả nhất khi:

• Bạn dùng phiên bản Excel hiện đại (Microsoft 365 hoặc Excel 2021+)
• Văn bản có khoảng cách giữa các từ sạch
• Bộ dữ liệu chứa văn bản ngắn hoặc trung bình

Nếu văn bản có xuống dòng hoặc dấu phân tách lạ, bạn có thể cần làm sạch bổ sung trước khi tách. 

Copilot trong Excel và các phương pháp dùng AI

Microsoft Excel hiện có hỗ trợ AI qua Copilot. Copilot có thể phân tích dữ liệu bảng tính và phản hồi các yêu cầu ngôn ngữ tự nhiên, bao gồm câu hỏi về văn bản.

Ví dụ, bạn có thể yêu cầu Copilot:

Count the number of words in this column.

Copilot phân tích dữ liệu và trả về kết quả mà không cần bất kỳ công thức nào.

Trong các thử nghiệm đơn giản, Copilot thường đưa ra con số ước tính hợp lý. Tuy nhiên, kết quả có thể không luôn khớp với kết quả từ công thức Excel.

Vì sao các con số có thể khác nhau

Hệ thống AI thường phân tích văn bản bằng tokens thay vì từ truyền thống. Token đại diện cho một phần văn bản được mô hình xử lý. Token không phải lúc nào cũng khớp với ranh giới từ.

Ví dụ:

• Một từ dài có thể bị tách thành nhiều token
• Từ ngắn hoặc dấu câu có thể dùng chung một token
• Ký tự đặc biệt có thể thay đổi cách chia văn bản

Vì thế, Copilot có thể diễn giải văn bản hơi khác so với các công thức Excel dựa vào khoảng trắng để ước tính số từ.

Kết luận

Hãy dùng các phương pháp đếm từ này như một quy trình làm việc đơn giản khi bạn xử lý văn bản trong Excel. Làm sạch văn bản trước, áp dụng công thức rõ ràng và kiểm tra kết quả trên toàn bộ tập dữ liệu. Thói quen này hữu ích khi bạn xem lại câu trả lời khảo sát, kiểm toán các trường nội dung hoặc phân tích ghi chú lưu trong bảng tính.

Bạn có thể mở rộng kỹ năng này bằng cách luyện tập các hàm Excel và kỹ thuật chuẩn bị dữ liệu.