Excel'de Kelimeler Nasıl Sayılır: 4 Kolay Yöntem

Excel'de kelimeleri, bir hücredeki boşluk sayısını ölçen ve bunları kelime sayısına çeviren formüller kullanarak sayabilirsiniz. Excel yerleşik bir kelime sayımı özelliği sunmaz; bu nedenle yöntemlerin çoğu LEN(), SUBSTITUTE() gibi işlevlere veya modern Excel sürümlerinde bulunan daha yeni işlevlere dayanır.

Bu rehberde, Excel'de formüller, modern işlevler ve yapay zeka araçları kullanarak kelime saymanın birkaç basit yolunu ele alacağız. Ayrıca sonuçların doğruluğunu etkileyebilecek yaygın hatalar ve istisnai durumlara da bakacağız.

Excel'de Kelime Sayımının Zorluğu

Excel, metin analizi yerine sayılar ve yapılandırılmış verilerle çalışacak şekilde tasarlandığından yerleşik bir kelime sayımı özelliği içermez. Bu yüzden kelime sayımı için bir geçici çözüme ihtiyaç vardır. 

Excel neden yerel bir kelime sayımı işlevine sahip değil

Microsoft Word gibi kelime işlemciler cümlelere, paragraflara ve dil kurallarına odaklanır. Excel ise hesaplamalara ve yapılandırılmış verilere odaklanır. 

Bu tasarım nedeniyle:

• Excel metni bir belgenin parçası olarak değil, hücre değerleri olarak depolar
• Excel kelimeleri ayrı birimler olarak tanımaz
• Excel işlevleri dil yapısı yerine karakterlerle çalışır

Tanım sorunu ve bir kelimeyi neyin oluşturduğu

Bir kelimenin tanımı da kafa karışıklığı yaratabilir. 

Örneğin e-posta pazarlamasını düşünün. Ya da bazı araçların tireli terimleri tek kelime sayarken, bazılarının iki kelime olarak saymasını ele alın. Ayrıca kısaltmalar da uç durumlar yaratır.

Excel bu durumları çözmek için dil kurallarını uygulamaz. Çoğu Excel formülü kelimelerin boşluklarla ayrıldığını varsayar. Bu nedenle Excel'deki kelime sayıları bazen diğer araçlarda gördüğünüz sayımlardan farklı olabilir.

Excel'de kelime sayımının yaygın kullanım alanları

Birçoğumuz pek çok pratik görev için hâlâ kelime sayılarını bilmeye ihtiyaç duyarız.

Yaygın durumlar şunları içerebilir:

• Başlıklar, açıklamalar veya reklam metinleri için kelime sınırlarını kontrol etmek
• Anket veya formlardan gelen yanıt uzunluklarını incelemek
• Veri temizliği sırasında içeriği denetlemek
• Elektronik tablolarda saklanan notları veya dokümantasyonu yönetmek

Bu durumlarda, kelime sayılarını tahmin etmek için formülleri kullanabilirsiniz.

Excel'de Kelimeler Nasıl Sayılır

Excel'de kelimeleri saymak için LEN() ve SUBSTITUTE() işlevlerini birleştirin. Bunlar bir hücredeki kelimeleri sayar. 

Metnin A2 hücresinde olduğunu varsayalım. Bu formülü B2 gibi başka bir hücreye girin:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1

Formül şöyle çalışır:

• LEN(A2) hücredeki tüm karakterleri sayar

• SUBSTITUTE(A2," ","") metindeki boşlukları kaldırır

• LEN(SUBSTITUTE(...)) boşluklar kaldırıldıktan sonraki karakterleri sayar

• İki sayı arasındaki fark boşluk sayısını verir

• +1 eklemek, boşluk sayısını kelime sayısına dönüştürür

Bir hücredeki toplam kelime sayısı. Görsel: Yazar.

Excel karakterleri, kelimeleri değil, saydığından boşluklar kelimeleri ayıran bir işaret görevi görür.

A2 hücresinde "The little cat slept" metnini örnek alalım: 

• "The" ile "little" arasında bir boşluk vardır
• "little" ile "cat" arasında bir boşluk
• "cat" ile "slept" arasında bir boşluk

Bu cümlede üç boşluk ve dört kelime vardır. Açıklık için: Kelime sayısı = boşluk sayısı + 1

Formül önce boşlukları sayar, ardından bir ekleyerek nihai kelime sayısını döndürür.

Boş hücreler ve fazladan boşlukları yöneten geliştirilmiş formül

Bazen hücrelerde fazladan boşluklar olabilir veya bazı hücreler boştur. Bu gibi durumlarda, yukarıdaki formül çalışmaz çünkü fazladan boşluklar iki yaygın soruna yol açar:

• Boş hücreler 0 yerine 1 döndürür.

• Kelimeler arasındaki birden çok boşluk sayımı şişirir.

Bunu düzeltmek için LEN() ve SUBSTITUTE()'ı TRIM() ile birleştirin: 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)

Bu formülde: 

• TRIM(A2) baştaki, sondaki ve kelimeler arasındaki fazladan boşlukları kaldırır

• LEN(TRIM(A2))=0 hücrenin boş olup olmadığını veya yalnızca boşluk içerip içermediğini kontrol eder

• Hücre boşsa formül 0 döndürür

• Aksi halde, aynı boşluk temelli mantıkla kelimeleri sayar

Fazladan boşlukları hariç tutarak kelime saymak için TRIM-LEN-SUBSTITUTE kullanın. Görsel: Yazar 

Formülü birden çok hücreye ve aralığa uygulayın

Formül bir hücrede çalıştıktan sonra, birçok satıra uygulayabilirsiniz. Bunu yapmanın üç ana yoluna bakalım: 

Formülü bir sütunda aşağı kopyalayın

Formülü bir sütunda aşağı kopyalamak için: 

1. Formülü içeren hücreyi seçin
2. Doldurma tutamacı görünene kadar imleci sağ alt köşeye getirin
3. Doldurma tutamacını aşağı sürükleyin veya çift tıklayın

Böylece Excel başvuruları otomatik olarak günceller:

• A2 A3 olur

• A3 A4 olur

• Ve böyle devam eder

Her satır kendi kelime sayımını hesaplar.

Formülü aşağı kopyalamak için doldurma tutamacını sürükleyin veya çift tıklayın. Görsel: Yazar.

Tüm bir sütundaki kelimeleri sayın

Birden fazla hücredeki toplam kelime sayısını bulmak için, tek tek sayımları toplayın. Örneğin, kelime sayıları B2:B4'te görünüyorsa, şunu kullanın:

=SUM(B2:B4)

Bu, tüm aralık için toplam kelime sayısını verir.

Tüm bir sütundaki toplam kelime sayısını hesaplayın. Görsel: Yazar.

Excel tablosunda kelimeleri sayın

Excel tabloları formülleri satırlara otomatik olarak kopyaladığından, yapılandırılmış veriler için kullanışlıdır. Bir tabloda kelimeleri saymak için: 

1. Verilerinizi seçin
2. Ekle > Tablo'ya gidin
3. Kelime Sayısı adlı yeni bir sütun ekleyin

Yeni sütunun ilk satırına şu formülü girin:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Not: Benim sütun adım Text, bu yüzden yukarıdaki formülde kendi sütun adınızla değiştirin.

Excel tablosunda kelimeleri sayın. Görsel: Yazar.

İşlem tamamlandığında Excel tablodaki her satır için formülü otomatik olarak doldurur. Bu kurulum, büyük veri kümelerinde kelime sayılarını takip ederken iyi çalışır.

Excel'de Belirli Kelimeler Nasıl Sayılır

LEN() ve SUBSTITUTE() işlevlerini birleştirerek belirli bir kelimenin bir hücrede kaç kez göründüğünü sayabilirsiniz. 

Şu formülü ele alalım: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Bu formül, A2 hücresinde cat kelimesinin kaç kez göründüğünü sayar.

Şöyle çalışır:

• SUBSTITUTE(A2,"cat","") cat kelimesinin her geçişini kaldırır

• LEN(A2) orijinal karakter sayısını sayar

• LEN(SUBSTITUTE(...)) kaldırma sonrası karakterleri sayar

• İki uzunluk arasındaki fark, kaç karakterin kaldırıldığını gösterir

• LEN("cat")'e bölmek, kaldırılan karakterleri kelimenin kaç kez geçtiğine dönüştürür

Bir hücrede belirli bir kelimeyi sayın. Görsel: Yazar.

Büyük/küçük harf duyarsız kelime sayımı

Excel formülleri genellikle metni yazıldığı gibi ele alır. Formülün büyük/küçük harf farklarını yok saymasını istiyorsanız, metni aynı harf büyüklüğüne dönüştürün.

Bunu LOWER() veya UPPER() ile yapabilirsiniz.

LOWER() kullanımı örneği:

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")

UPPER() kullanımı örneği:

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")

Her iki formül de metni önce aynı harf büyüklüğüne dönüştürür; böylece Cat, CAT ve cat aynı kelime olarak sayılır.

Belirli bir ifadeyi sayın

Aynı yaklaşım ifadeler için de çalışır. Örneğin little cat ifadesini saymak istiyorsanız, formülde kelimeyi değiştirin:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")

Excel ifadeyi kaldırır, karakter farkını ölçer ve bu farkı ifadenin kaç kez göründüğüne dönüştürür.

Bir aralıkta belirli kelimeleri sayın

Belirli bir kelimeyi birden çok hücrede saymak için, formülü her satıra uygulayın ve ardından sonuçları toplayın.

Metninizin A2:A10'da olduğunu ve cat kelimesini saymak istediğinizi varsayalım. Bu formülü B2'ye girin:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Enter'a basın, ardından formülü B10'a kadar aşağı sürükleyin. Her satır, kelimenin o hücrede kaç kez göründüğünü döndürecektir.

Belirli kelimeyi sayın. Görsel: Yazar.

Kısmi eşleşmeleri sayın

Bazen Excel, bir kelime daha uzun bir kelimenin içinde geçtiğinde bile onu sayar. Buna kısmi eşleşme denir.

Örneğin, "cat" araması yaparsanız, Excel şunları da sayabilir:

• "catalog"
• "cats"
• "category"

Görünümleri saymak için bu formülü kullanabilirsiniz:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")

Kısmi eşleşmeleri sayın. Görsel: Yazar.

Farkında olunması gereken sınırlamalar

Excel formülleri kelime sınırlarını tespit edemez. Yalnızca metin içindeki eşleşen karakterleri ararlar.

Bu sınırlama nedeniyle formüller kısmi eşleşmeleri sayabilir.

Birçok e-tablo görevinde bu davranış kabul edilebilir. Hızlı bir tahmin istediğinizde veya katı dil kurallarına gerek olmadığında iyi çalışır.

Birden Fazla Hücre ve Aralıkta Kelimeler Nasıl Sayılır

Metin birçok hücreye yayılmış olsa bile tek bir kelime sayımı hesaplayabilirsiniz. Bu yaklaşım, tek bir hücrede kelime saymak için kullanılan aynı formül üzerine kuruludur.

Bir aralık genelinde kelime sayılarını toplayın

Bir aralık genelinde kelime sayılarını toplamak için, hedef kelimeyi her hücrede sayın. Ardından sonuçları aralık genelinde toplayın.

Metninizin A2:A10'da olduğunu varsayalım. cat kelimesinin toplam geçişlerini şu formülle hesaplayabilirsiniz:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))

Bu formül aralıktaki her hücreyi kontrol eder, kelimenin kaç kez geçtiğini sayar ve tek bir toplam döndürür.

Büyük/küçük harf farklarını yok saymak istiyorsanız, önce metni dönüştürün:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))

Bu sürüm Cat, CAT ve cat'i aynı kelime olarak ele alır.

SUMPRODUCT kullanarak birden fazla hücrede kelimeleri sayın. Görsel: Yazar.

Tüm bir sütun veya tablo için toplam kelime sayısı alın

Bir diğer seçenek, yardımcı bir sütun kullanmaktır.

A2:A10'da metin olduğunu ve A1'de başlık bulunduğunu varsayalım.

1. B2'ye kelime sayımı formülünü girin

2. Formülü sütunda aşağı kopyalamak için doldurma tutamacını çift tıklayın

3. Sonuçları şu şekilde toplayın: =SUM(B2:B10)

Excel her satırdaki kelime sayılarını toplar ve sütun için toplamı döndürür.

Tüm sütundaki kelimeleri sayın ve toplayın. Görsel: Yazar.

Excel tablosunda kelimeleri sayın

Excel tabloları bu süreci kolaylaştırır çünkü formüller yeni satırlara otomatik olarak uygulanır:

1. Veri setinizi seçin
2. Şuraya gidin: Ekle > Tablo
3. Adı Kelime Sayısı olan yeni bir sütun ekleyin

Yeni sütunun ilk satırına şunu girin:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)

Excel tablosunda kelimeleri sayma. Görsel: Yazar.

Text'i tablonuzdaki gerçek sütun adıyla değiştirin. Excel formülü her satır için otomatik olarak doldurur. Tüm tablo için toplam kelime sayısını hesaplamak üzere şunu kullanın:

=SUM(Table2[Word Count])

Table2'yi tablo adınızla ve Word Count'u sayfanızda kullanılan sütun başlığıyla değiştirin.

Excel'de Yaygın Kelime Sayımı Hatalarını Giderme

Excel'deki kelime sayımı formülleri genellikle iyi çalışır. Ancak verideki veya formül kurulumundaki küçük sorunlar yanlış sonuçlar üretebilir. Aşağıdaki düzeltmeler en yaygın sorunları ele alır.

Yaygın hatalar ve nasıl düzeltileceği

İşte bazı yaygın hatalar ve çözümleri: 

Hatalı aralık kullanımı

Bazen formüller boş satırları veya başlık hücrelerini içerir. Bu, toplam sayımı şişirebilir veya hesaplamaları yavaşlatabilir.

Bunu düzeltmek için: Aralığı gerçek veri satırlarıyla sınırlandırın. Örneğin, A:A yerine A2:A100 kullanın.

Formülleri kopyalarken yanlış hücre başvuruları

Bir formül sabit bir hücreyi işaret ediyorsa, her satır aynı sonucu döndürür.

Bunu düzeltmek için: Her satırda aynı hücreye başvurmak istemedikçe $A$2 yerine A2 gibi bağıl başvurular kullanın.

Formülde TRIM() eksik

Kelimeler arasındaki fazladan boşluklar kelime sayısını artırabilir.

Bunu düzeltmek için: Excel'in baştaki, sondaki ve tekrarlanan boşlukları kaldırması için formülü uygulamadan önce metni TRIM() ile sarın.

Boş hücreler, metin olmayan veriler ve özel durumların ele alınması

Kelime sayarken özel durumları nasıl yöneteceğimize bakalım: 

Boş hücreler veya yalnızca boşluk içeren hücreler

Gizli boşluklar içeren hücreler 0 yerine 1 döndürebilir. Boş hücreler için 0 döndürmek üzere bu formülü kullanın:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)

TRIM(), Excel kelime sayısını hesaplamadan önce fazladan boşlukları kaldırır.

Kelime sayarken boş hücreleri ele almak için TRIM kullanın. Görsel: Yazar.

Sayılar veya formüller içeren hücreler

Excel, sayısal hücrelerdeki karakterleri de sayar; bu da sonuçları etkileyebilir. Sayımı yalnızca metin hücreleriyle sınırlamak için ISTEXT() işlevini kullanın:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)

Bu formül, hücre metin içermediğinde 0 döndürür.

Kelime sayarken hücrelerdeki sayılarla başa çıkmak için ISTEXT() kullanın. Görsel: Yazar.

Bir hücre içinde çok satırlı metin

Diğer kaynaklardan kopyalanan metin satır sonları veya gizli karakterler içerebilir. Bunlar sayımı etkileyebilir.

Bunu önlemek için, gereksiz karakterleri kelime sayımı formülünü çalıştırmadan önce kaldırdıkları için TRIM() veya CLEAN() uygulayın.

Birleştirilmiş hücreler

Birleştirilmiş hücreler, tutarlı aralıklara dayanan formülleri bozabilir. Bu nedenle, büyük veri kümelerinde hesaplama yaparken birleştirilmiş hücrelerden kaçının.

Doğru kelime sayımı için veri doğrulama

Doğru kelime sayımları, temiz girdi verilerine bağlıdır. Basit birkaç kontrol, hataları ortaya çıkmadan önce engelleyebilir.

Saymadan önce metni temizleyin

Kopyalanmış veya içe aktarılmış metin genellikle fazladan boşluklar veya gizli karakterler içerir. Kelime sayısını hesaplamadan önce metni temizlemek için TRIM() uygulayan yardımcı bir sütun kullanın.

Belirli kelimeleri sayarken metni standartlaştırın

Aynı kelime farklı harf büyüklüklerinde görünebilir. Belirli kelimeleri sayan formülleri çalıştırmadan önce metni LOWER() veya UPPER() ile küçük/büyük harfe dönüştürün.

Büyük veri kümeleri için yardımcı sütunlar kullanın

Büyük veri kümeleri, karmaşık formüllerin incelenmesini zorlaştırabilir. Süreci adımlara ayırın:

• Metni temizlemek için bir sütun
• Kelimeleri saymak için bir sütun
• Toplamları hesaplamak için bir hücre

Bu yapı, hataların tespitini kolaylaştırır ve performansı artırır.

Boş girişleri önlemek için veri doğrulama kullanın

Excel'in veri doğrulama özelliğiyle boş girişleri de önleyebilirsiniz:

1. A2:A100 gibi giriş aralığını seçin

2. Şuraya gidin: Veri > Veri Doğrulama

3. "İzin ver" altında Metin uzunluğu'nu seçin

4. "Veri" altında büyüktür seçin ve değeri 0 olarak ayarlayın

Boş hücrelerden kaçınmak için veri doğrulama. Görsel: Yazar.

Excel artık tamamen boş girişleri engelleyecek ve biri hücreyi boş bırakmaya çalışırsa bir hata mesajı gösterecektir.

Modern Çözümler ve Yapay Zeka Destekli Metin Analizi

Excel'in daha yeni sürümleri modern metin işlevleri ve yerleşik yapay zeka özellikleri içerir. Bu araçlar, yalnızca geleneksel formüllere dayanmak zorunda kalmadan metni analiz etmeyi ve kelime sayılarını tahmin etmeyi kolaylaştırır.

Excel'de TEXTSPLIT()

Modern Excel sürümleri, birçok dize işleme görevini basitleştiren yeni metin işlevleri içerir. Boşlukları elle saymak yerine, metni tek tek kelimelere bölebilir ve doğrudan sayabilirsiniz.

TEXTSPLIT(), bir ayırıcıya göre metni birden çok değere böler. Kelimeleri ayırmak için ayırıcı olarak boşluk kullanabilirsiniz.

Metnin A2 hücresinde olduğunu varsayalım. B2'ye aşağıdaki formülü girin:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))

Nasıl çalışır:

• TRIM(A2) fazladan boşlukları kaldırır

• TEXTSPLIT(...," ") boşluk görünen yerlerde metni böler

• COUNTA() ortaya çıkan kelimeleri sayar

Bu yaklaşım, geleneksel boşluk sayma formüllerine göre okunması daha kolaydır.

Şu durumlarda en iyi sonucu verir:

• Modern Excel sürümlerini kullanıyorsanız (Microsoft 365 veya Excel 2021+)
• Metin, kelimeler arasında temiz boşluklar içeriyorsa
• Veri kümesi kısa veya orta uzunlukta metin içeriyorsa

Metin satır sonları veya alışılmadık ayırıcılar içeriyorsa, bölmeden önce ek temizlik gerekebilir. 

Excel'de Copilot ve yapay zeka güdümlü yöntemler

Microsoft Excel artık Copilot aracılığıyla yapay zeka desteği içeriyor. Copilot, e-tablo verilerini analiz edebilir ve metinle ilgili sorular da dahil olmak üzere doğal dildeki isteklere yanıt verebilir.

Örneğin Copilot'a şunu sorabilirsiniz:

Count the number of words in this column.

Copilot verileri analiz eder ve herhangi bir formül gerektirmeden bir sonuç döndürür.

Basit testlerde Copilot genellikle makul bir tahmin üretir. Ancak sayı, her zaman Excel formüllerinden elde ettiğiniz sonuçla eşleşmeyebilir.

Sayılar neden farklı olabilir

Yapay zeka sistemleri genellikle metni geleneksel kelimeler yerine belirteçler (token) kullanarak analiz eder. Bir belirteç, model tarafından işlenen bir metin parçasını temsil eder. Belirteçler her zaman kelime sınırlarıyla örtüşmez.

Örneğin:

• Uzun bir kelime birden çok belirtece bölünebilir
• Kısa kelimeler veya noktalama işaretleri bir belirteci paylaşabilir
• Özel karakterler metnin nasıl bölündüğünü değiştirebilir

Bu nedenle Copilot, kelimeleri boşluklara dayanarak tahmin eden Excel formüllerinden metni biraz farklı yorumlayabilir.

Son Düşünceler

Excel'de metinle çalışırken bu kelime sayımı yöntemlerini basit bir iş akışının parçası olarak kullanın. Önce metni temizleyin, net bir formül uygulayın ve sonuçları veri kümeniz genelinde kontrol edin. Bu alışkanlık, anket yanıtlarını incelerken, içerik alanlarını denetlerken veya e-tablolarda saklanan notları analiz ederken işinize yarar.

Bu becerileri Excel işlevleri ve veri hazırlama teknikleri ile pratik yaparak geliştirebilirsiniz.