Woorden tellen in Excel: 4 eenvoudige methoden

Je kunt woorden in Excel tellen met behulp van formules die het aantal spaties in een cel meten en die omzetten naar een woordentelling. Excel biedt geen ingebouwde woordenteller, dus de meeste methoden steunen op functies zoals LEN(), SUBSTITUTE() of nieuwere functies in moderne Excel-versies.

In deze gids bespreken we verschillende eenvoudige manieren om woorden in Excel te tellen met formules, moderne functies en AI-tools. We bekijken ook veelgemaakte fouten en randgevallen die de nauwkeurigheid kunnen beïnvloeden.

De uitdaging van woorden tellen in Excel

Excel heeft geen ingebouwde woordenteller omdat het is ontworpen voor getallen en gestructureerde data, niet voor tekstanalyse. Woorden tellen vereist dus een workaround. 

Waarom Excel geen native woordenteller heeft

Tekstverwerkers zoals Microsoft Word richten zich op zinnen, alinea’s en taalregels. Excel richt zich op berekeningen en gestructureerde data. 

Door dit ontwerp:

• Excel slaat tekst op als celwaarden, niet als onderdeel van een document
• Excel herkent woorden niet als afzonderlijke eenheden
• Excel-functies werken met tekens in plaats van taalstructuur

Het definitieprobleem: wat is een woord?

De definitie van een woord kan ook voor verwarring zorgen. 

Neem e-mailmarketing, bijvoorbeeld. Of denk aan hoe sommige tools samengestelde termen met een koppelteken als één woord tellen, terwijl andere ze als twee tellen. Ook afkortingen leveren randgevallen op.

Excel past geen taalregels toe om dit op te lossen. De meeste Excel-formules gaan ervan uit dat spaties woorden scheiden. Daarom wijken de woordentellingen in Excel soms af van de tellingen die je in andere tools ziet.

Veelvoorkomende use-cases voor woorden tellen in Excel

Toch hebben velen van ons de woordentelling nodig voor allerlei praktische taken.

Veelvoorkomende situaties zijn onder meer:

• Controleren van woordlimieten voor titels, beschrijvingen of advertentieteksten
• Beoordelen van de lengte van antwoorden uit enquêtes of formulieren
• Content controleren tijdens het opschonen van data
• Notities of documentatie beheren die in spreadsheets zijn opgeslagen

In deze situaties kun je formules gebruiken om de woordentelling te schatten.

Woorden tellen in Excel

Om woorden in Excel te tellen, combineer je de functies LEN() en SUBSTITUTE(). Ze tellen de woorden in één cel. 

Stel dat de tekst in cel A2 staat. Voer deze formule in een andere cel in, bijvoorbeeld B2:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1Mogelijk gemaakt door

Zo werkt de formule:

• LEN(A2) telt alle tekens in de cel

• SUBSTITUTE(A2," ","") verwijdert spaties uit de tekst

• LEN(SUBSTITUTE(...)) telt de tekens nadat de spaties zijn verwijderd

• Het verschil tussen beide tellingen geeft het aantal spaties

• Door +1 toe te voegen, zet je het aantal spaties om in een woordentelling

Totaal aantal woorden in een cel. Afbeelding door de auteur.

Omdat Excel tekens telt en geen woorden, fungeren spaties als signaal dat woorden scheidt.

Neem de tekst "The little cat slept" in cel A2 als voorbeeld: 

• Er staat één spatie tussen "The" en "little"
• Één spatie tussen "little" en "cat"
• Één spatie tussen "cat" en "slept"

Deze zin bevat drie spaties en vier woorden. Ter verduidelijking: Aantal woorden = aantal spaties + 1

De formule telt eerst de spaties en telt er vervolgens één bij op om de uiteindelijke woordentelling te geven.

Verbeterde formule die lege cellen en extra spaties verwerkt

Soms bevatten cellen extra spaties of zijn sommige cellen leeg. In zulke gevallen werkt de bovenstaande formule niet goed, omdat extra spaties twee veelvoorkomende problemen veroorzaken:

• Lege cellen geven 1 terug in plaats van 0.

• Meerdere spaties tussen woorden blazen de telling op.

Om dit te verhelpen, combineer je LEN() en SUBSTITUTE() met TRIM(): 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)Mogelijk gemaakt door

In deze formule: 

• TRIM(A2) verwijdert leidende, sluitende en extra spaties tussen woorden

• LEN(TRIM(A2))=0 controleert of de cel leeg is of alleen spaties bevat

• Als de cel leeg is, geeft de formule 0 terug

• Anders telt hij de woorden met dezelfde op spaties gebaseerde logica

Gebruik TRIM-LEN-SUBSTITUTE om woorden te tellen zonder extra spaties. Afbeelding door de auteur 

De formule toepassen op meerdere cellen en bereiken

Als de formule voor één cel werkt, kun je die op veel rijen toepassen. Laten we drie hoofdmethoden bekijken: 

De formule omlaag kopiëren in een kolom

Om de formule omlaag te kopiëren in een kolom: 

1. Selecteer de cel met de formule
2. Beweeg de cursor naar de rechterbenedenhoek tot de vulgreep verschijnt
3. Sleep de vulgreep omlaag of dubbelklik erop

Daardoor werkt Excel de verwijzingen automatisch bij:

• A2 wordt A3

• A3 wordt A4

• Enzovoort

Elke rij berekent zijn eigen woordentelling.

Sleep of dubbelklik de vulgreep om de formule omlaag te kopiëren. Afbeelding door de auteur.

Woorden tellen over een hele kolom

Tel de totale hoeveelheid woorden over meerdere cellen door de individuele tellingen op te tellen. Als de woordentellingen bijvoorbeeld in B2:B4 staan, gebruik dan:

=SUM(B2:B4)Mogelijk gemaakt door

Dit geeft je de totale woordentelling voor het hele bereik.

Het totale aantal woorden over een hele kolom tellen. Afbeelding door de auteur.

Woorden tellen in een Excel-tabel

Excel-tabellen kopiëren formules automatisch over rijen, wat handig is voor gestructureerde data. Zo tel je woorden in een tabel: 

1. Selecteer je data
2. Ga naar Invoegen > Tabel
3. Voeg een nieuwe kolom toe met de naam Word Count

Voer deze formule in de eerste rij van de nieuwe kolom in:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)Mogelijk gemaakt door

Opmerking: Mijn kolomnaam is Text, vervang die in de bovenstaande formule door je eigen kolomnaam.

Woorden tellen in een Excel-tabel. Afbeelding door de auteur.

Als je klaar bent, vult Excel de formule automatisch in voor elke rij in de tabel. Deze opzet werkt goed wanneer je woordentellingen bijhoudt in grote datasets.

Specifieke woorden tellen in Excel

Je kunt tellen hoe vaak een specifiek woord in een cel voorkomt door de functies LEN() en SUBSTITUTE() te combineren. 

Bekijk deze formule: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")Mogelijk gemaakt door

Deze formule telt hoe vaak het woord cat voorkomt in cel A2.

Zo werkt het:

• SUBSTITUTE(A2,"cat","") verwijdert elke vermelding van het woord cat

• LEN(A2) telt het oorspronkelijke aantal tekens

• LEN(SUBSTITUTE(...)) telt de tekens na het verwijderen

• Het verschil tussen beide lengtes toont hoeveel tekens zijn verwijderd

• Door te delen door LEN("cat") zet je de verwijderde tekens om in het aantal keren dat het woord voorkomt

Een specifiek woord in een cel tellen. Afbeelding door de auteur.

Hoofdletterongevoelig tellen

Excel-formules behandelen tekst vaak precies zoals die is geschreven. Als je hoofd- en kleine letters wilt negeren, zet je de tekst om naar dezelfde lettergrootte.

Dat kan met LOWER() of UPPER().

Voorbeeld met LOWER():

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")Mogelijk gemaakt door

Voorbeeld met UPPER():

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")Mogelijk gemaakt door

Beide formules zetten de tekst eerst om naar dezelfde lettergrootte, zodat Cat, CAT en cat als hetzelfde woord tellen.

Een specifieke woordgroep tellen

Dezelfde aanpak werkt ook voor woordgroepen. Als je bijvoorbeeld little cat wilt tellen, vervang dan het woord in de formule:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")Mogelijk gemaakt door

Excel verwijdert de woordgroep, meet het verschil in tekens en zet dat verschil om in het aantal keren dat de woordgroep voorkomt.

Specifieke woorden over een bereik tellen

Om een specifiek woord over meerdere cellen te tellen, pas je de formule toe op elke rij en tel je daarna de resultaten op.

Stel dat je tekst in A2:A10 staat en je het woord cat wilt tellen. Voer deze formule in B2 in:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")Mogelijk gemaakt door

Druk op Enter en sleep de formule omlaag tot B10. Elke rij geeft dan terug hoe vaak het woord in die cel voorkomt.

Het specifieke woord tellen. Afbeelding door de auteur.

Gedeeltelijke overeenkomsten tellen

Soms telt Excel een woord ook als het binnen een groter woord voorkomt. Dat heet een gedeeltelijke overeenkomst.

Als je bijvoorbeeld zoekt op "cat", kan Excel ook het volgende meetellen:

• "catalog"
• "cats"
• "category"

Je kunt deze formule gebruiken om voorkomens te tellen:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")Mogelijk gemaakt door

Gedeeltelijke overeenkomsten tellen. Afbeelding door de auteur.

Beperkingen om rekening mee te houden

Excel-formules kunnen geen woordgrenzen detecteren. Ze zoeken alleen naar overeenkomende tekens in de tekst.

Door deze beperking kunnen formules gedeeltelijke overeenkomsten meetellen.

Voor veel spreadsheettaken is dit gedrag acceptabel. Het werkt goed als je een snelle schatting wilt of als strikte taalregels niet nodig zijn.

Woorden tellen over meerdere cellen en bereiken

Je kunt nog steeds één woordentelling berekenen, zelfs als tekst over veel cellen is verspreid. Deze aanpak bouwt voort op dezelfde formule die je gebruikt om woorden in één cel te tellen.

Woordentellingen over een bereik optellen

Om woordentellingen over een bereik op te tellen, tel je het doelwoord in elke cel. Tel daarna de resultaten over het bereik op.

Stel dat je tekst in A2:A10 staat. Je kunt het totale aantal voorkomens van cat berekenen met de volgende formule:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))Mogelijk gemaakt door

Deze formule bekijkt elke cel in het bereik, telt hoe vaak het woord voorkomt en geeft één totaal terug.

Als je hoofd- en kleine letters wilt negeren, zet dan eerst de tekst om:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))Mogelijk gemaakt door

Deze versie behandelt Cat, CAT en cat als hetzelfde woord.

Woorden tellen over meerdere cellen met SUMPRODUCT. Afbeelding door de auteur.

Een totale woordentelling voor een hele kolom of tabel

Een andere optie gebruikt een hulpkolom.

Stel dat de tekst in A2:A10 staat en A1 de kop bevat.

1. Voer de woordentelformule in B2 in

2. Dubbelklik op de vulgreep om de formule omlaag te kopiëren

3. Tel de resultaten op met: =SUM(B2:B10)

Excel telt de woordentellingen per rij op en geeft het totaal voor de kolom.

Woorden in de hele kolom tellen en optellen. Afbeelding door de auteur.

Woorden tellen in een Excel-tabel

Excel-tabellen maken dit proces eenvoudiger omdat formules automatisch worden toegepast op nieuwe rijen:

1. Selecteer je dataset
2. Ga naar Invoegen > Tabel
3. Voeg een nieuwe kolom toe met de naam Word Count

Voer in de eerste rij van de nieuwe kolom in:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)Mogelijk gemaakt door

Woorden tellen in een Excel-tabel. Afbeelding door de auteur.

Vervang Text door de daadwerkelijke kolomnaam in je tabel. Excel vult de formule automatisch in voor elke rij. Om de totale woordentelling voor de hele tabel te berekenen, gebruik je:

=SUM(Table2[Word Count])Mogelijk gemaakt door

Vervang Table2 door je tabelnaam en Word Count door de kolomtitel die in je werkblad wordt gebruikt.

Veelvoorkomende fouten bij woordentelling in Excel oplossen

Formules voor woordentelling in Excel werken meestal goed. Toch kunnen kleine issues in de data of formulesetup onjuiste resultaten opleveren. De volgende oplossingen pakken de meest voorkomende problemen aan.

Veelgemaakte fouten en hoe je ze oplost

Hier zijn enkele veelvoorkomende fouten en hun oplossingen: 

Een onjuist bereik gebruiken

Soms bevatten formules lege rijen of kopcellen. Dat kan de totale telling opblazen of berekeningen vertragen.

Oplossing: Beperk het bereik tot de werkelijke gegevensrijen. Gebruik bijvoorbeeld A2:A100 in plaats van A:A.

Onjuiste celverwijzingen bij het kopiëren van formules

Als een formule naar een vaste cel verwijst, geeft elke rij hetzelfde resultaat.

Oplossing: Gebruik relatieve verwijzingen zoals A2 in plaats van $A$2, tenzij je wilt dat de formule in elke rij naar dezelfde cel verwijst.

TRIM() ontbreekt in de formule

Extra spaties tussen woorden kunnen de woordentelling verhogen.

Oplossing: Omhul de tekst met TRIM() voordat je de formule toepast, zodat Excel leidende, sluitende en dubbele spaties verwijdert.

Omgaan met lege cellen, niet-tekstgegevens en speciale gevallen

Laten we nu bekijken hoe je speciale gevallen aanpakt bij het tellen van woorden: 

Lege cellen of cellen met alleen spaties

Cellen met verborgen spaties kunnen 1 teruggeven in plaats van 0. Gebruik deze formule om 0 te krijgen voor lege cellen:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)Mogelijk gemaakt door

TRIM() verwijdert extra spaties voordat Excel de woordentelling berekent.

Gebruik TRIM om lege cellen af te handelen bij het tellen van woorden. Afbeelding door de auteur.

Cellen met getallen of formules

Excel telt ook tekens in numerieke cellen, wat de resultaten kan beïnvloeden. Gebruik de functie ISTEXT() om het tellen te beperken tot tekstcellen:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)Mogelijk gemaakt door

Deze formule geeft 0 terug wanneer de cel geen tekst bevat.

Gebruik ISTEXT() om met getallen in cellen om te gaan bij het tellen van woorden. Afbeelding door de auteur.

Meerdere regels tekst in één cel

Tekst die uit andere bronnen is gekopieerd, kan regeleinden of verborgen tekens bevatten. Die kunnen de telling beïnvloeden.

Voorkom dit door TRIM() of CLEAN() toe te passen, want die verwijderen onnodige tekens voordat je de woordentelformule uitvoert.

Samengevoegde cellen

Samengevoegde cellen kunnen formules verstoren die afhankelijk zijn van consistente bereiken. Vermijd daarom samengevoegde cellen bij berekeningen over grote datasets.

Datavalidatie voor nauwkeurig woorden tellen

Nauwkeurige woordentellingen hangen af van schone invoerdata. Een paar eenvoudige controles kunnen fouten voorkomen voordat ze optreden.

Reinig de tekst vóór het tellen

Gekopieerde of geïmporteerde tekst bevat vaak extra spaties of verborgen tekens. Gebruik een hulpkolom met TRIM() om de tekst te schonen voordat je de woordentelling berekent.

Standaardiseer tekst bij het tellen van specifieke woorden

Hetzelfde woord kan in verschillende schrijfwijzen voorkomen. Zet tekst om naar kleine of hoofdletters met LOWER() of UPPER() voordat je formules gebruikt die specifieke woorden tellen.

Gebruik hulpkolommen voor grote datasets

Grote datasets kunnen complexe formules lastig te controleren maken. Splits het proces in stappen:

• Eén kolom om de tekst te schonen
• Eén kolom om woorden te tellen
• Eén cel om totalen te berekenen

Deze structuur maakt fouten makkelijker te vinden en verbetert de prestaties.

Gebruik datavalidatie om lege invoer te voorkomen

Je kunt lege invoer voorkomen met de datavalidatiefunctie van Excel:

1. Selecteer het invoerbereik, bijvoorbeeld A2:A100

2. Ga naar Gegevens > Gegevensvalidatie

3. Kies bij Toestaan de optie Tekstlengte

4. Selecteer bij Gegevens de optie groter dan en stel de waarde in op 0

Datavalidatie om lege cellen te vermijden. Afbeelding door de auteur.

Excel blokkeert nu volledig lege invoer en toont een foutmelding als iemand de cel leeg probeert te laten.

Moderne oplossingen en AI-aangedreven tekstanalyse

Nieuwere versies van Excel bevatten moderne tekstfuncties en ingebouwde AI-functies. Deze tools maken het makkelijker om tekst te analyseren en woordentellingen te schatten zonder alleen op traditionele formules te vertrouwen.

TEXTSPLIT() in Excel

Moderne Excel-versies bevatten nieuwe tekstfuncties die veel taken met tekenreeksen vereenvoudigen. In plaats van handmatig spaties te tellen, kun je tekst in afzonderlijke woorden splitsen en die direct tellen.

TEXTSPLIT() verdeelt tekst in meerdere waarden op basis van een scheidingsteken. Je kunt een spatie als scheidingsteken gebruiken om woorden te scheiden.

Stel dat de tekst in cel A2 staat. Voer de volgende formule in B2 in:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))Mogelijk gemaakt door

Zo werkt dit:

• TRIM(A2) verwijdert extra spaties

• TEXTSPLIT(...," ") splitst de tekst waar een spatie staat

• COUNTA() telt de resulterende woorden

Deze aanpak leest makkelijker dan traditionele formules die spaties tellen.

Het werkt het best wanneer:

• Je moderne versies van Excel gebruikt (Microsoft 365 of Excel 2021+)
• De tekst een nette spatiëring tussen woorden heeft
• De dataset korte of middellange tekst bevat

Als de tekst regeleinden of ongebruikelijke scheidingstekens bevat, heb je mogelijk extra opschoning nodig voordat je splitst. 

Copilot in Excel en AI-gedreven methoden

Microsoft Excel bevat nu AI-assistentie via Copilot. Copilot kan spreadsheetdata analyseren en reageren op natuurlijke taal, inclusief vragen over tekst.

Je kunt Copilot bijvoorbeeld vragen:

Count the number of words in this column.Mogelijk gemaakt door

Copilot analyseert de data en geeft een resultaat terug zonder dat er formules nodig zijn.

In eenvoudige tests levert Copilot meestal een redelijke schatting op. Toch komt het aantal niet altijd overeen met het resultaat van Excel-formules.

Waarom de aantallen kunnen verschillen

AI-systemen analyseren tekst vaak met tokens in plaats van traditionele woorden. Een token vertegenwoordigt een stuk tekst dat door het model wordt verwerkt. Tokens komen niet altijd overeen met woordgrenzen.

Bijvoorbeeld:

• Een lang woord kan in meerdere tokens worden opgesplitst
• Korte woorden of leestekens kunnen een token delen
• Speciale tekens kunnen de manier waarop tekst wordt verdeeld veranderen

Daardoor kan Copilot tekst net iets anders interpreteren dan Excel-formules die op spaties vertrouwen om woorden te schatten.

Tot slot

Gebruik deze methoden voor woordentelling als onderdeel van een eenvoudige workflow wanneer je met tekst in Excel werkt. Reinig eerst de tekst, pas een duidelijke formule toe en controleer de resultaten over je dataset. Deze gewoonte helpt bij het beoordelen van enquête-antwoorden, het controleren van contentvelden of het analyseren van notities in spreadsheets.

Je kunt hierop voortbouwen door te oefenen met Excel-functies en technieken voor gegevensvoorbereiding.