Excel में शब्द कैसे गिनें: 4 आसान तरीके

आप Excel में फ़ॉर्मूलों का उपयोग करके किसी सेल में मौजूद स्पेस की संख्या मापकर उन्हें शब्द-गिनती में बदल सकते हैं। Excel में बिल्ट-इन वर्ड काउंट फ़ीचर नहीं है, इसलिए अधिकांश तरीके LEN(), SUBSTITUTE() जैसी फ़ंक्शंस या आधुनिक Excel संस्करणों में उपलब्ध नए फ़ंक्शंस पर निर्भर करते हैं।

इस गाइड में, हम फ़ॉर्मूला, आधुनिक फ़ंक्शंस और AI टूल्स का उपयोग करके Excel में शब्द गिनने के कई सरल तरीके कवर करेंगे। हम उन सामान्य गलतियों और विशेष स्थितियों पर भी नज़र डालेंगे जो नतीजों की सटीकता को प्रभावित कर सकती हैं।

Excel में शब्द गिनने की चुनौती

Excel में बिल्ट-इन वर्ड काउंट फ़ीचर नहीं है क्योंकि इसे टेक्स्ट विश्लेषण की बजाय संख्याओं और संरचित डेटा पर काम करने के लिए डिज़ाइन किया गया था। इसलिए शब्द गिनने के लिए आपको वर्कअराउंड अपनाना पड़ता है. 

क्यों Excel में नेटिव वर्ड काउंट फ़ंक्शनलिटी नहीं है

Microsoft Word जैसे वर्ड प्रोसेसर वाक्यों, अनुच्छेदों और भाषा के नियमों पर केंद्रित होते हैं। Excel का फ़ोकस गणनाओं और संरचित डेटा पर होता है। 

इस डिज़ाइन के कारण:

• Excel टेक्स्ट को दस्तावेज़ का हिस्सा नहीं, बल्कि सेल वैल्यू के रूप में स्टोर करता है
• Excel शब्दों को अलग इकाइयों के रूप में नहीं पहचानता
• Excel फ़ंक्शंस भाषा-संरचना के बजाय कैरेक्टर्स के साथ काम करते हैं

परिभाषा की समस्या: शब्द क्या माना जाए

शब्द की परिभाषा भी भ्रम पैदा कर सकती है. 

उदाहरण के लिए, ईमेल मार्केटिंग पर विचार करें। या यह देखें कि कुछ टूल्स हाइफ़न से जुड़े शब्दों को एक शब्द मानते हैं, जबकि दूसरे उन्हें दो गिनते हैं। संक्षिप्ताक्षर (acronyms) भी विशेष स्थितियाँ बनाते हैं।

Excel इन मामलों को हल करने के लिए भाषा-नियम लागू नहीं करता। अधिकांश Excel फ़ॉर्मूले मानते हैं कि शब्द स्पेस से अलग होते हैं। यही कारण है कि Excel की शब्द-गिनती अन्य टूल्स में दिखने वाली गिनती से कभी-कभी अलग होती है।

Excel में शब्द-गिनती के सामान्य उपयोग

हममें से कई लोगों को व्यावहारिक कामों के लिए अब भी शब्द-गिनती जानने की ज़रूरत पड़ती है।

आम स्थितियाँ शामिल हो सकती हैं:

• शीर्षकों, विवरणों या विज्ञापन कॉपी के शब्द-सीमाओं की जाँच
• सर्वे या फ़ॉर्म से प्राप्त उत्तरों की लंबाई की समीक्षा
• डेटा क्लीनअप के दौरान सामग्री का ऑडिट
• स्प्रेडशीट में संग्रहीत नोट्स या डॉक्यूमेंटेशन का प्रबंधन

ऐसी स्थितियों में, आप शब्द-गिनती का अनुमान लगाने के लिए फ़ॉर्मूले इस्तेमाल कर सकते हैं।

Excel में शब्द कैसे गिनें

Excel में शब्द गिनने के लिए LEN() और SUBSTITUTE() फ़ंक्शंस को मिलाएँ। ये किसी एक सेल में शब्द गिनते हैं. 

मान लें कि टेक्स्ट सेल A2 में है। यह फ़ॉर्मूला किसी दूसरे सेल, जैसे B2, में डालें:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1संचालित द्वारा

यह फ़ॉर्मूला इस प्रकार काम करता है:

• LEN(A2) सेल के सभी कैरेक्टर्स गिनता है

• SUBSTITUTE(A2," ","") टेक्स्ट से स्पेस हटा देता है

• LEN(SUBSTITUTE(...)) स्पेस हटाने के बाद के कैरेक्टर्स गिनता है

• दोनों गिनतियों का अंतर स्पेस की संख्या देता है

• +1 जोड़ने से स्पेस की संख्या को शब्द-गिनती में बदला जाता है

एक सेल में कुल शब्द-गिनती। चित्र: लेखक।

क्योंकि Excel शब्दों के बजाय कैरेक्टर्स गिनता है, इसलिए स्पेस शब्दों को अलग करने का संकेत बनते हैं।

उदाहरण के लिए, सेल A2 में "The little cat slept" टेक्स्ट लें: 

• "The" और "little" के बीच एक स्पेस है
• "little" और "cat" के बीच एक स्पेस
• "cat" और "slept" के बीच एक स्पेस

इस वाक्य में तीन स्पेस और चार शब्द हैं। स्पष्टता के लिए: शब्दों की संख्या = स्पेस की संख्या + 1

फ़ॉर्मूला पहले स्पेस गिनता है, फिर अंतिम शब्द-गिनती देने के लिए एक जोड़ता है।

बेहतर फ़ॉर्मूला: खाली सेल और अतिरिक्त स्पेस संभालें

कभी-कभी सेल में अतिरिक्त स्पेस होते हैं, या कुछ सेल खाली होते हैं। ऐसे मामलों में ऊपर दिया फ़ॉर्मूला काम नहीं करेगा क्योंकि अतिरिक्त स्पेस दो सामान्य समस्याएँ पैदा करते हैं:

• खाली सेल 0 के बजाय 1 लौटाते हैं।

• शब्दों के बीच कई स्पेस गिनती बढ़ा देते हैं।

इसे ठीक करने के लिए, LEN() और SUBSTITUTE() को TRIM() के साथ मिलाएँ: 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)संचालित द्वारा

इस फ़ॉर्मूले में: 

• TRIM(A2) शब्दों के बीच के अतिरिक्त स्पेस सहित आगे-पीछे के स्पेस हटाता है

• LEN(TRIM(A2))=0 जाँचता है कि सेल खाली है या केवल स्पेस हैं

• यदि सेल खाली हो, तो फ़ॉर्मूला 0 लौटाता है

• अन्यथा, वही स्पेस-आधारित तर्क से शब्द गिनता है

अतिरिक्त स्पेस को छोड़कर शब्द गिनने के लिए TRIM-LEN-SUBSTITUTE का उपयोग करें। चित्र: लेखक 

फ़ॉर्मूला कई सेल और रेंज पर लागू करें

जब फ़ॉर्मूला एक सेल के लिए काम करने लगे, तो आप इसे कई पंक्तियों पर लागू कर सकते हैं। ऐसा करने के तीन मुख्य तरीके देखें: 

फ़ॉर्मूला को कॉलम में नीचे कॉपी करें

फ़ॉर्मूला नीचे कॉपी करने के लिए: 

1. उस सेल को चुनें जिसमें फ़ॉर्मूला है
2. कर्सर को निचले-दाएँ कोने पर ले जाएँ जब तक फ़िल हैंडल दिखाई न दे
3. फ़िल हैंडल को नीचे खींचें या उस पर डबल‑क्लिक करें

ऐसा करने पर Excel रेफ़रेंस अपने‑आप अपडेट कर देता है:

• A2 से A3 हो जाता है

• A3 से A4 हो जाता है

• और आगे भी ऐसे ही

हर पंक्ति अपनी खुद की शब्द-गिनती निकालती है।

फ़ॉर्मूला नीचे कॉपी करने के लिए फ़िल हैंडल को ड्रैग करें या डबल‑क्लिक करें। चित्र: लेखक।

पूरे कॉलम में शब्द गिनें

कई सेल्स में कुल शब्द-गिनती निकालने के लिए, व्यक्तिगत गिनतियों को जोड़ दें। उदाहरण के लिए, यदि शब्द-गिनती B2:B4 में है, तो उपयोग करें:

=SUM(B2:B4)संचालित द्वारा

यह आपको पूरी रेंज की कुल शब्द-गिनती देता है।

पूरे कॉलम में कुल शब्द गिनें। चित्र: लेखक।

Excel तालिका में शब्द गिनें

Excel टेबल्स पंक्तियों में फ़ॉर्मूला अपने‑आप कॉपी करती हैं, इसलिए ये संरचित डेटा के लिए उपयोगी होती हैं। टेबल में शब्द गिनने के लिए: 

1. अपने डेटा का चयन करें
2. Insert > Table पर जाएँ
3. Word Count नाम का एक नया कॉलम जोड़ें

नए कॉलम की पहली पंक्ति में यह फ़ॉर्मूला दर्ज करें:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)संचालित द्वारा

नोट: मेरे कॉलम का नाम Text है, इसलिए ऊपर दिए फ़ॉर्मूले में इसे अपने कॉलम के नाम से बदलें।

Excel टेबल में शब्द गिनें। चित्र: लेखक।

एक बार करने पर Excel टेबल की हर पंक्ति के लिए फ़ॉर्मूला अपने‑आप भर देता है। बड़े डेटासेट में शब्द-गिनती ट्रैक करने पर यह सेटअप अच्छा काम करता है।

Excel में विशिष्ट शब्द कैसे गिनें

आप LEN() और SUBSTITUTE() फ़ंक्शंस को मिलाकर किसी विशिष्ट शब्द के किसी सेल में आने की संख्या गिन सकते हैं. 

यह फ़ॉर्मूला देखें: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")संचालित द्वारा

यह फ़ॉर्मूला गिनता है कि सेल A2 में cat शब्द कितनी बार आता है।

यह इस प्रकार काम करता है:

• SUBSTITUTE(A2,"cat","") cat शब्द की हर उपस्थिति हटा देता है

• LEN(A2) मूल कैरेक्टर‑गिनती देता है

• LEN(SUBSTITUTE(...)) हटाने के बाद की कैरेक्टर‑गिनती देता है

• दोनों लंबाइयों का अंतर दिखाता है कि कितने कैरेक्टर्स हटे

• LEN("cat") से भाग देने पर हटे कैरेक्टर्स को शब्द‑आवृत्ति में बदला जाता है

किसी विशिष्ट शब्द की गिनती। चित्र: लेखक।

केस‑इंसेंसिटिव (case-insensitive) शब्द‑गिनती

Excel फ़ॉर्मूले अक्सर टेक्स्ट को जैसा लिखा गया है वैसा ही मानते हैं। यदि आप अपरकेस और लोअरकेस के अंतर को नज़रअंदाज़ करना चाहते हैं, तो टेक्स्ट को एक ही केस में बदलें।

आप यह LOWER() या UPPER() से कर सकते हैं।

LOWER() का उदाहरण:

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")संचालित द्वारा

UPPER() का उदाहरण:

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")संचालित द्वारा

दोनों फ़ॉर्मूले पहले टेक्स्ट को एक ही केस में बदलते हैं, इसलिए Cat, CAT और cat सभी को एक ही शब्द माना जाता है।

किसी विशिष्ट वाक्यांश की गिनती

यही तरीका वाक्यांशों पर भी काम करता है। उदाहरण के लिए, यदि आप little cat गिनना चाहते हैं, तो फ़ॉर्मूले में शब्द बदल दें:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")संचालित द्वारा

Excel वाक्यांश को हटाता है, कैरेक्टर्स के अंतर को मापता है, और उस अंतर को वाक्यांश की आवृत्तियों में बदलता है।

किसी रेंज में विशिष्ट शब्द गिनें

कई सेल्स में किसी विशिष्ट शब्द की गिनती के लिए, फ़ॉर्मूला हर पंक्ति पर लागू करें और फिर नतीजों को जोड़ दें।

मान लें आपका टेक्स्ट A2:A10 में है और आपको cat शब्द गिनना है। B2 में यह फ़ॉर्मूला दर्ज करें:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")संचालित द्वारा

Enter दबाएँ, फिर फ़ॉर्मूला को B10 तक नीचे खींचें। हर पंक्ति बताएगी कि उस सेल में शब्द कितनी बार आता है।

विशिष्ट शब्द की गिनती। चित्र: लेखक।

आंशिक मिलान (partial matches) गिनें

कभी‑कभी Excel किसी शब्द को तब भी गिन लेता है जब वह किसी बड़े शब्द के भीतर आता है। इसे आंशिक मिलान कहते हैं।

उदाहरण के लिए, यदि आप "cat" ढूँढ़ते हैं, तो Excel इनमें भी गिन सकता है:

• "catalog"
• "cats"
• "category"

आप घटनाओं की गिनती के लिए यह फ़ॉर्मूला इस्तेमाल कर सकते हैं:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")संचालित द्वारा

आंशिक मिलान गिनें। चित्र: लेखक।

सीमाएँ जिनका ध्यान रखें

Excel फ़ॉर्मूले शब्द‑सीमाओं (word boundaries) का पता नहीं लगा सकते। वे केवल टेक्स्ट के भीतर मिलते हुए कैरेक्टर्स ढूँढ़ते हैं।

इस सीमा के कारण, फ़ॉर्मूले आंशिक मिलानों की गिनती कर सकते हैं।

कई स्प्रेडशीट कार्यों में यह व्यवहार स्वीकार्य है। जब आपको त्वरित अनुमान चाहिए या कड़े भाषा नियम आवश्यक नहीं हैं, तब यह अच्छी तरह काम करता है।

कई सेल्स और रेंज में शब्द कैसे गिनें

जब टेक्स्ट कई सेल्स में बिखरा हो, तब भी आप एक संयुक्त शब्द‑गिनती निकाल सकते हैं। यह तरीका उसी फ़ॉर्मूले पर आधारित है जो किसी एक सेल में शब्द गिनता है।

किसी रेंज में शब्द‑गिनतियाँ जोड़ें

किसी रेंज में शब्द‑गिनतियों को जोड़ने के लिए, लक्ष्य शब्द को हर सेल में गिनें। फिर रेंज में नतीजों को जोड़ें।

मान लें टेक्स्ट A2:A10 में है। आप cat की कुल आवृत्तियाँ इस फ़ॉर्मूले से निकाल सकते हैं:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))संचालित द्वारा

यह फ़ॉर्मूला रेंज के हर सेल की जाँच करता है, शब्द की उपस्थिति गिनता है और एक कुल देता है।

यदि आप अपर/लोअर केस के अंतर को नज़रअंदाज़ करना चाहते हैं, तो पहले टेक्स्ट बदलें:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))संचालित द्वारा

यह संस्करण Cat, CAT और cat को एक ही शब्द मानता है।

SUMPRODUCT से कई सेल्स में शब्द गिनें। चित्र: लेखक।

पूरे कॉलम या टेबल के लिए कुल शब्द‑गिनती पाएँ

एक और विकल्प है हेल्पर कॉलम का उपयोग।

मान लें टेक्स्ट A2:A10 में है और A1 में हेडर है।

1. B2 में शब्द‑गिनती का फ़ॉर्मूला दर्ज करें

2. कॉलम में नीचे फ़ॉर्मूला कॉपी करने के लिए फ़िल हैंडल पर डबल‑क्लिक करें

3. नतीजों को जोड़ें: =SUM(B2:B10)

Excel हर पंक्ति की शब्द‑गिनती जोड़कर कॉलम का कुल लौटाता है।

पूरे कॉलम में शब्द गिनें और उन्हें जोड़ें। चित्र: लेखक।

Excel टेबल में शब्द गिनें

Excel टेबल्स इस प्रक्रिया को आसान बनाती हैं क्योंकि फ़ॉर्मूले नई पंक्तियों पर अपने‑आप लागू होते हैं:

1. अपना डेटासेट चुनें
2. यहाँ जाएँ: Insert > Table
3. एक नया कॉलम जोड़ें जिसका नाम हो Word Count

नए कॉलम की पहली पंक्ति में दर्ज करें:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)संचालित द्वारा

Excel टेबल में शब्दों की गिनती। चित्र: लेखक।

अपने टेबल में Text को वास्तविक कॉलम नाम से बदलें। Excel हर पंक्ति के लिए फ़ॉर्मूला अपने‑आप भर देता है। पूरी टेबल की कुल शब्द‑गिनती निकालने के लिए उपयोग करें:

=SUM(Table2[Word Count])संचालित द्वारा

Table2 को अपनी टेबल के नाम से और Word Count को अपनी शीट में उपयोग किए गए कॉलम हेडर से बदलें।

Excel में शब्द‑गिनती की सामान्य त्रुटियों का समाधान

Excel में शब्द‑गिनती फ़ॉर्मूले आम तौर पर ठीक काम करते हैं। फिर भी, डेटा या फ़ॉर्मूला सेटअप में छोटी‑मोटी समस्याएँ गलत नतीजे दे सकती हैं। निम्नलिखित समाधान सबसे आम समस्याओं को संबोधित करते हैं।

आम गलतियाँ और उनके समाधान

कुछ सामान्य त्रुटियाँ और उनके समाधान इस प्रकार हैं: 

गलत रेंज का उपयोग

कभी‑कभी फ़ॉर्मूलों में खाली पंक्तियाँ या हेडर सेल्स शामिल हो जाते हैं। इससे कुल गिनती बढ़ सकती है या गणनाएँ धीमी हो सकती हैं।

समाधान: रेंज को वास्तविक डेटा‑पंक्तियों तक सीमित रखें। उदाहरण के लिए, A:A की जगह A2:A100 उपयोग करें।

फ़ॉर्मूला कॉपी करते समय गलत सेल रेफ़रेंस

यदि कोई फ़ॉर्मूला किसी स्थिर सेल की ओर इशारा करता है, तो हर पंक्ति एक जैसा नतीजा देगी।

समाधान: जब तक हर पंक्ति में वही सेल संदर्भित करना न हो, तब तक $A$2 की जगह A2 जैसे रिलेटिव रेफ़रेंस का उपयोग करें।

फ़ॉर्मूला में TRIM() का न होना

शब्दों के बीच अतिरिक्त स्पेस शब्द‑गिनती बढ़ा सकते हैं।

समाधान: फ़ॉर्मूला लगाने से पहले टेक्स्ट को TRIM() से रैप करें ताकि Excel आगे‑पीछे और दोहराए गए स्पेस हटा दे।

खाली सेल, नॉन‑टेक्स्ट डेटा और विशेष मामलों को संभालना

आइए देखें शब्द‑गिनती करते समय विशेष मामलों को कैसे संभालें: 

खाली सेल या केवल स्पेस वाले सेल

छिपे स्पेस वाले सेल 0 के बजाय 1 लौटा सकते हैं। खाली सेल के लिए 0 लौटाने हेतु यह फ़ॉर्मूला उपयोग करें:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)संचालित द्वारा

TRIM() अतिरिक्त स्पेस हटाता है, फिर Excel शब्द‑गिनती करता है।

शब्द गिनते समय खाली सेल संभालने के लिए TRIM का उपयोग करें। चित्र: लेखक।

संख्याएँ या फ़ॉर्मूलों वाले सेल

Excel संख्यात्मक सेल्स में भी कैरेक्टर्स गिनता है, जो नतीजों को प्रभावित कर सकता है। केवल टेक्स्ट सेल्स पर गिनती सीमित करने के लिए ISTEXT() फ़ंक्शन का उपयोग करें:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)संचालित द्वारा

जब सेल में टेक्स्ट नहीं होता, तो यह फ़ॉर्मूला 0 लौटाता है।

सेल में संख्याएँ होने पर शब्द‑गिनती के लिए ISTEXT() का उपयोग करें। चित्र: लेखक।

किसी सेल में मल्टीलाइन टेक्स्ट

किसी अन्य स्रोत से कॉपी किया गया टेक्स्ट लाइन ब्रेक या छिपे कैरेक्टर्स शामिल कर सकता है। ये गिनती को प्रभावित कर सकते हैं।

इसे रोकने के लिए, TRIM() या CLEAN() लागू करें क्योंकि ये शब्द‑गिनती फ़ॉर्मूला चलाने से पहले अनावश्यक कैरेक्टर्स हटाते हैं।

मर्ज्ड सेल्स

मर्ज्ड सेल्स उन फ़ॉर्मूलों को बिगाड़ सकते हैं जो सुसंगत रेंज पर निर्भर करते हैं। इसलिए बड़े डेटासेट पर गणना करते समय मर्ज्ड सेल्स से बचें।

सटीक शब्द‑गिनती के लिए डेटा वैलिडेशन

सटीक शब्द‑गिनती साफ़ इनपुट डेटा पर निर्भर करती है। कुछ सरल जाँचें त्रुटियों को पहले ही रोक सकती हैं।

गिनने से पहले टेक्स्ट को साफ़ करें

कॉपी या इम्पोर्ट किया गया टेक्स्ट अक्सर अतिरिक्त स्पेस या छिपे कैरेक्टर्स रखता है। शब्द‑गिनती से पहले टेक्स्ट को साफ़ करने हेतु TRIM() लगाने वाला एक हेल्पर कॉलम इस्तेमाल करें।

विशिष्ट शब्द गिनते समय टेक्स्ट मानकीकृत करें

वही शब्द अलग‑अलग केस में आ सकता है। विशिष्ट शब्द गिनने वाले फ़ॉर्मूलों से पहले टेक्स्ट को LOWER() या UPPER() से लोअर/अपरकेस में बदलें।

बड़े डेटासेट के लिए हेल्पर कॉलम का उपयोग करें

बड़े डेटासेट में जटिल फ़ॉर्मूले रिव्यू करना कठिन हो सकता है। प्रक्रिया को चरणों में बाँटें:

• एक कॉलम टेक्स्ट साफ़ करने के लिए
• एक कॉलम शब्द गिनने के लिए
• एक सेल कुल निकालने के लिए

यह संरचना त्रुटियाँ पकड़ना आसान बनाती है और प्रदर्शन बेहतर करती है।

खाली इनपुट रोकने के लिए डेटा वैलिडेशन का उपयोग करें

आप Excel के डेटा वैलिडेशन फ़ीचर से पूरी तरह खाली प्रविष्टियों को भी रोक सकते हैं:

1. इनपुट रेंज चुनें, जैसे A2:A100

2. यहाँ जाएँ Data > Data Validation

3. Allow के अंतर्गत Text length चुनें

4. Data में greater than चुनें और मान 0 सेट करें

खाली सेल्स से बचने के लिए डेटा वैलिडेशन। चित्र: लेखक।

अब Excel पूरी तरह खाली प्रविष्टियों को ब्लॉक करेगा और कोई सेल खाली छोड़ने पर त्रुटि संदेश दिखाएगा।

आधुनिक समाधान और AI‑संचालित टेक्स्ट विश्लेषण

Excel के नए संस्करणों में आधुनिक टेक्स्ट फ़ंक्शंस और बिल्ट‑इन AI फ़ीचर्स शामिल हैं। ये टूल्स केवल पारंपरिक फ़ॉर्मूलों पर निर्भर हुए बिना टेक्स्ट का विश्लेषण और शब्द‑गिनती का अनुमान लगाना आसान बनाते हैं।

Excel में TEXTSPLIT()

आधुनिक Excel संस्करणों में नए टेक्स्ट फ़ंक्शंस हैं जो कई स्ट्रिंग‑हैंडलिंग कार्यों को सरल बनाते हैं। स्पेस मैन्युअली गिनने के बजाय, आप टेक्स्ट को अलग‑अलग शब्दों में बाँटकर सीधे उन्हें गिन सकते हैं।

TEXTSPLIT() किसी डिलिमिटर के आधार पर टेक्स्ट को कई मानों में बाँटता है। आप शब्द अलग करने के लिए स्पेस को डिलिमिटर के रूप में उपयोग कर सकते हैं।

मान लें टेक्स्ट सेल A2 में है। B2 में यह फ़ॉर्मूला दर्ज करें:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))संचालित द्वारा

यह ऐसे काम करता है:

• TRIM(A2) अतिरिक्त स्पेस हटाता है

• TEXTSPLIT(...," ") जहाँ भी स्पेस हो, वहाँ टेक्स्ट को बाँट देता है

• COUNTA() प्राप्त शब्दों की गिनती करता है

यह तरीका पारंपरिक स्पेस‑गिनती फ़ॉर्मूलों की तुलना में पढ़ने में आसान है।

यह सबसे अच्छा तब काम करता है जब:

• आप Excel के आधुनिक संस्करण (Microsoft 365 या Excel 2021+) इस्तेमाल करते हैं
• टेक्स्ट में शब्दों के बीच साफ़ स्पेसिंग है
• डेटासेट में छोटा या मध्यम‑लंबाई का टेक्स्ट है

यदि टेक्स्ट में लाइन ब्रेक या असामान्य सेपरेटर्स हों, तो स्प्लिट करने से पहले अतिरिक्त सफ़ाई की ज़रूरत पड़ सकती है. 

Excel में Copilot और AI‑आधारित तरीके

Microsoft Excel में अब Copilot के ज़रिए AI सहायता शामिल है। Copilot स्प्रेडशीट डेटा का विश्लेषण कर सकता है और प्राकृतिक भाषा के अनुरोधों का उत्तर दे सकता है, जिनमें टेक्स्ट से जुड़े सवाल भी शामिल हैं।

उदाहरण के लिए, आप Copilot से कह सकते हैं:

Count the number of words in this column.संचालित द्वारा

Copilot डेटा का विश्लेषण करता है और बिना किसी फ़ॉर्मूले की ज़रूरत के नतीजा देता है।

सरल परीक्षणों में, Copilot आमतौर पर उचित अनुमान देता है। हालाँकि, संख्या हमेशा Excel फ़ॉर्मूलों से मिलने वाले नतीजों से मेल नहीं खा सकती।

क्यों नतीजे भिन्न हो सकते हैं

AI प्रणालियाँ अक्सर पारंपरिक शब्दों के बजाय टोकन्स के आधार पर टेक्स्ट का विश्लेषण करती हैं। टोकन वह टेक्स्ट‑खंड है जिसे मॉडल प्रोसेस करता है। टोकन हमेशा शब्द‑सीमाओं से मेल नहीं खाते।

उदाहरण के लिए:

• लंबे शब्द कई टोकन्स में बँट सकते हैं
• छोटे शब्द या विराम चिह्न एक टोकन साझा कर सकते हैं
• विशेष कैरेक्टर्स टेक्स्ट के विभाजन का तरीका बदल सकते हैं

इसी वजह से, Copilot टेक्स्ट की व्याख्या Excel के स्पेस‑आधारित फ़ॉर्मूलों से थोड़ी अलग कर सकता है।

अंतिम विचार

Excel में टेक्स्ट के साथ काम करते समय इन शब्द‑गिनती तरीकों को एक सरल वर्कफ़्लो के रूप में अपनाएँ। पहले टेक्स्ट साफ़ करें, स्पष्ट फ़ॉर्मूला लगाएँ, और अपने डेटासेट में नतीजों की जाँच करें। यह आदत सर्वे उत्तरों की समीक्षा, कंटेंट फ़ील्ड्स का ऑडिट, या स्प्रेडशीट में संग्रहीत नोट्स का विश्लेषण करते समय मदद करती है।

आप इन कौशलों को Excel फ़ंक्शंस और डेटा तैयारी तकनीकों का अभ्यास करके और मज़बूत कर सकते हैं.