COUNTIF() Excel: Koşullara Göre Hücreleri Sayma

Excel COUNTIF() İşlevini Kullanmanın Farklı Yolları

Artık Excel'de COUNTIF() işlevinin nasıl çalıştığını bildiğinize göre, nerelerde kullanabileceğimize dair daha fazla örneğe bakalım.

Metin içeren hücreleri sayma

COUNTIF(), belirli bir metnin verilerde kaç kez geçtiğini sayabilir. Örneğin, A2:A10 aralığında bir meyve listem var ve Elma'nın kaç kez geçtiğini bilmek istiyorum. Bunun için şunu giriyorum:

=COUNTIF(A2:A10, "Apple")

Bu formül, o aralıkta Apple ile tam olarak eşleşen tüm hücreleri sayacaktır.

COUNTIF() ile metin içeren hücreleri sayın. Görsel: Yazar.

Sayısal değerleri sayma

Belirli bir değerden büyük, küçük veya ona eşit sayıları da sayabiliriz. Örneğin bir veri setim var ve şimdi COUNTIF() formülüyle bundan farklı bilgiler bulabilirim.  

• 500'den büyük miktara sahip meyvelerin sayısını bulmak için: =COUNTIF(B2:B10,">500")

• Meyve miktarı 500'e eşit olmayanların sayısını bulmak için: =COUNTIF(B2:B10, "<>500")

• Tam olarak 500 olanların sayısını bulmak için: =COUNTIF(B2:B10, “500”)

• Miktarı 500'ün altında olan meyveleri saymak için: =COUNTIF(B2:B10,"<500")

COUNTIF() işleviyle sayısal değerleri sayın. Görsel: Yazar.

Kısmi eşleşmeler için joker karakter kullanma

Bazen bir kelimenin veya ifadenin belirli bir bölümünü içeren hücreleri saymak isteriz. Bu durumda joker karakterleri kullanırız. İki tür joker karakter vardır:  

• * herhangi bir sayıda karakterle eşleşir.

• ? yalnızca tek bir karakterle eşleşir. 

Örneğin bir meyve veri setim var ve COUNTIF()'in joker durumlarını nasıl ele aldığını göstermek için burada iki farklı formül kullanıyorum. Meyve listesinde herhangi bir yerde n harfini içeren tüm meyveleri saymak için şu formülü giriyorum:

=COUNTIF(A2:A10, "*n*")

Bu formül, sıfır dahil herhangi bir sayıda karakteri temsil eden * joker karakterini kullanır. "*n*" yazarak Excel, "n" harfinin metnin başında, ortasında veya sonunda herhangi bir yerde geçtiği hücreleri arar. Formül, A2:A10 aralığındaki tüm eşleşen hücreleri sayar ve içinde "n" harfi bulunan meyvelerin toplam sayısını döndürür.

Baş harfi K olan ve dört harften oluşan tüm meyveleri saymak için şunu yazarım:

=COUNTIF(A2:A10,"K???")

Bu formül, tam olarak bir karakteri temsil eden ? joker karakterini kullanır. "K???" yazarak Excel, A2:A10 aralığında K harfiyle başlayan ve tam olarak dört harften oluşan tüm hücreleri sayar ve nihai sonucu görüntüler. 

COUNTIF() işlevinde joker karakterleri kullanın. Görsel: Yazar.

Kriteri başka bir hücreden almak

Koşulları formüle sabitlemek yerine, hücre başvurusu da kullanabiliriz. Bu, hücre değeri değiştiğinde formülün otomatik güncellenmesini sağlayarak daha esnek hale getirir.

Kaç meyvenin miktarının 300'den fazla olduğunu bilmek istersem, koşulu D2 hücresine yazar ve formülde bu hücre başvurusunu şöyle kullanırım:

=COUNTIF(B2:B11, D2)

Veya mantıksal operatörü formül içinde tırnak işaretleriyle yazıp, & ile D3 hücresine şu şekilde başvurabiliriz:

=COUNTIF(B2:B11, ">"&D3)

COUNTIF() işlevinde hücre başvurusu kullanarak hücreleri sayın. Görsel: Yazar.

Boş ve dolu hücreleri sayma

Eksik veriler, elinizdeki veriler kadar önemli olabilir. COUNTIF() bu boşlukları tespit etmemize yardımcı olur. Diyelim ki stoğu yönetiyorum ve stokta olmayan meyvelerin sayısını (boş hücreler) bilmek istiyorum. Bunun için şu formülü oluşturuyorum:

=COUNTIF(B2:B11,"")

Ve mevcut (boş olmayan) meyvelerin sayısını bulmak için şu formülü kullanırım:

=COUNTIF(B2:B11, "<>")

Ancak, hücrenizde boşluk gibi görünmeyen bir karakter veya özel bir karakter varsa, COUNTIF() bunları dolu hücre olarak sayar.

COUNTIF() işlevini kullanarak boş ve dolu hücreleri sayın. Görsel: Yazar.

Farklı koşullara göre tarihleri sayma   

Tarihleri de farklı koşullara göre sayabiliriz. Diyelim ki B11 hücresindeki tarihte (1 Mart 2024) işe alınan kaç çalışan olduğunu saymak istiyoruz. Formülümüz şöyle olur:

=COUNTIF(B2:B9, B11)

Ve B11 hücresindeki tarihte veya ondan önce kimlerin işe alındığını kontrol etmek için şu formülü kullanırım:

=COUNTIF(B2:B9, ">="&B11)

COUNTIF() işlevini kullanarak tarihlerdeki farkı sayın. Görsel: Yazar.

Birden çok kriterle COUNTIF() 

COUNTIF()'i birden çok kriterle de kullanabiliriz. 1 Ocak 2024 ile 30 Ocak 2024 arasına düşen tarihlerin sayısını bulmak istersem, şöyle yazarım:

=COUNTIF(B2:B9, ">="&B12) - COUNTIF(B2:B9, ">"&B13)

Alternatif olarak, birden çok kriter için COUNTIFS() işlevini şu şekilde kullanabilirsiniz:

=COUNTIFS(B2:B9,">="&B12,B2:B9,"<="&B13)

Her ikisi de aynı sonucu verir. 

İki koşul için COUNTIF() kullanın. Görsel: Yazar.

Excel COUNTIF() ve COUNTIFS()

Excel'in COUNTIF() işlevi, yukarıdaki örneklerde gördüğümüz gibi tek bir kritere göre hücreleri sayar ve son örnekte gördüğümüz gibi birden fazla koşulu da birden fazla COUNTIF() kullanarak filtreleyebiliriz.

Verileriniz birden çok kriter gerektiriyorsa, Excel COUNTIFS() adında daha kapsamlı ve daha yeni bir işlev sunar demenin de tam zamanı. COUNTIFS() yalnızca tek bir koşul belirtildiğinde COUNTIF() ile aynı şekilde davranırken, birden fazla koşulu da uygulamanıza olanak tanır.

COUNTIFS() daha yeni olup AND koşullarında daha yetenekli olsa da, COUNTIF() Excel'de hâlâ yerini korur. Basit koşullar için daha okunabilir formüller üretir, bu da elektronik tablolarınızı anlamayı ve bakımını kolaylaştırır. Daha da önemlisi, COUNTIFS()'ten farklı olarak COUNTIF(), birden fazla kriterden herhangi birini karşılayan hücreleri saymak istediğiniz OR koşullarını ele alır.

Bunu basit bir örnekle anlayalım: 

=COUNTIF(B2:B11, "100") + COUNTIF(B2:B11, "900")

Bu formül, değerin 100 veya 900 olduğu hücreleri sayacaktır. Hücrelerde 900 olmadığı ve yalnızca bir adet 100 bulunduğu için sonuç olarak 1 gösterir.

COUNTIF() ile OR mantığını uygulama. Görsel: Yazar. 

Diyelim ki ayrıca aynı satırda değerin 300 ve metnin kiwi olduğu kaç satır olduğunu da bilmem gerekiyor. Bunun için COUNTIFS() kullanabilirim:

=COUNTIFS(B1:B11, "300", A1:A11, "kiwi")

Formül, her iki koşulun da sağlandığı satırları sayacaktır. Ancak, koşulların hiçbiri sağlanmadığı için 0 verir. 

COUNTIFS() ile AND mantığını uygulama. Görsel: Yazar. 

Bu ayrım bilmek açısından faydalıdır; bu yüzden Excel formülleri kopya kağıdımıza dahil ettik. Ve en güncel gelişmeleri yakından takip etmek istiyorsanız, Excel Fundamentals beceri yolumuzu almanızı öneririm.

Yaygın Hatalar ve Sorun Giderme

En iyi Excel kullanıcıları bile bazen COUNTIF() ile sorun yaşayabilir. İşlev kullanışlıdır ancak birkaç tuhaflığı sizi yanıltabilir. İnsanların en sık karşılaştığı sorunlar ve hızlı çözümleri şunlardır.

Uzun metin dizileri için hatalı sayım

COUNTIF(), 255 karakterden uzun metin dizilerini desteklemez. Daha uzun metinlerle çalışıyor ve beklenmeyen sonuçlar alıyorsanız, ölçütünüzü yönetilebilir hale getirmek için CONCATENATE() veya & işleçlerini kullanarak parçalayın ve birleştirin: 

=COUNTIF(range, CONCATENATE("First part of text", "Second part of text"))

Ya da

=COUNTIF(range, "First part of text" & "Second part of text")

COUNTIF() içinde VALUE! hatası

#VALUE! hatası genellikle formül kapalı bir çalışma kitabına başvurduğunda ortaya çıkar. Bunun nedeni, Excel'in COUNTIF()'in harici bir dosyadaki verileri, dosya açık değilse saymasına izin vermemesidir. Bunu çözmek için, formülü çalıştırmadan önce başvurulan çalışma kitabının açık olduğundan emin olun. Dosya açıldığında hata kaybolacak ve COUNTIF() düzgün çalışacaktır.

Operatörlerin hatalı kullanımı

Bazen mantıksal operatörleri tırnak içine almayı unutabiliriz. >, < ve <> gibi operatörlerin ölçüt içinde her zaman tırnak içinde olduğundan emin olun. Aksi halde çıktı alamazsınız.

 örneğin, aşağıdaki formül hata verecektir:

=COUNTIF(B2:B10,>500)

Bunu önlemek için, mantıksal operatörün tırnak işaretleri içinde olduğundan emin olun. 

=COUNTIF(B2:B10,">500")

Excel COUNTIF() En İyi Uygulamalar

Excel'de COUNTIF() ile çalışırken izlemeniz gereken bazı temel uygulamalar şunlardır. 

• Adlandırılmış aralıklar kullanın: Formülde A2:A10 gibi bir aralık seçmek yerine, aralığa özel bir ad vererek formülü daha anlaşılır hale getirin. Örneğin, bir listede Muz'un kaç kez geçtiğini saymak için =COUNTIF(A2:A10, "Banana") kullanırdık. Ancak aralığa Items adını verip koşul için hücre başvurusu kullanırsam, formülü şu şekilde güncelleyebilirim: =COUNTIF(Items, C2). Böylece formül daha net ve anlaşılır olur. 

• Birden çok koşul için COUNTIFS() kullanın: Bazen birden fazla koşula göre sayım yapmamız gerekir. Böyle bir durumda, birden çok COUNTIF() formülü kullanmak yerine COUNTIFS() kullanın; çünkü birden fazla filtre uygulamak için en iyi tercihtir.

COUNTIF() ve İlgili İşlevler

COUNTIF() ve COUNTIFS()'in yanı sıra, hücreleri saymak için birçok başka Excel işlevi de vardır. Ancak her işlevin belirli bir amacı vardır. O hâlde bunlara yakından bakalım:

Birçok Excel işlevinde olduğu gibi, COUNTIF() de verileri saymanın ve filtrelemenin en kullanışlı yollarından biridir. Listenizi tek tek gözden geçirmek yerine bu işlevi kullanarak ihtiyacınız olanı anında bulabilirsiniz. Ve en güzeli; metin, sayı, boş hücre ve desenlerle çalışır; bu da veri analizini kolaylaştırır. 

Daha fazlasını öğrenmek isterseniz, temel bilgileri öğrenmek için Introduction to Excel kursumuzla başlayın. Sağlam bir temel için Excel Fundamentals beceri yolu, tüm temel kavramları adım adım ele alır. Son olarak, finansal verilerle çalışıyorsanız, Financial Modeling in Excel kursumuz profesyonel finansal modeller ve tahminler oluşturma konusunda size yol gösterecektir.