मुख्य सामग्री पर जाएँ

Excel LAMBDA(): कस्टम फ़ंक्शंस कैसे बनाएं

जानें कि LAMBDA() के साथ अपनी स्प्रेडशीट्स को कैसे सरल बनाएं। एक बार लिखें, हर जगह पुन: उपयोग करें, और इसे Excel के अन्य आधुनिक फ़ंक्शंस के साथ जोड़ें।
· 7 मि॰ पढ़ें

AI के साथ खोजें

Excel के LAMBDA() फ़ंक्शन से कस्टम फ़ॉर्मूले बनाना संभव होता है। यह आपको किसी भी गणना को समाहित करने, उसे एक नाम देने और अपने वर्कबुक में कहीं भी पुन: उपयोग करने देता है।

इसका मतलब है कि आपको वही फ़ॉर्मूला बार-बार कॉपी नहीं करना पड़ेगा। इसके बजाय, आप LAMBDA() का उपयोग करके अपनी स्प्रेडशीट्स को अधिक साफ़-सुथरा और संभालने में आसान बना सकते हैं और, अगर आप मुझसे पूछें, तो यह VBA से भी थोड़ा आसान है।

Excel LAMBDA() का उपयोग क्यों करें?

मूल रूप से, LAMBDA() आपको किसी भी फ़ॉर्मूले को आपके द्वारा परिभाषित फ़ंक्शन में लपेटने देता है। आप इनपुट पैरामीटर देते हैं (ठीक वैसे ही जैसे SUM() या VLOOKUP() में आर्ग्युमेंट्स देते हैं) और फिर जब भी ज़रूरत हो, उन्हीं पैरामीटर्स के साथ अपने नए फ़ंक्शन को कॉल करते हैं। इसकी संरचना इस प्रकार है:

=LAMBDA(parameter1, parameter2, ..., calculation)

आप सीधे किसी सेल में LAMBDA() फ़ॉर्मूलों के साथ प्रयोग कर सकते हैं, लेकिन इसकी असली ताकत तब आती है जब आप इसे एक नामित फ़ंक्शन के रूप में सहेजते हैं। एक बार नाम देने के बाद, आपका कस्टम फ़ंक्शन आपके वर्कबुक में ठीक SUM(), AVERAGE() आदि की तरह दिखाई देता है। 

यहाँ कुछ मज़बूत कारण हैं कि आपको अपने वर्कफ़्लो में LAMBDA() शामिल क्यों करना चाहिए:

  • दोहराए जाने वाले फ़ॉर्मूलों को हटाएँ। किसी जटिल फ़ॉर्मूले को हर जगह लिखने के बजाय, उसे एक फ़ंक्शन में बदलें और नाम से कॉल करें।

  • अपनी स्प्रेडशीट्स को अधिक स्पष्ट बनाएँ। नामित फ़ंक्शंस आपके और आपके सहयोगियों के लिए बार-बार दोहराए गए, दुरूह फ़ॉर्मूले की तुलना में कहीं अधिक समझने योग्य होते हैं।

  • अन्य नए फ़ंक्शंस के साथ मिलाएँ। LAMBDA() LET(), MAP(), REDUCE() और Excel की अन्य आधुनिक क्षमताओं के साथ अच्छी तरह काम करता है।

  • त्रुटियाँ कम करें। एक बार आपका लॉजिक जाँचकर LAMBDA() में लपेट दिया जाए, तो आप उसे पुन: उपयोग कर सकते हैं — फ़ॉर्मूला कॉपी करते समय होने वाली टाइपो की दिक्कत नहीं रहती।

Excel LAMBDA() फ़ंक्शन कैसे बनाएँ

किसी भी चीज़ की तरह, इसमें भी अभ्यास लगता है। तो आइए अपने खुद के LAMBDA() फ़ंक्शंस बनाकर देखते हैं।

मान लीजिए आप किसी वृत्त का क्षेत्रफल उसके त्रिज्या से निकाल रहे हैं और बार-बार =PI()*A1^2 टाइप कर रहे हैं।

पहले, सीधे किसी सेल में LAMBDA() फ़ॉर्मूला बनाकर चलाने की कोशिश करें:

=LAMBDA(r, PI()*r^2)(3)

Excel LAMBDA function for pi

यहाँ, हमने एक LAMBDA() फ़ंक्शन बनाया है जो r को पैरामीटर के रूप में लेता है और वृत्त का क्षेत्रफल लौटाता है। अंत में (3) त्रिज्या देता है, इसलिए यह फ़ॉर्मूला त्रिज्या 3 वाले वृत्त का क्षेत्रफल निकालता है।

बेशक, हर बार LAMBDA() टाइप करना मूल फ़ॉर्मूले पर बहुत बड़ा सुधार नहीं है। लेकिन ज़रा ठहरिए, क्योंकि अब नामित फ़ंक्शंस काम आते हैं:

  1. Formulas > Name Manager > New पर जाएँ।

  2. अपने फ़ंक्शन के लिए कोई नाम चुनें, जैसे CircleArea।

  3. Refers to बॉक्स में यह दर्ज करें:

=LAMBDA(r, PI()*r^2)

Excel LAMBDA function for a circle

अब, आप अपने कस्टम फ़ंक्शन को पूरे वर्कबुक में उपयोग कर सकते हैं:

=CircleArea(A1)

Excel LAMBDA function for a circle area

अब आपने एक पुन: प्रयोज्य, कस्टम फ़ंक्शन बना लिया है।

Excel LAMBDA() की सिंटैक्स और पैरामीटर्स

LAMBDA() किसी भी संख्या में पैरामीटर्स स्वीकार कर सकता है (Excel की सीमा 253 तक), प्रत्येक को कॉमा से अलग किया जाता है। (हालाँकि आप वास्तव में इतने ज़्यादा शायद ही उपयोग करेंगे।) 

यह समझना महत्वपूर्ण है कि अंतिम आर्ग्युमेंट हमेशा स्वयं गणना होती है, जो आपके द्वारा परिभाषित किसी भी पैरामीटर का उपयोग कर सकती है।

=LAMBDA(parameter1, parameter2, ..., calculation)

उदाहरण के लिए, अगर आप दो संख्याओं में से बड़ी संख्या लौटाने वाला फ़ंक्शन बनाना चाहते हैं, तो आप कुछ यूँ लिख सकते हैं:

=LAMBDA(a, b, IF(a > b, a, b))

इसे एक नामित फ़ंक्शन के रूप में सहेजने के बाद — MaxOfTwo एक अच्छा नाम है — आप इसे किसी भी अन्य Excel फ़ंक्शन की तरह उपयोग करेंगे:

=MaxOfTwo(7, 4)

यह फ़ॉर्मूला 7 लौटाता है, जो दो इनपुट्स में बड़ी संख्या है।

Excel LAMBDA() के और विशिष्ट उदाहरण

आइए अभ्यास जारी रखें।

कई पैरामीटर्स के साथ Excel LAMBDA()

अब उन फ़ंक्शंस पर काम करते हैं जो कई इनपुट लेते हैं। पहले की तरह, हम अपने पैरामीटर्स को कॉमा से अलग करते हैं और फ़ंक्शन को कॉल करते समय उतने ही आर्ग्युमेंट्स देते हैं।

दो संख्याएँ जोड़ने के लिए:

=LAMBDA(a, b, a + b)(4, 9)

यह 13 लौटाएगा।

यदि आप इसे AddTwo नामक नामित फ़ंक्शन में बदलने का निर्णय लेते हैं, तो आप इसे पूरे वर्कबुक में ऐसे उपयोग कर सकते हैं:

=AddTwo(A1, A2)

अब आपके पास एक कस्टम जोड़ (addition) फ़ंक्शन है।

दोहराए जाने वाले लॉजिक को साफ़ करें

मान लीजिए आप कई जगहों पर इस फ़ॉर्मूले से कमीशन की गणना कर रहे हैं:

=IF(A2 > 1000, A2*0.1, 0)

जहाँ-जहाँ इसकी ज़रूरत हो वहाँ यह फ़ॉर्मूला कॉपी करने के बजाय, आप LAMBDA() से इस लॉजिक को समाहित कर सकते हैं:

=LAMBDA(amount, IF(amount > 1000, amount*0.1, 0))

इस फ़ंक्शन का नाम Commission रखें, और अब आप उपयोग कर सकते हैं:

=Commission(A2)

यदि आपको कभी कमीशन लॉजिक बदलना पड़े, तो आपको केवल एक ही जगह LAMBDA() अपडेट करना होगा, और जहाँ-जहाँ Commission उपयोग हो रहा है, सबमें अपडेट हो जाएगा।

Excel LAMBDA function to calculate commission

Excel LAMBDA vs IF logic

Excel LAMBDA function vs IF function logic

रिकर्शन और नेस्टेड फ़ंक्शंस

LAMBDA() रिकर्शन सपोर्ट करता है, यानी कोई फ़ंक्शन स्वयं को कॉल कर सकता है। इससे नई संभावनाएँ खुलती हैं, जैसे कस्टम एग्रीगेशंस।

उदाहरण के लिए, आप एक रिकर्सिव फैक्टोरियल फ़ंक्शन ऐसे परिभाषित कर सकते हैं:

=LAMBDA(n, IF(n=1, 1, n*Factorial(n-1))) 

Excel LAMBDA for a factorial

आप इसे एक नामित फ़ंक्शन के रूप में सहेजेंगे, और यह प्रोग्रामिंग में किसी भी रिकर्सिव फ़ंक्शन की तरह ही काम करेगा। (नाम के लिए, मैं कुछ स्पष्ट, जैसे Factorial, चुनूँगा।) 

अन्य डायनेमिक एरे फ़ंक्शंस के साथ LAMBDA()

LAMBDA() को Excel के अन्य डायनेमिक फ़ंक्शंस जैसे LET(), MAP(), और REDUCE() के साथ जोड़ा जा सकता है। 

LET() आपको किसी फ़ॉर्मूले के भीतर वैरिएबल सौंपने और पुन: उपयोग करने देता है, जबकि MAP() और REDUCE() एरेज़ या सूचियों पर LAMBDA() लागू करते हैं।

उदाहरण के लिए, किसी रेंज में हर मान को दोगुना करने के लिए:

=MAP(A1:A5, LAMBDA(x, IF(x>10, x*2, x)))

Excel LAMBDA combined with MAP

यहाँ, MAP() आपके LAMBDA() फ़ंक्शन को A1:A5 के हर आइटम पर लागू करता है। बैच कैलकुलेशंस के लिए यह काफ़ी अच्छा है।

(ऊपर का फ़ॉर्मूला रेंज के मान को तभी दोगुना करता है जब वह मान 10 से बड़ा हो।)

(एक और अच्छी बात यह है कि आपको फ़ॉर्मूला सिर्फ़ एक बार, सेल B1 में लिखना होता है, और नीचे की कोशिकाएँ अपने-आप भर जाती हैं।)

Excel LAMBDA() के साथ प्रो टिप्स

अनुभव से कुछ सुझाव यहाँ दिए गए हैं।

नाम देने से पहले Excel LAMBDA() फ़ंक्शंस का परीक्षण करें

अपने LAMBDA() को नाम देकर सहेजने से पहले, उसे सीधे किसी सेल में टेस्ट करना समझदारी है। ऐसा आप अपने परीक्षण आर्ग्युमेंट्स को कोष्ठकों में जोड़कर कर सकते हैं, बिल्कुल किसी फ़ंक्शन को कॉल करने की तरह:

=LAMBDA(x, x*2)(5)

यह 10 लौटाता है, वही परिणाम जिसकी हमें उम्मीद थी।

यदि आप टेस्ट करते समय आर्ग्युमेंट देना भूल जाते हैं, जैसे केवल =LAMBDA(x, x*2) टाइप करते हैं, तो Excel परिणाम नहीं बल्कि स्वयं फ़ंक्शन दिखाएगा। हमेशा याद रखें कि अंत में अपने इनपुट मानों के साथ वे अंतिम कोष्ठक ज़रूर जोड़ें।

कुछ सावधानियाँ

आइए रुककर सीमाओं पर नज़र डालें:

  • LAMBDA() फ़ंक्शंस वर्कबुक-स्कोप्ड होते हैं। यदि आप अपने कस्टम फ़ंक्शंस को किसी अन्य वर्कबुक में उपयोग करना चाहते हैं, तो आपको उन्हें कॉपी करना होगा, या यदि उपलब्ध हो तो Excel की नई Named Functions फ़ीचर का उपयोग करना होगा।

  • आप LAMBDA() से वॉलेटाइल फ़ंक्शंस (जैसे NOW() या RAND()) नहीं बना सकते।

  • LAMBDA() को कॉल करते समय गलत संख्या में आर्ग्युमेंट्स देने पर #VALUE! त्रुटि आती है, इसलिए हमेशा अपने इनपुट्स को दोबारा जाँचें।

  • सभी Excel संस्करण LAMBDA() सपोर्ट नहीं करते। इन सुविधाओं का उपयोग करने के लिए आपको Microsoft 365 या नवीनतम वेब संस्करण की आवश्यकता होगी।

LAMDA() और अन्य फ़ंक्शंस

अंत में, आइए LAMBDA() की तुलना अन्य तरीकों से करें। 

Excel LAMBDA() का उपयोग कब करें?

जो कुछ हमने देखा और सीखा है, उसके आधार पर आप सोच रहे होंगे, किस समय LAMBDA() सही टूल है? LAMBDA() का उपयोग तब करें जब:

  • आपके पास जटिल या बार-बार होने वाले फ़ॉर्मूले हों जिन्हें आप सरल बनाना चाहते हैं।
  • ऐसा लॉजिक हो जिसे आप नाम देकर समझाना चाहें।
  • आपको ऐसे कस्टम कैलकुलेशन या लॉजिक चाहिए जो Excel डिफ़ॉल्ट रूप से प्रदान नहीं करता।

मेरे विचार में, LAMBDA() टीमें के लिए विशेष रूप से उपयोगी है, खासकर जब फ़ंक्शन के नाम स्पष्ट हों। तब टीम के सदस्य बिना गणना को सुलझाए सीधे देख सकते हैं कि लॉजिक क्या कर रहा है। 

संबंधित Excel फ़ंक्शंस

उन अन्य नए Excel फ़ंक्शंस से परिचित होना फ़ायदेमंद है जो LAMBDA() के पूरक हैं। यहाँ कुछ हैं। कुछ का उल्लेख मैंने पहले किया था।

  • LET(): किसी फ़ॉर्मूले के भीतर गणनाओं को नाम दें

  • MAP(): किसी एरे के प्रत्येक आइटम पर LAMBDA() लागू करें

  • REDUCE(): LAMBDA() का उपयोग करके किसी एरे को एकल मान तक समेटें

  • BYROW(), BYCOL(): पंक्ति या स्तम्भ के आधार पर LAMBDA() लागू करें

ये फ़ंक्शंस, जब LAMBDA() के साथ जोड़े जाते हैं, तो अधिक परिष्कृत लॉजिक और डेटा ट्रांसफॉरमाtions को संभव बनाते हैं। हमारे Advanced Excel Functions कोर्स में Excel के सचमुच उपयोगी फ़ंक्शंस के बारे में सीखें जो यह प्रदान करता है। 

निष्कर्ष

जैसा कि हमने देखा और अभ्यास किया, Excel LAMBDA() आपको बिना VBA छुए अपने खुद के वर्कशीट फ़ंक्शंस बनाने देता है। तो LAMBDA() का उपयोग तब करें जब आप एक ही गणना कई जगहों पर बार-बार लिखते हों, या जटिल फ़ॉर्मूलों को काबू में करना चाहते हों।

और हमारे Advanced Excel Functions कोर्स को याद से करें ताकि आप Excel में तेज़ और स्मार्ट बन सकें। और यदि आप एक वित्तीय विश्लेषक हैं या बनना चाहते हैं, तो हमारा Financial Modeling in Excel कोर्स भी करें। LAMDA() फ़ंक्शंस वित्त जगत में विशेष रूप से उपयोगी होने वाले हैं।

Josef Waples

लेखक

Josef Waples

मैं एक डेटा साइंस संपादक हूँ और वैज्ञानिक पत्रिकाओं में प्रकाशित शोध लेखों में योगदान दे चुका/चुकी हूँ। मुझे विशेष रूप से रैखिक बीजगणित, सांख्यिकी, R, और इसी तरह के विषयों में रुचि है।

विषय