Excel’de Sıralama Formülü: Örneklerle Kapsamlı Rehber

Sıralama, değerleri karşılaştırmanızı ve veri kümelerinizdeki örüntüleri belirlemenizi sağlar. Excel, sıralamayı kolaylaştırmak için RANK(), RANK.EQ() ve RANK.AVG() gibi güçlü araçlar sunar. Bu fonksiyonlar, bir spor turnuvasında katılımcıları puana göre sıralamaktan, sıralanmış satış verilerine dayalı pazar trendlerini analiz etmeye kadar her durumda faydalıdır.

Bu yazıda, Excel’deki üç sıralama fonksiyonunu inceleyecek ve uygulamalı örneklerle nasıl kullanabileceğinizi açıklayacağız. Ayrıca, sıralama fonksiyonlarını diğer Excel fonksiyonlarıyla birlikte kullanmayı ve yüzdelik sıralama hesaplamayı da ele alacağız. 

Kısa Cevap: Excel’de Sıralama Nasıl Hesaplanır? 

İstediğiniz veri kümelerinde sıralama hesaplamak için aşağıdaki formülü kullanın:

=RANK(number, ref, [order])

Excel’de RANK() Fonksiyonunu Anlamak

Diyelim ki okul öğrencileri arasında bir yarışma düzenlediniz ve şimdi binlerce öğrenciyi performanslarına göre sıralamak istiyorsunuz. 

Verileri saatlerce sıralar mıydınız? Hayır, çünkü Excel yardımcı olabilir. Sayısız güçlü fonksiyonu arasında, tek tıkla birinin sırasını belirlemenizi sağlayan RANK() fonksiyonu da vardır. 

Bir değerin, bir değer aralığı içindeki sırasını hesaplamak için şu formülü girin:

RANK(number, ref, [order])

Yukarıdaki formülde:

• number: sıralamak istediğiniz sayıdır.
• ref: sıralama için dikkate alınacak sayı aralığıdır.
• order: sıralama düzenini belirtir. Artan için değer olarak “1”; azalan için “0” (varsayılan) kullanın.

Excel’de RANK() Formülü Nasıl Kullanılır

Şimdi RANK() fonksiyonunu gerçek hayattan örneklerde uygulayalım:

Öğrenci notlarını sıralama

Binlerce öğrenciniz varsa notları hesaplamak zor ve zaman alıcı olabilir. Diyelim ki öğrenciler için yıl sonu sonuçlarını hazırlıyorsunuz ve onları puanlarına göre sıralamak istiyorsunuz. 

Bunu yapmak için önce veri kümenizi hazırlayın.

Excel’de öğrenci veri kümesi örneği. Kaynak: Yazarın görseli.

Bir hücreye =RANK(B3,($B$3:$B$7)) formülünü girin ve derecelendirmeyi almak için son dolu hücreye kadar sürükleyin.

Öğrencilerin sırasını hesaplamak için RANK() fonksiyonunu kullanma. Kaynak: Yazarın görseli.

Artık tek tıkla öğrencinin sırasını elde ettiniz.

Ancak aynı puana sahip iki öğrencinin 4. sırayı paylaştığını fark ettiniz mi? Sonraki öğrenci 23 puanla 5. sırayı atlayıp 6. sıraya zıplıyor. Bu, formülün yinelenen puanlara aynı sırayı verdiği anlamına gelir. 

Bu durum, yakın puanlar için sıralamayı bozabilir. Ancak bu eşitlikleri COUNTIF() fonksiyonuyla çözebilirsiniz. Şu formülü girin: 

=RANK(B3,($B$3:$B$8)) + COUNTIF($B$3:B3, B3)-1

COUNTIF() fonksiyonu, yinelenen değerler için sırayı ayarlar. Listedeki mevcut öğrencinin puanlarının kendisinden yukarıda kaç kez göründüğünü sayar.

Excel’de COUNTIF() ile eşitlikleri çözme. Kaynak: Yazarın görseli.

28 değeri iki kez geçiyor ve COUNTIF() bu tekrar sayısını takip ediyor. Bu tekrar sayısı sırayı ayarlamak için kullanılıyor. Formül, orijinal sıraya tekrar sayısından bir eksik değeri ekliyor. Böylece her yinelenen değer benzersiz bir sıra alıyor.

Bir veri kümesinde satış rakamlarını sıralama

Excel’in RANK() fonksiyonunu artan veya azalan düzende nasıl kullanacağımızı göstermek için başka bir örneğe bakalım. 

Satış ekibinizin performansını değerlendirmek istiyorsanız, aylık satış rakamlarını Excel’in RANK() fonksiyonuyla sıralayabilirsiniz.

Burada, her satış temsilcisi için aylık satış rakamlarından oluşan bir veri kümesi var. Kim en çok satışı getirmiş (yüksekten düşüğe) bunu baz alarak sıralama yapmak için RANK() fonksiyonunu kullanacağız.

Sıralanacak satış rakamları listesi. Kaynak: Yazarın görseli.

Satışları artan düzende sıralamak için =RANK(B2, ($B$2:$B$6), 1) formülünü uyguladık. Burada order parametresi için “1” değeri, sıralamanın artan düzende yapılacağını belirtir. 

Değerleri artan düzende sıralama. Kaynak: Yazarın görseli.

Formülü girdikten sonra, imleci basılı tutup hücrenin köşesini aşağı sürükleyerek kalan satış verilerinize uygulayın.

Benzer şekilde, değerleri azalan düzende sıralamak isterseniz, formülde order parametre değerini “0” olarak yazın: =RANK(B2, ($B$2:$B$6), 0)

Sonuçlardaki farkı görebilirsiniz:

Değerleri azalan düzende sıralama. Kaynak: Yazarın görseli.

Başvurulardaki dolar işaretlerini ($B$2:$B$6) fark etmiş olabilirsiniz. Bunlara mutlak başvuru denir. Formülün kopyaladığınızda daima aynı satış veri aralığına atıfta bulunmasını sağlar ve hataları önler.

Mutlak başvuru kullanmazsanız, örneğin =RANK(A2, A2:A10) gibi, aralık aşağı sürükledikçe ayarlanır:

• G3’teki formül: =RANK(G3,(G3:G7), 1)
• G4’teki formül: =RANK(G4,(G4:G8), 1)

Bu sorunu önlemek için “F4” tuşuna basarak mutlak başvuru kullanın. Artık formül şöyle olur: =RANK(G3,($G$3:$G$7), 1)

Yukarıdaki formülü son dolu hücreye kadar sürüklediğinizde, bağıl başvurular her hücrenin konumuna göre değişir. Mutlak başvuru kullanıldığında sonuçlardaki farkı görebilirsiniz:

Mutlak başvurulu ve başvurusuz sıralamalar arasındaki fark. Kaynak: Yazarın görseli.

Gelişmiş Sıralama Fonksiyonları: RANK.EQ() ve RANK.AVG()

Excel’de yinelenen değerlere rastladığınızda işler zorlaşabilir. İşte bu noktada ben RANK.EQ() ve RANK.AVG() fonksiyonlarını kullanmayı tercih ediyorum. Her ikisi de bağlamaya göre biraz farklı davranır. Nasıl çalıştıklarına bakalım.

RANK.EQ() Excel fonksiyonu

RANK.EQ() tıpkı standart RANK() gibi çalışır ancak adı daha açıklayıcıdır. Yinelenenler olduğunda, RANK.EQ() hepsine aynı sırayı verir ve sıradaki bir sonraki sıra(ları) atlar.

Sözdizimi: =RANK.EQ(number, ref, [order])

Yukarıdaki formülde:

• number: sıralamak istediğiniz sayıdır.
• ref: sıralama için dikkate alınacak sayı aralığıdır.
• order: sıralama düzenini belirtir. Artan için değer olarak “1”; azalan için “0” (varsayılan) kullanın.

Bunu bir örnekle anlayalım: Birkaç ülkenin nüfuslarından oluşan bir veri kümem vardı ve bu ülkeleri nüfuslarına göre sıralamak istedim.

Bunu RANK.EQ() fonksiyonunu kullanarak şöyle yaptım:

RANK.EQ() fonksiyonunu kullanma. Kaynak: Yazarın görseli.

Yukarıdaki görselde, en yüksek nüfusa sahip ülke 1. sırada ve devamı geliyor. Şimdi RANK.EQ()’nun eşitlikleri nasıl ele aldığını görüyorsunuz. 

ABD ve Endonezya’nın nüfusları aynı olduğundan, 2. sırayı paylaşıyorlar. Bu, RANK.EQ()’nun yinelenen değerlere aynı sırayı verip bir sonraki sırayı atladığını net biçimde gösterir.

RANK.AVG() Excel fonksiyonu

RANK.AVG() fonksiyonu, eşitlikleri farklı bir şekilde ele alır. Tüm yinelenen değerlere aynı sırayı vermek yerine, tek tek alacakları sıraların ortalamasını hesaplar.

Sözdizimi: RANK.AVG(number, ref, [order])

Yukarıdaki formülde:

• number: sıralamak istediğiniz sayıdır.
• ref: sıralama için dikkate alınacak sayı aralığıdır.
• order: sıralama düzenini belirtir. Artan için değer olarak “1”; azalan için “0” (varsayılan) kullanın.

Bunu bir örnekle anlayalım: Bir puan veri kümem vardı ve eşit puanları nasıl ele aldığını görmek için RANK.AVG() fonksiyonunu uyguladım.

RANK.AVG() fonksiyonunu kullanma. Kaynak: Yazarın görseli.

=RANK.AVG(D3,$D$3:$D$6) kullanıldığında 88 puanı 2,5 sırası alır. Bu, fonksiyonun tek tek atayacağı sıraların ortalamasını aldığı anlamına gelir. 

Bu yaklaşım, özellikle sık eşitliklerin olduğu veri kümelerinde daha dengeli bir sıralama dağılımı sağlar.

RANK()’i Diğer Excel Fonksiyonlarıyla Birleştirme

RANK() fonksiyonunu diğer Excel fonksiyonlarıyla kullanmak bazı senaryolarda faydalıdır. Yaygın birkaç kullanım durumuna bakalım.

RANK() ve ROUNDUP()’ı birleştirerek verileri kategorize etme

İşte ROUNDUP() fonksiyonunu RANK() ile nasıl birleştirebileceğiniz:

Excel’de RANK() ve ROUNDUP() fonksiyonlarını birleştirme. Kaynak. Yazarın görseli.

=ROUNDUP(RANK(B2, $B$2:$B$7, 1)/3, 0) formülünü kullandım; bu formül, B2 hücresindeki değerin B2 aralığı içindeki sırasını artan düzende hesaplar. Ardından bu sırayı üçe böler ve sonucu en yakın tam sayıya yuvarlar.

Bu formülle verileri etkin biçimde ayrı gruplara veya katmanlara ayırırsınız; bu da farklı performans düzeylerini belirlemeye ve daha ileri analizler için verileri kategorize etmeye yardımcı olur.

Eşitlikleri bozmak için RANK.EQ() ve COUNTIFS()’i birleştirme

Excel’in RANK() fonksiyonuyla eşitliklerin nasıl ele alınacağını birkaç şekilde tartıştık. Ancak, ürünleri yalnızca fiyata göre sıralamak istediğinizi düşünelim. Birden fazla ürün aynı fiyata sahipse bu keyfî gelebilir. 

Bu nedenle, eşitlikleri bozmak ve daha nesnel bir sıralama sistemi oluşturmak için ikincil bir ölçüt ekleyelim.

Kulaklık satın alan müşterilerden oluşan bir liste düşünün. Onları fiyata göre (birincil ölçüt) sıralamak ve eşitlik durumunda müşteri değerlendirmesini (ikincil ölçüt) kullanarak ayrım yapmak istiyoruz.

Müşteri listesi örneği. Kaynak: Yazarın görseli 

Bunu başarmak için RANK.EQ() fonksiyonunu COUNTIFS() ile birleştireceğiz. İşte nasıl:

=RANK.EQ($B2,$B$2:$B$9) + COUNTIFS($B$2:$B$9, $B2, $C$2:$C$9, ">"& $C2)

RANK.EQ() ve COUNTIFS() ile sıralama hesaplama. Kaynak: Yazarın görseli.

COUNTIFS($B$2:$B$9,$B2) bölümü, mevcut fiyatın listede kaç kez geçtiğini sayar. Tutarlılık için aralıkta $B$2:$B$9 mutlak başvuru kullanırız; ancak ölçüt hücresi olan $B2 bağıldır; böylece formül her satırı ayrı ayrı kontrol eder.

İkinci bölüm olan $C$2:$C$9,">"&$C2 ise mevcut kulaklığın C2 puanından daha yüksek müşteri değerlendirmelerinin sayısını bulur.

COUNTIFS() “VE” mantığıyla çalışır: Yalnızca tüm koşulları karşılayan hücreleri sayar. Aynı fiyattaki diğer kulaklıklardan daha yüksek bir puan yoksa, COUNTIFS() 0 döndürür. Bu nedenle, RANK.EQ() tarafından belirlenen sıra değişmez.

Excel’de Yüzdelik Sıralama Hesaplama

RANK() fonksiyonu sayısal bir değeri sıraladığından, bir Excel yüzdelik sıralama formülü kullanarak bir değerin veri kümesi içindeki sırasını, toplam veri kümesinin yüzdesi olarak hesaplayabilirsiniz. 

Excel, yüzdelik sıralamayı hesaplamak için iki fonksiyon sunar. İkisini de inceleyelim. 

PERCENTRANK.INC() Excel fonksiyonu

PERCENTRANK.INC(), veri kümesindeki en küçük ve en büyük değerler dahil olmak üzere bir değerin yüzdelik sırasını hesaplar.

Bu fonksiyonu bir örnekle anlayalım: 10 öğrencinin sınav puanlarını içeren bir veri kümem vardı ve en küçük ve en büyük değerler dahil her puanın yüzdelik sırasını hesaplamak istedim. 

Bu nedenle =PERCENTRANK.INC($A$2:$A$11, A2) formülünü kullandım:

PERCENTRANK.INC() ile sıralama hesaplama. Kaynak: Yazarın görseli

Yukarıdaki örnekte PERCENTRANK.INC() fonksiyonunun veri kümesindeki en küçük ve en büyük değerleri dahil ettiğini görüyorsunuz. 45 (en küçük değer) puanının yüzdelik sırası 0, 90 (en büyük değer) puanının yüzdelik sırası ise 1’dir.

PERCENTRANK.EXC() Excel fonksiyonu

PERCENTRANK.EXC(), veri kümesindeki en küçük ve en büyük değerler hariç olmak üzere bir değerin yüzdelik sırasını hesaplar.

Bu fonksiyonu bir örnekle anlayalım:  Önceki bölümdeki aynı öğrenci veri kümesine PERCENTRANK.EXC() fonksiyonunu uyguladım:

PERCENTRANK.EXC() fonksiyonuyla sıralama hesaplama. Kaynak: Yazarın görseli

Yukarıdaki örnekte PERCENTRANK.EXC() fonksiyonu veri kümesindeki en küçük ve en büyük değerleri hariç tutar. Bu, 45 (en küçük değer) puanının yüzdelik sırasının 0 olmadığı ve 90 (en büyük değer) puanının yüzdelik sırasının 1 olmadığı anlamına gelir.

Excel RANK() Fonksiyonunda Yaygın Hatalar ve Kaçınma Yolları

Excel fonksiyonları iş süreçleri için kullanışlı ve pratiktir. Ancak bazen en deneyimli kullanıcılar bile yaygın hatalar yapabilir. Bu nedenle dikkat etmeniz gereken başlıca hataları ve nasıl kaçınabileceğinizi paylaşıyorum:

Formülleri kopyalayıp yapıştırma

Sıralama formülünüzü hücreler arasında kopyalarken, yanlışlıkla mutlak başvuru kullanmadığınızdan emin olun. Her hücre farklı bir veri parçasına başvurabilir ve sıralamanızı bozabilir. 

Bunu önlemek için formüllerinizi kurarken aralığı sabitlemek amacıyla $A$1:$A$10 gibi mutlak başvurular kullanın ve tüm sıralamalarınızda doğru aralığı koruyun.

Yinelenenleri ele almamak

Diyelim ki en çok satış yapan iki satış görevlisi eşit. Sıralamada eşitlikleri nasıl ele aldığınız büyük fark yaratır: RANK() ve RANK.EQ() fonksiyonları eşitlikleri benzer şekilde ele alır.

Bu nedenle, eşit değerlere aynı mı farklı mı sıra verileceğine ya da sıralarının RANK.AVG() ile ortalamasının mı alınacağına karar vermelisiniz. Ardından uygun fonksiyonu kullanın. 

Yanlış sıralama düzeni 

Basit görünebilir; ancak fonksiyonunuzda order argümanını ayarlamayı unutmak, sıralamayı yanlış yönde (artan veya azalan) yapmanıza neden olabilir. 

Bu yüzden bu argümanı her zaman iki kez kontrol edin: Azalan için “0” (veya boş bırakın), artan için “1” kullanın. Sıralama düzeninin istediğiniz şekilde olduğundan emin olun.

Fonksiyon karmaşası

Farklı veri kümeleriyle çalışırken doğru sıralama fonksiyonunu seçmek çok önemlidir; yanlış fonksiyonla ilerlemek istenmeyen sonuçlar doğurur.

Bu sorunlardan kaçınmak için, standart sıralama için RANK.EQ()’yu; eşitliklerin sonucu etkilediği, istatistiksel analiz gibi durumlarda ise RANK.AVG()’yi kullanın. 

Güncellenmeyen formüller 

Verileriniz büyüdükçe formüllerinizdeki aralık başvurularını güncellemeniz gerekir. Aksi halde yeni veri noktaları sıralamaya dahil edilmez ve doğru sonuca neden ulaşamadığınızı merak edersiniz.

Bu yüzden formüllerinizdeki aralıkları düzenli olarak güncelleyin ve kontrol edin. Böylece tüm değerli verileriniz sıralamaya dahil edilir.

Son Düşünceler

Artık RANK(), RANK.EQ() ve RANK.AVG() gibi fonksiyonları kullanarak eşitlikleri ele almayı ve çeşitli sıralama sorunlarını çözmeyi biliyorsunuz. Bu fonksiyonlar, öğrenci notlarını analiz etmekten satış rakamlarını sıralamaya kadar farklı senaryolarda yardımcı olur.

Excel becerilerinizi daha da geliştirmek isterseniz, Datacamp’teki bazı harika kurs ve kaynaklara göz atmanızı öneririm: 

• Temel bilgileri oluşturmak için Introduction to Excel kursuyla başlayın; ardından Data Analysis in Excel ve Excel Fundamentals ile ilerleyin.  
• Veriyi görselleştirme becerinizi geliştirmek için Data Visualization in Excel kursunu değerlendirin. 
• Daha ileri düzey veri düzenleme için Introduction to PowerQuery in Excel kursu büyük fayda sağlar. 
• Excel uzmanlığınızı resmileştirmek için ise How to Earn a Microsoft Excel Certification başlıklı kapsamlı rehbere göz atın.