COUNTIF() Excel: conta le celle in base a condizioni

Tutti i modi per usare COUNTIF() in Excel

Ora che sai come funziona la funzione COUNTIF() in Excel, vediamo altri esempi di utilizzo.

Contare le celle che contengono testo

COUNTIF() può contare quante volte un testo specifico appare nei dati. Per esempio, ho un elenco di frutti in A2:A10 e voglio sapere quante volte compaiono le mele. Per questo, inserisco:

=COUNTIF(A2:A10, "Apple")

Questa formula conterà tutte le celle in quell'intervallo che corrispondono esattamente a Apple.

Conta le celle con testo usando COUNTIF(). Immagine dell'autore.

Contare valori numerici

Possiamo anche contare numeri maggiori, minori o uguali a un valore specifico. Per esempio, ho un dataset e ora posso trovare cose diverse con la formula COUNTIF().  

• Per contare quanti frutti hanno una quantità maggiore di 500: =COUNTIF(B2:B10,">500")

• Per contare quante quantità di frutti non sono uguali a 500: =COUNTIF(B2:B10, "<>500")

• Per trovare quanti frutti sono esattamente 500 in quantità: =COUNTIF(B2:B10, “500”)

• Per contare quanti frutti hanno quantità inferiore a 500: =COUNTIF(B2:B10,"<500")

Conta i valori numerici con la funzione COUNTIF(). Immagine dell'autore.

Usare i caratteri jolly per corrispondenze parziali

A volte vogliamo contare le celle che contengono una parte specifica di una parola o frase. In quel caso, usiamo i caratteri jolly. Ce ne sono due tipi:  

• * corrisponde a un numero qualsiasi di caratteri.

• ? corrisponde a un solo carattere.

Per esempio, ho un dataset di frutti e qui uso due formule diverse per mostrarti come COUNTIF() gestisce i casi con caratteri jolly. Per contare tutti i frutti che contengono n in qualsiasi punto dell'elenco dei frutti, inserisco la seguente formula:

=COUNTIF(A2:A10, "*n*")

Questa formula usa il carattere jolly asterisco *, che rappresenta un numero qualsiasi di caratteri (incluso zero). Digitando "*n*", Excel cerca le celle in cui "n" compare in qualsiasi punto del testo — all'inizio, al centro o alla fine. La formula conta tutte le celle corrispondenti nell'intervallo A2:A10 e restituisce il conteggio totale dei frutti che contengono la lettera "n".

Per contare tutti i frutti di quattro lettere che iniziano con K, digito:

=COUNTIF(A2:A10,"K???")

Questa formula usa il carattere jolly ?, che rappresenta esattamente un carattere. Digitando "K???", Excel conta tutte le celle nell'intervallo A2:A10 che iniziano con la lettera K e hanno esattamente quattro lettere, e mostra il risultato finale. 

Usa i caratteri jolly nella funzione COUNTIF(). Immagine dell'autore.

Applicare criteri da un'altra cella

Invece di inserire manualmente le condizioni, possiamo anche usare un riferimento di cella. Questo rende la formula più flessibile perché si aggiorna automaticamente quando cambia il valore della cella.

Se voglio sapere quanti frutti hanno una quantità maggiore di 300, digito la condizione nella cella D2 e poi uso questo riferimento di cella nella formula così:

=COUNTIF(B2:B11, D2)

Oppure possiamo anche scrivere l'operatore logico tra virgolette all'interno della formula e usare & per fare riferimento alla cella D3 così:

=COUNTIF(B2:B11, ">"&D3)

Conta le celle usando il riferimento di cella nella funzione COUNTIF(). Immagine dell'autore.

Contare celle vuote e non vuote

I dati mancanti possono essere importanti quanto quelli che hai. E COUNTIF() ci aiuta a individuare queste lacune. Diciamo che sto gestendo l'inventario e voglio sapere quanti frutti sono esauriti (celle vuote). Per questo, creo la seguente formula:

=COUNTIF(B2:B11,"")

E per contare quanti frutti sono disponibili (celle non vuote), uso questa formula:

=COUNTIF(B2:B11, "<>")

Tuttavia, se la tua cella contiene testo invisibile come uno spazio o un carattere speciale, COUNTIF() li conterà come celle non vuote.

Conta celle vuote e non vuote con la funzione COUNTIF(). Immagine dell'autore.

Contare date in base a condizioni diverse   

Possiamo anche contare le date in base a condizioni diverse. Supponiamo di voler contare quanti dipendenti sono stati assunti nella data nella cella B11 (1 marzo 2024). Quindi la nostra formula sarebbe:

=COUNTIF(B2:B9, B11)

E per verificare chi è stato assunto in o prima della data nella cella B11, uso questa formula:

=COUNTIF(B2:B9, ">="&B11)

Conta le differenze nelle date con la funzione COUNTIF(). Immagine dell'autore.

COUNTIF() con criteri multipli 

Possiamo anche usare COUNTIF() con criteri multipli. Se voglio contare quante date rientrano tra il 1° gennaio 2024 e il 30 gennaio 2024, digito:

=COUNTIF(B2:B9, ">="&B12) - COUNTIF(B2:B9, ">"&B13)

In alternativa, puoi usare la funzione COUNTIFS() per criteri multipli così:

=COUNTIFS(B2:B9,">="&B12,B2:B9,"<="&B13)

Entrambe daranno lo stesso risultato. 

Usa COUNTIF() per due condizioni. Immagine dell'autore.

Excel COUNTIF() vs COUNTIFS()

La funzione COUNTIF() di Excel conta le celle in base a un solo criterio, come abbiamo visto negli esempi qui sopra, e possiamo persino filtrare condizioni multiple usando più di una COUNTIF(), come visto nell'ultimo esempio.

Vale la pena dire che, se i tuoi dati richiedono criteri multipli, Excel fornisce una funzione estesa e più recente chiamata COUNTIFS(). Sebbene COUNTIFS() si comporti esattamente come COUNTIF() quando è specificata una sola condizione, consente anche di applicare più di una condizione.

Nonostante COUNTIFS() sia più recente e più capace con condizioni AND, COUNTIF() ha ancora il suo ruolo in Excel. Spesso crea formule più leggibili per condizioni semplici, rendendo i fogli di calcolo più facili da capire e mantenere. Ancora più importante, a differenza di COUNTIFS(), COUNTIF() gestisce condizioni OR, quando vuoi contare celle che soddisfano una qualsiasi tra più condizioni.

Capciamolo con un semplice esempio: 

=COUNTIF(B2:B11, "100") + COUNTIF(B2:B11, "900")

Questa formula conterà le celle in cui il valore è 100 oppure 900. Poiché non c'è alcun 900 nelle celle e solo un 100 è presente, mostrerà 1 come risultato.

Applicare la logica OR con COUNTIF(). Immagine dell'autore. 

Supponiamo inoltre di dover sapere quante volte in una riga compaiono 300 e kiwi insieme. Per questo posso usare COUNTIFS():

=COUNTIFS(B1:B11, "300", A1:A11, "kiwi")

La formula conterà le righe in cui entrambe le condizioni sono soddisfatte. Tuttavia, restituisce 0 perché nessuna delle condizioni è stata soddisfatta. 

Applicare la logica AND con COUNTIFS(). Immagine dell'autore. 

Questa distinzione è utile da conoscere, motivo per cui l'abbiamo inclusa nel nostro cheat sheet delle formule di Excel. E se vuoi davvero restare aggiornato sugli ultimi sviluppi, ti consiglio di seguire il nostro percorso di competenze Excel Fundamentals.

Errori comuni e risoluzione dei problemi

Anche i migliori utenti di Excel a volte si imbattono in problemi con COUNTIF(). La funzione è utile, ma ha alcune particolarità che possono trarti in inganno. Ecco i problemi più comuni e come risolverli rapidamente.

Conteggio errato per stringhe di testo lunghe

COUNTIF() non supporta stringhe di testo più lunghe di 255 caratteri. Se lavori con blocchi di testo più lunghi e ottieni risultati inattesi, prova a usare CONCATENATE() o l'operatore & per suddividere e combinare i tuoi criteri in una forma gestibile: 

=COUNTIF(range, CONCATENATE("First part of text", "Second part of text"))

Oppure

=COUNTIF(range, "First part of text" & "Second part of text")

Errore VALUE! in COUNTIF()

Un errore #VALUE! in COUNTIF() spesso si verifica quando la formula fa riferimento a una cartella di lavoro chiusa. Succede perché Excel non consente a COUNTIF() di contare dati da un file esterno a meno che il file non sia aperto. Per risolvere, assicurati che la cartella di lavoro di riferimento sia aperta prima di eseguire la formula. L'errore dovrebbe scomparire una volta aperto il file e COUNTIF() funzionerà correttamente.

Uso scorretto degli operatori

A volte potremmo dimenticare di racchiudere gli operatori logici tra virgolette. Assicurati sempre che operatori come >, < e <> siano tra virgolette nei tuoi criteri. Altrimenti non otterrai l'output.

 or example, the formula below will show an error:

=COUNTIF(B2:B10,>500)

Per evitarlo, assicurati che l'operatore logico sia racchiuso tra virgolette. 

=COUNTIF(B2:B10,">500")

Buone pratiche per Excel COUNTIF()

Ecco alcune buone pratiche da seguire quando lavori con COUNTIF() in Excel. 

• Usa intervalli denominati: invece di selezionare un intervallo come A2:A10 nella tua formula, assegna un nome personalizzato all'intervallo per rendere la formula più comprensibile. Per esempio, per contare quante volte Banana compare in un elenco, useremmo =COUNTIF(A2:A10, "Banana"). Ma se rinomino l'intervallo in Items e uso il riferimento di cella per la condizione, posso aggiornare la formula così: =COUNTIF(Items, C2). In questo modo la formula è più chiara e facile da capire. 

• Usa COUNTIFS() per condizioni multiple: a volte dobbiamo contare dati in base a più di una condizione. In tal caso, invece di usare più formule COUNTIF(), usa COUNTIFS() perché è la scelta migliore per applicare filtri multipli.

COUNTIF() vs. funzioni correlate

Oltre a COUNTIF() e COUNTIFS(), abbiamo molte altre funzioni di Excel per contare le celle. Tuttavia, ogni funzione ha uno scopo specifico. Quindi, diamo un'occhiata più da vicino a queste:

Come molte altre funzioni di Excel, anche COUNTIF() è uno dei modi più utili per contare e filtrare i dati. Invece di scorrere manualmente il tuo elenco, puoi usare questa funzione per trovare subito ciò di cui hai bisogno. E la parte migliore è che funziona con testo, numeri, celle vuote e modelli, il che rende più semplice la data analysis. 

Se vuoi saperne di più, inizia con il nostro corso Introduction to Excel per apprendere le nozioni di base. Per una base solida, il percorso Excel Fundamentals ti guiderà attraverso tutti i concetti chiave passo dopo passo. Infine, se lavori con dati finanziari, il nostro corso Financial Modeling in Excel ti guiderà nella creazione di modelli e previsioni finanziarie professionali.