Excel TEXT() İşlevi: Sayıları Okunabilir Metin Olarak Biçimlendirme

Excel’deki TEXT() işlevi, sayısal verileri okunabilir ve iyi sunulmuş metin dizelerine biçimlendirmek için güçlü bir araçtır. Tarihler, para birimi, yüzdeler veya özel sayı biçimleriyle çalışıyor olun, TEXT() işlevi bu değerlerin tam olarak nasıl görüneceğini kontrol etmenizi sağlar. 

Excel, yerleşik hücre biçimlendirme seçenekleri sunsa da bunlar yalnızca değerin hücrede nasıl göründüğünü etkiler. TEXT() işlevi; özel mesajlar, dinamik etiketler veya birleştirilmiş hücre çıktıları gibi daha büyük metin dizelerine biçimlendirilmiş değerler yerleştirmeniz gerektiğinde kullanışlıdır. Bu eğitimde, Excel TEXT() işlevinin farklı kullanım alanlarını gösterecek ve pratik örneklerle yaygın hataları nasıl gidereceğinizi anlatacağım.

Bazı temel kavramlara aşina değilseniz, sağlam bir Excel temeli oluşturmak için Introduction to Excel kursumuzu almanızı öneririm. Ham veriyi dönüştürme hakkında daha fazla bilgi edinmek için Data Preparation in Excel kursumuza da göz atmalısınız.

Excel TEXT() İşlevi Ne Yapar

Excel’deki TEXT() işlevi, Excel’in sayı biçimlendirme kodlarını kullanarak bir sayısal değeri belirtilen bir biçimi izleyen bir metin dizisine dönüştürür. Bu nedenle, TEXT() işlevinin temel kullanım amacı ham sayıları insan dostu, biçimlendirilmiş metne dönüştürmektir; böylece verilerinizi okumayı ve yorumlamayı kolaylaştırır.

TEXT() işlevinin diğer yaygın kullanım alanları şunlardır:

• Sayıları para birimi sembolleri veya binlik ayraçlarıyla görüntüleme
• Okunabilir tarih veya saat gösterme
• Sabit uzunluklu kodlara başına sıfır ekleme
• Telefon numarası veya bilimsel gösterim gibi biçimlendirilmiş çıktılar oluşturma

Yukarıdaki kullanım alanlarını sonraki bölümlerde pratik örneklerle göstereceğim.

Excel TEXT() İşlevi Nasıl Kullanılır

Excel TEXT() işlevinin nasıl kullanılacağını anlamak için sözdizimini ve uygulayabileceğiniz biçim kodu türlerinin örneklerini inceleyelim.

Formülün yapısı

Excel TEXT() işlevi, sayısal bir girdiyi biçimlendirilmiş bir metin dizesine dönüştürmek için iki temel bağımsız değişken kullanır:

=TEXT(value, format_text)

Burada:

• value: Biçimlendirmek istediğiniz sayısal girdi. Bir sayı, sayı içeren bir hücre başvurusu, bir tarih veya sayısal değer döndüren bir formül olabilir.

• format_text: Uygulamak istediğiniz biçimi belirten ve her zaman çift tırnak içine alınan bir metin dizesi. 

Biçim kodu türleri ve örnekler

TEXT() işlevinde yaygın Excel biçim kodlarını ve uygulamalarını aşağıdaki tablo özetler.

Excel’in Format Cells iletişim kutusunu açmak, yukarıda listelenen biçim kodlarının çoğunu kolayca bulup yeniden kullanmanızı sağlar. 

• Bir hücre seçin ve Ctrl+1 (Mac’te Cmd+1) tuşlarına basarak Format Cells penceresini açın. 
• Number sekmesinde Number, Date, Custom veya Special gibi bir kategori seçin.
• Type alanında görünen biçim kodunu kopyalayın. Uygulamak için OK tıklayın.

TEXT() İşlevini Tarih ve Saatlerle Kullanma

Excel tarih ve saatleri sayılar olarak depolar; ancak bunları metin içinde net bir şekilde sunmak istediğinizde, TEXT() işlevi görünümlerini hassas biçimde kontrol etmenizi sağlar.

TEXT() işlevini TODAY() ve NOW() ile kullanma

TEXT() işlevi, Excel’in TODAY() ve NOW() işlevlerinin döndürdüğü dinamik tarih ve saat değerlerini biçimlendirmek için kullanışlıdır. 

Örneğin, aşağıdaki formül geçerli tarihi "May 1, 2025" gibi tam metin biçimine dönüştürür.

=TEXT(TODAY(), "mmmm d, yyyy")

Aşağıdaki formül, geçerli saati AM/PM ile 12 saatlik biçimde göstermek için NOW() işlevinin saat kısmını alır.

=TEXT(NOW(), "hh:mm AM/PM")

Tarih/saat değerlerini etiketlerle birleştirme

Biçimlendirilmiş tarih veya saatleri bir cümleye ya da etikete gömmek için de TEXT() işlevini kullanabilirsiniz. Örneğin, aşağıdaki işlev "Report generated on: 05/01/25" çıktısını üretir.

="Report generated on: " & TEXT(TODAY(), "MM/DD/YY")

Dikkat: Bir tarih veya saati TEXT() işlevi olmadan doğrudan birleştirirseniz, Excel okunabilir bir tarih yerine altta yatan seri numarasını görüntüler. 

TEXT() işlevini yüzdeler, para birimi ve kesirlerle kullanma

Excel’de TEXT() işlevi, yüzdeleri, para birimi değerlerini ve kesirleri günlük analiz ve görevler için biçimlendirmede özellikle kullanışlıdır. Bu farklı türdeki sayısal verileri şöyle dönüştürebilirsiniz:

Yüzdeler için TEXT() işlevi ondalık değeri 100 ile çarpar ve yüzde simgesi ekler. Örneğin, aşağıdaki formül 0,275 değerini bir ondalık basamak hassasiyetle "27.5%" olarak dönüştürür.

=TEXT(0.275, "0.0%")

Para birimiyle çalışırken, tutarları uygun sembol, binlik ayraçları ve ondalık basamaklarla biçimlendirebilirsiniz. Örneğin, aşağıdaki işlev "1234.56" değerini dolar simgesi, binlik ayraç ve iki ondalıkla "$1,234.56" olarak gösterir.

=TEXT(1234.56, "$#,##0.00")

Kesirlerde, TEXT() işlevi ondalık değerleri kesir gösterimine dönüştürebilir. Aşağıdaki işlev, ”4.5” değerini, tam sayı ve kesir bileşenleriyle bir bileşik sayı olarak ”4 ½” şeklinde gösterir.

=TEXT(4.5, "# ?/?")

Pratik Uygulamalar ve Kombinasyonlar

TEXT() işlevinin gerçek gücü, onu metin ve diğer işlevlerle birleştirerek özenli çıktılar ürettiğinizde ortaya çıkar. Aşağıdaki örneklere bakalım.

Mesajların içine değer gömme

& veya CONCAT() işlevini kullanarak biçimlendirilmiş sayıları doğrudan mesajların içine dahil edebilirsiniz. Örneğin, A2’deki fiyat 2500 ise, aşağıdaki işlev "Final Price: $2,500.00" görüntüler.

="Final Price: $" & TEXT(A2, "#,##0.00")

Başına sıfır ekleme

TEXT() işlevini, kodları, kimlikleri veya posta kodlarını başına sıfır ekleyerek standartlaştırmak için de kullanabilirsiniz. Örneğin, A2’de 4567 kodu varsa, aşağıdaki işlev "000004567" görüntüler.

=TEXT(A2, "000000000")

Telefon numaralarını biçimlendirme

Telefon numaraları daha iyi okunabilirlik için belirli bir biçimlendirme gerektirdiğinden, bunları dönüştürmek için TEXT() işlevini kullanabilirsiniz. Örneğin, A2 1234567890 içeriyorsa, aşağıdaki formül bunu ”(123) 456-7890” olarak gösterir.

=TEXT(A2, "(###) ###-####")

İleri Düzey Örnekler ve İpuçları

TEXT() işlevi, daha karmaşık formüllerde ve dinamik raporlarda da netliği ve etkileşimi artırmak için kullanılabilir. Aşağıdakiler gelişmiş uygulamalarına bazı örneklerdir.

IF() veya IFS() formüllerinin içinde kullanma

TEXT() işlevini, IF() veya IFS() gibi mantıksal işlevlerle birleştirerek sayısal değerlere bağlı koşullu mesajlar üretebilirsiniz. Örneğin, aşağıdaki formül A2 değerine bağlı olarak "Profit: $250.00" veya "Loss: $250.00" görüntüler.

=IFS(A2 > 0, "Profit: " & TEXT(A2, "$0.00"), A2 < 0, "Loss: " & TEXT(ABS(A2), "$0.00"))

Dizi formülleri veya dinamik raporlarla kullanma

TEXT() işlevi, ay bazında gruplama veya sıralama gibi dizi formülleri ya da dinamik raporlar içinde değerleri dinamik olarak biçimlendirmenize olanak tanır. Örneğin, aşağıdaki formül bir tarihten ay ve günü çıkarır ve biçimlendirir; böylece yıldan bağımsız olarak doğum günlerini veya olayları sıralamak ya da analiz etmek kolaylaşır.

=TEXT(A2, "mm-dd")

Bölgeye özgü davranış

TEXT() biçim kodlarının yerel ayarlara göre değişebileceğini bilmelisiniz. Örneğin, ABD dışında birçok bölgede "dd/mm/yyyy" tarih biçimi standartken, ABD’de "mm/dd/yyyy" tipiktir. Bölgeniz için yanlış biçim kodunu kullanmak hatalara veya beklenmedik sonuçlara neden olabilir. Uluslararası ekiplerle veya paylaşılan e-tablolarla çalışıyorsanız, bölgesel ayarların biçimlendirme sonuçlarınızı nasıl etkileyebileceğini her zaman iki kez kontrol edin.

TEXT() İşlevi Sorunlarını Giderme

Excel TEXT() işlevini kullanırken hatalarla karşılaşabilirsiniz. Bu sorunlardan bazılarını ve nasıl gidereceğinizi inceleyelim.

Yaygın hatalar

TEXT() işlevindeki yaygın hatalar şunları içerir:

• #NAME?: Bu hata, biçim dizesindeki tırnak işaretleri eksik olduğunda oluşur. Örneğin, =TEXT(A1, mm/dd/yyyy) yerine =TEXT(A1, "mm/dd/yyyy") yazmanız gerekir.

• #VALUE!: Bu sorun, biçim kodu geçersiz, yanlış yapılandırılmış veya bölgenizde desteklenmiyor olduğunda ortaya çıkar.

En iyi uygulamalar

Excel’de TEXT() işlevini kullanırken bu tuzaklardan kaçınmak için aşağıdaki en iyi uygulamaları dikkate alın.

• Orijinal değerleri ayrı tutun: TEXT() sayıları metne dönüştürdüğünden, sonuç daha ileri hesaplamalarda kullanılamaz. Hesaplamalar için orijinal sayısal değerleri ayrı hücrelerde veya sütunlarda saklayın ve TEXT() işlevini yalnızca görüntüleme veya raporlama amacıyla kullanın

• Yalnızca gerektiğinde biçimlendirin: TEXT() işlevini, etiketlerde, raporlarda veya birleştirilmiş dizelerde biçimlendirilmiş değerlere ihtiyaç duyduğunuzda uygulayın; hesaplamalar veya veri analizi için kullanmayın.

Excel’deki Diğer Yararlı Metin İşlevleri

TEXT() işlevine ek olarak, Excel metinsel verileri düzenlemeye, temizlemeye ve birleştirmeye yardımcı olan çeşitli metin işlevleri sunar. Aşağıda bu işlevler ve kullanım alanları yer almaktadır:

• VALUE(): Bir sayıya benzeyen metin dizesini tekrar sayısal bir değere dönüştürür. Örneğin, =VALUE("123.45") işlevi 123.45 değerini sayı olarak görüntüler.

• LEFT(), RIGHT(), MID(): Bu işlevler, metin dizelerinin bölümlerini çıkarmanıza olanak tanır. Örneğin, =LEFT(A1, 4) ilk 4 karakteri çıkarır ve =RIGHT(A1, 3) son 3 karakteri çıkarır. =MID(A1, 2, 5) 2. pozisyondan başlayarak 5 karakter çıkarır.

• CONCAT(), TEXTJOIN(): Bu işlevler, birden çok hücredeki metni birleştirmenizi sağlar. CONCAT() iki veya daha fazla metin dizesini tek bir dizede birleştirirken, TEXTJOIN() her bir öğe arasında belirtilen bir ayraç kullanarak metni bir araya getirir.

• TRIM(), SUBSTITUTE(), REPLACE(): Bu işlevler metin verilerini temizlemeye ve değiştirmeye yardımcı olur. TRIM() işlevi metinden fazladan boşlukları kaldırırken SUBSTITUTE() bir dize içindeki belirli metni değiştirir. REPLACE() işlevi ise belirli bir konumdaki metni değiştirir.

Sonuç

Gördüğünüz gibi ve umarım artık takdir edip kullanacağınız üzere, TEXT() işlevi önemlidir; çünkü biçimlendirilmiş değerleri dinamik etiketlere, raporlara, şablonlara ve diğerlerine yerleştirebilir ve en önemlisi verilerinizin tam olarak istediğiniz gibi görünmesini sağlar. Tamamen kozmetiktir, ancak büyük fark yaratır. Bununla birlikte, hesaplamalar ve analiz için, doğruluğu ve esnekliği korumak amacıyla orijinal sayısal değerleri e-tablonun başka bir yerinde sağlam tutmanın ve kozmetik kısmı yalnızca nihai sonuca uygulamanın en iyisi olduğunu özellikle vurgulamak isterim.

Bir sonraki adım olarak, becerilerinizi geliştirmeye devam etmek için Data Analysis in Excel kursumuzu ve en yeni Excel sürümlerinde mevcut farklı işlevlerin tümünü kapsayan Excel Fundamentals yetkinlik yolumuzu öneririm.