Cách so sánh hai cột trong Excel: Hướng dẫn từng bước

Cách so sánh hai cột trong Excel để tìm giá trị khớp

Khi làm việc với dữ liệu, bạn thường cần so sánh hai cột để xác định các giá trị khớp. Excel cung cấp nhiều phương pháp, mỗi phương pháp có ưu điểm riêng tùy theo độ phức tạp của dữ liệu bạn có.

So sánh hai cột bằng toán tử bằng

Một cách trực tiếp để so sánh hai cột trong Excel là dùng toán tử bằng =. Toán tử này kiểm tra trực tiếp xem giá trị ở hai ô có giống nhau hay không. Ví dụ, tôi có hai cột—Cột A và Cột B. Tôi cũng thêm cột thứ ba và nhập công thức sau để kiểm tra liệu cả hai giá trị có giống nhau không.

=A2=B2

Nhập công thức Equal vào một ô. Hình minh họa của Tác giả.

Toán tử = so sánh nội dung của hai ô và trả về TRUE nếu chúng giống hệt nhau và FALSE nếu không.

Kiểm tra hai cột có bằng nhau. Hình minh họa của Tác giả.

Bạn có thể dùng phương pháp này khi cần cách so sánh nhanh, đơn giản giữa hai cột để xác minh các bản ghi có khớp nhau hay không, như khi so sánh danh sách tên hoặc mã sản phẩm.

So sánh hai cột bằng hàm IF()

Vì toán tử = chỉ cho kết quả mặc định TRUE hoặc FALSE, nên không lý tưởng cho mọi nhu cầu, chẳng hạn khi bạn muốn tạo nội dung xuất tuỳ chỉnh. Nếu cần kết quả tuỳ chỉnh, bạn có thể dùng hàm IF(). Đây là cùng một ví dụ nhưng lần này tôi dùng hàm IF():

=IF(A2=B2, "Found", "Not Found")

Nhập công thức IF() vào ô. Hình minh họa của Tác giả.

Tôi đã tuỳ chỉnh nội dung xuất theo ý mình. Tôi ghi Found và Not Found nhưng bạn có thể dùng bất cứ nhãn nào.

Tuỳ chỉnh thông điệp bằng hàm IF(). Hình minh họa của Tác giả.

So sánh hai cột bằng hàm EXACT()

Hàm EXACT() so sánh hai giá trị theo cách phân biệt chữ hoa/thường, hữu ích khi bạn cần phân biệt giữa chữ hoa và chữ thường.Ví dụ, tôi có hai cột, Cột A và Cột B, và cột thứ ba gọi là Kết quả, nơi tôi nhập công thức sau:

=EXACT(A2,B2)

Nhập công thức EXACT() vào ô. Hình minh họa của Tác giả.

Bạn có thể thấy tôi đã viết Apple và Cherry với hai kiểu chữ khác nhau, và khi áp dụng công thức, nó hiển thị FALSE mặc dù tên giống nhau. Lý do là vì đây là công thức phân biệt chữ hoa/thường, nên nó phân biệt giữa chữ hoa và chữ thường.

So sánh giá trị phân biệt hoa/thường với hàm Exact(). Hình minh họa của Tác giả.

Nếu bạn muốn thay TRUE hoặc FALSE bằng thông điệp tuỳ chỉnh, hãy bọc công thức trong hàm IF() như tôi làm dưới đây.

=IF(EXACT(A2,B2),"Match","Mismatch")

Để tuỳ chỉnh thông điệp, kết hợp IF() với EXACT(). Hình minh họa của Tác giả.

Phương pháp này lý tưởng khi xác minh tên người dùng, mã sản phẩm, hoặc các chuỗi văn bản khác mà sự khác biệt giữa chữ hoa và chữ thường có thể dẫn đến kết quả khác nhau.

So sánh hai cột bằng tô màu có điều kiện

Conditional formatting là tính năng trong Excel cho phép bạn áp dụng các kiểu định dạng khác nhau cho ô dựa trên tiêu chí cụ thể. Để tô nổi bật các giá trị trùng lặp trong một cột, hãy làm theo các bước sau:

• Chọn phạm vi ô nơi bạn muốn xác định các mục trùng lặp.
• Tiếp theo, vào Home > Styles > Conditional Formatting > Highlight Cells Rules > Duplicate Values.

Chọn tuỳ chọn giá trị trùng lặp. Hình minh họa của Tác giả

• Khi hộp thoại xuất hiện, bạn sẽ thấy định dạng light red filled with dark red được chọn sẵn. Nhấn OK.

Minh họa hộp thoại với các giá trị trùng lặp. Hình minh họa của Tác giả.

Lưu ý: Nếu bạn thích định dạng khác, có thể chọn các định dạng dựng sẵn khác trong menu thả xuống. Và nếu muốn giao diện hoàn toàn khác, chọn Custom Format... ở cuối menu và chọn màu tô và màu phông chữ mong muốn. Nhấn OK khi hoàn tất.

Tô nổi bật giá trị trùng lặp bằng Conditional Formatting. Hình minh họa của Tác giả.

• Tương tự, chọn Unique từ menu thả xuống để tô nổi bật giá trị duy nhất thay vì Duplicate.

Tô nổi bật giá trị duy nhất. Hình minh họa của Tác giả.

Để tìm hiểu sâu hơn về các kỹ thuật tô nổi bật trực quan, xem hướng dẫn cách tô nổi bật bản sao trong Excel, trong đó bao gồm các quy tắc định dạng có điều kiện bổ sung và cách tiếp cận Power Query cho bộ dữ liệu lớn.

So sánh hai cột bằng hàm VLOOKUP()

Bạn cũng có thể dùng hàm VLOOKUP() để so sánh các cột trong Excel. Ví dụ, tôi có cùng bộ dữ liệu như ví dụ hàm IF(), nhưng ở đây, tôi nhập công thức sau:

=VLOOKUP(A2, $B$2:$B$10, 1, FALSE)

Dùng VLOOKUP() để so sánh giá trị. Hình minh họa của Tác giả.

Nếu so sánh của bạn xuất hiện lỗi như trong hình trên, hãy bọc công thức trong hàm IFERROR() để xử lý.

=IFERROR(VLOOKUP(A2, $B$2:$B$10, 1, FALSE), "Not Matched")

Hoạt động như sau:

• Nó tìm giá trị ở ô A2 trong phạm vi $B$2:$B10.

• Nếu tìm thấy khớp chính xác, VLOOKUP() trả về giá trị khớp.

• Nếu không tìm thấy, IFERROR() sẽ trả về Not Matched thay vì lỗi.

Xử lý lỗi bằng IFERROR() với VLOOKUP(). Hình minh họa của Tác giả.

So sánh hai cột bằng XLOOKUP() (Excel 365)

Nếu bạn dùng Excel 365 hoặc Excel 2021, XLOOKUP() là lựa chọn linh hoạt hơn VLOOKUP() cho việc so sánh cột. Khác với VLOOKUP(), nó tìm kiếm theo mọi hướng, không cần số chỉ mục cột và xử lý giá trị thiếu bằng phương án dự phòng tích hợp—không cần bọc trong IFERROR().

=XLOOKUP(A2, $B$2:$B$10, $B$2:$B$10, "Not Found")

Các đối số hoạt động như sau:

• A2 — giá trị dò (mục từ Cột A cần tìm trong Cột B)
• $B$2:$B$10 (lần 1) — mảng dò (nơi tìm)
• $B$2:$B$10 (lần 2) — mảng trả về (trả gì khi tìm thấy)
• "Not Found" — giá trị trả về khi không có khớp (thay cho IFERROR())

Công thức trả về giá trị khớp từ Cột B nếu tìm thấy, hoặc “Not Found” khi không có khớp. Với người dùng Excel 2019 hoặc cũ hơn, hãy dùng cách VLOOKUP() như trên. Để hiểu khi nào nên chọn cái nào, xem so sánh XLOOKUP vs. VLOOKUP.

So sánh hai cột bằng công thức mảng

Công thức mảng có thể xử lý nhiều giá trị cùng lúc. Thay vì hoạt động trên một giá trị, chúng xử lý một phạm vi dữ liệu, giúp các phép tính phức tạp hiệu quả hơn. Để dùng công thức mảng, gõ vào ô và nhấn Ctrl+Shift+Enter.

Ví dụ, tôi có hai cột—Cột A và Cột B. Giờ tôi muốn xác định xem có giá trị khớp giữa hai cột này không.

Cột A và Cột B chứa dữ liệu. Hình minh họa của Tác giả.

Với mục đích này, tôi sẽ dùng công thức sau:

=SUM(--(A2=B2))

Cụ thể:

• Hàm SUM() cộng các giá trị trong mảng. Nếu có ít nhất một giá trị khớp, tổng sẽ lớn hơn 0. Nếu không, sẽ là 0.
• Toán tử hai dấu trừ (-- ) chuyển các giá trị TRUE và FALSE thành 1 và 0, tạo thành một mảng gồm các số 1 và 0.

So sánh cột bằng công thức SUM(). Hình minh họa của Tác giả.

Giờ tôi muốn hiển thị thông điệp tuỳ chỉnh thay cho 0 và 1, nên tôi bọc hàm SUM() trong hàm IF().

=IF(SUM(--(A2=B2))=0, "No match", "Match")

Hàm IF() kiểm tra xem tổng có bằng 0 hay không. Nếu có, trả về No match. Ngược lại, trả về Match.

Công thức SUM() bên trong IF(). Hình minh họa của Tác giả.

Vậy là xong. Với công thức mảng, bạn có thể thực hiện hiệu quả các phép so sánh phức tạp tương tự.

Cách so sánh hai cột trong Excel để tìm giá trị trùng lặp

Giờ bạn đã biết cách so sánh cột để tìm giá trị khớp, nhưng có những tình huống bạn cũng phải xác định trùng lặp. Nói rõ hơn, khớp đề cập đến các giá trị tương ứng ở các cột khác nhau nhưng cùng một hàng. Còn trùng lặp cụ thể là các giá trị xuất hiện một hoặc nhiều lần trên cả hai cột nhưng ở các hàng khác nhau.

So sánh hai cột bằng IF() và MATCH()

Hàm IF() hoặc MATCH() riêng lẻ không thể thực hiện tra cứu để xác định trùng lặp. Nhưng nếu dùng cùng nhau, chúng ta có thể xác định trùng lặp. Ví dụ, tôi có bộ dữ liệu tên các tháng được sắp ở Cột A và Cột B. Sau đó tôi tạo thêm cột để lấy kết quả. Tôi gõ công thức MATCH() sau vào ô đầu tiên và kéo đến ô cuối cùng để kiểm tra các giá trị trùng trong phạm vi dữ liệu.

=MATCH(A2,$B$2:$B$7,0)

Dùng MATCH() để tìm trùng lặp. Hình minh họa của Tác giả.

Bạn có thể thấy nếu giá trị bị trùng—MATCH() trả về vị trí của giá trị từ cột thứ hai. Nếu không, nó trả về lỗi #N/A. Thay vì hiển thị lỗi #N/A hãy bọc công thức trong hàm ISERROR(). Khi đó sẽ hiển thị TRUE nếu có lỗi #N/A. Nếu không thì FALSE.

Xử lý lỗi bằng ISERROR(). Hình minh họa của Tác giả.

Tôi thích kết quả tuỳ chỉnh hơn là TRUE hoặc FALSE. Để có kết quả tuỳ chỉnh, bọc công thức trong hàm IF() như sau:

=IF(ISERROR(MATCH(A2,$B$2:$B$7,0)),"Unique","Duplicate")

Hiển thị giá trị trùng lặp bằng các hàm IF() và MATCH(). Hình minh họa của Tác giả.

So sánh hai cột bằng COUNTIF()

Bạn cũng có thể dùng hàm COUNTIF() để so sánh hai cột và xác định trùng lặp. Hàm này đếm số lần xuất hiện của một giá trị trong cột thứ hai và hiển thị 0 khi giá trị là duy nhất và 1 khi là trùng lặp. Xem công thức sau:

=COUNTIF($B$2:$B$7,$A2:$A7)

Dùng COUNTIF() để kiểm tra giá trị trùng lặp. Hình minh họa của Tác giả.

Nếu bạn muốn hiển thị thông điệp tuỳ chỉnh thay cho 0 và 1, hãy bọc COUNTIF() trong hàm IF().

=IF(COUNTIF($B$2:$B$7,$A2:$A7)=0,"Unique","Duplicate")

Dùng IF() để hiển thị thông điệp tuỳ chỉnh. Hình minh họa của Tác giả.

Chọn phương pháp so sánh phù hợp

Với nhiều phương pháp sẵn có, dưới đây là tham chiếu nhanh giúp bạn chọn cách phù hợp với tình huống của mình:

Kết luận

Đến đây, bạn đã nắm vững các phương pháp khác nhau để so sánh hai cột trong Excel, từ toán tử cơ bản = cho đến các kỹ thuật nâng cao như VLOOKUP() và công thức mảng. Mỗi phương pháp đều hữu ích, dù bạn cần so sánh nhanh hay đang thực hiện các tác vụ kiểm tra tính hợp lệ dữ liệu phức tạp. Các phương pháp này cũng hoạt động khi bạn cần so sánh để tìm giá trị khớp hoặc giá trị trùng lặp.

Nếu bạn muốn nâng cao kỹ năng hơn nữa, tôi khuyến khích bạn xem thêm các tài nguyên khác. Bắt đầu với khóa học Introduction to Excel để có nền tảng vững chắc. Sau đó, khám phá khóa Data Analysis in Excel để học cách biến dữ liệu thô thành báo cáo hữu ích.

Để cải thiện mức độ thành thạo, hãy cân nhắc hoàn thành lộ trình kỹ năng Excel Fundamentals, bao quát nhiều chức năng và tính năng thiết yếu. Và đừng quên tải về Excel Formulas Cheat Sheet—một tài liệu tham khảo tiện dụng luôn trong tầm tay.