Cách cộng ngày vào một ngày trong Excel: Mọi phương pháp được giải thích

Các phương pháp cộng ngày vào một ngày trong Excel

Trong phần này, tôi sẽ so sánh các cách tiếp cận phổ biến nhất, bắt đầu từ lựa chọn đơn giản và trực tiếp nhất.

Phương pháp 1: Số học đơn giản (Cộng hoặc trừ ngày trực tiếp)

Cách nhanh nhất để cộng ngày vào một ngày trong Excel là dùng số học cơ bản. Vì Excel lưu ngày tháng dưới dạng số, bạn có thể cộng hoặc trừ ngày giống như với bất kỳ giá trị số nào khác. Bạn có thể làm những điều sau bằng số học đơn giản:

Cộng ngày bằng công thức

Nếu ô A2 chứa một ngày, bạn có thể cộng ngày chỉ bằng cách cộng một số. Ví dụ, công thức dưới đây cộng bảy ngày dương lịch vào ngày trong A2 và trả về ngày mới.

=A2 + 7Được hỗ trợ bởi

Trừ ngày bằng số âm

Bạn cũng có thể trừ một số từ một ngày để tìm ngày trong quá khứ. Ví dụ, công thức dưới đây lùi ngày lại năm ngày.

=A2 - 5Được hỗ trợ bởi

Áp dụng công thức cho nhiều hàng

Để áp dụng cùng một logic cho một danh sách ngày:

• Nhập công thức ở hàng đầu tiên.
• Chọn ô đó.
• Kéo tay cầm điền xuống để sao chép công thức cho các hàng khác.

Excel tự động điều chỉnh tham chiếu ô, giúp phương pháp này hiệu quả cho bộ dữ liệu lớn.

Dùng Dán đặc biệt (Paste Special) để chỉnh nhanh

Nếu bạn không muốn dùng công thức, bạn có thể dùng Dán đặc biệt (Paste Special) theo các bước dưới đây:

• Gõ số ngày bạn muốn cộng vào một ô trống.
• Sao chép ô đó.
• Chọn các ô ngày bạn muốn điều chỉnh.
• Nhấp chuột phải và chọn Paste Special → Add. Excel sẽ cập nhật ngay tất cả các ngày đó và giữ chúng dưới dạng giá trị tĩnh thay vì công thức.

Hạn chế của phương pháp số học đơn giản là luôn tính mọi ngày dương lịch. Do đó, cuối tuần và ngày lễ vẫn được bao gồm, có thể không phù hợp cho mốc thời gian công việc, tiến độ dự án hoặc tính lương. Trong những trường hợp đó, bạn sẽ cần cách tiếp cận nâng cao hơn, tôi sẽ trình bày ở phần sau của hướng dẫn.

Phương pháp 2: Hàm DATE() cho phép tính có cấu trúc và điều kiện

Hàm DATE() hữu ích khi bạn cần kiểm soát nhiều hơn cách tạo hoặc điều chỉnh ngày. Điều này lý tưởng cho các phép tính có cấu trúc, logic điều kiện và các kịch bản ngày có thể thay đổi động. 

Cấu trúc và tham số của hàm DATE()

Dưới đây là cú pháp cơ bản của hàm DATE().

=DATE(year, month, day)Được hỗ trợ bởi

Trong đó:

• year: Giá trị năm
• month: Số tháng
• day: Ngày trong tháng

Vì vậy, bạn có thể tái tạo một ngày bằng cách tách các phần của nó. Ví dụ, công thức dưới đây cộng mười ngày vào ngày trong A2 bằng cách chỉ sửa phần ngày, giữ nguyên năm và tháng gốc.

=DATE(YEAR(A2), MONTH(A2), DAY(A2) + 10)
`Được hỗ trợ bởi

Xử lý ranh giới cuối tháng và cuối năm

Một điểm mạnh của hàm DATE() là tự động xử lý tràn. Ví dụ, nếu bạn cộng 5 ngày vào ngày 29 tháng 1, Excel sẽ biết kết quả là ngày 3 tháng 2.

Hàm DATE() cũng tự động xử lý năm nhuận. Ví dụ, nếu bạn cộng ngày vào các ngày trong tháng 2 của năm nhuận, hàm sẽ tính đúng ngày 29 tháng 2 mà không cần logic bổ sung.

Dùng tham chiếu ô để công thức linh hoạt

Thay vì mã cứng các giá trị, bạn có thể tham chiếu ô để công thức động và tái sử dụng qua nhiều hàng.

=DATE(YEAR(A2), MONTH(A2), DAY(A2) + B2)Được hỗ trợ bởi

Xử lý ngày trống hoặc không hợp lệ

Để tránh lỗi khi các ô nguồn trống hoặc chứa dữ liệu không hợp lệ, bạn có thể bọc công thức trong IF() hoặc IFERROR(). Những cách này giúp trang tính sạch sẽ và tránh thông báo lỗi không cần thiết.

Công thức dưới đây trả về ô trống nếu ô nguồn trống hoặc có giá trị không ở định dạng ngày.

=IFERROR(DATE(YEAR(A2), MONTH(A2), DAY(A2) + B2), "")Được hỗ trợ bởi

Phương pháp 3: Hàm EDATE() để cộng tháng và năm

Hàm EDATE() trong Excel quan trọng trong các phép tính ngày nếu bạn muốn điều chỉnh ngày theo trọn tháng hoặc năm.

Mục đích và cú pháp của EDATE()

Hàm EDATE() dịch chuyển một ngày theo số tháng chỉ định. Cú pháp như sau:

=EDATE(start_date, months)Được hỗ trợ bởi

Trong đó: 

• start_date: Ngày gốc

• months: Số tháng để cộng hoặc trừ

Công thức dưới đây cộng 3 tháng vào ngày hiện có:

=EDATE(A2, 3)Được hỗ trợ bởi

Tương tự, bạn có thể trừ 3 tháng với cùng logic nhưng dùng giá trị âm.

=EDATE(A2, -3)Được hỗ trợ bởi

Cộng và trừ năm bằng cách bù tháng

Bạn có thể cộng hoặc trừ năm bằng hàm EDATE() bằng cách dùng số tháng trong đối số month. Ví dụ, công thức dưới đây trừ 2 năm (24 tháng) khỏi ngày ở ô A2.

=EDATE(A2, -24)Được hỗ trợ bởi

Kết hợp EDATE() với số học đơn giản

Bạn cũng có thể kết hợp hàm EDATE() với tháng và ngày cho các trường hợp cụ thể. Ví dụ, công thức dưới đây cộng 2 tháng và thêm bảy ngày dương lịch vào ngày ở ô A2.

=EDATE(A2, 1) + 7Được hỗ trợ bởi

Phương pháp 4: WORKDAY() và WORKDAY.INTL() cho phép tính ngày làm việc

Các hàm WORKDAY() và WORKDAY.INTL() cho phép bạn cộng hoặc trừ ngày đồng thời tự động bỏ qua ngày không làm việc. Những hàm này lý tưởng cho mốc thời gian dự án, hạn chót và lịch vận hành.

Dùng hàm WORKDAY() để bỏ qua cuối tuần

Hàm WORKDAY() trong Excel được thiết kế để tự động bỏ qua Thứ Bảy và Chủ Nhật. Cú pháp như sau:

=WORKDAY(start_date, days)Được hỗ trợ bởi

Trong đó:

• start_date: Ngày bắt đầu

• days: Số ngày để cộng hoặc trừ

Ví dụ, công thức dưới đây cộng năm ngày làm việc vào ngày trong A2, tự động bỏ qua Thứ Bảy và Chủ Nhật.

=WORKDAY(A2, 5)Được hỗ trợ bởi

Bao gồm ngày lễ với danh sách ngày nghỉ

Giả sử bạn muốn cộng ngày trong Excel nhưng cũng tính đến ngày lễ và ngày nghỉ toàn công ty. Hãy làm theo các bước dưới đây để đảm bảo tính toán chính xác:

• Tạo danh sách ngày nghỉ lễ ở một phạm vi riêng như D2:D5.

• Thêm phạm vi này làm đối số thứ ba trong hàm WORKDAY().

=WORKDAY(A2, 5, D2:D5)Được hỗ trợ bởi

Với phương pháp này, mọi ngày được liệt kê trong phạm vi D2:D5 sẽ bị loại trừ khỏi phép tính, ngay cả khi rơi vào ngày trong tuần.

Thay vì mã cứng các ô ngày nghỉ, tốt nhất là giữ ngày lễ trong một cột hoặc bảng riêng. Theo thông lệ tốt, hãy luôn dùng vùng đã đặt tên hoặc một Bảng Excel. Cách này giúp công thức gọn gàng và đảm bảo mọi phép tính ngày làm việc nhất quán trong sổ làm việc.

Tôi khuyến nghị bạn học khóa Các hàm Excel nâng cao để tìm hiểu thêm về bù và phạm vi động trong Excel.

Mẫu cuối tuần tùy chỉnh với WORKDAY.INTL()

Vì không phải mọi lịch làm việc đều theo cuối tuần Thứ Bảy–Chủ Nhật, Excel cung cấp hàm WORKDAY.INTL(), cho phép bạn xác định mẫu cuối tuần tùy chỉnh. Cú pháp như sau:

=WORKDAY.INTL(start_date, days, weekend, holidays)Được hỗ trợ bởi

Trong đó:

• start_date: Ngày bắt đầu tính và không được tính là ngày làm việc.

• days: Số ngày làm việc để cộng hoặc trừ.

• weekend (tùy chọn): Xác định ngày nào là cuối tuần. Có thể là một số (1–17) đại diện cho các mẫu cuối tuần định sẵn [1 → Thứ Bảy và Chủ Nhật (mặc định), 2 → Chủ Nhật và Thứ Hai, 7 → Thứ Sáu và Thứ Bảy]. Cũng có thể là chuỗi 7 ký tự như "0000011" trong đó 1 đánh dấu ngày cuối tuần và 0 đánh dấu ngày làm việc, bắt đầu từ Thứ Hai.

• holidays (tùy chọn): Phạm vi hoặc mảng ngày cũng cần loại trừ khỏi ngày làm việc

Ví dụ, công thức dưới đây trả về ngày sau 10 ngày làm việc kể từ 15/01/2026, loại trừ Thứ Bảy, Chủ Nhật và các ngày lễ trong các ô D2:D5.

=WORKDAY.INTL("2026-01-15", 10, 1, D2:D5)Được hỗ trợ bởi

Các hàm liên quan: NETWORKDAYS() và NETWORKDAYS.INTL()

Trong khi WORKDAY() và WORKDAY.INTL() trả về một ngày, các hàm NETWORKDAYS() và NETWORKDAYS.INTL() đếm có bao nhiêu ngày làm việc rơi giữa hai ngày. Chúng hữu ích khi bạn cần đo thời lượng, không phải tính hạn chót.

Hàm NETWORKDAYS() đếm số ngày làm việc giữa hai ngày, loại trừ Thứ Bảy, Chủ Nhật và ngày lễ tùy chọn. Trong ví dụ dưới đây, công thức trả về 7, là số ngày làm việc giữa 1/1 và 10/1 (loại trừ cuối tuần).

=NETWORKDAYS("2026-01-01", "2026-01-10")Được hỗ trợ bởi

Tương tự, hàm NETWORKDAYS.INTL() đếm ngày làm việc với quy tắc cuối tuần tùy chỉnh, hữu ích cho các khu vực có cuối tuần không tiêu chuẩn. Ví dụ, công thức dưới đây trả về số ngày làm việc giả định Thứ Sáu–Thứ Bảy là cuối tuần.

=NETWORKDAYS.INTL("2026-01-01", "2026-01-10", 7)Được hỗ trợ bởi

Hạn chế cần lưu ý

Mặc dù các hàm WORKDAY() và WORKDAY.INTL() trong Excel hoạt động tốt cho lịch làm việc tiêu chuẩn, chúng có các hạn chế sau:

• Không xử lý ca kíp luân phiên hoặc ngày làm việc bán thời gian
• Không mô hình được lịch phức tạp với số giờ khác nhau mỗi ngày
• Lập lịch nâng cao có thể cần cột phụ trợ hoặc logic tùy chỉnh

Lưu ý về hệ thống ngày của Excel

Khi làm việc với ngày trong Excel, bạn có thể gặp một số kết quả bất ngờ, thường không xuất phát từ công thức đã dùng. Trong phần này, tôi sẽ giúp bạn hiểu những gì diễn ra phía sau và tránh các cạm bẫy thường gặp.

Excel lưu ngày dưới dạng số sê-ri

Excel lưu ngày tháng dưới dạng số sê-ri, trong đó mỗi số nguyên đại diện cho một ngày. Ví dụ, ngày 1 tháng 1 năm 1900 được lưu là 1, ngày 2 tháng 1 năm 1900 là 2, v.v. Vì ngày là giá trị số, bạn có thể cộng hoặc trừ ngày bằng số học đơn giản, đó là lý do các công thức ngày hoạt động rất tự nhiên trong Excel.

Ngày so với giá trị văn bản

Không phải mọi thứ trông giống ngày đều thực sự là ngày. Một ngày đúng trong Excel là một con số được áp định dạng ngày. Ngày ở dạng văn bản, thường nhập từ hệ thống bên ngoài, sẽ không hoạt động đúng trong phép tính. Công thức tham chiếu đến ngày văn bản có thể trả về lỗi hoặc kết quả sai.

Để kiểm tra sự không nhất quán này, hãy đổi định dạng ô thành General. Nếu bạn thấy một con số, đó là ngày thật; nếu giữ nguyên, đó là văn bản

Hệ thống ngày 1900 và 1904

Excel hỗ trợ hai hệ thống ngày: hệ thống 1900, mặc định trên Windows, và hệ thống 1904, trước đây dùng trên macOS.

Sự khác biệt giữa hai hệ thống này là 1.462 ngày. Vì vậy, điều quan trọng là xác nhận tất cả người dùng đang dùng cùng hệ thống ngày khi chia sẻ sổ làm việc có phép tính ngày để đảm bảo nhất quán.

Cách Excel xử lý năm nhuận

Excel tự động tính đến năm nhuận khi thực hiện phép tính ngày. Tuy nhiên, vì lý do tương thích, Excel coi 1900 là năm nhuận dù thực tế không phải. Điều chỉnh này có thể giải thích vì sao các ngày rất cũ có hành vi bất thường, nhưng không ảnh hưởng đáng kể đến quy trình làm việc hiện đại.

Vấn đề thường gặp với định dạng và cài đặt vùng

Theo kinh nghiệm làm việc với ngày trong Excel, tôi nhận thấy các vấn đề thường đến từ:

• Cài đặt vùng hiểu ngày khác nhau, như MM/DD/YYYY so với DD/MM/YYYY.
• Dữ liệu nhập vào có ngày được lưu dưới dạng văn bản
• Định dạng không nhất quán giữa các ô

Những vấn đề này có thể khiến công thức lỗi âm thầm hoặc trả về kết quả sai. Tôi sẽ chỉ bạn cách khắc phục những lỗi như vậy ở phần tiếp theo.

Khắc phục sự cố trong phép tính ngày

Như chúng ta đã thấy, không phải mọi lỗi trong phép tính ngày đều do công thức sai. Dưới đây là một số phương pháp để xử lý các vấn đề ngày tháng thường gặp trong Excel.

Xác định và chuyển đổi ngày dạng văn bản

Nếu một ngày được lưu dưới dạng văn bản, các hàm như WORKDAY() hoặc EDATE() sẽ không hoạt động. Bạn thường có thể chuyển ngày văn bản bằng cách nhập lại thủ công hoặc dùng DATEVALUE() khi định dạng văn bản có thể nhận diện.

Bạn cũng có thể dùng công cụ Text to Columns để sửa ngày nhập vào theo các bước dưới đây:

Chọn cột bị ảnh hưởng

Vào Data → Text to Columns

Chọn Delimited hoặc Fixed Width

Đặt kiểu dữ liệu cột là Date. Chọn Finish.

Vấn đề định dạng và số sê-ri

Nếu một ô hiển thị số thay vì ngày, giá trị thường đúng nhưng định dạng sai. Để khắc phục, vào thẻ Home, nhấp vào danh sách Number Format và chọn Short Date.

Xem thêm Bảng phím tắt Excel để học cách tăng năng suất với các phím tắt cho nhiều tính năng Excel.

Xử lý khoảng trắng thừa và dấu phân cách không chuẩn

Dữ liệu nhập vào có thể chứa khoảng trắng đầu dòng hoặc dấu phân cách lạ như " 01/21/2026". Bạn có thể dùng các hàm TRIM() hoặc SUBSTITUTE() để loại bỏ khoảng trắng trước khi thực hiện thao tác khác.

Sự nhập nhằng năm hai chữ số

Năm có hai chữ số có thể được hiểu khác nhau tùy cài đặt hệ thống. Excel thường coi 00–29 là các năm 2000 và 30–99 là các năm 1900. Để tránh vấn đề này, luôn dùng năm bốn chữ số như 2029 khi nhập hoặc nhập khẩu ngày.

Quản lý đầu vào hỗn hợp với cột phụ trợ

Nếu cột của bạn có lẫn ngày và ghi chú như “TBD”, phép tính sẽ hỏng. Để ngăn vấn đề này, hãy dùng các cột phụ trợ để làm sạch hoặc chuyển đổi giá trị, hoặc áp dụng hàm IFERROR() để bắt các mục không hợp lệ.

Phép tính ngày nâng cao và kịch bản động

Khi bạn đã quen với các hàm ngày cơ bản, Excel cho phép bạn xây dựng các phép tính linh hoạt và động hơn. Trong phần này, tôi sẽ chỉ bạn cách xây dựng các hàm ngày nâng cao để tự động hóa công việc.

Kết hợp bù năm, tháng và ngày

Bạn luôn có thể điều chỉnh nhiều phần của một ngày trong một công thức bằng cách kết hợp các hàm. Ví dụ, công thức dưới đây cộng một năm, hai tháng và mười ngày vào ngày gốc trong A2. Excel tự động xử lý mọi tràn qua tháng hoặc năm.

=DATE(YEAR(A2) + 1, MONTH(A2) + 2, DAY(A2) + 10)Được hỗ trợ bởi

Năm tài chính và logic phi dương lịch

Không phải tổ chức nào cũng theo lịch tháng 1 đến tháng 12. Bạn có thể tính năm tài chính bằng cách điều chỉnh tháng trước khi trích xuất năm. Ví dụ, nếu năm tài chính bắt đầu từ tháng 4, bạn có thể tính “Năm tài chính” từ một ngày chuẩn bằng logic dưới đây để lùi ngày lại 3 tháng:

=YEAR(EDATE(A2, -3))Được hỗ trợ bởi

Ngày động với TODAY() và NOW()

Nếu bạn xử lý các phép tính cần cập nhật tự động mỗi ngày, bạn có thể dùng các hàm sau:

• =TODAY(): Trả về ngày hiện tại.

• =NOW(): Trả về ngày hiện tại và thời gian chính xác.

Tạo dải ngày với SEQUENCE()

Bạn có thể dùng hàm SEQUENCE() nếu cần nhanh chóng tạo danh sách ngày liên tiếp. Ví dụ, =SEQUENCE(30, 1, TODAY(), 1) tạo danh sách 30 ngày bắt đầu từ hôm nay.

Tô sáng ngày bằng định dạng có điều kiện

Nếu bạn muốn làm nổi bật các ngày quan trọng trong bảng tính, bạn có thể dùng định dạng có điều kiện. Ví dụ, bạn có thể áp dụng định dạng để làm nổi bật hạn chót sắp tới, gắn cờ công việc quá hạn hoặc tách biệt trực quan ngày quá khứ và tương lai.

Tôi khuyến nghị xem khóa học Định dạng có điều kiện trong Google Sheets để học cách áp dụng định dạng có điều kiện nhằm xác thực dữ liệu và rút ra thông tin nhanh.

Kết luận

Excel cung cấp nhiều cách để thêm và quản lý ngày, và việc chọn phương pháp phù hợp phụ thuộc vào trường hợp sử dụng. Để duy trì sổ làm việc hiệu quả, hãy dùng số học đơn giản cho ngày dương lịch, EDATE() cho chu kỳ theo tháng và WORKDAY() cho lịch làm việc, đồng thời luôn xác minh rằng ngày của bạn được lưu dưới dạng số sê-ri thực thay vì văn bản.

Nếu bạn muốn nâng cao kỹ năng Excel, tôi khuyến nghị học khóa Phân tích dữ liệu trong Excel. Khóa học này sẽ giúp bạn làm chủ phân tích nâng cao và thúc đẩy sự nghiệp. Tôi cũng khuyến nghị học khóa Power Query trung cấp trong Excel để tìm hiểu về biến đổi dữ liệu và dùng ngôn ngữ M để tạo hàm động.