Excel Substring तकनीकें: टेक्स्ट निकालें और फॉर्मेट करें

Excel Substring फ़ंक्शंस का उपयोग करके पोजिशन के आधार पर टेक्स्ट निकालना

हम अक्सर किसी टेक्स्ट स्ट्रिंग के विशिष्ट हिस्सों—जैसे कोई शब्द या अक्षरों का क्रम—को उनकी स्थिति के आधार पर निकालना चाहते हैं। Excel कई बिल्ट-इन फ़ंक्शंस प्रदान करता है जो आपको टेक्स्ट स्ट्रिंग्स के विशिष्ट हिस्से निकालने में मदद करते हैं। सबसे आम फ़ंक्शंस हैं LEFT(), RIGHT(), MID(), TEXTBEFORE(), और TEXTAFTER()। आइए एक-एक करके देखें। 

LEFT() Excel substring फ़ंक्शन का उपयोग

आप LEFT() फ़ंक्शन का उपयोग करके किसी टेक्स्ट स्ट्रिंग की शुरुआत से अक्षर निकाल सकते हैं। इसका सिंटैक्स इस प्रकार है:

=LEFT(text, [num_chars])

यहाँ: 

• text उस सेल पते को संदर्भित करता है जहाँ मूल टेक्स्ट स्ट्रिंग स्थित है।

• num_chars निकाले जाने वाले अक्षरों की संख्या को संदर्भित करता है। इसका डिफ़ॉल्ट मान 1 है।

एक उदाहरण देखते हैं। यहाँ, मेरे पास कुछ प्रोडक्ट कोड हैं, और मैं उनसे पहले तीन अक्षर निकालना चाहता/चाहती हूँ। 

=LEFT(A2,3)

LEFT() फ़ंक्शन का उपयोग करके पहले तीन अक्षर निकालें। इमेज: लेखक द्वारा।

RIGHT() Excel substring फ़ंक्शन का उपयोग

Excel में RIGHT() फ़ंक्शन किसी टेक्स्ट स्ट्रिंग के अंत से अक्षर निकालता है। इसका सिंटैक्स इस प्रकार है:

=Right(text, [num_chars])

यहाँ: 

• text उस सेल पते को संदर्भित करता है जहाँ मूल टेक्स्ट स्ट्रिंग स्थित है।

• num_chars निकाले जाने वाले अक्षरों की संख्या को संदर्भित करता है। इसका डिफ़ॉल्ट मान 1 है।

एक उदाहरण देखते हैं। यहाँ, मैं RIGHT() फ़ंक्शन का उपयोग करके अंतिम तीन अक्षर निकालता/निकालती हूँ।

=RIGHT(A2, 3)

RIGHT() फ़ंक्शन का उपयोग करके अंतिम तीन अक्षर निकालें। इमेज: लेखक द्वारा।

MID() Excel substring फ़ंक्शन का उपयोग

MID() फ़ंक्शन किसी टेक्स्ट स्ट्रिंग के बीच से अक्षर निकालता है। इसका सिंटैक्स इस प्रकार है:

=MID(text, start_num, num_chars)

यहाँ:

• text उस सेल पते को संदर्भित करता है जहाँ मूल टेक्स्ट स्ट्रिंग स्थित है।

• num_chars निकाले जाने वाले अक्षरों की संख्या को संदर्भित करता है। इसका डिफ़ॉल्ट मान 1 है।

• start_num टेक्स्ट स्ट्रिंग के भीतर शुरुआती पोज़िशन को दर्शाता है।

इस उदाहरण में, मैं MID() फ़ॉर्मूला का उपयोग स्ट्रिंग के चौथे अक्षर से शुरू होकर बीच के मान को निकालने के लिए करता/करती हूँ।

=MID(A2,4,3)

MID() फ़ंक्शन का उपयोग करके बीच के तीन अक्षर निकालें। इमेज: लेखक द्वारा। 

और हो गया। =MID(A2,4,3) सेल A2 के टेक्स्ट से 4थे अक्षर से शुरू होकर तीन अक्षर निकालता है।

FIND() Excel substring फ़ंक्शन का उपयोग

Excel में FIND() फ़ंक्शन किसी टेक्स्ट स्ट्रिंग के भीतर एक सबस्ट्रिंग का पता लगाता है और सबस्ट्रिंग के पहले अक्षर की पोज़िशन लौटाता है। इसका सिंटैक्स इस प्रकार है:

FIND(find_text, within_text, [start_num]) 

यहाँ:

• find_text उस टेक्स्ट को संदर्भित करता है जिसे हम खोजना चाहते हैं।

• within_text वह टेक्स्ट है जिसमें वह टेक्स्ट शामिल है जिसे हम खोजना चाहते हैं।

• start_num खोज शुरू करने की पोज़िशन बताता है, जिसका डिफ़ॉल्ट 1 है।

आइए एक सरल डेटासेट पर विचार करें ताकि Excel के FIND() फ़ंक्शन का काम समझ आए। इस उदाहरण में, मेरे पास Text कॉलम में DataCamp नाम है, और मुझे सबस्ट्रिंग Camp की पोज़िशन ढूँढनी है। यह 5 लौटाता है क्योंकि Camp टेक्स्ट के पाँचवें अक्षर से शुरू होता है।

=FIND("Camp", A2)

टेक्स्ट की पोज़िशन निकालने के लिए FIND() फ़ंक्शन का उपयोग। इमेज: लेखक द्वारा।

SUBSTITUTE() Excel substring फ़ंक्शन का उपयोग

SUBSTITUTE() फ़ंक्शन किसी विशेष सबस्ट्रिंग को दूसरी से बदल देता है। इसका सिंटैक्स इस प्रकार है:

 SUBSTITUTE(text, old_text, new_text, [instance_num])

यहाँ:

• text वह टेक्स्ट है जिसे आप बदलना चाहते हैं।

• old_text उस टेक्स्ट को संदर्भित करता है जिसे आप बदलना चाहते हैं।

• new_text वह टेक्स्ट है जिससे आप पुराने टेक्स्ट को बदलना चाहते हैं।

• instance_num यह बताता है कि किस आवृत्ति (occurrence) को बदलना है। यदि निर्दिष्ट नहीं है, तो हर आवृत्ति बदली जाती है। 

इसे समझने के लिए, एक सरल डेटासेट देखते हैं जिसमें विशेष डिलिमिटर्स वाले टेक्स्ट स्ट्रिंग्स हैं। Text कॉलम में नाम और आयु सेमीकोलन को डिलिमिटर के रूप में फॉर्मेट किए गए हैं। इसे साफ करने के लिए, मैं निम्न फ़ॉर्मूला टाइप करता/करती हूँ:

=SUBSTITUTE(A2, ";" , ",")

यहाँ:

• A2 मूल टेक्स्ट वाला सेल है।

• ";" पुराने टेक्स्ट को निर्दिष्ट करता है जिसे हम बदलने वाले हैं।

• "," वह नया टेक्स्ट है जिससे हम पुराने टेक्स्ट को बदलना चाहते हैं।

पुराने टेक्स्ट को बदलने के लिए SUBSTITUTE फ़ंक्शन का उपयोग। इमेज: लेखक द्वारा।

और बस। B2 सेल में हमारा फ़ॉर्मूला लगाने पर Excel सेमीकोलन को कॉमा से बदल देता है।

Excel Substring फ़ंक्शंस का उपयोग करके डिलिमिटर के आधार पर टेक्स्ट निकालना

डिलिमिटर वे विशेष कैरेक्टर होते हैं जो दो टेक्स्ट स्ट्रिंग्स को अलग करते हैं, जैसे सेमीकोलन या कॉमा। Excel में, जब डिलिमिटर मौजूद हों तो आप TEXTBEFORE() और TEXTAFTER() फ़ंक्शंस का उपयोग करके टेक्स्ट निकाल सकते हैं।  

TEXTBEFORE() Excel substring फ़ंक्शन का उपयोग 

जैसा कि नाम से स्पष्ट है, TEXTBEFORE() फ़ंक्शन किसी निर्दिष्ट कैरेक्टर या सबस्ट्रिंग से पहले स्थित टेक्स्ट निकालता है। इसका सिंटैक्स इस प्रकार है:

=TEXTBEFORE(text, delimiter, [instance_num], [match_mode], [match_end], [if_not_found]

यहाँ: 

• text मूल टेक्स्ट को संदर्भित करता है।

• delimiter आमतौर पर कॉमा या सेमीकोलन होता है।

• instance_num डिलिमिटर की इच्छित आवृत्ति है। इसका डिफ़ॉल्ट मान 1 है।

• match_mode इंगित करता है कि डिलिमिटर की खोज केस-सेंसिटिव (TRUE, डिफ़ॉल्ट) हो या केस-इनसेंसिटिव (FALSE)।

• match_end यह निर्धारित करता है कि क्या टेक्स्ट स्ट्रिंग के अंत को डिलिमिटर माना जाए। यदि TRUE है, तो डिलिमिटर न मिलने पर फ़ंक्शन मूल टेक्स्ट लौटाएगा।

• if_not_found डिलिमिटर न मिलने पर लौटाने के लिए कस्टम मान निर्दिष्ट करता है।

अब, इस फ़ॉर्मूला को क्रिया में देखने के लिए एक उदाहरण लेते हैं। मेरे पास Text नामक कॉलम है जिसमें कर्मचारियों का विवरण है—उनके नाम, विभाग और शाखा स्थान। अब मैं केवल नाम और विभाग निकालना चाहता/चाहती हूँ।

=TEXTBEFORE(A2, ",", 2, 1, 1)

डेटा निकालने के लिए TEXTBEFORE() फ़ंक्शन का उपयोग। इमेज: लेखक द्वारा 

यह इस प्रकार काम करता है: 

• A2 में वह टेक्स्ट है जिससे मुझे निकालना है। 

• "," वह डिलिमिटर है जो मूल डेटा में टेक्स्ट को विभाजित करता है। 

• 2 का अर्थ है कि फ़ंक्शन डिलिमिटर की दूसरी आवृत्ति को मानेगा।

• 1 केस-सेंसिटिव घटनाओं को, यदि हों, नज़रअंदाज़ करता है।

• अंत में 1 डिलिमिटर अनुपस्थित होने पर मूल टेक्स्ट लौटाता है।

TEXTAFTER() Excel substring फ़ंक्शन का उपयोग

TEXTAFTER() फ़ंक्शन TEXTBEFORE() के समान है—अंतर केवल परिणाम में है। TEXTAFTER() डिलिमिटर के बाद आने वाला टेक्स्ट निकालता है। इसका सिंटैक्स इस प्रकार है:

=TEXTAFTER(text, delimiter, [instance_num], [match_mode], [match_end], [if_not_found]

यहाँ: 

• text मूल टेक्स्ट को संदर्भित करता है।

• delimiter कॉमा या सेमीकोलन होता है। 

• instance_num डिलिमिटर की इच्छित आवृत्ति है। इसका डिफ़ॉल्ट मान 1 है।

• match_mode इंगित करता है कि डिलिमिटर की खोज केस-सेंसिटिव (TRUE, डिफ़ॉल्ट) हो या केस-इनसेंसिटिव (FALSE)।

• match_end यह निर्धारित करता है कि क्या टेक्स्ट स्ट्रिंग के अंत को डिलिमिटर माना जाए। यदि TRUE है, तो डिलिमिटर न मिलने पर फ़ंक्शन मूल टेक्स्ट लौटाएगा।

• if_not_found डिलिमिटर न मिलने पर लौटाने के लिए कस्टम मान निर्दिष्ट करता है।

यहाँ, मेरे पास Text कॉलम है जिसमें कर्मचारियों का विवरण—नाम, विभाग और शाखा स्थान—शामिल है। इसमें से, मैं कर्मचारियों के लोकेशन और ID निकालना चाहता/चाहती हूँ। 

=TEXTAFTER(A2,",",2,1,1)

डेटा निकालने के लिए TEXTAFTER() फ़ंक्शन का उपयोग। इमेज: लेखक द्वारा 

यह इस प्रकार काम करता है: 

• A2 में वह टेक्स्ट है जिससे मुझे निकालना है। 

• ","  वह डिलिमिटर है जो मूल डेटा में टेक्स्ट को विभाजित करता है। 

• 2 का अर्थ है कि फ़ंक्शन डिलिमिटर की दूसरी आवृत्ति को मानेगा। 

• 1 केस-सेंसिटिव घटनाओं को, यदि हों, नज़रअंदाज़ करता है।

• 1 (अंत में) डिलिमिटर अनुपस्थित होने पर मूल टेक्स्ट लौटाता है।

विशिष्ट Excel Substring उपयोग के मामले

अब जब आपको सबस्ट्रिंग्स की बुनियादी जानकारी हो गई है, तो उन्नत तरीकों को सीखने का समय है। ये तरीके अधिक जटिल टेक्स्ट मैनिपुलेशन की अनुमति देते हैं, जिससे आपकी डेटा प्रोसेसिंग और भी कुशल हो जाती है। 

विभिन्न लंबाई के पहले नाम संभालना

मेरे पास एक डेटासेट है जिसमें पूरा नाम है, लेकिन मुझे केवल पहला नाम निकालना है।

पूरा नाम वाला एक टेबल। इमेज: लेखक द्वारा।

आप सोचेंगे यह तो आसान है—पहला नाम पाने के लिए LEFT() फ़ंक्शन का उपयोग करें। इसलिए, मैंने यह फ़ॉर्मूला आज़माया:

=LEFT(A2,4)

पहला नाम निकालने के लिए LEFT() का उपयोग। इमेज: लेखक द्वारा।

लेकिन पहले नाम के बजाय मुझे नाम के पहले चार अक्षर मिले, क्योंकि मैंने num_char को 4 दिया था, यह देखकर कि Jane के पहले नाम में चार अक्षर हैं। जब मैंने फ़ॉर्मूला कॉपी-पेस्ट किया, तो यह अन्य नामों के लिए इच्छित आउटपुट नहीं देता।

मुझे अधिक लचीला समाधान चाहिए। पहले नाम को उसकी लंबाई की परवाह किए बिना निकालने के लिए, आप LEFT() को FIND() के साथ जोड़ सकते हैं। मैं FIND() का उपयोग पूरे नाम में पहले स्पेस की पोज़िशन खोजने के लिए करता/करती हूँ, जो पहले और अंतिम नाम को अलग करता है। फिर, मैं LEFT() का उपयोग उस पोज़िशन तक अक्षर निकालने के लिए करता/करती हूँ। 

=LEFT(A2,FIND(" ",A2)-1)

पहला नाम निकालने के लिए FIND() और LEFT() को जोड़ें। इमेज: लेखक द्वारा।

फ़ॉर्मूला को समझने में मदद के लिए इसे विभाजित करते हैं:

• A2 सेल में पूरा नाम है।

• FIND(" ", A2, 1) सेल A2 की टेक्स्ट स्ट्रिंग में पहले अक्षर से शुरू होकर पहले स्पेस की पोज़िशन ढूँढता है।

• -1 स्पेस हटाने के लिए प्रयोग होता है।

• LEFT(A2, ...) टेक्स्ट स्ट्रिंग के बाएँ से निर्दिष्ट संख्या में अक्षर निकालता है।

ईमेल पते से डोमेन निकालना

एक और उदाहरण लेते हैं यह देखने के लिए कि क्या  LEFT() और FIND() अलग परिदृश्य संभाल सकते हैं। मेरे पास ईमेल पतों का एक अलग डेटासेट है, जिससे मुझे डोमेन नाम निकालना है।

ईमेल पतों वाला डेटा। इमेज: लेखक द्वारा।

इसके लिए, मैं एक अलग कॉलम Email Domain बनाता/बनाती हूँ, और एक अलग सेल में निम्न फ़ॉर्मूला टाइप करता/करती हूँ, जिसे फिर तीन अन्य सेल में कॉपी करता/करती हूँ:

=RIGHT(A2, LEN(A2) - FIND("@",A2))

RIGHT(), LEN(), और FIND() का उपयोग करके डोमेन नाम निकालें। इमेज: लेखक द्वारा।

लीजिए—सभी डोमेन नाम आ गए। लेकिन समझते हैं कि Excel ने इच्छित परिणाम कैसे निकाले:

• FIND("@", A2) ईमेल पते में @ सिंबल की पोज़िशन ढूँढता है।

• LEN(A2) ईमेल पते की कुल लंबाई निकालता है।

• LEN(A2) - FIND("@", A2) @ सिंबल के बाद आने वाले अक्षरों की संख्या की गणना करता है।

• अंत में, RIGHT(A2, LEN(A2) - FIND("@", A2)) स्ट्रिंग के दाएँ छोर से उतने अक्षर निकालता है।

LEFT(), MID(), और RIGHT() मिलाकर प्रोडक्ट कोड निकालना

अब तक, मैंने केवल बताया कि LEFT(), MID(), और RIGHT() फ़ंक्शंस अलग-अलग कैसे काम करते हैं। लेकिन आप इन्हें मिलाकर और भी बहुत कुछ कर सकते हैं। ये विशेष पैटर्न के आधार पर टेक्स्ट स्ट्रिंग के अलग-अलग हिस्से निकाल सकते हैं।

यहाँ, मेरे पास प्रोडक्ट कोड्स की एक सूची है और मैं उनसे एक विशेष सेक्शन निकालना चाहता/चाहती हूँ। 

• पहले सेक्शन से, मुझे एक अक्षर चाहिए।
• दूसरे सेक्शन से, मुझे सभी चार अक्षर चाहिए।
• अंतिम सेक्शन से, मुझे अंतिम तीन अक्षर निकालने हैं।

प्रोडक्ट कोड्स की सूची। इमेज: लेखक द्वारा।

इसे करने के लिए, मैं LEFT(), RIGHT(), और MID() फ़ंक्शंस को जोड़ता/जोड़ती हूँ और निम्न फ़ॉर्मूला दर्ज करता/करती हूँ:  

=LEFT(A2, 1) & "-"& MID(A2, FIND("-", A2) + 1, 4) & "-" & RIGHT(A2, 3)

डेटा निकालने के लिए MID(), LEFT(), और RIGHT() फ़ंक्शंस को मिलाएँ। इमेज: लेखक द्वारा।

जैसा कि आप देख सकते हैं, इस संयुक्त फ़ॉर्मूला ने कोड्स के प्रत्येक सेक्शन से इच्छित अक्षर निकाल लिए। ऐसे:

• LEFT(A2, 1) पहला अक्षर निकालता है।

• MID(A2, FIND("-", A2) + 1, 4) पहला हाइफ़न ढूँढता है, एक कैरेक्टर दाएँ बढ़ता है, फिर चार अक्षर निकालता है।

• "-" एक हाइफ़न जोड़ता है।

• RIGHT(A2, 3) अंतिम तीन अक्षर निकालता है।

• & अक्षरों को जोड़ता (concatenate) है। 

डायनेमिक टेक्स्ट एक्सट्रैक्शन के लिए SUBSTITUTE() को MID() के साथ उपयोग करना 

अब, देखते हैं कि आप MID() फ़ंक्शन को SUBSTITUTE() के साथ कैसे जोड़ सकते हैं ताकि टेक्स्ट स्ट्रिंग के विशेष हिस्सों को निकालकर उस निकले हिस्से के भीतर कैरेक्टर या सबस्ट्रिंग्स को बदला जा सके।

उदाहरण के लिए, मेरे पास ग्राहक Order Details हैं और मैं ऑर्डर ID को Order confirmed टेक्स्ट से बदलना चाहता/चाहती हूँ।

ऑर्डर विवरण वाला टेबल। इमेज: लेखक द्वारा।

मैं निम्न फ़ॉर्मूला उपयोग करता/करती हूँ:

=SUBSTITUTE(A2, MID(A2,1,19), "Order confirmed")

टेक्स्ट बदलने के लिए SUBSTITUTE() और MID() फ़ंक्शंस। इमेज: लेखक द्वारा।

बस इतना ही! आप देख सकते हैं कि यह फ़ॉर्मूला मेरी आवश्यकता के अनुसार टेक्स्ट स्ट्रिंग्स के विशेष हिस्से निकालता और बदलता है।

• MID(A2, 1, 19) सेल A2 के टेक्स्ट से पहले 19 अक्षर निकालता है।

• SUBSTITUTE(text, old_text, new_text) old_text को new_text से बदल देता है।

एक और उदाहरण देखते हैं: यहाँ मेरे पास Product Detail कॉलम है, और मैं वर्ग कोष्ठक (square bracket) से प्रोडक्ट साइज निकालना चाहता/चाहती हूँ।

=SUBSTITUTE(MID(A2, FIND("[", A2)+1, FIND("]", A2)-FIND("[", A2)-1), "[", "")

वर्ग कोष्ठक से प्रोडक्ट साइज निकालना। इमेज: लेखक द्वारा।

और हो गया—इसने सभी विवरण निकाल दिए।

• FIND("[", A2) ओपनिंग वर्ग कोष्ठक की शुरुआती पोज़िशन ढूँढता है।

• FIND("]", A2) क्लोज़िंग वर्ग कोष्ठक की अंतिम पोज़िशन ढूँढता है।

• MID(A2, FIND("[", A2)+1, FIND("]", A2)-FIND("[", A2)-1) दोनों कोष्ठकों के बीच का टेक्स्ट निकालता है।

• SUBSTITUTE(...,"[", "") निकले टेक्स्ट से ओपनिंग वर्ग कोष्ठक हटाता है।

डेटा प्रविष्टियाँ साफ़ करना

कभी-कभी हमारा डेटा अव्यवस्थित होता है, लेकिन इसका मतलब यह नहीं कि आपको ऐसा डेटा ही उपयोग करना पड़े। यहाँ, मेरे पास फोन नंबरों की सूची है जो कई फॉर्मैट में हैं, लेकिन मैं उन्हें एक समान फॉर्मैट में मानकीकृत करना चाहता/चाहती हूँ और प्रविष्टियों में असंगतियों को साफ करना चाहता/चाहती हूँ।

अनफॉर्मैटेड फोन नंबर। इमेज: लेखक द्वारा।

इसे मानकीकृत करने के लिए, मैं Clean data नाम का एक अलग कॉलम बनाता/बनाती हूँ। दूसरे सेल में निम्न फ़ॉर्मूला टाइप करता/करती हूँ और जहाँ-जहाँ परिणाम चाहिए वहाँ सभी सेल में इसे कॉपी कर देता/देती हूँ:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2, "-", ""), "(", ""), ")", ""), ".", "")

यहाँ: 

• SUBSTITUTE(A2, "-", "") हाइफ़न हटाता है।

• SUBSTITUTE(..., "(", "") कोष्ठक हटाता है।

• SUBSTITUTE(..., ")", "") क्लोज़िंग कोष्ठक हटाता है।

• SUBSTITUTE(..., ".", "") पीरियड्स हटाता है।

यह कई फॉर्मैट्स को अंकों की एक सतत स्ट्रिंग में बदल देता है, जैसा कि नीचे दिखाया गया है। अब डेटा साफ, अच्छे से फॉर्मैटेड और उपयोग के लिए तैयार है। चाहें तो आप इसे ऐसे ही छोड़ सकते हैं।

SUBSTITUTE() फ़ंक्शन का उपयोग करके डेटा साफ करें। इमेज: लेखक द्वारा।

रिपोर्ट के लिए टेक्स्ट फॉर्मेट करना

यदि आप डेटा क्लीनिंग के बाद एक कदम और बढ़कर उपयुक्त फॉर्मेटिंग करना चाहते हैं, तो आप अलग-अलग substring फ़ंक्शंस का उपयोग भी कर सकते हैं।

पिछले उदाहरण पर विचार करें, जहाँ मैंने फोन नंबर साफ किए थे। अब, मैं नंबरों का फॉर्मेट बदलना चाहता/चाहती हूँ ताकि वे केवल अंकों की स्ट्रिंग न लगें बल्कि फोन नंबर जैसे दिखें। 

=TEXT(LEFT(B2, 3), "000") & "-" & TEXT(MID(B2, 4, 3), "000") & "-" & TEXT(RIGHT(B2, 4), "0000")

कई सबस्ट्रिंग्स का उपयोग करके नंबरों का मानकीकृत फॉर्मेट। इमेज: लेखक द्वारा।

और हो गया। अब मेरे पास सभी नंबर मनचाहे फॉर्मेट में हैं। यह फ़ॉर्मूला इस प्रकार काम करता है:

• LEFT(B2, 3) पहले तीन अंक निकालता है।

• MID(B2, 4, 3) चौथे पोज़िशन से शुरू होकर अगले तीन अंक निकालता है।

• RIGHT(B2, 4) अंतिम चार अंक निकालता है।

• TEXT(..., "000") और TEXT(..., "0000") प्रत्येक सेक्शन को इस तरह फॉर्मेट करता है कि यदि ज़रूरत हो तो अग्रणी शून्य सहित सही संख्या में अंक सुनिश्चित हों।

• & "-" & हाइफ़न के साथ फॉर्मेटेड सेक्शंस को जोड़ता है।

अंतिम विचार

अब आपने Excel के substring फ़ंक्शंस—जैसे LEFT(), RIGHT(), MID(), TEXTBEFORE(), और TEXTAFTER()—का उपयोग करके टेक्स्ट डेटा को मैनिपुलेट करना सीख लिया है। चाहे स्ट्रिंग के विशिष्ट हिस्से निकालने हों या अव्यवस्थित डेटा को साफ करना हो, ये फ़ंक्शंस आपका काम बहुत आसान और कुशल बना सकते हैं।

लेकिन Excel के साथ सीखने के लिए हमेशा और भी है। यदि आप अभी शुरुआत कर रहे हैं, तो Introduction to Excel कोर्स अगला उत्तम कदम है। यदि आप डेटा विश्लेषण के बारे में अधिक सीखना चाहते हैं, तो Data Analysis in Excel कोर्स आज़माएँ, जो हमारे Data Manipulation in Excel Cheat Sheet के साथ अच्छा मेल खाता है। ये आपको मजबूत नींव बनाने और अपने कौशल को अगले स्तर पर ले जाने में मदद करेंगे।