Excel Bileşik Faiz Formülü: Kapsamlı Bir Rehber

Bileşik faizi anlamak, kişisel finans, yatırım stratejileri ve iş kararları üzerinde önemli etkisi olduğu için finansal analiz açısından kritik öneme sahiptir. Excel bu hesaplamaları basitleştirir; gelecekteki birikimleri öngörmeyi, yatırım getirilerini değerlendirmeyi ve kredi geri ödemelerini planlamayı kolaylaştırır.

Bu rehber, Excel’de bileşik faiz hesaplamanın temel formüllerden ileri tekniklere kadar farklı yöntemlerini adım adım anlatacaktır. Excel’de Finansal Modellemeden kursumuz, bu derste ele alınan teknik ve stratejiler üzerine inşa edilir. Bu kavramları öğrenmek finansal analiz becerilerinizi önemli ölçüde geliştirebilir.

Bileşik Faiz Nedir?

Bileşik faiz, paranın zaman içindeki üstel büyümesini ifade eder. Doğrusal büyüyen basit faizin aksine, bileşik faiz her dönemde kazanılan faizin bir sonraki dönem için ana paraya eklenmesiyle ivmelenir.

Bileşik faizin gücü, uzun vadeli yatırımları görselleştirdiğinizde belirginleşir. Örneğin faiz oranlarındaki küçük bir fark (örneğin %6’ya karşı %8), on yıllar içinde dramatik biçimde farklı sonuçlar doğurabilir; bu da rahat bir emeklilikle finansal zorluk arasında fark yaratabilir.

Bileşik Faiz Formülü

Bileşik faiz şu formülle hesaplanır:

Bileşik faiz formülü. Görsel: Yazar.

Burada:

• A = Faiz sonrası nihai tutar
• P = Anapara (başlangıç yatırımı)
• r = Yıllık faiz oranı (ondalık biçimde)
• n = Yılda kaç kez bileşikleme yapıldığı
• t = Yıl sayısı

Artık kavramı ve matematiksel formülü anladığımıza göre, bunu Excel’de uygulayalım.

Excel’de Bileşik Faiz Nasıl Hesaplanır

Bu formülü Excel’de uygulamak için, her değişken için açıkça etiketlenmiş hücrelerden oluşan temel bir çalışma sayfası yapısı kurun.

Önce, çalışma sayfanızı aşağıdaki etiketlerle düzenleyin:

• Hücre A1: “Anapara”
• Hücre A2: “Yıllık Faiz Oranı”
• Hücre A3: “Yıldaki Bileşikleme Sayısı”
• Hücre A4: “Süre (yıl)”
• Hücre A5: “Nihai Tutar”

Ardından, değerlerinizi B sütununa girin:

• Hücre B1: Anapara tutarınızı girin (ör. 1000)

• Hücre B2: Faiz oranını ondalık olarak girin (ör., 0.05 için %5)

• Hücre B3: Yıldaki bileşikleme sayısını girin (ör., aylık için 12)

• Hücre B4: Süreyi yıl olarak girin (ör., 5)

Verileri hazırladıktan sonra, Excel sayfanız şöyle görünmelidir:

Excel tablosunun kurulumu. Görsel: Yazar.

Son olarak, B5 hücresine bileşik faiz formülünü girin:

=B1*(1+B2/B3)^(B3*B4)

Excel’de bileşik faiz formülü. Görsel: Yazar.

Bu formül, yukarıdaki matematiksel denklemi doğrudan uygular ve bileşik faiz sonrası nihai tutarı hesaplar.

Bileşik faiz hesaplama. Görsel: Yazar.

FV() işlevini kullanma

El ile yazılan formül işe yarasa da, Excel bileşik faiz hesaplamalarını basitleştiren yerleşik finansal işlevler sağlar. FV() (Gelecek Değer) işlevi, özellikle düzenli ödemeler veya yatırımlar yaparken bileşik faizi hesaplamak için yararlıdır.

FV() işlevinin söz dizimi:

=FV(rate, nper, pmt, [pv], [type])

Burada:

• rate = Dönem başına faiz oranı

• nper = Toplam ödeme dönemi sayısı

• pmt = Her dönemde yapılan ödeme (yoksa 0 girin)

• pv = Bugünkü değer (başlangıç anaparası), negatif sayı olarak girilmelidir

• type = Ödemelerin zamanı (dönem sonu için 0, dönem başı için 1)

Elektronik tablomuzu FV() işlevini kullanacak şekilde güncelleyelim:

• Hücre A6: “FV() İşlevini Kullanma”

B6 hücresine şunu yazın:

=FV(B2/B3, B3*B4, 0, -B1)

FV() kullanarak bileşik faiz hesaplama. Görsel: Yazar.

Dikkat ederseniz, dönem başına oranı elde etmek için yıllık faiz oranını bileşikleme sayısına bölüyoruz ve işlevin gerektirdiği şekilde anaparayı negatif sayı olarak giriyoruz.

Hesaplanan bileşik faizi aşağıdaki gibi görebilirsiniz:

FV() kullanarak bileşik faiz. Görsel: Yazar.

PMT() işlevini kullanma

PMT() işlevi, sabit ödemeler ve sabit faiz oranına dayalı bir kredi için ödeme tutarını hesaplar. Aslen kredi ödemeleri için tasarlanmış olsa da, hedef bir tutara ulaşmak için düzenli katkı paylarını belirlemek istediğiniz bileşik faiz senaryolarına uyarlanabilir.

PMT() işlevinin söz dizimi:

=PMT(rate, nper, pv, [fv], [type])

Burada:

• rate = Dönem başına faiz oranı

• nper = Toplam ödeme dönemi sayısı

• pv = Bugünkü değer (başlangıç anaparası)

• fv = Gelecek değer (ulaşmak istediğiniz hedef tutar)

• type = Ödemelerin zamanı (dönem sonu için 0, dönem başı için 1)

Bunu çalışma sayfamıza ekleyelim:

• Hücre A7: “Hedef Tutar”

• Hücre B7: Hedef tutarınızı girin (ör., 5000)

• Hücre A8: “Gerekli Aylık Ödeme”

B8 hücresine şunu yazın:

=PMT(B2/12, B4*12, -B1, B7)

PMT() kullanarak bileşik faiz hesaplama. Görsel: Yazar.

Bu formül, başlangıç anaparanız ve faiz oranınız verilmişken hedef tutara ulaşmak için aylık ne kadar katkı yapmanız gerektiğini hesaplar.

Hesaplanan aylık ödeme aşağıdaki gibi görülebilir:

PMT() kullanarak bileşik faiz. Görsel: Yazar.

Excel’de PMT() işlevi varsayılan olarak negatif bir değer döndürür; çünkü nakit akışı perspektifinden tasarlanmıştır:

• Negatif değerler ödediğiniz parayı (nakit çıkışı) temsil eder
• Pozitif değerler aldığınız parayı (nakit girişi) temsil eder

Excel’de Bileşik Faiz Uygulamada

Excel’deki bileşik faiz formülünün, kişisel finans ve iş bağlamlarında çok sayıda gerçek dünya uygulaması vardır. Bu pratik senaryolardan bazılarını inceleyelim.

Birikim ve yatırımlar

Bileşik faiz hesaplamalarının en yaygın uygulamalarından biri, birikim veya yatırım hesaplarının büyümesini projeksiyonlamaktır. Paranın zaman içinde nasıl büyüdüğünü anlamak, bilinçli kararlar almamıza yardımcı olur.

Çalışma sayfamızın yeni bir bölümünde emeklilik birikimi projeksiyon modeli oluşturalım. D1 hücresine “Emeklilik Birikimi Projeksiyonu” yazdıktan sonra, D2’den D6’ya kadar olan hücrelerde parametrelerinizi ayarlayabilirsiniz:

• Hücre D2: “Başlangıç Yatırımı” ve E2: 10000

• Hücre D3: “Aylık Katkı” ve E3: 500

• Hücre D4: “Yıllık Faiz Oranı” ve E4: 0.07

• Hücre D5: “Zaman Ufku (yıl)” ve E5: 30

• Hücre D6: “Bileşikleme Sıklığı” ve E6: “Aylık”

D7 hücresine “Projeksiyonlu Gelecek Değer” yazdıktan sonra, E7’ye şu denklemi yazın:

=FV(E4/12, E5*12, -E3, -E2)

Projeksiyonlu gelecek değeri hesaplama. Görsel: Yazar.

Bu formül, hem başlangıç yatırımınızı hem de düzenli katkılarınızı dikkate alarak emeklilik birikiminizi projekte eder. Gelecek değeri aşağıdaki gibi görebilirsiniz:

FV() kullanarak projeksiyonlu gelecek değer. Görsel: Yazar.

Bu modeli, yıl bazında bir projeksiyon tablosu oluşturarak geliştirebiliriz:

• D9 hücresine “Yıl Bazında Projeksiyon” yazın

• D10 hücresine “Yıl” ve E10 hücresine “Bakiye” yazın

• D11 hücresine 0 yazın (başlangıç yılı)

• E11 hücresine başlangıç yatırımınızı girin: =E2

• D12 hücresine 1 yazın

• E12 hücresine, 1. yıldan sonraki bakiyeyi hesaplayın:

=FV($E$4/12, 1*12, -$E$3, -E11)

Yıl bazında projeksiyon tablosu oluşturma. Görsel: Yazar.

• D11 ve D12 hücrelerini seçin; sonra doldurma tutamacını (sağ alt köşedeki küçük kare) 41. satıra kadar sürükleyerek 0’dan 30’a kadar yılları oluşturun
• E12 hücresini seçin; sonra doldurma tutamacını 41. satıra kadar sürükleyin

Excel, her satırda hücre başvurularını otomatik olarak ayarlayarak, her yılın bir önceki yılın bakiyesi üzerine inşa edildiği bir hesaplama dizisi oluşturacaktır.

Yıl bazında projeksiyon tablosu. Görsel: Yazar.

Bu grafik, birikimlerinizin zamanla nasıl büyüdüğünü anlamanıza yardımcı olur ve bileşik faize özgü ivmelenen büyüme modelini göstererek düzenli yatırım yapmaya motive eder.

Kredi hesaplamaları

Bileşik faiz, bakiyeye faiz işleyen krediler için de geçerlidir. Excel’in işlevleri, aylık ödemelerden toplam ödenen faize kadar kredilerin çeşitli yönlerini anlamanıza yardımcı olabilir.

Bir amortisman planı oluşturmak için kredi parametrelerinizi aşağıdaki gibi ayarlayın:

Kredinin aylık ödemesini hesaplama. Görsel: Yazar.

Aylık ödemeyi hesaplamak için H3 hücresine şunu yazın:

=PMT(H3/12, H4*12, H2)

PMT() kullanarak kredi aylık ödemesini hesaplama. Görsel: Yazar.

Aylık ödeme şöyle görünecektir:

Kredi aylık ödemesi. Görsel: Yazar.

Ardından, başlıkları aşağıdaki gibi olan amortisman planı tablosunu kurun:

Amortisman planı tablosu oluşturma. Görsel: Yazar.

İlk ödeme (8. satır) için başlangıç değerlerini girin:

• Hücre G8: 1 (ilk ödeme)

• Hücre H8: =H2 (başlangıç kredi tutarı)

• Hücre I8: =ABS(H5) (ödeme tutarı; negatif PMT() sonucunu pozitife çevirmek için ABS() kullanılır)

• Hücre J8: =H8*($H$3/12) (faiz kısmı: dönem başı bakiye × aylık oran)

• Hücre K8: =I8-J8 (anapara kısmı: ödeme tutarı − faiz kısmı)

• Hücre L8: =H8-K8 (dönem sonu bakiye: dönem başı bakiye − anapara kısmı)

Amortisman planı tablosu hesaplamaları. Görsel: Yazar.

İkinci ödeme (9. satır) için şu formülleri oluşturun:

• Hücre G9: 2 (ikinci ödeme)

• Hücre H9: =L8 (dönem başı bakiye, önceki dönemin dönem sonu bakiyesine eşittir)

• Hücre I9: =I8 (ödeme tutarı aynı kalır)

• Hücre J9: =H9*($H$3/12) (yeni dönem başı bakiyeye göre faiz kısmı)

• Hücre K9: =I9-J9 (anapara kısmı)

• Hücre L9: =H9-K9 (dönem sonu bakiye)

Amortisman planı tablosu hesaplamaları. Görsel: Yazar.

Sonra H9’dan L9’a kadar olan hücreleri seçin ve 367. satıra kadar (toplam 360 ödeme için) aşağı sürükleyin.

H6 hücresinde toplam ödenen faizi hesaplayabiliriz: 

=SUM(J8:J367)

Nihai plan şöyle görünmelidir:

Amortisman planı tablosu. Görsel: Yazar.

Bu amortisman planı, her ödemenin kredi bakiyenizi nasıl etkilediğini ve kredi süresi boyunca ödenen önemli faiz tutarını gösterir. İlk ödemeler ağırlıkla faizi karşılar; sonraki ödemeler ise esas olarak anaparayı azaltır — ipotek kredilerini anlamak için önemli bir içgörü.

İleri Düzey Bileşik Faiz Teknikleri

Düzensiz bileşikleme dönemleri ve değişken faiz oranları gibi ileri tekniklerin kullanıldığı senaryoları inceleyelim.

Değişken faiz oranları

Gerçek dünyada, değişken faiz oranları söz konusu olabilir; örneğin değişken faizli ipotekler veya piyasa bağlı yatırımlar. Excel, biraz ek kurulumla bu karmaşık senaryoları da yönetebilir.

Farklı zaman dilimleri için farklı faiz oranlarına sahip bir model oluşturabiliriz. Faiz oranlarının her 5 yılda bir %0,5 artacağı varsayımıyla değişken faiz oranı tablosu kuralım:

Değişken faiz oranları için tablo kurulumu. Görsel: Yazar.

1. Yılın dönem sonu bakiyesini ve 2. Yılın dönem başı bakiyesini hesaplamak için şunları yazın:

• Hücre Q4: =P4*(1+O4)

• Hücre P5: =Q4

Değişken faiz oranı hesaplamaları. Görsel: Yazar.

Şimdi 1–2. Yıllara ait satırları seçip tabloyu istediğimiz yıl sayısına kadar aşağı sürükleyebilir; ihtiyaç duydukça faiz oranlarını değiştirebiliriz. Aşağıdaki görselde gösterildiği gibi:

Değişken faiz oranı hesaplayıcı. Görsel: Yazar.

Bu model, değişen faiz oranlarının yatırımınızı veya kredinizi zaman içinde nasıl etkilediğini görselleştirmenizi sağlar. 

Bileşikleme sıklığı

Gerçek dünyadaki finansal ürünler sıklıkla standart dışı bileşikleme dönemleri kullanır. Bazı yatırımlar üç aylık, bazıları aylık, bazıları ise günlük bileşikler. Bu bileşikleme sıklığı farklılıkları, zamanla getirilerinizi önemli ölçüde etkileyebilir.

Bu değişkenleri Excel’de karşılamak için bileşik faiz formülünü uygun şekilde ayarlayabilirsiniz. Örneğin, %6 yıllık faizle günlük bileşikleme üzerinden 5 yıl boyunca 10.000 $’lık bir yatırımın hesaplanması için şu formül kullanılır:

=10000*(1+0.06/365)^(365*5)

Örnek bir düzensiz bileşikleme hesaplayıcısı şöyle görünür:

Düzensiz bileşikleme hesaplayıcısı. Görsel: Yazar.

Bu karşılaştırma, bileşikleme sıklığının yatırım getirilerinizi nasıl etkilediğini açıkça gösterir.

Gördüğünüz gibi, daha sık bileşikleme daha yüksek getiri sağlar; ancak sıklık arttıkça marjinal fayda azalır. Bu içgörü, farklı bileşikleme yöntemleri sunan finansal ürünleri değerlendirirken özellikle değerlidir.

Sonuç

Bu rehber boyunca, Excel’in bileşik faiz formüllerinin çeşitli pratik uygulamalarını inceledik. Temel matematiksel formülü anlamaktan FV() ve PMT() gibi Excel’in finansal işlevlerini uygulamaya kadar, anlamlı finansal hesaplamalar yapmak için gerekli araçlara artık sahibiz.

Bu derste anlatılanların ötesinde Excel becerilerinizi derinleştirmek için Excel’de Finansal Modellemeden kursumuza kaydolmayı düşünün. Bu kurs, derste ele alınan temel kavramları daha ileri finansal modelleme teknikleriyle geliştirir.