Cara Menghitung Kata di Excel: 4 Metode Mudah

Anda dapat menghitung kata di Excel menggunakan rumus yang mengukur jumlah spasi dalam sebuah sel dan mengonversinya menjadi jumlah kata. Excel tidak menyediakan fitur bawaan untuk menghitung kata, sehingga sebagian besar metode mengandalkan fungsi seperti LEN(), SUBSTITUTE(), atau fungsi yang lebih baru di versi Excel modern.

Dalam panduan ini, kami membahas beberapa cara sederhana untuk menghitung kata di Excel menggunakan rumus, fungsi modern, dan alat AI. Kami juga akan melihat kesalahan umum dan kasus tepi yang dapat memengaruhi akurasi hasil.

Tantangan Menghitung Kata di Excel

Excel tidak menyertakan fitur hitung kata bawaan karena dirancang untuk bekerja dengan angka dan data terstruktur, bukan analisis teks. Jadi, menghitung kata memerlukan solusi alternatif. 

Mengapa Excel tidak memiliki fungsionalitas hitung kata native

Pengolah kata seperti Microsoft Word berfokus pada kalimat, paragraf, dan kaidah bahasa. Excel berfokus pada perhitungan dan data terstruktur. 

Karena desain ini:

• Excel menyimpan teks sebagai nilai sel, bukan sebagai bagian dari dokumen
• Excel tidak mengenali kata sebagai unit terpisah
• Fungsi Excel bekerja dengan karakter, bukan struktur bahasa

Masalah definisi dan apa yang dianggap sebagai kata

Definisi kata juga dapat menimbulkan kebingungan. 

Pertimbangkan pemasaran email, misalnya. Atau pertimbangkan bagaimana beberapa alat memperlakukan istilah berhipen sebagai satu kata, sementara alat lain menghitungnya sebagai dua. Akronim juga menimbulkan kasus tepi.

Excel tidak menerapkan kaidah bahasa untuk menyelesaikan kasus-kasus ini. Sebagian besar rumus Excel menganggap bahwa kata dipisahkan oleh spasi. Itulah mengapa jumlah kata di Excel terkadang berbeda dari hitungan yang Anda lihat di alat lain.

Kasus penggunaan umum untuk menghitung kata di Excel

Sebagian dari kita masih perlu mengetahui jumlah kata untuk banyak tugas praktis.

Situasi umum dapat mencakup:

• Memeriksa batas kata untuk judul, deskripsi, atau salinan iklan
• Meninjau panjang respons dari survei atau formulir
• Audit konten saat pembersihan data
• Mengelola catatan atau dokumentasi yang disimpan di spreadsheet

Dalam situasi ini, Anda dapat menggunakan rumus untuk memperkirakan jumlah kata.

Cara Menghitung Kata di Excel

Untuk menghitung kata di Excel, gabungkan fungsi LEN() dan SUBSTITUTE(). Keduanya menghitung kata dalam satu sel. 

Misalkan teks ada di sel A2. Masukkan rumus ini di sel lain, seperti B2:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))+1Didukung oleh

Begini cara kerja rumusnya:

• LEN(A2) menghitung semua karakter dalam sel

• SUBSTITUTE(A2," ","") menghapus spasi dari teks

• LEN(SUBSTITUTE(...)) menghitung karakter setelah spasi dihapus

• Selisih antara kedua hitungan memberikan jumlah spasi

• Menambahkan +1 mengonversi jumlah spasi menjadi jumlah kata

Jumlah kata total dalam satu sel. Gambar oleh Penulis.

Karena Excel menghitung karakter, bukan kata, spasi berperan sebagai penanda yang memisahkan kata.

Ambil teks "The little cat slept" di sel A2 sebagai contoh: 

• Ada satu spasi antara "The" dan "little"
• Satu spasi antara "little" dan "cat"
• Satu spasi antara "cat" dan "slept"

Kalimat ini berisi tiga spasi dan empat kata. Untuk memperjelas: Jumlah kata = jumlah spasi + 1

Rumus menghitung spasi terlebih dahulu, lalu menambah satu untuk menghasilkan jumlah kata akhir.

Rumus yang ditingkatkan untuk menangani sel kosong dan spasi berlebih

Terkadang sel memiliki spasi berlebih, atau beberapa sel kosong. Dalam kasus seperti itu, rumus di atas tidak akan berfungsi karena spasi berlebih menimbulkan dua masalah umum:

• Sel kosong mengembalikan 1 alih-alih 0.

• Beberapa spasi di antara kata membuat hitungan membengkak.

Untuk memperbaikinya, gabungkan LEN() dan SUBSTITUTE() dengan TRIM(): 

=IF(LEN(TRIM(A3))=0,0,LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))+1)Didukung oleh

Dalam rumus ini: 

• TRIM(A2) menghapus spasi di awal, akhir, dan spasi ganda di antara kata

• LEN(TRIM(A2))=0 memeriksa apakah sel kosong atau hanya berisi spasi

• Jika sel kosong, rumus mengembalikan 0

• Jika tidak, rumus menghitung kata dengan logika berbasis spasi yang sama

Gunakan TRIM-LEN-SUBSTITUTE untuk menghitung kata tanpa menyertakan spasi berlebih. Gambar oleh Penulis 

Menerapkan rumus ke banyak sel dan rentang

Setelah rumus berfungsi untuk satu sel, Anda dapat menerapkannya ke banyak baris. Mari lihat tiga cara utama untuk melakukannya: 

Menyalin rumus ke bawah kolom

Untuk menyalin rumus ke bawah kolom: 

1. Pilih sel yang berisi rumus
2. Arahkan kursor ke sudut kanan bawah hingga muncul gagang isian (fill handle)
3. Seret gagang isian ke bawah atau klik dua kali

Dengan begitu, Excel memperbarui referensi secara otomatis:

• A2 menjadi A3

• A3 menjadi A4

• Dan seterusnya

Setiap baris menghitung jumlah katanya sendiri.

Seret atau klik ganda gagang isian untuk menyalin rumus ke bawah. Gambar oleh Penulis.

Menghitung kata di seluruh kolom

Untuk menghitung total jumlah kata di beberapa sel, jumlahkan hitungan masing-masing. Misalnya, jika jumlah kata ada di B2:B4, gunakan:

=SUM(B2:B4)Didukung oleh

Ini memberi Anda jumlah kata total untuk seluruh rentang.

Hitung total kata di seluruh kolom. Gambar oleh Penulis.

Menghitung kata di tabel Excel

Tabel Excel secara otomatis menyalin rumus ke seluruh baris, sehingga berguna untuk data terstruktur. Untuk menghitung kata di tabel: 

1. Pilih data Anda
2. Buka Insert > Table
3. Tambahkan kolom baru bernama Word Count

Masukkan rumus ini di baris pertama kolom baru:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)Didukung oleh

Catatan: Nama kolom saya adalah Text, jadi ganti dengan nama kolom Anda pada rumus di atas.

Hitung kata di tabel Excel. Gambar oleh Penulis.

Setelah selesai, Excel mengisi rumus secara otomatis untuk setiap baris di tabel. Pengaturan ini cocok saat Anda melacak jumlah kata di dataset besar.

Cara Menghitung Kata Tertentu di Excel

Anda dapat menghitung berapa kali kata tertentu muncul dalam sebuah sel dengan menggabungkan fungsi LEN() dan SUBSTITUTE(). 

Pertimbangkan rumus berikut: 

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")Didukung oleh

Rumus ini menghitung berapa kali kata cat muncul di sel A2.

Begini cara kerjanya:

• SUBSTITUTE(A2,"cat","") menghapus setiap kemunculan kata cat

• LEN(A2) menghitung jumlah karakter asli

• LEN(SUBSTITUTE(...)) menghitung karakter setelah penghapusan

• Selisih antara kedua panjang menunjukkan berapa banyak karakter yang dihapus

• Membagi dengan LEN("cat") mengonversi karakter yang dihapus menjadi jumlah kemunculan kata

Hitung kata tertentu dalam sebuah sel. Gambar oleh Penulis.

Penghitungan kata tidak peka huruf besar/kecil

Rumus Excel sering memperlakukan teks persis seperti yang ditulis. Jika Anda ingin rumus mengabaikan perbedaan huruf besar dan kecil, ubah teks ke huruf yang sama.

Anda dapat melakukannya dengan LOWER() atau UPPER().

Contoh menggunakan LOWER():

=(LEN(LOWER(A2))-LEN(SUBSTITUTE(LOWER(A2),"cat","")))/LEN("cat")Didukung oleh

Contoh menggunakan UPPER():

=(LEN(UPPER(A2))-LEN(SUBSTITUTE(UPPER(A2),"CAT","")))/LEN("CAT")Didukung oleh

Kedua rumus mengonversi teks ke huruf yang sama terlebih dahulu, sehingga Cat, CAT, dan cat dihitung sebagai kata yang sama.

Menghitung frasa tertentu

Pendekatan yang sama juga berfungsi untuk frasa. Misalnya, jika Anda ingin menghitung little cat, ganti kata dalam rumus:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"little cat","")))/LEN("little cat")Didukung oleh

Excel menghapus frasa tersebut, mengukur selisih karakter, dan mengonversi selisih itu menjadi jumlah kemunculan frasa.

Menghitung kata tertentu di seluruh rentang

Untuk menghitung kata tertentu di beberapa sel, terapkan rumus ke setiap baris lalu jumlahkan hasilnya.

Misalkan teks Anda ada di A2:A10 dan Anda ingin menghitung kata cat. Masukkan rumus ini di B2:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")Didukung oleh

Tekan Enter, lalu seret rumus ke bawah hingga B10. Setiap baris akan menampilkan jumlah kemunculan kata tersebut dalam sel itu.

Hitung kata tertentu. Gambar oleh Penulis.

Menghitung kecocokan parsial

Terkadang Excel menghitung sebuah kata meskipun muncul di dalam kata yang lebih panjang. Ini disebut kecocokan parsial.

Misalnya, jika Anda mencari "cat", Excel mungkin juga menghitung:

• "catalog"
• "cats"
• "category"

Anda dapat menggunakan rumus ini untuk menghitung kemunculan:

=(LEN(A2)-LEN(SUBSTITUTE(A2,"cat","")))/LEN("cat")Didukung oleh

Hitung kecocokan parsial. Gambar oleh Penulis.

Batasan yang perlu diperhatikan

Rumus Excel tidak dapat mendeteksi batas kata. Rumus hanya mencari karakter yang cocok di dalam teks.

Karena batasan ini, rumus dapat menghitung kecocokan parsial.

Dalam banyak tugas spreadsheet, perilaku ini dapat diterima. Ini bekerja baik saat Anda memerlukan perkiraan cepat atau ketika kaidah bahasa yang ketat tidak diperlukan.

Cara Menghitung Kata di Banyak Sel dan Rentang

Anda tetap dapat menghitung jumlah kata tunggal meskipun teks muncul di banyak sel. Pendekatan ini dibangun dari rumus yang sama yang digunakan untuk menghitung kata dalam satu sel.

Menjumlahkan hitungan kata di seluruh rentang

Untuk menjumlahkan hitungan kata di seluruh rentang, hitung kata target di setiap sel. Lalu jumlahkan hasil di seluruh rentang.

Misalkan teks Anda ada di A2:A10. Anda dapat menghitung total kemunculan cat dengan rumus berikut:

=SUMPRODUCT((LEN(A2:A10)-LEN(SUBSTITUTE(A2:A10,"cat","")))/LEN("cat"))Didukung oleh

Rumus ini memeriksa setiap sel dalam rentang, menghitung berapa kali kata tersebut muncul, dan mengembalikan satu total.

Jika Anda ingin mengabaikan perbedaan huruf besar/kecil, ubah teks terlebih dahulu:

=SUMPRODUCT((LEN(LOWER(A2:A10))-LEN(SUBSTITUTE(LOWER(A2:A10),"cat","")))/LEN("cat"))Didukung oleh

Versi ini memperlakukan Cat, CAT, dan cat sebagai kata yang sama.

Hitung kata di banyak sel menggunakan SUMPRODUCT. Gambar oleh Penulis.

Mendapatkan total jumlah kata untuk seluruh kolom atau tabel

Opsi lain menggunakan kolom pembantu.

Misalkan teks ada di A2:A10 dan A1 berisi header.

1. Masukkan rumus hitung kata di B2

2. Klik ganda gagang isian untuk menyalin rumus ke bawah kolom

3. Jumlahkan hasil dengan: =SUM(B2:B10)

Excel menjumlahkan hitungan kata dari setiap baris dan mengembalikan total untuk kolom tersebut.

Hitung kata di seluruh kolom dan jumlahkan. Gambar oleh Penulis.

Menghitung kata di tabel Excel

Tabel Excel memudahkan proses ini karena rumus otomatis diterapkan ke baris baru:

1. Pilih dataset Anda
2. Buka Insert > Table
3. Tambahkan kolom baru bernama Word Count

Di baris pertama kolom baru, masukkan:

=IF(LEN(TRIM([@Text]))=0,0,LEN(TRIM([@Text]))-LEN(SUBSTITUTE(TRIM([@Text])," ",""))+1)Didukung oleh

Hitung kata di tabel Excel. Gambar oleh Penulis.

Ganti Text dengan nama kolom sebenarnya di tabel Anda. Excel secara otomatis mengisi rumus untuk setiap baris. Untuk menghitung total jumlah kata untuk seluruh tabel, gunakan:

=SUM(Table2[Word Count])Didukung oleh

Ganti Table2 dengan nama tabel Anda dan Word Count dengan header kolom yang digunakan di lembar Anda.

Memecahkan Masalah Umum Saat Menghitung Kata di Excel

Rumus hitung kata di Excel umumnya bekerja dengan baik. Namun, masalah kecil pada data atau pengaturan rumus dapat menghasilkan hasil yang tidak akurat. Perbaikan berikut membahas masalah yang paling umum.

Kesalahan umum dan cara memperbaikinya

Berikut beberapa kesalahan umum dan solusinya: 

Menggunakan rentang yang tidak tepat

Terkadang rumus menyertakan baris kosong atau sel header. Hal ini dapat membengkakkan jumlah total atau memperlambat perhitungan.

Solusinya: Batasi rentang pada baris data yang sebenarnya. Misalnya, gunakan A2:A100 alih-alih A:A.

Referensi sel tidak tepat saat menyalin rumus

Jika rumus menunjuk ke sel tetap, setiap baris akan menghasilkan hasil yang sama.

Solusinya: Gunakan referensi relatif seperti A2 alih-alih $A$2 kecuali Anda memang ingin rumus merujuk ke sel yang sama di setiap baris.

Tidak menyertakan TRIM() dalam rumus

Spasi berlebih di antara kata dapat meningkatkan jumlah kata.

Solusinya: Bungkus teks dengan TRIM() sebelum menerapkan rumus agar Excel menghapus spasi di awal, akhir, dan spasi berulang.

Menangani sel kosong, data nonteks, dan kasus khusus

Sekarang mari kita lihat cara menangani kasus khusus saat menghitung kata: 

Sel kosong atau sel yang hanya berisi spasi

Sel yang berisi spasi tersembunyi dapat mengembalikan 1 alih-alih 0. Gunakan rumus ini untuk mengembalikan 0 untuk sel kosong:

=IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1)Didukung oleh

TRIM() menghapus spasi berlebih sebelum Excel menghitung jumlah kata.

Gunakan TRIM untuk menangani sel kosong saat menghitung kata. Gambar oleh Penulis.

Sel dengan angka atau rumus

Excel juga menghitung karakter di sel numerik, yang dapat memengaruhi hasil. Gunakan fungsi ISTEXT() untuk membatasi perhitungan pada sel teks:

=IF(ISTEXT(A2),IF(LEN(TRIM(A2))=0,0,LEN(TRIM(A2))-LEN(SUBSTITUTE(TRIM(A2)," ",""))+1),0)Didukung oleh

Rumus ini mengembalikan 0 saat sel tidak berisi teks.

Gunakan ISTEXT() untuk menangani angka di sel saat menghitung kata. Gambar oleh Penulis.

Teks multi-baris di dalam sel

Teks yang disalin dari sumber lain dapat menyertakan pemisah baris atau karakter tersembunyi. Ini dapat memengaruhi hitungan.

Untuk mencegah hal ini, terapkan TRIM() atau CLEAN() karena keduanya menghapus karakter yang tidak perlu sebelum menjalankan rumus hitung kata.

Sel yang digabung (merged cells)

Sel yang digabung dapat merusak rumus yang bergantung pada rentang konsisten. Jadi hindari menggabungkan sel saat melakukan perhitungan pada dataset besar.

Validasi data untuk penghitungan kata yang akurat

Akurasi jumlah kata bergantung pada input data yang bersih. Beberapa pemeriksaan sederhana dapat mencegah kesalahan sebelum muncul.

Bersihkan teks sebelum menghitung

Teks yang disalin atau diimpor sering mengandung spasi berlebih atau karakter tersembunyi. Gunakan kolom pembantu yang menerapkan TRIM() untuk membersihkan teks sebelum menghitung jumlah kata.

Standarkan teks saat menghitung kata tertentu

Kata yang sama dapat muncul dalam huruf yang berbeda. Ubah teks menjadi huruf kecil atau besar dengan LOWER() atau UPPER() sebelum menjalankan rumus yang menghitung kata tertentu.

Gunakan kolom pembantu untuk dataset besar

Dataset besar dapat membuat rumus kompleks sulit ditinjau. Pecah proses menjadi beberapa langkah:

• Satu kolom untuk membersihkan teks
• Satu kolom untuk menghitung kata
• Satu sel untuk menghitung total

Struktur ini memudahkan deteksi kesalahan dan meningkatkan kinerja.

Gunakan validasi data untuk mencegah input kosong

Anda juga dapat mencegah entri kosong dengan fitur validasi data Excel:

1. Pilih rentang input, seperti A2:A100

2. Buka Data > Data Validation

3. Di bawah Allow, pilih Text length

4. Di bawah Data, pilih greater than dan atur nilainya ke 0

Validasi data untuk menghindari sel kosong. Gambar oleh Penulis.

Sekarang Excel akan memblokir entri yang benar-benar kosong dan menampilkan pesan kesalahan jika seseorang mencoba membiarkan sel kosong.

Solusi Modern dan Analisis Teks Bertenaga AI

Versi Excel yang lebih baru menyertakan fungsi teks modern dan fitur AI bawaan. Alat-alat ini memudahkan analisis teks dan memperkirakan jumlah kata tanpa hanya mengandalkan rumus tradisional.

TEXTSPLIT() di Excel

Versi Excel modern menyertakan fungsi teks baru yang menyederhanakan banyak tugas penanganan string. Alih-alih menghitung spasi secara manual, Anda dapat membagi teks menjadi kata-kata dan menghitungnya langsung.

TEXTSPLIT() membagi teks menjadi beberapa nilai berdasarkan pembatas. Anda dapat menggunakan spasi sebagai pembatas untuk memisahkan kata.

Misalkan teks ada di sel A2. Masukkan rumus berikut di B2:

=COUNTA(TEXTSPLIT(TRIM(A2)," "))Didukung oleh

Cara kerjanya:

• TRIM(A2) menghapus spasi berlebih

• TEXTSPLIT(...," ") membagi teks setiap kali ada spasi

• COUNTA() menghitung kata yang dihasilkan

Pendekatan ini lebih mudah dibaca dibandingkan rumus penghitungan spasi tradisional.

Paling cocok saat:

• Anda menggunakan versi Excel modern (Microsoft 365 atau Excel 2021+)
• Teks berisi spasi yang rapi di antara kata
• Dataset berisi teks pendek atau menengah

Jika teks menyertakan pemisah baris atau pemisah yang tidak biasa, Anda mungkin memerlukan pembersihan tambahan sebelum melakukan pemisahan. 

Copilot di Excel dan metode berbasis AI

Microsoft Excel kini menyertakan bantuan AI melalui Copilot. Copilot dapat menganalisis data spreadsheet dan merespons permintaan bahasa alami, termasuk pertanyaan tentang teks.

Misalnya, Anda dapat meminta Copilot:

Count the number of words in this column.Didukung oleh

Copilot menganalisis data dan memberikan hasil tanpa memerlukan rumus apa pun.

Dalam pengujian sederhana, Copilot biasanya menghasilkan perkiraan yang masuk akal. Namun, angkanya tidak selalu sama dengan hasil dari rumus Excel.

Mengapa angkanya bisa berbeda

Sistem AI sering menganalisis teks menggunakan token alih-alih kata tradisional. Token mewakili potongan teks yang diproses oleh model. Token tidak selalu cocok dengan batas kata.

Sebagai contoh:

• Kata panjang dapat dipecah menjadi beberapa token
• Kata pendek atau tanda baca dapat berbagi satu token
• Karakter khusus dapat mengubah cara teks dibagi

Karena hal ini, Copilot mungkin menafsirkan teks sedikit berbeda dari rumus Excel yang mengandalkan spasi untuk memperkirakan kata.

Penutup

Gunakan metode hitung kata ini sebagai bagian dari alur kerja sederhana saat Anda bekerja dengan teks di Excel. Bersihkan teks terlebih dahulu, terapkan rumus yang jelas, dan periksa hasilnya di seluruh dataset. Kebiasaan ini membantu saat Anda meninjau respons survei, mengaudit kolom konten, atau menganalisis catatan yang disimpan di spreadsheet.

Anda dapat membangun keterampilan ini dengan mempraktikkan fungsi Excel dan teknik penyiapan data.